--- /dev/null
+package FS::svc_acct;
+
+use strict;
+use vars qw(@ISA @EXPORT_OK $nossh_hack $conf $dir_prefix @shells
+ $shellmachine @saltset @pw_set);
+use Exporter;
+use FS::Conf;
+use FS::Record qw(fields qsearchs);
+use FS::SSH qw(ssh);
+use FS::cust_svc;
+
+@ISA = qw(FS::Record Exporter);
+@EXPORT_OK = qw(fields);
+
+$conf = new FS::Conf;
+$dir_prefix = $conf->config('home');
+@shells = $conf->config('shells');
+$shellmachine = $conf->config('shellmachine');
+
+@saltset = ( 'a'..'z' , 'A'..'Z' , '0'..'9' , '.' , '/' );
+@pw_set = ( 'a'..'z', 'A'..'Z', '0'..'9', '(', ')', '#', '!', '.', ',' );
+
+#not needed in 5.004 #srand($$|time);
+
+=head1 NAME
+
+FS::svc_acct - Object methods for svc_acct records
+
+=head1 SYNOPSIS
+
+ use FS::svc_acct;
+
+ $record = create FS::svc_acct \%hash;
+ $record = create FS::svc_acct { 'column' => 'value' };
+
+ $error = $record->insert;
+
+ $error = $new_record->replace($old_record);
+
+ $error = $record->delete;
+
+ $error = $record->check;
+
+ $error = $record->suspend;
+
+ $error = $record->unsuspend;
+
+ $error = $record->cancel;
+
+=head1 DESCRIPTION
+
+An FS::svc_acct object represents an account. FS::svc_acct inherits from
+FS::Record. The following fields are currently supported:
+
+=over 4
+
+=item svcnum - primary key (assigned automatcially for new accounts)
+
+=item username
+
+=item _password - generated if blank
+
+=item popnum - Point of presence (see L<FS::svc_acct_pop>)
+
+=item uid
+
+=item gid
+
+=item finger - GECOS
+
+=item dir - set automatically if blank (and uid is not)
+
+=item shell
+
+=item quota - (unimplementd)
+
+=item slipip - IP address
+
+=item radius_I<Radius_Attribute> - I<Radius-Attribute>
+
+=back
+
+=head1 METHODS
+
+=over 4
+
+=item create HASHREF
+
+Creates a new account. To add the account to the database, see L<"insert">.
+
+=cut
+
+sub create {
+ my($proto,$hashref)=@_;
+
+ #now in FS::Record::new
+ #my($field);
+ #foreach $field (fields('svc_acct')) {
+ # $hashref->{$field}='' unless defined $hashref->{$field};
+ #}
+
+ $proto->new('svc_acct',$hashref);
+
+}
+
+=item insert
+
+Adds this account to the database. If there is an error, returns the error,
+otherwise returns false.
+
+The additional fields pkgnum and svcpart (see L<FS::cust_svc>) should be
+defined. An FS::cust_svc record will be created and inserted.
+
+If the configuration value (see L<FS::Conf>) shellmachine exists, and the
+username, uid, and dir fields are defined, the command
+
+ useradd -d $dir -m -s $shell -u $uid $username
+
+is executed on shellmachine via ssh. This behaviour can be surpressed by
+setting $FS::svc_acct::nossh_hack true.
+
+=cut
+
+sub insert {
+ my($self)=@_;
+ my($error);
+
+ local $SIG{HUP} = 'IGNORE';
+ local $SIG{INT} = 'IGNORE';
+ local $SIG{QUIT} = 'IGNORE';
+ local $SIG{TERM} = 'IGNORE';
+ local $SIG{TSTP} = 'IGNORE';
+
+ $error=$self->check;
+ return $error if $error;
+
+ return "Username ". $self->username. " in use"
+ if qsearchs('svc_acct',{'username'=> $self->username } );
+
+ my($part_svc) = qsearchs('part_svc',{ 'svcpart' => $self->svcpart });
+ return "Unkonwn svcpart" unless $part_svc;
+ return "uid in use"
+ if $part_svc->svc_acct__uid_flag ne 'F'
+ && qsearchs('svc_acct',{'uid'=> $self->uid } )
+ && $self->username !~ /^(hyla)?fax$/
+ ;
+
+ my($svcnum)=$self->svcnum;
+ my($cust_svc);
+ unless ( $svcnum ) {
+ $cust_svc=create FS::cust_svc ( {
+ 'svcnum' => $svcnum,
+ 'pkgnum' => $self->pkgnum,
+ 'svcpart' => $self->svcpart,
+ } );
+ my($error) = $cust_svc->insert;
+ return $error if $error;
+ $svcnum = $self->svcnum($cust_svc->svcnum);
+ }
+
+ $error = $self->add;
+ if ($error) {
+ #$cust_svc->del if $cust_svc;
+ $cust_svc->delete if $cust_svc;
+ return $error;
+ }
+
+ my($username,$uid,$dir,$shell) = (
+ $self->username,
+ $self->uid,
+ $self->dir,
+ $self->shell,
+ );
+ if ( $username
+ && $uid
+ && $dir
+ && $shellmachine
+ && ! $nossh_hack ) {
+ #one way
+ ssh("root\@$shellmachine",
+ "useradd -d $dir -m -s $shell -u $uid $username"
+ );
+ #another way
+ #ssh("root\@$shellmachine","/bin/mkdir $dir; /bin/chmod 711 $dir; ".
+ # "/bin/cp -p /etc/skel/.* $dir 2>/dev/null; ".
+ # "/bin/cp -pR /etc/skel/Maildir $dir 2>/dev/null; ".
+ # "/bin/chown -R $uid $dir") unless $nossh_hack;
+ }
+
+ ''; #no error
+}
+
+=item delete
+
+Deletes this account from the database. If there is an error, returns the
+error, otherwise returns false.
+
+The corresponding FS::cust_svc record will be deleted as well.
+
+If the configuration value (see L<FS::Conf>) shellmachine exists, the command:
+
+ userdel $username
+
+is executed on shellmachine via ssh. This behaviour can be surpressed by
+setting $FS::svc_acct::nossh_hack true.
+
+=cut
+
+sub delete {
+ my($self)=@_;
+ my($error);
+
+ local $SIG{HUP} = 'IGNORE';
+ local $SIG{INT} = 'IGNORE';
+ local $SIG{QUIT} = 'IGNORE';
+ local $SIG{TERM} = 'IGNORE';
+ local $SIG{TSTP} = 'IGNORE';
+
+ my($svcnum)=$self->getfield('svcnum');
+
+ $error = $self->del;
+ return $error if $error;
+
+ my($cust_svc)=qsearchs('cust_svc',{'svcnum'=>$svcnum});
+ $error = $cust_svc->del;
+ return $error if $error;
+
+ my($username) = $self->getfield('username');
+ if ( $username && $shellmachine && ! $nossh_hack ) {
+ ssh("root\@$shellmachine","userdel $username");
+ }
+
+ '';
+}
+
+=item replace OLD_RECORD
+
+Replaces OLD_RECORD with this one in the database. If there is an error,
+returns the error, otherwise returns false.
+
+If the configuration value (see L<FS::Conf>) shellmachine exists, and the
+dir field has changed, the command:
+
+ [ -d $old_dir ] && (
+ chmod u+t $old_dir;
+ umask 022;
+ mkdir $new_dir;
+ cd $old_dir;
+ find . -depth -print | cpio -pdm $new_dir;
+ chmod u-t $new_dir;
+ chown -R $uid.$gid $new_dir;
+ rm -rf $old_dir
+ )
+
+is executed on shellmachine via ssh. This behaviour can be surpressed by
+setting $FS::svc_acct::nossh_hack true.
+
+=cut
+
+sub replace {
+ my($new,$old)=@_;
+ my($error);
+
+ return "(Old) Not a svc_acct record!" unless $old->table eq "svc_acct";
+ return "Can't change svcnum!"
+ unless $old->getfield('svcnum') eq $new->getfield('svcnum');
+
+ return "Username in use"
+ if $old->getfield('username') ne $new->getfield('username') &&
+ qsearchs('svc_acct',{'username'=> $new->getfield('username') } );
+
+ return "Can't change uid!"
+ if $old->getfield('uid') ne $new->getfield('uid');
+
+ #change homdir when we change username
+ if ( $old->getfield('username') ne $new->getfield('username') ) {
+ $new->setfield('dir','');
+ }
+
+ $error=$new->check;
+ return $error if $error;
+
+ local $SIG{HUP} = 'IGNORE';
+ local $SIG{INT} = 'IGNORE';
+ local $SIG{QUIT} = 'IGNORE';
+ local $SIG{TERM} = 'IGNORE';
+ local $SIG{TSTP} = 'IGNORE';
+
+ $error = $new->rep($old);
+ return $error if $error;
+
+ my($old_dir,$new_dir)=( $old->getfield('dir'),$new->getfield('dir') );
+ my($uid,$gid)=( $new->getfield('uid'), $new->getfield('gid') );
+ if ( $old_dir
+ && $new_dir
+ && $old_dir ne $new_dir
+ && ! $nossh_hack
+ ) {
+ ssh("root\@$shellmachine","[ -d $old_dir ] && ".
+ "( chmod u+t $old_dir; ". #turn off qmail delivery
+ "umask 022; mkdir $new_dir; cd $old_dir; ".
+ "find . -depth -print | cpio -pdm $new_dir; ".
+ "chmod u-t $new_dir; chown -R $uid.$gid $new_dir; ".
+ "rm -rf $old_dir".
+ ")"
+ );
+ }
+
+ ''; #no error
+}
+
+=item suspend
+
+Suspends this account by prefixing *SUSPENDED* to the password. If there is an
+error, returns the error, otherwise returns false.
+
+Called by the suspend method of FS::cust_pkg (see L<FS::cust_pkg>).
+
+=cut
+
+sub suspend {
+ my($old) = @_;
+ my(%hash) = $old->hash;
+ unless ( $hash{_password} =~ /^\*SUSPENDED\* / ) {
+ $hash{_password} = '*SUSPENDED* '.$hash{_password};
+ my($new) = create FS::svc_acct ( \%hash );
+# $new->replace($old);
+ $new->rep($old); #to avoid password checking :)
+ } else {
+ ''; #no error (already suspended)
+ }
+
+}
+
+=item unsuspend
+
+Unsuspends this account by removing *SUSPENDED* from the password. If there is
+an error, returns the error, otherwise returns false.
+
+Called by the unsuspend method of FS::cust_pkg (see L<FS::cust_pkg>).
+
+=cut
+
+sub unsuspend {
+ my($old) = @_;
+ my(%hash) = $old->hash;
+ if ( $hash{_password} =~ /^\*SUSPENDED\* (.*)$/ ) {
+ $hash{_password} = $1;
+ my($new) = create FS::svc_acct ( \%hash );
+# $new->replace($old);
+ $new->rep($old); #to avoid password checking :)
+ } else {
+ ''; #no error (already unsuspended)
+ }
+}
+
+=item cancel
+
+Just returns false (no error) for now.
+
+Called by the cancel method of FS::cust_pkg (see L<FS::cust_pkg>).
+
+=cut
+
+# Usage: $error = $record -> cancel;
+sub cancel {
+ ''; #stub (no error) - taken care of in delete
+}
+
+=item check
+
+Checks all fields to make sure this is a valid service. If there is an error,
+returns the error, otherwise returns false. Called by the insert and replace
+methods.
+
+Sets any fixed values; see L<FS::part_svc>.
+
+=cut
+
+sub check {
+ my($self)=@_;
+ return "Not a svc_acct record!" unless $self->table eq "svc_acct";
+ my($recref) = $self->hashref;
+
+ $recref->{svcnum} =~ /^(\d*)$/ or return "Illegal svcnum";
+ $recref->{svcnum} = $1;
+
+ #get part_svc
+ my($svcpart);
+ my($svcnum)=$self->getfield('svcnum');
+ if ($svcnum) {
+ my($cust_svc)=qsearchs('cust_svc',{'svcnum'=>$svcnum});
+ return "Unknown svcnum" unless $cust_svc;
+ $svcpart=$cust_svc->svcpart;
+ } else {
+ $svcpart=$self->getfield('svcpart');
+ }
+ my($part_svc)=qsearchs('part_svc',{'svcpart'=>$svcpart});
+ return "Unkonwn svcpart" unless $part_svc;
+
+ #set fixed fields from part_svc
+ my($field);
+ foreach $field ( fields('svc_acct') ) {
+ if ( $part_svc->getfield('svc_acct__'. $field. '_flag') eq 'F' ) {
+ $self->setfield($field,$part_svc->getfield('svc_acct__'. $field) );
+ }
+ }
+
+ my($ulen)=$self->dbdef_table->column('username')->length;
+ $recref->{username} =~ /^([a-z0-9_\-]{2,$ulen})$/
+ or return "Illegal username";
+ $recref->{username} = $1;
+ $recref->{username} =~ /[a-z]/ or return "Illegal username";
+
+ $recref->{popnum} =~ /^(\d*)$/ or return "Illegal popnum";
+ $recref->{popnum} = $1;
+ return "Unkonwn popnum" unless
+ ! $recref->{popnum} ||
+ qsearchs('svc_acct_pop',{'popnum'=> $recref->{popnum} } );
+
+ unless ( $part_svc->getfield('svc_acct__uid_flag') eq 'F' ) {
+
+ $recref->{uid} =~ /^(\d*)$/ or return "Illegal uid";
+ $recref->{uid} = $1 eq '' ? $self->unique('uid') : $1;
+
+ $recref->{gid} =~ /^(\d*)$/ or return "Illegal gid";
+ $recref->{gid} = $1 eq '' ? $recref->{uid} : $1;
+ #not all systems use gid=uid
+ #you can set a fixed gid in part_svc
+
+ return "Only root can have uid 0"
+ if $recref->{uid} == 0 && $recref->{username} ne 'root';
+
+ my($error);
+ return $error if $error=$self->ut_textn('finger');
+
+ $recref->{dir} =~ /^([\/\w\-]*)$/
+ or return "Illegal directory";
+ $recref->{dir} = $1 ||
+ $dir_prefix . '/' . $recref->{username}
+ #$dir_prefix . '/' . substr($recref->{username},0,1). '/' . $recref->{username}
+ ;
+
+ unless ( $recref->{username} eq 'sync' ) {
+ my($shell);
+ if ( $shell = (grep $_ eq $recref->{shell}, @shells)[0] ) {
+ $recref->{shell} = $shell;
+ } else {
+ return "Illegal shell ". $self->shell;
+ }
+ } else {
+ $recref->{shell} = '/bin/sync';
+ }
+
+ $recref->{quota} =~ /^(\d*)$/ or return "Illegal quota (unimplemented)";
+ $recref->{quota} = $1;
+
+ } else {
+ $recref->{gid} ne '' ?
+ return "Can't have gid without uid" : ( $recref->{gid}='' );
+ $recref->{finger} ne '' ?
+ return "Can't have finger-name without uid" : ( $recref->{finger}='' );
+ $recref->{dir} ne '' ?
+ return "Can't have directory without uid" : ( $recref->{dir}='' );
+ $recref->{shell} ne '' ?
+ return "Can't have shell without uid" : ( $recref->{shell}='' );
+ $recref->{quota} ne '' ?
+ return "Can't have quota without uid" : ( $recref->{quota}='' );
+ }
+
+ unless ( $part_svc->getfield('svc_acct__slipip_flag') eq 'F' ) {
+ unless ( $recref->{slipip} eq '0e0' ) {
+ $recref->{slipip} =~ /^(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})$/
+ or return "Illegal slipip". $self->slipip;
+ $recref->{slipip} = $1;
+ } else {
+ $recref->{slipip} = '0e0';
+ }
+
+ }
+
+ #arbitrary RADIUS stuff; allow ut_textn for now
+ foreach ( grep /^radius_/, fields('svc_acct') ) {
+ $self->ut_textn($_);
+ }
+
+ #generate a password if it is blank
+ $recref->{_password} = join('',map($pw_set[ int(rand $#pw_set) ], (0..7) ) )
+ unless ( $recref->{_password} );
+
+ #if ( $recref->{_password} =~ /^((\*SUSPENDED\* )?)([^\t\n]{4,16})$/ ) {
+ if ( $recref->{_password} =~ /^((\*SUSPENDED\* )?)([^\t\n]{4,8})$/ ) {
+ $recref->{_password} = $1.$3;
+ #uncomment this to encrypt password immediately upon entry, or run
+ #bin/crypt_pw in cron to give new users a window during which their
+ #password is available to techs, for faxing, etc. (also be aware of
+ #radius issues!)
+ #$recref->{password} = $1.
+ # crypt($3,$saltset[int(rand(64))].$saltset[int(rand(64))]
+ #;
+ } elsif ( $recref->{_password} =~ /^((\*SUSPENDED\* )?)([\w\.\/]{13,24})$/ ) {
+ $recref->{_password} = $1.$3;
+ } elsif ( $recref->{_password} eq '*' ) {
+ $recref->{_password} = '*';
+ } else {
+ return "Illegal password";
+ }
+
+ ''; #no error
+}
+
+=back
+
+=head1 BUGS
+
+It doesn't properly override FS::Record yet.
+
+The remote commands should be configurable.
+
+The create method should set defaults from part_svc (like the check method
+sets fixed values).
+
+=head1 SEE ALSO
+
+L<FS::Record>, L<FS::Conf>, L<FS::cust_svc>, L<FS::part_svc>, L<FS::cust_pkg>,
+L<FS::SSH>, L<ssh>, L<FS::svc_acct_pop>, schema.html from the base
+documentation.
+
+=head1 HISTORY
+
+ivan@voicenet.com 97-jul-16 - 21
+
+rewrite (among other things, now know about part_svc) ivan@sisd.com 98-mar-8
+
+Changed 'password' to '_password' because Pg6.3 reserves the password word
+ bmccane@maxbaud.net 98-apr-3
+
+username length and shell no longer hardcoded ivan@sisd.com 98-jun-28
+
+eww but needed: ignore uid duplicates for 'fax' and 'hylafax'
+ivan@sisd.com 98-jun-29
+
+$nossh_hack ivan@sisd.com 98-jul-13
+
+protections against UID/GID of 0 for incorrectly-setup RDBMSs (also
+in bin/svc_acct.export) ivan@sisd.com 98-jul-13
+
+arbitrary radius attributes ivan@sisd.com 98-aug-13
+
+/var/spool/freeside/conf/shellmachine ivan@sisd.com 98-aug-13
+
+pod and FS::conf ivan@sisd.com 98-sep-22
+
+=cut
+
+1;
+
--- /dev/null
+package FS::svc_domain;
+
+use strict;
+use vars qw(@ISA @EXPORT_OK $whois_hack $conf $mydomain $smtpmachine);
+use Exporter;
+use Carp;
+use Mail::Internet;
+use Mail::Header;
+use Date::Format;
+use FS::Record qw(fields qsearch qsearchs);
+use FS::cust_svc;
+use FS::Conf;
+
+@ISA = qw(FS::Record Exporter);
+@EXPORT_OK = qw(fields);
+
+$conf = new FS::Conf;
+
+$mydomain = $conf->config('domain');
+$smtpmachine = $conf->config('smtpmachine');
+
+my($internic)="/var/spool/freeside/conf/registries/internic";
+my($conf_tech)="$internic/tech_contact";
+my($conf_from)="$internic/from";
+my($conf_to)="$internic/to";
+my($nameservers)="$internic/nameservers";
+my($template)="$internic/template";
+
+open(TECH_CONTACT,$conf_tech) or die "Can't open $conf_tech: $!";
+my($tech_contact)=map {
+ /^(.*)$/ or die "Illegal line in $conf_tech!"; #yes, we trust the file
+ $1;
+} grep $_ !~ /^(#|$)/, <TECH_CONTACT>;
+close TECH_CONTACT;
+
+open(FROM,$conf_from) or die "Can't open $conf_from: $!";
+my($from)=map {
+ /^(.*)$/ or die "Illegal line in $conf_from!"; #yes, we trust the file
+ $1;
+} grep $_ !~ /^(#|$)/, <FROM>;
+close FROM;
+
+open(TO,$conf_to) or die "Can't open $conf_to: $!";
+my($to)=map {
+ /^(.*)$/ or die "Illegal line in $conf_to!"; #yes, we trust the file
+ $1;
+} grep $_ !~ /^(#|$)/, <TO>;
+close TO;
+
+open(NAMESERVERS,$nameservers) or die "Can't open $nameservers: $!";
+my(@nameservers)=map {
+ /^\s*\d+\.\d+\.\d+\.\d+\s+([^\s]+)\s*$/
+ or die "Illegal line in $nameservers!"; #yes, we trust the file
+ $1;
+} grep $_ !~ /^(#|$)/, <NAMESERVERS>;
+close NAMESERVERS;
+open(NAMESERVERS,$nameservers) or die "Can't open $nameservers: $!";
+my(@nameserver_ips)=map {
+ /^\s*(\d+\.\d+\.\d+\.\d+)\s+([^\s]+)\s*$/
+ or die "Illegal line in $nameservers!"; #yes, we trust the file
+ $1;
+} grep $_ !~ /^(#|$)/, <NAMESERVERS>;
+close NAMESERVERS;
+
+open(TEMPLATE,$template) or die "Can't open $template: $!";
+my(@template)=map {
+ /^(.*)$/ or die "Illegal line in $to!"; #yes, we trust the file
+ $1. "\n";
+} <TEMPLATE>;
+close TEMPLATE;
+
+=head1 NAME
+
+FS::svc_domain - Object methods for svc_domain records
+
+=head1 SYNOPSIS
+
+ use FS::svc_domain;
+
+ $record = create FS::svc_domain \%hash;
+ $record = create FS::svc_domain { 'column' => 'value' };
+
+ $error = $record->insert;
+
+ $error = $new_record->replace($old_record);
+
+ $error = $record->delete;
+
+ $error = $record->check;
+
+ $error = $record->suspend;
+
+ $error = $record->unsuspend;
+
+ $error = $record->cancel;
+
+=head1 DESCRIPTION
+
+An FS::svc_domain object represents a domain. FS::svc_domain inherits from
+FS::Record. The following fields are currently supported:
+
+=over 4
+
+=item svcnum - primary key (assigned automatically for new accounts)
+
+=item domain
+
+=back
+
+=head1 METHODS
+
+=over 4
+
+=item create HASHREF
+
+Creates a new domain. To add the domain to the database, see L<"insert">.
+
+=cut
+
+sub create {
+ my($proto,$hashref)=@_;
+
+ #now in FS::Record::new
+ #my($field);
+ #foreach $field (fields('svc_domain')) {
+ # $hashref->{$field}='' unless defined $hashref->{$field};
+ #}
+
+ $proto->new('svc_domain',$hashref);
+
+}
+
+=item insert
+
+Adds this domain to the database. If there is an error, returns the error,
+otherwise returns false.
+
+The additional fields I<pkgnum> and I<svcpart> (see L<FS::cust_svc>) should be
+defined. An FS::cust_svc record will be created and inserted.
+
+The additional field I<action> should be set to I<N> for new domains or I<M>
+for transfers.
+
+A registration or transfer email will be submitted unless
+$FS::svc_domain::whois_hack is true.
+
+=cut
+
+sub insert {
+ my($self)=@_;
+ my($error);
+
+ local $SIG{HUP} = 'IGNORE';
+ local $SIG{INT} = 'IGNORE';
+ local $SIG{QUIT} = 'IGNORE';
+ local $SIG{TERM} = 'IGNORE';
+ local $SIG{TSTP} = 'IGNORE';
+
+ $error=$self->check;
+ return $error if $error;
+
+ return "Domain in use (here)"
+ if qsearchs('svc_domain',{'domain'=> $self->domain } );
+
+ my($whois)=(($self->_whois)[0]);
+ return "Domain in use (see whois)"
+ if ( $self->action eq "N" && $whois !~ /^No match for/ );
+ return "Domain not found (see whois)"
+ if ( $self->action eq "M" && $whois =~ /^No match for/ );
+
+ my($svcnum)=$self->getfield('svcnum');
+ my($cust_svc);
+ unless ( $svcnum ) {
+ $cust_svc=create FS::cust_svc ( {
+ 'svcnum' => $svcnum,
+ 'pkgnum' => $self->getfield('pkgnum'),
+ 'svcpart' => $self->getfield('svcpart'),
+ } );
+ my($error) = $cust_svc->insert;
+ return $error if $error;
+ $svcnum = $self->setfield('svcnum',$cust_svc->getfield('svcnum'));
+ }
+
+ $error = $self->add;
+ if ($error) {
+ $cust_svc->del if $cust_svc;
+ return $error;
+ }
+
+ $self->submit_internic unless $whois_hack;
+
+ ''; #no error
+}
+
+=item delete
+
+Deletes this domain from the database. If there is an error, returns the
+error, otherwise returns false.
+
+The corresponding FS::cust_svc record will be deleted as well.
+
+=cut
+
+sub delete {
+ my($self)=@_;
+ my($error);
+
+ my($svcnum)=$self->getfield('svcnum');
+
+ $error = $self->del;
+ return $error if $error;
+
+ my($cust_svc)=qsearchs('cust_svc',{'svcnum'=>$svcnum});
+ $error = $cust_svc->del;
+ return $error if $error;
+
+ '';
+}
+
+=item replace OLD_RECORD
+
+Replaces OLD_RECORD with this one in the database. If there is an error,
+returns the error, otherwise returns false.
+
+=cut
+
+sub replace {
+ my($new,$old)=@_;
+ my($error);
+
+ return "(Old) Not a svc_domain record!" unless $old->table eq "svc_domain";
+ return "Can't change svcnum!"
+ unless $old->getfield('svcnum') eq $new->getfield('svcnum');
+
+ return "Can't change domain - reorder."
+ if $old->getfield('domain') ne $new->getfield('domain');
+
+ $error=$new->check;
+ return $error if $error;
+
+ local $SIG{HUP} = 'IGNORE';
+ local $SIG{INT} = 'IGNORE';
+ local $SIG{QUIT} = 'IGNORE';
+ local $SIG{TERM} = 'IGNORE';
+ local $SIG{TSTP} = 'IGNORE';
+
+ $error = $new->rep($old);
+ return $error if $error;
+
+ '';
+
+}
+
+=item suspend
+
+Just returns false (no error) for now.
+
+Called by the suspend method of FS::cust_pkg (see L<FS::cust_pkg>).
+
+=cut
+
+sub suspend {
+ ''; #no error (stub)
+}
+
+=item unsuspend
+
+Just returns false (no error) for now.
+
+Called by the unsuspend method of FS::cust_pkg (see L<FS::cust_pkg>).
+
+=cut
+
+sub unsuspend {
+ ''; #no error (stub)
+}
+
+=item cancel
+
+Just returns false (no error) for now.
+
+Called by the cancel method of FS::cust_pkg (see L<FS::cust_pkg>).
+
+=cut
+
+sub cancel {
+ ''; #no error (stub)
+}
+
+=item check
+
+Checks all fields to make sure this is a valid domain. If there is an error,
+returns the error, otherwise returns false. Called by the insert and replace
+methods.
+
+Sets any fixed values; see L<FS::part_svc>.
+
+=cut
+
+sub check {
+ my($self)=@_;
+ return "Not a svc_domain record!" unless $self->table eq "svc_domain";
+ my($recref) = $self->hashref;
+
+ $recref->{svcnum} =~ /^(\d*)$/ or return "Illegal svcnum";
+ $recref->{svcnum} = $1;
+
+ #get part_svc (and pkgnum)
+ my($svcpart,$pkgnum);
+ my($svcnum)=$self->getfield('svcnum');
+ if ($svcnum) {
+ my($cust_svc)=qsearchs('cust_svc',{'svcnum'=>$svcnum});
+ return "Unknown svcnum" unless $cust_svc;
+ $svcpart=$cust_svc->svcpart;
+ $pkgnum=$cust_svc->pkgnum;
+ } else {
+ $svcpart=$self->svcpart;
+ $pkgnum=$self->pkgnum;
+ }
+ my($part_svc)=qsearchs('part_svc',{'svcpart'=>$svcpart});
+ return "Unkonwn svcpart" unless $part_svc;
+
+ #set fixed fields from part_svc
+ my($field);
+ foreach $field ( fields('svc_acct') ) {
+ if ( $part_svc->getfield('svc_domain__'. $field. '_flag') eq 'F' ) {
+ $self->setfield($field,$part_svc->getfield('svc_domain__'. $field) );
+ }
+ }
+
+ unless ( $whois_hack ) {
+ unless ( $self->email ) { #find out an email address
+ my(@svc_acct);
+ foreach ( qsearch('cust_svc',{'pkgnum'=>$pkgnum}) ) {
+ my($svc_acct)=qsearchs('svc_acct',{'svcnum'=>$_->svcnum});
+ push @svc_acct, $svc_acct if $svc_acct;
+ }
+
+ if ( scalar(@svc_acct) == 0 ) {
+ return "Must order an account first";
+ } elsif ( scalar(@svc_acct) > 1 ) {
+ return "More than one account in package ". $pkgnum. ": specify admin contact email";
+ } else {
+ $self->email($svc_acct[0]->username. '@'. $mydomain);
+ }
+ }
+ }
+
+ #if ( $recref->{domain} =~ /^([\w\-\.]{1,22})\.(com|net|org|edu)$/ ) {
+ if ( $recref->{domain} =~ /^([\w\-]{1,22})\.(com|net|org|edu)$/ ) {
+ $recref->{domain} = "$1.$2";
+ # hmmmmmmmm.
+ } elsif ( $whois_hack && $recref->{domain} =~ /^([\w\-\.]+)$/ ) {
+ $recref->{domain} = $1;
+ } else {
+ return "Illegal domain ". $recref->{domain}.
+ " (or unknown registry - try \$whois_hack)";
+ }
+
+ $recref->{action} =~ /^(M|N)$/ or return "Illegal action";
+ $recref->{action} = $1;
+
+ $self->ut_textn('purpose');
+
+}
+
+=item _whois
+
+Executes the command:
+
+ whois do $domain
+
+and returns the output.
+
+(Always returns I<No match for domian "$domain".> if
+$FS::svc_domain::whois_hack is set true.)
+
+=cut
+
+sub _whois {
+ my($self)=@_;
+ my($domain)=$self->domain;
+ return ( "No match for domain \"$domain\"." ) if $whois_hack;
+ open(WHOIS,"whois do $domain |");
+ return <WHOIS>;
+}
+
+=item submit_internic
+
+Submits a registration email for this domain.
+
+=cut
+
+sub submit_internic {
+ my($self)=@_;
+
+ my($cust_pkg)=qsearchs('cust_pkg',{'pkgnum'=>$self->pkgnum});
+ return unless $cust_pkg;
+ my($cust_main)=qsearchs('cust_main',{'custnum'=>$cust_pkg->custnum});
+ return unless $cust_main;
+
+ my(%subs)=(
+ 'action' => $self->action,
+ 'purpose' => $self->purpose,
+ 'domain' => $self->domain,
+ 'company' => $cust_main->company
+ || $cust_main->getfield('first'). ' '.
+ $cust_main->getfield('last')
+ ,
+ 'city' => $cust_main->city,
+ 'state' => $cust_main->state,
+ 'zip' => $cust_main->zip,
+ 'country' => $cust_main->country,
+ 'last' => $cust_main->getfield('last'),
+ 'first' => $cust_main->getfield('first'),
+ 'daytime' => $cust_main->daytime,
+ 'fax' => $cust_main->fax,
+ 'email' => $self->email,
+ 'tech_contact' => $tech_contact,
+ 'primary' => shift @nameservers,
+ 'primary_ip' => shift @nameserver_ips,
+ );
+
+ #yuck
+ my(@xtemplate)=@template;
+ my(@body);
+ my($line);
+ OLOOP: while ( defined($line = shift @xtemplate) ) {
+
+ if ( $line =~ /^###LOOP###$/ ) {
+ my(@buffer);
+ LOADBUF: while ( defined($line = shift @xtemplate) ) {
+ last LOADBUF if ( $line =~ /^###ENDLOOP###$/ );
+ push @buffer, $line;
+ }
+ my(%lubs)=(
+ 'address' => $cust_main->address2
+ ? [ $cust_main->address1, $cust_main->address2 ]
+ : [ $cust_main->address1 ]
+ ,
+ 'secondary' => [ @nameservers ],
+ 'secondary_ip' => [ @nameserver_ips ],
+ );
+ LOOP: while (1) {
+ my(@xbuffer)=@buffer;
+ SUBLOOP: while ( defined($line = shift @xbuffer) ) {
+ if ( $line =~ /###(\w+)###/ ) {
+ #last LOOP unless my($lub)=shift@{$lubs{$1}};
+ next OLOOP unless my $lub = shift @{$lubs{$1}};
+ $line =~ s/###(\w+)###/$lub/e;
+ redo SUBLOOP;
+ } else {
+ push @body, $line;
+ }
+ } #SUBLOOP
+ } #LOOP
+
+ }
+
+ if ( $line =~ /###(\w+)###/ ) {
+ #$line =~ s/###(\w+)###/$subs{$1}/eg;
+ $line =~ s/###(\w+)###/$subs{$1}/e;
+ redo OLOOP;
+ } else {
+ push @body, $line;
+ }
+
+ } #OLOOP
+
+ my($subject);
+ if ( $self->action eq "M" ) {
+ $subject = "MODIFY DOMAIN ". $self->domain;
+ } elsif ($self->action eq "N" ) {
+ $subject = "NEW DOMAIN ". $self->domain;
+ } else {
+ croak "submit_internic called with action ". $self->action;
+ }
+
+ $ENV{SMTPHOSTS}=$smtpmachine;
+ $ENV{MAILADDRESS}=$from;
+ my($header)=Mail::Header->new( [
+ "From: $from",
+ "To: $to",
+ "Sender: $from",
+ "Reply-To: $from",
+ "Date: ". time2str("%a, %d %b %Y %X %z",time),
+ "Subject: $subject",
+ ] );
+
+ my($msg)=Mail::Internet->new(
+ 'Header' => $header,
+ 'Body' => \@body,
+ );
+
+ $msg->smtpsend or die "Can't send registration email"; #die? warn?
+
+}
+
+=back
+
+=head1 BUGS
+
+It doesn't properly override FS::Record yet.
+
+All BIND/DNS fields should be included (and exported).
+
+All registries should be supported.
+
+Not all configuration access is through FS::Conf!
+
+Should change action to a real field.
+
+=head1 SEE ALSO
+
+L<FS::Record>, L<FS::Conf>, L<FS::cust_svc>, L<FS::part_svc>, L<FS::cust_pkg>,
+L<FS::SSH>, L<ssh>, L<dot-qmail>, schema.html from the base documentation,
+config.html from the base documentation.
+
+=head1 HISTORY
+
+ivan@voicenet.com 97-jul-21
+
+rewrite ivan@sisd.com 98-mar-10
+
+add internic bits ivan@sisd.com 98-mar-14
+
+Changed 'day' to 'daytime' because Pg6.3 reserves the day word
+ bmccane@maxbaud.net 98-apr-3
+
+/var/spool/freeside/conf/registries/internic/, Mail::Internet, etc.
+ivan@sisd.com 98-jul-17-19
+
+pod, some FS::Conf (not complete) ivan@sisd.com 98-sep-23
+
+=cut
+
+1;
+
+
projects / freeside.git / commitdiff