torrus/perllib/Torrus/Renderer/HTML.pm

   1 #  Copyright (C) 2002  Stanislav Sinyagin
   2 #
   3 #  This program is free software; you can redistribute it and/or modify
   4 #  it under the terms of the GNU General Public License as published by
   5 #  the Free Software Foundation; either version 2 of the License, or
   6 #  (at your option) any later version.
   7 #
   8 #  This program is distributed in the hope that it will be useful,
   9 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 #  GNU General Public License for more details.
  12 #
  13 #  You should have received a copy of the GNU General Public License
  14 #  along with this program; if not, write to the Free Software
  15 #  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307, USA.
  16
  17 # $Id: HTML.pm,v 1.5 2011-01-28 02:49:15 levinse Exp $
  18 # Stanislav Sinyagin <ssinyagin@yahoo.com>
  19
  20 package Torrus::Renderer::HTML;
  21
  22 use strict;
  23
  24 use Torrus::ConfigTree;
  25 use Torrus::Search;
  26 use Torrus::Log;
  27
  28 use URI::Escape;
  29 use Template;
  30 use POSIX qw(abs log floor pow);
  31 use Date::Parse;
  32 use Date::Format;
  33
  34 Torrus::SiteConfig::loadStyling();
  35
  36 # All our methods are imported by Torrus::Renderer;
  37
  38 sub render_html
  39 {
  40     my $self = shift;
  41     my $config_tree = shift;
  42     my $token = shift;
  43     my $view = shift;
  44     my $outfile = shift;
  45
  46     my $tmplfile = $config_tree->getParam($view, 'html-template');
  47
  48     my $expires = $config_tree->getParam($view, 'expires');
  49
  50     # Create the Template Toolkit processor once, and reuse
  51     # it in subsequent render() calls
  52
  53     if( not defined( $self->{'tt'} ) )
  54     {
  55         $self->{'tt'} =
  56             new Template(INCLUDE_PATH => $Torrus::Global::templateDirs,
  57                          TRIM => 1);
  58     }
  59     my $ttvars =
  60     {
  61         'treeName'   => $config_tree->treeName(),
  62         'token'      => $token,
  63         'view'       => $view,
  64         'expires'    => $expires,
  65         'path'       => sub { return $config_tree->path($_[0]); },
  66         'pathToken'  => sub { return $config_tree->token($_[0]); },
  67         'nodeExists' => sub { return $config_tree->nodeExists($_[0]); },
  68         'children'   => sub { return $config_tree->getChildren($_[0]); },
  69         'isLeaf'     => sub { return $config_tree->isLeaf($_[0]); },
  70         'isAlias'    => sub { return $config_tree->isAlias($_[0]); },
  71         'sortTokens' => sub { return $self->sortTokens($config_tree,
  72                                                        $_[0]); },
  73         'nodeName'   => sub { return $self->nodeName($config_tree, $_[0]); },
  74         'parent'     => sub { return $config_tree->getParent($_[0]); },
  75         'nodeParam'  => sub { return $config_tree->getNodeParam(@_); },
  76         'param'      => sub { return $config_tree->getParam(@_); },
  77         'url'        => sub { return $self->makeURL($config_tree, 0, @_); },
  78         'persistentUrl' => sub { return $self->makeURL($config_tree, 1, @_); },
  79         'clearVar'   => sub { delete $self->{'options'}{'variables'}{$_[0]};
  80                               return undef;},
  81         'plainURL'   => $Torrus::Renderer::plainURL,
  82         'splitUrls'  => sub { return $self->makeSplitURLs($config_tree,
  83                                                           $_[0], $_[1]); },
  84         'topURL'     => ($Torrus::Renderer::rendererURL ne '' ?
  85                          $Torrus::Renderer::rendererURL : '/'),
  86         'rrprint'    => sub { return $self->rrPrint($config_tree,
  87                                                     $_[0], $_[1]); },
  88         'scale'      => sub { return $self->scale($_[0], $_[1]); },
  89         'tsetMembers' => sub { $config_tree->tsetMembers($_[0]); },
  90         'tsetList'   => sub { $config_tree->getTsets(); },
  91         'style'      => sub { return $self->style($_[0]); },
  92         'companyName'=> $Torrus::Renderer::companyName,
  93         'companyLogo'=> $Torrus::Renderer::companyLogo,
  94         'companyURL' => $Torrus::Renderer::companyURL,
  95         'siteInfo'   => $Torrus::Renderer::siteInfo,
  96         'treeInfo'   => sub { return $Torrus::Global::treeConfig{
  97             $config_tree->treeName()}{'info'}; },
  98         'version'    => $Torrus::Global::version,
  99         'xmlnorm'    => \&Torrus::Renderer::xmlnormalize,
 100         'userAuth'   => $Torrus::CGI::authorizeUsers,
 101         'uid'        => $self->{'options'}->{'uid'},
 102         'userAttr'   => sub { return $self->userAttribute( $_[0] ) },
 103         'mayDisplayAdmInfo' => sub {
 104             return $self->may_display_adminfo( $config_tree, $_[0] ) },
 105         'adminfo' => $self->{'adminfo'},
 106         'mayDisplayReports' => sub {
 107             return $self->may_display_reports($config_tree) },
 108         'reportsUrl' => sub {
 109             return $self->reportsUrl($config_tree); },
 110         'timestamp'  => sub { return time2str($Torrus::Renderer::timeFormat,
 111                                               time()); },
 112         'verifyDate'  => sub { return verifyDate($_[0]); },
 113         'markup'     => sub{ return $self->translateMarkup( @_ ); },
 114         'searchEnabled' => $Torrus::Renderer::searchEnabled,
 115         'searchResults' => sub { return $self->doSearch($config_tree, $_[0]); },
 116
 117         #Freeside
 118         'freesideHeader' => sub { return $self->freesideHeader(@_); },
 119         'freesideFooter' => sub { return $self->freesideFooter(); },
 120         'freesideComponent' => sub { return $self->freesideComponent(@_); },
 121         'uri_escape'        => sub { return uri_escape(@_); },
 122         'matches'        => sub { return $_[0] =~ $_[1]; },
 123         'popup_link'     => sub {
 124                                    my $type = shift;
 125
 126                                    if($type eq 'nms-add_iface.html') {
 127                                        my $host = shift;
 128                                        my $iface = shift;
 129                                         return
 130                                             $self->freesideComponent('/elements/popup_link.html',
 131                                                 'action' => "/freeside/misc/".
 132                                                         $type."?host=$host;iface=$iface",
 133                                                  'label' => 'Monitor for billing',
 134                                                  'actionlabel' => 'Monitor interface',
 135                                             );
 136                                    }
 137                                    '';
 138                                 },
 139
 140     };
 141
 142
 143     # Pass the options from Torrus::Renderer::render() to Template
 144     while( my( $opt, $val ) = each( %{$self->{'options'}} ) )
 145     {
 146         $ttvars->{$opt} = $val;
 147     }
 148
 149     my $result = $self->{'tt'}->process( $tmplfile, $ttvars, $outfile );
 150
 151     undef $ttvars;
 152
 153     if( not $result )
 154     {
 155         if( $config_tree->isTset( $token ) )
 156         {
 157             Error("Error while rendering tokenset $token: " .
 158                   $self->{'tt'}->error());
 159         }
 160         else
 161         {
 162             my $path = $config_tree->path($token);
 163             Error("Error while rendering $path: " .
 164                   $self->{'tt'}->error());
 165         }
 166         return undef;
 167     }
 168
 169     return ($expires+time(), 'text/html; charset=UTF-8');
 170 }
 171
 172
 173 sub nodeName
 174 {
 175     my $self = shift;
 176     my $config_tree = shift;
 177     my $token = shift;
 178
 179     my $n = $config_tree->getNodeParam($token, 'node-display-name', 1);
 180     if( defined( $n ) and length( $n ) > 0 )
 181     {
 182         return $n;
 183     }
 184
 185     return $config_tree->nodeName($config_tree->path($token));
 186 }
 187
 188
 189 sub sortTokens
 190 {
 191     my $self = shift;
 192     my $config_tree = shift;
 193     my $tokenlist = shift;
 194
 195     my @sorted = ();
 196     if( ref($tokenlist) and scalar(@{$tokenlist}) > 0 )
 197     {
 198         @sorted = sort
 199         {
 200             my $p_a = $config_tree->getNodeParam($a, 'precedence', 1);
 201             $p_a = 0 unless defined $p_a;
 202             my $p_b = $config_tree->getNodeParam($b, 'precedence', 1);
 203             $p_b = 0 unless defined $p_b;
 204             if( $p_a == $p_b )
 205             {
 206                 my $n_a = $config_tree->path($a);
 207                 my $n_b = $config_tree->path($b);
 208                 return $n_a cmp $n_b;
 209             }
 210             else
 211             {
 212                 return $p_b <=> $p_a;
 213             }
 214         } @{$tokenlist};
 215     }
 216     else
 217     {
 218         push(@sorted, $tokenlist);
 219     }
 220     return @sorted;
 221 }
 222
 223
 224 # compose an URL for a node.
 225 # $persistent defines if the link should be persistent
 226 # Persistent link is done with nodeid if available, or with path
 227
 228 sub makeURL
 229 {
 230     my $self = shift;
 231     my $config_tree = shift;
 232     my $persistent = shift;
 233     my $token = shift;
 234     my $view = shift;
 235     my @add_vars = @_;
 236
 237     my $ret = $Torrus::Renderer::rendererURL . '/' . $config_tree->treeName();
 238
 239     if( $persistent )
 240     {
 241         my $nodeid = $config_tree->getNodeParam($token, 'nodeid', 1);
 242         if( defined( $nodeid ) )
 243         {
 244             $ret .= '?nodeid=' .
 245                 uri_escape($nodeid, $Torrus::Renderer::uriEscapeExceptions);
 246         }
 247         else
 248         {
 249             $ret .= '?path=' .
 250                 uri_escape($config_tree->path($token),
 251                            $Torrus::Renderer::uriEscapeExceptions);
 252         }
 253     }
 254     else
 255     {
 256         $ret .= '?token=' . uri_escape($token);
 257     }
 258
 259     if( $view )
 260     {
 261         $ret .= '&amp;view=' . uri_escape($view);
 262     }
 263
 264     my %vars = ();
 265     # This could be array or a reference to array
 266     my $add_vars_size = scalar( @add_vars );
 267     if( $add_vars_size == 1 and ref( $add_vars[0] ) )
 268     {
 269         %vars = @{$add_vars[0]};
 270     }
 271     elsif( $add_vars_size > 0 and ($add_vars_size % 2 == 0) )
 272     {
 273         %vars = @add_vars;
 274     }
 275
 276     if( ref( $self->{'options'}->{'variables'} ) )
 277     {
 278         foreach my $name ( sort keys %{$self->{'options'}->{'variables'}} )
 279         {
 280             my $val = $self->{'options'}->{'variables'}->{$name};
 281             if( not defined( $vars{$name} ) )
 282             {
 283                 $vars{$name} = $val;
 284             }
 285         }
 286     }
 287
 288     foreach my $name ( sort keys %vars )
 289     {
 290         if( $vars{$name} ne '' )
 291         {
 292             $ret .= '&amp;' . $name . '=' .
 293                 uri_escape( $vars{$name},
 294                             $Torrus::Renderer::uriEscapeExceptions );
 295         }
 296     }
 297
 298     return $ret;
 299 }
 300
 301 sub makeSplitURLs
 302 {
 303     my $self = shift;
 304     my $config_tree = shift;
 305     my $token = shift;
 306     my $view = shift;
 307
 308     my $ret = '';
 309     while( defined( $token ) )
 310     {
 311         my $path = $config_tree->path($token);
 312
 313         my $str = '<SPAN CLASS="PathElement">';
 314         $str .=
 315             sprintf('<A HREF="%s">%s%s</A>',
 316                     $self->makeURL($config_tree, 0, $token, $view),
 317                     $config_tree->nodeName($path),
 318                     ( $config_tree->isSubtree($token) and
 319                       $path ne '/') ? '/':'' );
 320         $str .= "</SPAN>\n";
 321
 322         $ret = $str . $ret;
 323
 324         $token = $config_tree->getParent( $token );
 325     }
 326
 327     return $ret;
 328 }
 329
 330
 331 sub rrPrint
 332 {
 333     my $self = shift;
 334     my $config_tree = shift;
 335     my $token = shift;
 336     my $view = shift;
 337
 338     my @ret = ();
 339     my($fname, $mimetype) = $self->render( $config_tree, $token, $view );
 340
 341     if( $mimetype ne 'text/plain' )
 342     {
 343         Error("View $view does not produce text/plain for token $token");
 344     }
 345     else
 346     {
 347         if( not open(IN, $fname) )
 348         {
 349             Error("Cannot open $fname for reading: $!");
 350         }
 351         else
 352         {
 353             chomp(my $values = <IN>);
 354             @ret = split(':', $values);
 355             close IN;
 356         }
 357     }
 358     return @ret;
 359 }
 360
 361 # This subroutine is taken from Dave Plonka's Flowscan
 362
 363 sub scale
 364 {
 365     my $self = shift;
 366     # This is based somewhat on Tobi Oetiker's code in rrd_graph.c:
 367     my $fmt = shift;
 368     my $value = shift;
 369     my @symbols = ("a", # 10e-18 Ato
 370                    "f", # 10e-15 Femto
 371                    "p", # 10e-12 Pico
 372                    "n", # 10e-9  Nano
 373                    "u", # 10e-6  Micro
 374                    "m", # 10e-3  Milli
 375                    " ", # Base
 376                    "k", # 10e3   Kilo
 377                    "M", # 10e6   Mega
 378                    "G", # 10e9   Giga
 379                    "T", # 10e12  Terra
 380                    "P", # 10e15  Peta
 381                    "E"); # 10e18  Exa
 382
 383     my $symbcenter = 6;
 384     my $digits = (0 == $value)? 0 : floor(log(abs($value))/log(1000));
 385     return sprintf( $fmt . " %s", $value/pow(1000, $digits),
 386                     $symbols[ $symbcenter+$digits ] );
 387 }
 388
 389 sub style
 390 {
 391     my $self = shift;
 392     my $object = shift;
 393
 394     my $media;
 395     if( not defined( $media = $self->{'options'}->{'variables'}->{'MEDIA'} ) )
 396     {
 397         $media = 'default';
 398     }
 399     return  $Torrus::Renderer::styling{$media}{$object};
 400 }
 401
 402
 403
 404 sub userAttribute
 405 {
 406     my $self = shift;
 407     my $attr = shift;
 408
 409     if( $self->{'options'}->{'uid'} and $self->{'options'}->{'acl'} )
 410     {
 411         $self->{'options'}->{'acl'}->
 412             userAttribute( $self->{'options'}->{'uid'}, $attr );
 413     }
 414     else
 415     {
 416         return '';
 417     }
 418 }
 419
 420 sub hasPrivilege
 421 {
 422     my $self = shift;
 423     my $object = shift;
 424     my $privilege = shift;
 425
 426     if( $self->{'options'}->{'uid'} and $self->{'options'}->{'acl'} )
 427     {
 428         $self->{'options'}->{'acl'}->
 429             hasPrivilege( $self->{'options'}->{'uid'}, $object, $privilege );
 430     }
 431     else
 432     {
 433         return undef;
 434     }
 435 }
 436
 437
 438 sub translateMarkup
 439 {
 440     my $self = shift;
 441     my @strings = @_;
 442
 443     my $tt = new Template( TRIM => 1 );
 444
 445     my $ttvars =
 446     {
 447         'em'      =>  sub { return '<em>' . $_[0] . '</em>'; },
 448         'strong'  =>  sub { return '<strong>' . $_[0] . '</strong>'; }
 449     };
 450
 451     my $ret = '';
 452
 453     foreach my $str ( @strings )
 454     {
 455         my $output = '';
 456         my $result = $tt->process( \$str, $ttvars, \$output );
 457
 458         if( not $result )
 459         {
 460             Error('Error translating markup: ' . $tt->error());
 461         }
 462         else
 463         {
 464             $ret .= $output;
 465         }
 466     }
 467
 468     undef $tt;
 469
 470     return $ret;
 471 }
 472
 473
 474 sub verifyDate
 475 {
 476     my $input = shift;
 477
 478     my $time = str2time( $input );
 479     # rrdtool does not understand dates prior to 1980 (315529200)
 480     if( defined( $time ) and $time > 315529200 )
 481     {
 482         # Present the time in format understood by rrdtool
 483         return time2str('%H:%M %Y%m%d', $time);
 484     }
 485     else
 486     {
 487         return '';
 488     }
 489 }
 490
 491
 492 sub may_display_reports
 493 {
 494     my $self = shift;
 495     my $config_tree = shift;
 496
 497     if( $Torrus::Renderer::displayReports )
 498     {
 499         if( not $Torrus::CGI::authorizeUsers )
 500         {
 501             return 1;
 502         }
 503
 504         my $tree = $config_tree->treeName();
 505         if( $self->hasPrivilege( $tree, 'DisplayReports' ) and
 506             -r $Torrus::Global::reportsDir . '/' . $tree .
 507             '/html/index.html' )
 508         {
 509             return 1;
 510         }
 511     }
 512     return 0;
 513 }
 514
 515
 516 sub reportsUrl
 517 {
 518     my $self = shift;
 519     my $config_tree = shift;
 520
 521     return $Torrus::Renderer::rendererURL . '/' .
 522         $config_tree->treeName() . '?htmlreport=index.html';
 523 }
 524
 525
 526 sub doSearch
 527 {
 528     my $self = shift;
 529     my $config_tree = shift;
 530     my $string = shift;
 531
 532
 533     my $tree = $config_tree->treeName();
 534
 535     my $sr = new Torrus::Search;
 536     $sr->openTree( $tree );
 537     my $result = $sr->searchPrefix( $string, $tree );
 538     $sr->closeTree( $tree );
 539
 540     my $ret = [];
 541     push( @{$ret}, sort {$a->[0] cmp $b->[0]} @{$result} );
 542
 543     return $ret;
 544 }
 545
 546
 547 1;
 548
 549
 550 # Local Variables:
 551 # mode: perl
 552 # indent-tabs-mode: nil
 553 # perl-indent-level: 4
 554 # End: