1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
|
package FS::part_export;
use strict;
use vars qw( @ISA );
use FS::Record qw( qsearch qsearchs dbh );
use FS::part_svc;
use FS::part_export_option;
@ISA = qw(FS::Record);
=head1 NAME
FS::part_export - Object methods for part_export records
=head1 SYNOPSIS
use FS::part_export;
$record = new FS::part_export \%hash;
$record = new FS::part_export { 'column' => 'value' };
($new_record, $options) = $template_recored->clone( $svcpart );
$error = $record->insert( { 'option' => 'value' } );
$error = $record->insert( \$options );
$error = $new_record->replace($old_record);
$error = $record->delete;
$error = $record->check;
=head1 DESCRIPTION
An FS::part_export object represents an export of Freeside data to an external
provisioning system. FS::part_export inherits from FS::Record. The following
fields are currently supported:
=over 4
=item exportnum - primary key
=item svcpart - Service definition (see L<FS::part_svc>) to which this export applies
=item machine - Machine name
=item exporttype - Export type
=item nodomain - blank or "Y" : usernames are exported to this service with no domain
=back
=head1 METHODS
=over 4
=item new HASHREF
Creates a new export. To add the export to the database, see L<"insert">.
Note that this stores the hash reference, not a distinct copy of the hash it
points to. You can ask the object for a copy with the I<hash> method.
=cut
# the new method can be inherited from FS::Record, if a table method is defined
sub table { 'part_export'; }
=item clone SVCPART
An alternate constructor. Creates a new export by duplicating an existing
export. The given svcpart is assigned to the new export.
Returns a list consisting of the new export object and a hashref of options.
=cut
sub clone {
my $self = shift;
my $class = ref($self);
my %hash = $self->hash;
$hash{'exportnum'} = '';
$hash{'svcpart'} = shift;
( $class->new( \%hash ),
{ map { $_->optionname => $_->optionvalue }
qsearch('part_export_option', { 'exportnum' => $self->exportnum } )
}
);
}
=item insert HASHREF
Adds this record to the database. If there is an error, returns the error,
otherwise returns false.
If a hash reference of options is supplied, part_export_option records are
created (see L<FS::part_export_option>).
=cut
#false laziness w/queue.pm
sub insert {
my $self = shift;
local $SIG{HUP} = 'IGNORE';
local $SIG{INT} = 'IGNORE';
local $SIG{QUIT} = 'IGNORE';
local $SIG{TERM} = 'IGNORE';
local $SIG{TSTP} = 'IGNORE';
local $SIG{PIPE} = 'IGNORE';
my $oldAutoCommit = $FS::UID::AutoCommit;
local $FS::UID::AutoCommit = 0;
my $dbh = dbh;
my $error = $self->SUPER::insert;
if ( $error ) {
$dbh->rollback if $oldAutoCommit;
return $error;
}
my $options = shift;
foreach my $optionname ( keys %{$options} ) {
my $part_export_option = new FS::part_export_option ( {
'optionname' => $optionname,
'optionvalue' => $options->{$optionname},
} );
$error = $part_export_option->insert;
if ( $error ) {
$dbh->rollback if $oldAutoCommit;
return $error;
}
}
$dbh->commit or die $dbh->errstr if $oldAutoCommit;
'';
};
=item delete
Delete this record from the database.
=cut
# the delete method can be inherited from FS::Record
=item replace OLD_RECORD
Replaces the OLD_RECORD with this one in the database. If there is an error,
returns the error, otherwise returns false.
=cut
# the replace method can be inherited from FS::Record
=item check
Checks all fields to make sure this is a valid export. If there is
an error, returns the error, otherwise returns false. Called by the insert
and replace methods.
=cut
sub check {
my $self = shift;
my $error =
$self->ut_numbern('exportnum')
|| $self->ut_number('svcpart')
|| $self->ut_alpha('exporttype')
;
return $error if $error;
return "Unknown svcpart: ". $self->svcpart
unless qsearchs( 'part_svc', { 'svcpart' => $self->svcpart } );
$self->machine =~ /^([\w\-\.]*)$/
or return "Illegal machine: ". $self->machine;
$self->machine($1);
$self->nodomain =~ /^(Y?)$/ or return "Illegal nodomain: ". $self->nodomain;
$self->nodomain($1);
#check exporttype?
''; #no error
}
=item part_svc
Returns the service definition (see L<FS::part_svc>) for this export.
=cut
sub part_svc {
my $self = shift;
qsearchs('part_svc', { svcpart => $self->svcpart } );
}
=back
=head1 BUGS
Probably.
=head1 SEE ALSO
L<FS::part_export_option>, L<FS::part_svc>, L<FS::svc_acct>, L<FS::svc_domain>,
L<FS::svc_forward>, L<FS::Record>, schema.html from the base documentation.
=cut
1;
|
