#!/usr/bin/perl -Tw
#
# fs_signup_server
#

use strict;
use IO::Handle;
use Storable qw(nstore_fd fd_retrieve);
use Tie::RefHash;
use Net::SSH qw(sshopen2);
use FS::UID qw(adminsuidsetup);
use FS::Record qw( qsearch qsearchs );
use FS::cust_main_county;
use FS::cust_main;

use vars qw( $opt $Debug );

$Debug = 2;

my @payby = qw(CARD PREPAY);

my $user = shift or die &usage;
&adminsuidsetup( $user ); 

my $machine = shift or die &usage;

my $agentnum = shift or die &usage;
my $agent = qsearchs( 'agent', { 'agentnum' => $agentnum } ) or die &usage;
my $pkgpart_href = $agent->pkgpart_hashref;

my $refnum = shift or die &usage;

#causing trouble for some folks
#$SIG{CHLD} = sub { wait() };

my($fs_signupd)="/usr/local/sbin/fs_signupd";

while (1) {
  my($reader,$writer)=(new IO::Handle, new IO::Handle);
  #seems to be broken - calling ->flush explicitly# $writer->autoflush(1);
  warn "[fs_signup_server] Connecting to $machine...\n" if $Debug;
  sshopen2($machine,$reader,$writer,$fs_signupd);

  my $init_data = {

    #'_protocol' => 'signup',
    #'_version' => '0.1',
    #'_packet' => 'init'
  
    'cust_main_county' =>
      [ map { $_->hashref } qsearch('cust_main_county', {}) ],
      
    'part_pkg' =>
      [
        map { $_->hashref }
          grep { $_->svcpart('svc_acct') && $pkgpart_href->{ $_->pkgpart } }
            qsearch( 'part_pkg', { 'disabled' => '' } )
      ],

    'svc_acct_pop' => [ map { $_->hashref } qsearch ('svc_acct_pop',{} ) ],

  };

  warn "[fs_signup_server] Sending init data...\n" if $Debug;
  nstore_fd($init_data, $writer) or die "can't send init data: $!";
  $writer->flush;

  warn "[fs_signup_server] Entering main loop...\n" if $Debug;
  while (1) {
    warn "[fs_signup_server] Reading (waiting for) signup data...\n" if $Debug;
    my $signup_data = fd_retrieve($reader);

    if ( $Debug > 1 ) {
      warn join('',
        map { "  $_ => ". $signup_data->{$_}. "\n" } keys %$signup_data );
    }

    warn "[fs_signup_server] Processing signup...\n" if $Debug;

    my $error = '';

    #shares some stuff with htdocs/edit/process/cust_main.cgi... take any
    # common that are still here and library them.
    my $cust_main = new FS::cust_main ( {
      #'custnum'          => '',
      'agentnum'         => $agentnum,
      'refnum'           => $refnum,

      map { $_ => $signup_data->{$_} } qw(
        last first ss company address1 address2 city county state zip country
        daytime night fax payby payinfo paydate payname referral_custnum
      ),

    } );

    $error = "Illegal payment type"
      unless grep { $_ eq $signup_data->{'payby'} } @payby;

    my @invoicing_list = split( /\s*\,\s*/, $signup_data->{'invoicing_list'} );

    my $part_pkg =
      qsearchs( 'part_pkg', { 'pkgpart' => $signup_data->{'pkgpart'} } )
        or $error ||= "WARNING: unknown pkgpart ". $signup_data->{pkgpart};
    my $svcpart = $part_pkg->svcpart unless $error;

    # this should wind up in FS::cust_pkg!
    my $agent = qsearchs( 'agent', { 'agentnum' => $agentnum } );
    #my $pkgpart_href = $agent->pkgpart_hashref;
    $error ||= "WARNING: agent $agentnum can't purchase pkgpart ".
               $signup_data->{pkgpart}
      unless $pkgpart_href->{ $signup_data->{pkgpart} };

    my $cust_pkg = new FS::cust_pkg ( {
      #later#'custnum' => $custnum,
      'pkgpart' => $signup_data->{'pkgpart'},
    } );
    $error ||= $cust_pkg->check;

    my $svc_acct = new FS::svc_acct ( {
      'svcpart'   => $svcpart,
      map { $_ => $signup_data->{$_} } qw( username _password popnum ),
    } );

    my $y = $svc_acct->setdefault; # arguably should be in new method
    $error ||= $y unless ref($y);

    $error ||= $svc_acct->check;

    use Tie::RefHash;
    tie my %hash, 'Tie::RefHash';
    %hash = ( $cust_pkg => [ $svc_acct ] );
    $error ||= $cust_main->insert( \%hash, \@invoicing_list );

    warn "[fs_signup_server] Sending results...\n" if $Debug;
    print $writer $error, "\n";

  }
  close $writer;
  close $reader;
  warn "connection to $machine lost!  waiting 60 seconds...\n";
  sleep 60;
  warn "reconnecting...\n";
}

sub usage {
  die "Usage:\n\n  fs_signup_server user machine agentnum refnum\n";
}