torrus/perllib/Torrus/Renderer/HTML.pm

   1 #  Copyright (C) 2002  Stanislav Sinyagin
   2 #
   3 #  This program is free software; you can redistribute it and/or modify
   4 #  it under the terms of the GNU General Public License as published by
   5 #  the Free Software Foundation; either version 2 of the License, or
   6 #  (at your option) any later version.
   7 #
   8 #  This program is distributed in the hope that it will be useful,
   9 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 #  GNU General Public License for more details.
  12 #
  13 #  You should have received a copy of the GNU General Public License
  14 #  along with this program; if not, write to the Free Software
  15 #  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307, USA.
  16
  17 # $Id: HTML.pm,v 1.12 2011-02-27 19:14:47 ivan Exp $
  18 # Stanislav Sinyagin <ssinyagin@yahoo.com>
  19
  20 package Torrus::Renderer::HTML;
  21
  22 use strict;
  23
  24 use Torrus::ConfigTree;
  25 use Torrus::Search;
  26 use Torrus::Log;
  27
  28 use URI::Escape;
  29 use Template;
  30 use POSIX qw(abs log floor pow);
  31 use Date::Parse;
  32 use Date::Format;
  33
  34 Torrus::SiteConfig::loadStyling();
  35
  36 # All our methods are imported by Torrus::Renderer;
  37
  38 sub render_html
  39 {
  40     my $self = shift;
  41     my $config_tree = shift;
  42     my $token = shift;
  43     my $view = shift;
  44     my $outfile = shift;
  45
  46     my $tmplfile = $config_tree->getParam($view, 'html-template');
  47
  48     my $expires = $config_tree->getParam($view, 'expires');
  49
  50     # Create the Template Toolkit processor once, and reuse
  51     # it in subsequent render() calls
  52
  53     if( not defined( $self->{'tt'} ) )
  54     {
  55         $self->{'tt'} =
  56             new Template(INCLUDE_PATH => $Torrus::Global::templateDirs,
  57                          TRIM => 1);
  58     }
  59     my $ttvars =
  60     {
  61         'treeName'   => $config_tree->treeName(),
  62         'token'      => $token,
  63         'view'       => $view,
  64         'expires'    => $expires,
  65         'path'       => sub { return $config_tree->path($_[0]); },
  66         'pathToken'  => sub { return $config_tree->token($_[0]); },
  67         'nodeExists' => sub { return $config_tree->nodeExists($_[0]); },
  68         'children'   => sub { return $config_tree->getChildren($_[0]); },
  69         'isLeaf'     => sub { return $config_tree->isLeaf($_[0]); },
  70         'isAlias'    => sub { return $config_tree->isAlias($_[0]); },
  71         'sortTokens' => sub { return $self->sortTokens($config_tree,
  72                                                        $_[0]); },
  73         'nodeName'   => sub { return $self->nodeName($config_tree, $_[0]); },
  74         'parent'     => sub { return $config_tree->getParent($_[0]); },
  75         'nodeParam'  => sub { return $config_tree->getNodeParam(@_); },
  76         'param'      => sub { return $config_tree->getParam(@_); },
  77         'url'        => sub { return $self->makeURL($config_tree, 0, @_); },
  78         'persistentUrl' => sub { return $self->makeURL($config_tree, 1, @_); },
  79         'clearVar'   => sub { delete $self->{'options'}{'variables'}{$_[0]};
  80                               return undef;},
  81         'plainURL'   => $Torrus::Renderer::plainURL,
  82         'splitUrls'  => sub { return $self->makeSplitURLs($config_tree,
  83                                                           $_[0], $_[1]); },
  84         'topURL'     => ($Torrus::Renderer::rendererURL ne '' ?
  85                          $Torrus::Renderer::rendererURL : '/'),
  86         'rrprint'    => sub { return $self->rrPrint($config_tree,
  87                                                     $_[0], $_[1]); },
  88         'scale'      => sub { return $self->scale($_[0], $_[1]); },
  89         'tsetMembers' => sub { $config_tree->tsetMembers($_[0]); },
  90         'tsetList'   => sub { $config_tree->getTsets(); },
  91         'style'      => sub { return $self->style($_[0]); },
  92         'companyName'=> $Torrus::Renderer::companyName,
  93         'companyLogo'=> $Torrus::Renderer::companyLogo,
  94         'companyURL' => $Torrus::Renderer::companyURL,
  95         'siteInfo'   => $Torrus::Renderer::siteInfo,
  96         'treeInfo'   => sub { return $Torrus::Global::treeConfig{
  97             $config_tree->treeName()}{'info'}; },
  98         'version'    => $Torrus::Global::version,
  99         'xmlnorm'    => \&Torrus::Renderer::xmlnormalize,
 100         'userAuth'   => $Torrus::CGI::authorizeUsers,
 101         'uid'        => $self->{'options'}->{'uid'},
 102         'userAttr'   => sub { return $self->userAttribute( $_[0] ) },
 103         'mayDisplayAdmInfo' => sub {
 104             return $self->may_display_adminfo( $config_tree, $_[0] ) },
 105         'adminfo' => $self->{'adminfo'},
 106         'mayDisplayReports' => sub {
 107             return $self->may_display_reports($config_tree) },
 108         'reportsUrl' => sub {
 109             return $self->reportsUrl($config_tree); },
 110         'timestamp'  => sub { return time2str($Torrus::Renderer::timeFormat,
 111                                               time()); },
 112         'verifyDate'  => sub { return verifyDate($_[0]); },
 113         'markup'     => sub{ return $self->translateMarkup( @_ ); },
 114         'searchEnabled' => $Torrus::Renderer::searchEnabled,
 115         'searchResults' => sub { return $self->doSearch($config_tree, $_[0]); },
 116
 117         #Freeside
 118         'freesideHeader' => sub { return $self->freesideHeader(@_); },
 119         'freesideFooter' => sub { return $self->freesideFooter(); },
 120         'freesideComponent' => sub { return $self->freesideComponent(@_); },
 121         'uri_escape'        => sub { return uri_escape(@_); },
 122         'matches'        => sub { return $_[0] =~ $_[1]; },
 123         'slash2underscore' => sub { $_[0] =~ s/\//_/g; return $_[0]; },
 124         'load_nms'       => sub { return $self->load_nms; },
 125         'get_serviceids'    => sub { my $nms = shift;
 126                                   my $router = shift;
 127                                   return $nms->get_router_serviceids($router);
 128                                 },
 129         'popup_link'     => sub {
 130           my $type = shift;
 131
 132           if($type eq 'nms-add_iface.html') {
 133               my $host = shift;
 134               my $iface = shift;
 135               my $nms = shift;
 136               my $serviceids = shift;
 137
 138               if ( $serviceids && $serviceids->{$iface} ) {
 139
 140                 my $svc_port = $nms->find_svc($serviceids->{$iface});
 141
 142                 if ($svc_port) {
 143                    my $url = $Torrus::Freeside::FSURL.
 144                              "/view/svc_port.cgi?". $svc_port->svcnum;
 145                    return "<A HREF='$url'>View Service</A>";
 146                 } else {
 147                    return 'Monitored as '. $serviceids->{$iface}.
 148                           '; customer service not yet provisioned';
 149                 }
 150
 151               } else {
 152
 153                return
 154                    $self->freesideComponent('/elements/popup_link.html',
 155                        'action' => "/freeside/misc/".
 156                                $type."?host=$host;iface=$iface",
 157                         'label' => 'Monitor for billing',
 158                         'actionlabel' => 'Monitor interface',
 159                    );
 160
 161               }
 162
 163           } elsif ($type eq 'nms-add_router.html') {
 164                return
 165                    $self->freesideComponent('/elements/popup_link.html',
 166                        'action' => "/freeside/misc/$type",
 167                         'label' => 'Add Router',
 168                         'actionlabel' => 'Add Router',
 169                    );
 170           }
 171
 172           '';
 173        },
 174
 175     };
 176
 177
 178     # Pass the options from Torrus::Renderer::render() to Template
 179     while( my( $opt, $val ) = each( %{$self->{'options'}} ) )
 180     {
 181         $ttvars->{$opt} = $val;
 182     }
 183
 184     my $result = $self->{'tt'}->process( $tmplfile, $ttvars, $outfile );
 185
 186     undef $ttvars;
 187
 188     if( not $result )
 189     {
 190         if( $config_tree->isTset( $token ) )
 191         {
 192             Error("Error while rendering tokenset $token: " .
 193                   $self->{'tt'}->error());
 194         }
 195         else
 196         {
 197             my $path = $config_tree->path($token);
 198             Error("Error while rendering $path: " .
 199                   $self->{'tt'}->error());
 200         }
 201         return undef;
 202     }
 203
 204     return ($expires+time(), 'text/html; charset=UTF-8');
 205 }
 206
 207
 208 sub nodeName
 209 {
 210     my $self = shift;
 211     my $config_tree = shift;
 212     my $token = shift;
 213
 214     my $n = $config_tree->getNodeParam($token, 'node-display-name', 1);
 215     if( defined( $n ) and length( $n ) > 0 )
 216     {
 217         return $n;
 218     }
 219
 220     return $config_tree->nodeName($config_tree->path($token));
 221 }
 222
 223
 224 sub sortTokens
 225 {
 226     my $self = shift;
 227     my $config_tree = shift;
 228     my $tokenlist = shift;
 229
 230     my @sorted = ();
 231     if( ref($tokenlist) and scalar(@{$tokenlist}) > 0 )
 232     {
 233         @sorted = sort
 234         {
 235             my $p_a = $config_tree->getNodeParam($a, 'precedence', 1);
 236             $p_a = 0 unless defined $p_a;
 237             my $p_b = $config_tree->getNodeParam($b, 'precedence', 1);
 238             $p_b = 0 unless defined $p_b;
 239             if( $p_a == $p_b )
 240             {
 241                 my $n_a = $config_tree->path($a);
 242                 my $n_b = $config_tree->path($b);
 243                 return $n_a cmp $n_b;
 244             }
 245             else
 246             {
 247                 return $p_b <=> $p_a;
 248             }
 249         } @{$tokenlist};
 250     }
 251     else
 252     {
 253         push(@sorted, $tokenlist);
 254     }
 255     return @sorted;
 256 }
 257
 258
 259 # compose an URL for a node.
 260 # $persistent defines if the link should be persistent
 261 # Persistent link is done with nodeid if available, or with path
 262
 263 sub makeURL
 264 {
 265     my $self = shift;
 266     my $config_tree = shift;
 267     my $persistent = shift;
 268     my $token = shift;
 269     my $view = shift;
 270     my @add_vars = @_;
 271
 272     my $ret = $Torrus::Renderer::rendererURL . '/' . $config_tree->treeName();
 273
 274     if( $persistent )
 275     {
 276         my $nodeid = $config_tree->getNodeParam($token, 'nodeid', 1);
 277         if( defined( $nodeid ) )
 278         {
 279             $ret .= '?nodeid=' .
 280                 uri_escape($nodeid, $Torrus::Renderer::uriEscapeExceptions);
 281         }
 282         else
 283         {
 284             $ret .= '?path=' .
 285                 uri_escape($config_tree->path($token),
 286                            $Torrus::Renderer::uriEscapeExceptions);
 287         }
 288     }
 289     else
 290     {
 291         $ret .= '?token=' . uri_escape($token);
 292     }
 293
 294     if( $view )
 295     {
 296         $ret .= '&amp;view=' . uri_escape($view);
 297     }
 298
 299     my %vars = ();
 300     # This could be array or a reference to array
 301     my $add_vars_size = scalar( @add_vars );
 302     if( $add_vars_size == 1 and ref( $add_vars[0] ) )
 303     {
 304         %vars = @{$add_vars[0]};
 305     }
 306     elsif( $add_vars_size > 0 and ($add_vars_size % 2 == 0) )
 307     {
 308         %vars = @add_vars;
 309     }
 310
 311     if( ref( $self->{'options'}->{'variables'} ) )
 312     {
 313         foreach my $name ( sort keys %{$self->{'options'}->{'variables'}} )
 314         {
 315             my $val = $self->{'options'}->{'variables'}->{$name};
 316             if( not defined( $vars{$name} ) )
 317             {
 318                 $vars{$name} = $val;
 319             }
 320         }
 321     }
 322
 323     foreach my $name ( sort keys %vars )
 324     {
 325         if( $vars{$name} ne '' )
 326         {
 327             $ret .= '&amp;' . $name . '=' .
 328                 uri_escape( $vars{$name},
 329                             $Torrus::Renderer::uriEscapeExceptions );
 330         }
 331     }
 332
 333     return $ret;
 334 }
 335
 336 sub makeSplitURLs
 337 {
 338     my $self = shift;
 339     my $config_tree = shift;
 340     my $token = shift;
 341     my $view = shift;
 342
 343     my $ret = '';
 344     while( defined( $token ) )
 345     {
 346         my $path = $config_tree->path($token);
 347
 348         my $str = '<SPAN CLASS="PathElement">';
 349         $str .=
 350             sprintf('<A HREF="%s">%s%s</A>',
 351                     $self->makeURL($config_tree, 0, $token, $view),
 352                     $config_tree->nodeName($path),
 353                     ( $config_tree->isSubtree($token) and
 354                       $path ne '/') ? '/':'' );
 355         $str .= "</SPAN>\n";
 356
 357         $ret = $str . $ret;
 358
 359         $token = $config_tree->getParent( $token );
 360     }
 361
 362     return $ret;
 363 }
 364
 365
 366 sub rrPrint
 367 {
 368     my $self = shift;
 369     my $config_tree = shift;
 370     my $token = shift;
 371     my $view = shift;
 372
 373     my @ret = ();
 374     my($fname, $mimetype) = $self->render( $config_tree, $token, $view );
 375
 376     if( $mimetype ne 'text/plain' )
 377     {
 378         Error("View $view does not produce text/plain for token $token");
 379     }
 380     else
 381     {
 382         if( not open(IN, $fname) )
 383         {
 384             Error("Cannot open $fname for reading: $!");
 385         }
 386         else
 387         {
 388             chomp(my $values = <IN>);
 389             @ret = split(':', $values);
 390             close IN;
 391         }
 392     }
 393     return @ret;
 394 }
 395
 396 # This subroutine is taken from Dave Plonka's Flowscan
 397
 398 sub scale
 399 {
 400     my $self = shift;
 401     # This is based somewhat on Tobi Oetiker's code in rrd_graph.c:
 402     my $fmt = shift;
 403     my $value = shift;
 404     my @symbols = ("a", # 10e-18 Ato
 405                    "f", # 10e-15 Femto
 406                    "p", # 10e-12 Pico
 407                    "n", # 10e-9  Nano
 408                    "u", # 10e-6  Micro
 409                    "m", # 10e-3  Milli
 410                    " ", # Base
 411                    "k", # 10e3   Kilo
 412                    "M", # 10e6   Mega
 413                    "G", # 10e9   Giga
 414                    "T", # 10e12  Terra
 415                    "P", # 10e15  Peta
 416                    "E"); # 10e18  Exa
 417
 418     my $symbcenter = 6;
 419     my $digits = (0 == $value)? 0 : floor(log(abs($value))/log(1000));
 420     return sprintf( $fmt . " %s", $value/pow(1000, $digits),
 421                     $symbols[ $symbcenter+$digits ] );
 422 }
 423
 424 sub style
 425 {
 426     my $self = shift;
 427     my $object = shift;
 428
 429     my $media;
 430     if( not defined( $media = $self->{'options'}->{'variables'}->{'MEDIA'} ) )
 431     {
 432         $media = 'default';
 433     }
 434     return  $Torrus::Renderer::styling{$media}{$object};
 435 }
 436
 437
 438
 439 sub userAttribute
 440 {
 441     my $self = shift;
 442     my $attr = shift;
 443
 444     if( $self->{'options'}->{'uid'} and $self->{'options'}->{'acl'} )
 445     {
 446         $self->{'options'}->{'acl'}->
 447             userAttribute( $self->{'options'}->{'uid'}, $attr );
 448     }
 449     else
 450     {
 451         return '';
 452     }
 453 }
 454
 455 sub hasPrivilege
 456 {
 457     my $self = shift;
 458     my $object = shift;
 459     my $privilege = shift;
 460
 461     if( $self->{'options'}->{'uid'} and $self->{'options'}->{'acl'} )
 462     {
 463         $self->{'options'}->{'acl'}->
 464             hasPrivilege( $self->{'options'}->{'uid'}, $object, $privilege );
 465     }
 466     else
 467     {
 468         return undef;
 469     }
 470 }
 471
 472
 473 sub translateMarkup
 474 {
 475     my $self = shift;
 476     my @strings = @_;
 477
 478     my $tt = new Template( TRIM => 1 );
 479
 480     my $ttvars =
 481     {
 482         'em'      =>  sub { return '<em>' . $_[0] . '</em>'; },
 483         'strong'  =>  sub { return '<strong>' . $_[0] . '</strong>'; }
 484     };
 485
 486     my $ret = '';
 487
 488     foreach my $str ( @strings )
 489     {
 490         my $output = '';
 491         my $result = $tt->process( \$str, $ttvars, \$output );
 492
 493         if( not $result )
 494         {
 495             Error('Error translating markup: ' . $tt->error());
 496         }
 497         else
 498         {
 499             $ret .= $output;
 500         }
 501     }
 502
 503     undef $tt;
 504
 505     return $ret;
 506 }
 507
 508
 509 sub verifyDate
 510 {
 511     my $input = shift;
 512
 513     my $time = str2time( $input );
 514     # rrdtool does not understand dates prior to 1980 (315529200)
 515     if( defined( $time ) and $time > 315529200 )
 516     {
 517         # Present the time in format understood by rrdtool
 518         return time2str('%H:%M %Y%m%d', $time);
 519     }
 520     else
 521     {
 522         return '';
 523     }
 524 }
 525
 526
 527 sub may_display_reports
 528 {
 529     my $self = shift;
 530     my $config_tree = shift;
 531
 532     if( $Torrus::Renderer::displayReports )
 533     {
 534         if( not $Torrus::CGI::authorizeUsers )
 535         {
 536             return 1;
 537         }
 538
 539         my $tree = $config_tree->treeName();
 540         if( $self->hasPrivilege( $tree, 'DisplayReports' ) and
 541             -r $Torrus::Global::reportsDir . '/' . $tree .
 542             '/html/index.html' )
 543         {
 544             return 1;
 545         }
 546     }
 547     return 0;
 548 }
 549
 550
 551 sub reportsUrl
 552 {
 553     my $self = shift;
 554     my $config_tree = shift;
 555
 556     return $Torrus::Renderer::rendererURL . '/' .
 557         $config_tree->treeName() . '?htmlreport=index.html';
 558 }
 559
 560
 561 sub doSearch
 562 {
 563     my $self = shift;
 564     my $config_tree = shift;
 565     my $string = shift;
 566
 567
 568     my $tree = $config_tree->treeName();
 569
 570     my $sr = new Torrus::Search;
 571     $sr->openTree( $tree );
 572     my $result = $sr->searchPrefix( $string, $tree );
 573     $sr->closeTree( $tree );
 574
 575     my $ret = [];
 576     push( @{$ret}, sort {$a->[0] cmp $b->[0]} @{$result} );
 577
 578     return $ret;
 579 }
 580
 581
 582 1;
 583
 584
 585 # Local Variables:
 586 # mode: perl
 587 # indent-tabs-mode: nil
 588 # perl-indent-level: 4
 589 # End: