%# BEGIN BPS TAGGED BLOCK {{{
%#
%# COPYRIGHT:
%#
%# This software is Copyright (c) 1996-2017 Best Practical Solutions, LLC
%#                                          <sales@bestpractical.com>
%#
%# (Except where explicitly superseded by other copyright notices)
%#
%#
%# LICENSE:
%#
%# This work is made available to you under the terms of Version 2 of
%# the GNU General Public License. A copy of that license should have
%# been provided with this software, but in any event can be snarfed
%# from www.gnu.org.
%#
%# This work is distributed in the hope that it will be useful, but
%# WITHOUT ANY WARRANTY; without even the implied warranty of
%# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
%# General Public License for more details.
%#
%# You should have received a copy of the GNU General Public License
%# along with this program; if not, write to the Free Software
%# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
%# 02110-1301 or visit their web page on the internet at
%# http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
%#
%#
%# CONTRIBUTION SUBMISSION POLICY:
%#
%# (The following paragraph is not intended to limit the rights granted
%# to you to modify and distribute this software under the terms of
%# the GNU General Public License and is only of importance to you if
%# you choose to contribute your changes and enhancements to the
%# community by submitting them to Best Practical Solutions, LLC.)
%#
%# By intentionally submitting any modifications, corrections or
%# derivatives to this work, or any other work intended for use with
%# Request Tracker, to Best Practical Solutions, LLC, you confirm that
%# you are the copyright holder for those contributions and you grant
%# Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
%# royalty-free, perpetual, license to use, copy, create derivative
%# works based on those contributions, and sublicense and distribute
%# those contributions and any derivatives thereof.
%#
%# END BPS TAGGED BLOCK }}}
<%args>
$Context
$Principal => undef
$id
$acldesc => ''
</%args>
<%init>
# Find all our available rights...
my (%available_rights, %categories);
if ( blessed($Context) and $Context->can('AvailableRights') ) {
    %available_rights = %{$Context->AvailableRights( $Principal ? $Principal->PrincipalObj : undef )};
} else {
    %available_rights = ( loc('System Error') => loc("No rights found") );
}

# ...and their categories
if ( blessed($Context) and $Context->can('RightCategories') ) {
    my %right_categories = %{$Context->RightCategories};

    for my $right (keys %available_rights) {
        my $category = $right_categories{$right} || 'Miscellaneous'; # loc
        push @{$categories{$category}}, $right;
    }
}

# Find all the current rights for this principal
my %current_rights;
if ($Principal) {
    my $acls = RT::ACL->new($session{'CurrentUser'});
    $acls->LimitToObject( $Context );
    $acls->LimitToPrincipal( Id => $Principal->PrincipalId );

    while ( my $ace = $acls->Next ) {
        my $right = $ace->RightName;
        $current_rights{$right} = 1;
    }
}

my %category_desc = (
    'General' => loc('General rights'),
    'Staff'   => loc('Rights for Staff'),
    'Admin'   => loc('Rights for Administrators'),
    'Status'  => loc('Status changes'),
);

my %catsort = ( General => 1, Staff => 2, Admin => 3, Status => 4, Miscellaneous => 999 );
my $i = 5;
for my $category ( sort keys %categories ) {
    next if $catsort{$category};
    $catsort{$category} = $i++;
}

$acldesc ||= join '-', ($Principal ? $Principal->PrincipalId : 'addprincipal'),
                       ref($Context), $Context->Id;

$available_rights{$_} = loc( $available_rights{$_} ) for keys %available_rights;
</%init>
    <div class="category-tabs">
      <ul>
% for my $category (sort { $catsort{$a} <=> $catsort{$b} } keys %categories) {
        <li><a href="#<% "$id-$category" %>"><% $category_desc{$category} || loc($category) %></a></li>
% }
      </ul>
% for my $category (sort { $catsort{$a} <=> $catsort{$b} } keys %categories) {
    <div id="<% "$id-$category" %>">
    <ul class="rights-list">
%     for my $right (sort { $available_rights{$a} cmp $available_rights{$b} } @{$categories{$category}}) {
      <li>
        <input type="checkbox" class="checkbox"
               name="SetRights-<% $acldesc %>"
               id="SetRights-<% $acldesc %>-<% $right %>"
               value="<% $right %>"
               <% $current_rights{$right} ? 'checked' : '' %> />
        <label for="SetRights-<% $acldesc %>-<% $right %>" title="<% $right %>">
          <% $available_rights{$right} %>
          <span class="separator">&mdash;</span>
          <span class="rightname"><% $right %></span>
        </label>
      </li>
%     }
    </ul>
    </div>
% }
    </div>
    <input type="hidden" name="CheckACL" value="<% $acldesc %>" />