torrus/perllib/Torrus/Renderer/HTML.pm

   1 #  Copyright (C) 2002  Stanislav Sinyagin
   2 #
   3 #  This program is free software; you can redistribute it and/or modify
   4 #  it under the terms of the GNU General Public License as published by
   5 #  the Free Software Foundation; either version 2 of the License, or
   6 #  (at your option) any later version.
   7 #
   8 #  This program is distributed in the hope that it will be useful,
   9 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 #  GNU General Public License for more details.
  12 #
  13 #  You should have received a copy of the GNU General Public License
  14 #  along with this program; if not, write to the Free Software
  15 #  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307, USA.
  16
  17 # $Id: HTML.pm,v 1.3 2010-12-29 02:09:06 ivan Exp $
  18 # Stanislav Sinyagin <ssinyagin@yahoo.com>
  19
  20 package Torrus::Renderer::HTML;
  21
  22 use strict;
  23
  24 use Torrus::ConfigTree;
  25 use Torrus::Search;
  26 use Torrus::Log;
  27
  28 use URI::Escape;
  29 use Template;
  30 use POSIX qw(abs log floor pow);
  31 use Date::Parse;
  32 use Date::Format;
  33
  34 Torrus::SiteConfig::loadStyling();
  35
  36 # All our methods are imported by Torrus::Renderer;
  37
  38 sub render_html
  39 {
  40     my $self = shift;
  41     my $config_tree = shift;
  42     my $token = shift;
  43     my $view = shift;
  44     my $outfile = shift;
  45
  46     my $tmplfile = $config_tree->getParam($view, 'html-template');
  47
  48     my $expires = $config_tree->getParam($view, 'expires');
  49
  50     # Create the Template Toolkit processor once, and reuse
  51     # it in subsequent render() calls
  52
  53     if( not defined( $self->{'tt'} ) )
  54     {
  55         $self->{'tt'} =
  56             new Template(INCLUDE_PATH => $Torrus::Global::templateDirs,
  57                          TRIM => 1);
  58     }
  59     my $ttvars =
  60     {
  61         'treeName'   => $config_tree->treeName(),
  62         'token'      => $token,
  63         'view'       => $view,
  64         'expires'    => $expires,
  65         'path'       => sub { return $config_tree->path($_[0]); },
  66         'pathToken'  => sub { return $config_tree->token($_[0]); },
  67         'nodeExists' => sub { return $config_tree->nodeExists($_[0]); },
  68         'children'   => sub { return $config_tree->getChildren($_[0]); },
  69         'isLeaf'     => sub { return $config_tree->isLeaf($_[0]); },
  70         'isAlias'    => sub { return $config_tree->isAlias($_[0]); },
  71         'sortTokens' => sub { return $self->sortTokens($config_tree,
  72                                                        $_[0]); },
  73         'nodeName'   => sub { return $self->nodeName($config_tree, $_[0]); },
  74         'parent'     => sub { return $config_tree->getParent($_[0]); },
  75         'nodeParam'  => sub { return $config_tree->getNodeParam(@_); },
  76         'param'      => sub { return $config_tree->getParam(@_); },
  77         'url'        => sub { return $self->makeURL($config_tree, 0, @_); },
  78         'persistentUrl' => sub { return $self->makeURL($config_tree, 1, @_); },
  79         'clearVar'   => sub { delete $self->{'options'}{'variables'}{$_[0]};
  80                               return undef;},
  81         'plainURL'   => $Torrus::Renderer::plainURL,
  82         'splitUrls'  => sub { return $self->makeSplitURLs($config_tree,
  83                                                           $_[0], $_[1]); },
  84         'topURL'     => ($Torrus::Renderer::rendererURL ne '' ?
  85                          $Torrus::Renderer::rendererURL : '/'),
  86         'rrprint'    => sub { return $self->rrPrint($config_tree,
  87                                                     $_[0], $_[1]); },
  88         'scale'      => sub { return $self->scale($_[0], $_[1]); },
  89         'tsetMembers' => sub { $config_tree->tsetMembers($_[0]); },
  90         'tsetList'   => sub { $config_tree->getTsets(); },
  91         'style'      => sub { return $self->style($_[0]); },
  92         'companyName'=> $Torrus::Renderer::companyName,
  93         'companyLogo'=> $Torrus::Renderer::companyLogo,
  94         'companyURL' => $Torrus::Renderer::companyURL,
  95         'siteInfo'   => $Torrus::Renderer::siteInfo,
  96         'treeInfo'   => sub { return $Torrus::Global::treeConfig{
  97             $config_tree->treeName()}{'info'}; },
  98         'version'    => $Torrus::Global::version,
  99         'xmlnorm'    => \&Torrus::Renderer::xmlnormalize,
 100         'userAuth'   => $Torrus::CGI::authorizeUsers,
 101         'uid'        => $self->{'options'}->{'uid'},
 102         'userAttr'   => sub { return $self->userAttribute( $_[0] ) },
 103         'mayDisplayAdmInfo' => sub {
 104             return $self->may_display_adminfo( $config_tree, $_[0] ) },
 105         'adminfo' => $self->{'adminfo'},
 106         'mayDisplayReports' => sub {
 107             return $self->may_display_reports($config_tree) },
 108         'reportsUrl' => sub {
 109             return $self->reportsUrl($config_tree); },
 110         'timestamp'  => sub { return time2str($Torrus::Renderer::timeFormat,
 111                                               time()); },
 112         'verifyDate'  => sub { return verifyDate($_[0]); },
 113         'markup'     => sub{ return $self->translateMarkup( @_ ); },
 114         'searchEnabled' => $Torrus::Renderer::searchEnabled,
 115         'searchResults' => sub { return $self->doSearch($config_tree, $_[0]); },
 116
 117         #Freeside
 118         'freesideHeader' => sub { return $self->freesideHeader(@_); },
 119         'freesideFooter' => sub { return $self->freesideFooter(); },
 120     };
 121
 122
 123     # Pass the options from Torrus::Renderer::render() to Template
 124     while( my( $opt, $val ) = each( %{$self->{'options'}} ) )
 125     {
 126         $ttvars->{$opt} = $val;
 127     }
 128
 129     my $result = $self->{'tt'}->process( $tmplfile, $ttvars, $outfile );
 130
 131     undef $ttvars;
 132
 133     if( not $result )
 134     {
 135         if( $config_tree->isTset( $token ) )
 136         {
 137             Error("Error while rendering tokenset $token: " .
 138                   $self->{'tt'}->error());
 139         }
 140         else
 141         {
 142             my $path = $config_tree->path($token);
 143             Error("Error while rendering $path: " .
 144                   $self->{'tt'}->error());
 145         }
 146         return undef;
 147     }
 148
 149     return ($expires+time(), 'text/html; charset=UTF-8');
 150 }
 151
 152
 153 sub nodeName
 154 {
 155     my $self = shift;
 156     my $config_tree = shift;
 157     my $token = shift;
 158
 159     my $n = $config_tree->getNodeParam($token, 'node-display-name', 1);
 160     if( defined( $n ) and length( $n ) > 0 )
 161     {
 162         return $n;
 163     }
 164
 165     return $config_tree->nodeName($config_tree->path($token));
 166 }
 167
 168
 169 sub sortTokens
 170 {
 171     my $self = shift;
 172     my $config_tree = shift;
 173     my $tokenlist = shift;
 174
 175     my @sorted = ();
 176     if( ref($tokenlist) and scalar(@{$tokenlist}) > 0 )
 177     {
 178         @sorted = sort
 179         {
 180             my $p_a = $config_tree->getNodeParam($a, 'precedence', 1);
 181             $p_a = 0 unless defined $p_a;
 182             my $p_b = $config_tree->getNodeParam($b, 'precedence', 1);
 183             $p_b = 0 unless defined $p_b;
 184             if( $p_a == $p_b )
 185             {
 186                 my $n_a = $config_tree->path($a);
 187                 my $n_b = $config_tree->path($b);
 188                 return $n_a cmp $n_b;
 189             }
 190             else
 191             {
 192                 return $p_b <=> $p_a;
 193             }
 194         } @{$tokenlist};
 195     }
 196     else
 197     {
 198         push(@sorted, $tokenlist);
 199     }
 200     return @sorted;
 201 }
 202
 203
 204 # compose an URL for a node.
 205 # $persistent defines if the link should be persistent
 206 # Persistent link is done with nodeid if available, or with path
 207
 208 sub makeURL
 209 {
 210     my $self = shift;
 211     my $config_tree = shift;
 212     my $persistent = shift;
 213     my $token = shift;
 214     my $view = shift;
 215     my @add_vars = @_;
 216
 217     my $ret = $Torrus::Renderer::rendererURL . '/' . $config_tree->treeName();
 218
 219     if( $persistent )
 220     {
 221         my $nodeid = $config_tree->getNodeParam($token, 'nodeid', 1);
 222         if( defined( $nodeid ) )
 223         {
 224             $ret .= '?nodeid=' .
 225                 uri_escape($nodeid, $Torrus::Renderer::uriEscapeExceptions);
 226         }
 227         else
 228         {
 229             $ret .= '?path=' .
 230                 uri_escape($config_tree->path($token),
 231                            $Torrus::Renderer::uriEscapeExceptions);
 232         }
 233     }
 234     else
 235     {
 236         $ret .= '?token=' . uri_escape($token);
 237     }
 238
 239     if( $view )
 240     {
 241         $ret .= '&amp;view=' . uri_escape($view);
 242     }
 243
 244     my %vars = ();
 245     # This could be array or a reference to array
 246     my $add_vars_size = scalar( @add_vars );
 247     if( $add_vars_size == 1 and ref( $add_vars[0] ) )
 248     {
 249         %vars = @{$add_vars[0]};
 250     }
 251     elsif( $add_vars_size > 0 and ($add_vars_size % 2 == 0) )
 252     {
 253         %vars = @add_vars;
 254     }
 255
 256     if( ref( $self->{'options'}->{'variables'} ) )
 257     {
 258         foreach my $name ( sort keys %{$self->{'options'}->{'variables'}} )
 259         {
 260             my $val = $self->{'options'}->{'variables'}->{$name};
 261             if( not defined( $vars{$name} ) )
 262             {
 263                 $vars{$name} = $val;
 264             }
 265         }
 266     }
 267
 268     foreach my $name ( sort keys %vars )
 269     {
 270         if( $vars{$name} ne '' )
 271         {
 272             $ret .= '&amp;' . $name . '=' .
 273                 uri_escape( $vars{$name},
 274                             $Torrus::Renderer::uriEscapeExceptions );
 275         }
 276     }
 277
 278     return $ret;
 279 }
 280
 281 sub makeSplitURLs
 282 {
 283     my $self = shift;
 284     my $config_tree = shift;
 285     my $token = shift;
 286     my $view = shift;
 287
 288     my $ret = '';
 289     while( defined( $token ) )
 290     {
 291         my $path = $config_tree->path($token);
 292
 293         my $str = '<SPAN CLASS="PathElement">';
 294         $str .=
 295             sprintf('<A HREF="%s">%s%s</A>',
 296                     $self->makeURL($config_tree, 0, $token, $view),
 297                     $config_tree->nodeName($path),
 298                     ( $config_tree->isSubtree($token) and
 299                       $path ne '/') ? '/':'' );
 300         $str .= "</SPAN>\n";
 301
 302         $ret = $str . $ret;
 303
 304         $token = $config_tree->getParent( $token );
 305     }
 306
 307     return $ret;
 308 }
 309
 310
 311 sub rrPrint
 312 {
 313     my $self = shift;
 314     my $config_tree = shift;
 315     my $token = shift;
 316     my $view = shift;
 317
 318     my @ret = ();
 319     my($fname, $mimetype) = $self->render( $config_tree, $token, $view );
 320
 321     if( $mimetype ne 'text/plain' )
 322     {
 323         Error("View $view does not produce text/plain for token $token");
 324     }
 325     else
 326     {
 327         if( not open(IN, $fname) )
 328         {
 329             Error("Cannot open $fname for reading: $!");
 330         }
 331         else
 332         {
 333             chomp(my $values = <IN>);
 334             @ret = split(':', $values);
 335             close IN;
 336         }
 337     }
 338     return @ret;
 339 }
 340
 341 # This subroutine is taken from Dave Plonka's Flowscan
 342
 343 sub scale
 344 {
 345     my $self = shift;
 346     # This is based somewhat on Tobi Oetiker's code in rrd_graph.c:
 347     my $fmt = shift;
 348     my $value = shift;
 349     my @symbols = ("a", # 10e-18 Ato
 350                    "f", # 10e-15 Femto
 351                    "p", # 10e-12 Pico
 352                    "n", # 10e-9  Nano
 353                    "u", # 10e-6  Micro
 354                    "m", # 10e-3  Milli
 355                    " ", # Base
 356                    "k", # 10e3   Kilo
 357                    "M", # 10e6   Mega
 358                    "G", # 10e9   Giga
 359                    "T", # 10e12  Terra
 360                    "P", # 10e15  Peta
 361                    "E"); # 10e18  Exa
 362
 363     my $symbcenter = 6;
 364     my $digits = (0 == $value)? 0 : floor(log(abs($value))/log(1000));
 365     return sprintf( $fmt . " %s", $value/pow(1000, $digits),
 366                     $symbols[ $symbcenter+$digits ] );
 367 }
 368
 369 sub style
 370 {
 371     my $self = shift;
 372     my $object = shift;
 373
 374     my $media;
 375     if( not defined( $media = $self->{'options'}->{'variables'}->{'MEDIA'} ) )
 376     {
 377         $media = 'default';
 378     }
 379     return  $Torrus::Renderer::styling{$media}{$object};
 380 }
 381
 382
 383
 384 sub userAttribute
 385 {
 386     my $self = shift;
 387     my $attr = shift;
 388
 389     if( $self->{'options'}->{'uid'} and $self->{'options'}->{'acl'} )
 390     {
 391         $self->{'options'}->{'acl'}->
 392             userAttribute( $self->{'options'}->{'uid'}, $attr );
 393     }
 394     else
 395     {
 396         return '';
 397     }
 398 }
 399
 400 sub hasPrivilege
 401 {
 402     my $self = shift;
 403     my $object = shift;
 404     my $privilege = shift;
 405
 406     if( $self->{'options'}->{'uid'} and $self->{'options'}->{'acl'} )
 407     {
 408         $self->{'options'}->{'acl'}->
 409             hasPrivilege( $self->{'options'}->{'uid'}, $object, $privilege );
 410     }
 411     else
 412     {
 413         return undef;
 414     }
 415 }
 416
 417
 418 sub translateMarkup
 419 {
 420     my $self = shift;
 421     my @strings = @_;
 422
 423     my $tt = new Template( TRIM => 1 );
 424
 425     my $ttvars =
 426     {
 427         'em'      =>  sub { return '<em>' . $_[0] . '</em>'; },
 428         'strong'  =>  sub { return '<strong>' . $_[0] . '</strong>'; }
 429     };
 430
 431     my $ret = '';
 432
 433     foreach my $str ( @strings )
 434     {
 435         my $output = '';
 436         my $result = $tt->process( \$str, $ttvars, \$output );
 437
 438         if( not $result )
 439         {
 440             Error('Error translating markup: ' . $tt->error());
 441         }
 442         else
 443         {
 444             $ret .= $output;
 445         }
 446     }
 447
 448     undef $tt;
 449
 450     return $ret;
 451 }
 452
 453
 454 sub verifyDate
 455 {
 456     my $input = shift;
 457
 458     my $time = str2time( $input );
 459     # rrdtool does not understand dates prior to 1980 (315529200)
 460     if( defined( $time ) and $time > 315529200 )
 461     {
 462         # Present the time in format understood by rrdtool
 463         return time2str('%H:%M %Y%m%d', $time);
 464     }
 465     else
 466     {
 467         return '';
 468     }
 469 }
 470
 471
 472 sub may_display_reports
 473 {
 474     my $self = shift;
 475     my $config_tree = shift;
 476
 477     if( $Torrus::Renderer::displayReports )
 478     {
 479         if( not $Torrus::CGI::authorizeUsers )
 480         {
 481             return 1;
 482         }
 483
 484         my $tree = $config_tree->treeName();
 485         if( $self->hasPrivilege( $tree, 'DisplayReports' ) and
 486             -r $Torrus::Global::reportsDir . '/' . $tree .
 487             '/html/index.html' )
 488         {
 489             return 1;
 490         }
 491     }
 492     return 0;
 493 }
 494
 495
 496 sub reportsUrl
 497 {
 498     my $self = shift;
 499     my $config_tree = shift;
 500
 501     return $Torrus::Renderer::rendererURL . '/' .
 502         $config_tree->treeName() . '?htmlreport=index.html';
 503 }
 504
 505
 506 sub doSearch
 507 {
 508     my $self = shift;
 509     my $config_tree = shift;
 510     my $string = shift;
 511
 512
 513     my $tree = $config_tree->treeName();
 514
 515     my $sr = new Torrus::Search;
 516     $sr->openTree( $tree );
 517     my $result = $sr->searchPrefix( $string, $tree );
 518     $sr->closeTree( $tree );
 519
 520     my $ret = [];
 521     push( @{$ret}, sort {$a->[0] cmp $b->[0]} @{$result} );
 522
 523     return $ret;
 524 }
 525
 526
 527 1;
 528
 529
 530 # Local Variables:
 531 # mode: perl
 532 # indent-tabs-mode: nil
 533 # perl-indent-level: 4
 534 # End: