torrus/perllib/Torrus/Renderer/HTML.pm

   1 #  Copyright (C) 2002  Stanislav Sinyagin
   2 #
   3 #  This program is free software; you can redistribute it and/or modify
   4 #  it under the terms of the GNU General Public License as published by
   5 #  the Free Software Foundation; either version 2 of the License, or
   6 #  (at your option) any later version.
   7 #
   8 #  This program is distributed in the hope that it will be useful,
   9 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 #  GNU General Public License for more details.
  12 #
  13 #  You should have received a copy of the GNU General Public License
  14 #  along with this program; if not, write to the Free Software
  15 #  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307, USA.
  16
  17 # $Id: HTML.pm,v 1.4 2011-01-25 03:15:03 ivan Exp $
  18 # Stanislav Sinyagin <ssinyagin@yahoo.com>
  19
  20 package Torrus::Renderer::HTML;
  21
  22 use strict;
  23
  24 use Torrus::ConfigTree;
  25 use Torrus::Search;
  26 use Torrus::Log;
  27
  28 use URI::Escape;
  29 use Template;
  30 use POSIX qw(abs log floor pow);
  31 use Date::Parse;
  32 use Date::Format;
  33
  34 Torrus::SiteConfig::loadStyling();
  35
  36 # All our methods are imported by Torrus::Renderer;
  37
  38 sub render_html
  39 {
  40     my $self = shift;
  41     my $config_tree = shift;
  42     my $token = shift;
  43     my $view = shift;
  44     my $outfile = shift;
  45
  46     my $tmplfile = $config_tree->getParam($view, 'html-template');
  47
  48     my $expires = $config_tree->getParam($view, 'expires');
  49
  50     # Create the Template Toolkit processor once, and reuse
  51     # it in subsequent render() calls
  52
  53     if( not defined( $self->{'tt'} ) )
  54     {
  55         $self->{'tt'} =
  56             new Template(INCLUDE_PATH => $Torrus::Global::templateDirs,
  57                          TRIM => 1);
  58     }
  59     my $ttvars =
  60     {
  61         'treeName'   => $config_tree->treeName(),
  62         'token'      => $token,
  63         'view'       => $view,
  64         'expires'    => $expires,
  65         'path'       => sub { return $config_tree->path($_[0]); },
  66         'pathToken'  => sub { return $config_tree->token($_[0]); },
  67         'nodeExists' => sub { return $config_tree->nodeExists($_[0]); },
  68         'children'   => sub { return $config_tree->getChildren($_[0]); },
  69         'isLeaf'     => sub { return $config_tree->isLeaf($_[0]); },
  70         'isAlias'    => sub { return $config_tree->isAlias($_[0]); },
  71         'sortTokens' => sub { return $self->sortTokens($config_tree,
  72                                                        $_[0]); },
  73         'nodeName'   => sub { return $self->nodeName($config_tree, $_[0]); },
  74         'parent'     => sub { return $config_tree->getParent($_[0]); },
  75         'nodeParam'  => sub { return $config_tree->getNodeParam(@_); },
  76         'param'      => sub { return $config_tree->getParam(@_); },
  77         'url'        => sub { return $self->makeURL($config_tree, 0, @_); },
  78         'persistentUrl' => sub { return $self->makeURL($config_tree, 1, @_); },
  79         'clearVar'   => sub { delete $self->{'options'}{'variables'}{$_[0]};
  80                               return undef;},
  81         'plainURL'   => $Torrus::Renderer::plainURL,
  82         'splitUrls'  => sub { return $self->makeSplitURLs($config_tree,
  83                                                           $_[0], $_[1]); },
  84         'topURL'     => ($Torrus::Renderer::rendererURL ne '' ?
  85                          $Torrus::Renderer::rendererURL : '/'),
  86         'rrprint'    => sub { return $self->rrPrint($config_tree,
  87                                                     $_[0], $_[1]); },
  88         'scale'      => sub { return $self->scale($_[0], $_[1]); },
  89         'tsetMembers' => sub { $config_tree->tsetMembers($_[0]); },
  90         'tsetList'   => sub { $config_tree->getTsets(); },
  91         'style'      => sub { return $self->style($_[0]); },
  92         'companyName'=> $Torrus::Renderer::companyName,
  93         'companyLogo'=> $Torrus::Renderer::companyLogo,
  94         'companyURL' => $Torrus::Renderer::companyURL,
  95         'siteInfo'   => $Torrus::Renderer::siteInfo,
  96         'treeInfo'   => sub { return $Torrus::Global::treeConfig{
  97             $config_tree->treeName()}{'info'}; },
  98         'version'    => $Torrus::Global::version,
  99         'xmlnorm'    => \&Torrus::Renderer::xmlnormalize,
 100         'userAuth'   => $Torrus::CGI::authorizeUsers,
 101         'uid'        => $self->{'options'}->{'uid'},
 102         'userAttr'   => sub { return $self->userAttribute( $_[0] ) },
 103         'mayDisplayAdmInfo' => sub {
 104             return $self->may_display_adminfo( $config_tree, $_[0] ) },
 105         'adminfo' => $self->{'adminfo'},
 106         'mayDisplayReports' => sub {
 107             return $self->may_display_reports($config_tree) },
 108         'reportsUrl' => sub {
 109             return $self->reportsUrl($config_tree); },
 110         'timestamp'  => sub { return time2str($Torrus::Renderer::timeFormat,
 111                                               time()); },
 112         'verifyDate'  => sub { return verifyDate($_[0]); },
 113         'markup'     => sub{ return $self->translateMarkup( @_ ); },
 114         'searchEnabled' => $Torrus::Renderer::searchEnabled,
 115         'searchResults' => sub { return $self->doSearch($config_tree, $_[0]); },
 116
 117         #Freeside
 118         'freesideHeader' => sub { return $self->freesideHeader(@_); },
 119         'freesideFooter' => sub { return $self->freesideFooter(); },
 120         'freesideComponent' => sub { return $self->freesideComponent(@_); },
 121         'uri_escape'        => sub { return uri_escape(@_); },
 122
 123     };
 124
 125
 126     # Pass the options from Torrus::Renderer::render() to Template
 127     while( my( $opt, $val ) = each( %{$self->{'options'}} ) )
 128     {
 129         $ttvars->{$opt} = $val;
 130     }
 131
 132     my $result = $self->{'tt'}->process( $tmplfile, $ttvars, $outfile );
 133
 134     undef $ttvars;
 135
 136     if( not $result )
 137     {
 138         if( $config_tree->isTset( $token ) )
 139         {
 140             Error("Error while rendering tokenset $token: " .
 141                   $self->{'tt'}->error());
 142         }
 143         else
 144         {
 145             my $path = $config_tree->path($token);
 146             Error("Error while rendering $path: " .
 147                   $self->{'tt'}->error());
 148         }
 149         return undef;
 150     }
 151
 152     return ($expires+time(), 'text/html; charset=UTF-8');
 153 }
 154
 155
 156 sub nodeName
 157 {
 158     my $self = shift;
 159     my $config_tree = shift;
 160     my $token = shift;
 161
 162     my $n = $config_tree->getNodeParam($token, 'node-display-name', 1);
 163     if( defined( $n ) and length( $n ) > 0 )
 164     {
 165         return $n;
 166     }
 167
 168     return $config_tree->nodeName($config_tree->path($token));
 169 }
 170
 171
 172 sub sortTokens
 173 {
 174     my $self = shift;
 175     my $config_tree = shift;
 176     my $tokenlist = shift;
 177
 178     my @sorted = ();
 179     if( ref($tokenlist) and scalar(@{$tokenlist}) > 0 )
 180     {
 181         @sorted = sort
 182         {
 183             my $p_a = $config_tree->getNodeParam($a, 'precedence', 1);
 184             $p_a = 0 unless defined $p_a;
 185             my $p_b = $config_tree->getNodeParam($b, 'precedence', 1);
 186             $p_b = 0 unless defined $p_b;
 187             if( $p_a == $p_b )
 188             {
 189                 my $n_a = $config_tree->path($a);
 190                 my $n_b = $config_tree->path($b);
 191                 return $n_a cmp $n_b;
 192             }
 193             else
 194             {
 195                 return $p_b <=> $p_a;
 196             }
 197         } @{$tokenlist};
 198     }
 199     else
 200     {
 201         push(@sorted, $tokenlist);
 202     }
 203     return @sorted;
 204 }
 205
 206
 207 # compose an URL for a node.
 208 # $persistent defines if the link should be persistent
 209 # Persistent link is done with nodeid if available, or with path
 210
 211 sub makeURL
 212 {
 213     my $self = shift;
 214     my $config_tree = shift;
 215     my $persistent = shift;
 216     my $token = shift;
 217     my $view = shift;
 218     my @add_vars = @_;
 219
 220     my $ret = $Torrus::Renderer::rendererURL . '/' . $config_tree->treeName();
 221
 222     if( $persistent )
 223     {
 224         my $nodeid = $config_tree->getNodeParam($token, 'nodeid', 1);
 225         if( defined( $nodeid ) )
 226         {
 227             $ret .= '?nodeid=' .
 228                 uri_escape($nodeid, $Torrus::Renderer::uriEscapeExceptions);
 229         }
 230         else
 231         {
 232             $ret .= '?path=' .
 233                 uri_escape($config_tree->path($token),
 234                            $Torrus::Renderer::uriEscapeExceptions);
 235         }
 236     }
 237     else
 238     {
 239         $ret .= '?token=' . uri_escape($token);
 240     }
 241
 242     if( $view )
 243     {
 244         $ret .= '&amp;view=' . uri_escape($view);
 245     }
 246
 247     my %vars = ();
 248     # This could be array or a reference to array
 249     my $add_vars_size = scalar( @add_vars );
 250     if( $add_vars_size == 1 and ref( $add_vars[0] ) )
 251     {
 252         %vars = @{$add_vars[0]};
 253     }
 254     elsif( $add_vars_size > 0 and ($add_vars_size % 2 == 0) )
 255     {
 256         %vars = @add_vars;
 257     }
 258
 259     if( ref( $self->{'options'}->{'variables'} ) )
 260     {
 261         foreach my $name ( sort keys %{$self->{'options'}->{'variables'}} )
 262         {
 263             my $val = $self->{'options'}->{'variables'}->{$name};
 264             if( not defined( $vars{$name} ) )
 265             {
 266                 $vars{$name} = $val;
 267             }
 268         }
 269     }
 270
 271     foreach my $name ( sort keys %vars )
 272     {
 273         if( $vars{$name} ne '' )
 274         {
 275             $ret .= '&amp;' . $name . '=' .
 276                 uri_escape( $vars{$name},
 277                             $Torrus::Renderer::uriEscapeExceptions );
 278         }
 279     }
 280
 281     return $ret;
 282 }
 283
 284 sub makeSplitURLs
 285 {
 286     my $self = shift;
 287     my $config_tree = shift;
 288     my $token = shift;
 289     my $view = shift;
 290
 291     my $ret = '';
 292     while( defined( $token ) )
 293     {
 294         my $path = $config_tree->path($token);
 295
 296         my $str = '<SPAN CLASS="PathElement">';
 297         $str .=
 298             sprintf('<A HREF="%s">%s%s</A>',
 299                     $self->makeURL($config_tree, 0, $token, $view),
 300                     $config_tree->nodeName($path),
 301                     ( $config_tree->isSubtree($token) and
 302                       $path ne '/') ? '/':'' );
 303         $str .= "</SPAN>\n";
 304
 305         $ret = $str . $ret;
 306
 307         $token = $config_tree->getParent( $token );
 308     }
 309
 310     return $ret;
 311 }
 312
 313
 314 sub rrPrint
 315 {
 316     my $self = shift;
 317     my $config_tree = shift;
 318     my $token = shift;
 319     my $view = shift;
 320
 321     my @ret = ();
 322     my($fname, $mimetype) = $self->render( $config_tree, $token, $view );
 323
 324     if( $mimetype ne 'text/plain' )
 325     {
 326         Error("View $view does not produce text/plain for token $token");
 327     }
 328     else
 329     {
 330         if( not open(IN, $fname) )
 331         {
 332             Error("Cannot open $fname for reading: $!");
 333         }
 334         else
 335         {
 336             chomp(my $values = <IN>);
 337             @ret = split(':', $values);
 338             close IN;
 339         }
 340     }
 341     return @ret;
 342 }
 343
 344 # This subroutine is taken from Dave Plonka's Flowscan
 345
 346 sub scale
 347 {
 348     my $self = shift;
 349     # This is based somewhat on Tobi Oetiker's code in rrd_graph.c:
 350     my $fmt = shift;
 351     my $value = shift;
 352     my @symbols = ("a", # 10e-18 Ato
 353                    "f", # 10e-15 Femto
 354                    "p", # 10e-12 Pico
 355                    "n", # 10e-9  Nano
 356                    "u", # 10e-6  Micro
 357                    "m", # 10e-3  Milli
 358                    " ", # Base
 359                    "k", # 10e3   Kilo
 360                    "M", # 10e6   Mega
 361                    "G", # 10e9   Giga
 362                    "T", # 10e12  Terra
 363                    "P", # 10e15  Peta
 364                    "E"); # 10e18  Exa
 365
 366     my $symbcenter = 6;
 367     my $digits = (0 == $value)? 0 : floor(log(abs($value))/log(1000));
 368     return sprintf( $fmt . " %s", $value/pow(1000, $digits),
 369                     $symbols[ $symbcenter+$digits ] );
 370 }
 371
 372 sub style
 373 {
 374     my $self = shift;
 375     my $object = shift;
 376
 377     my $media;
 378     if( not defined( $media = $self->{'options'}->{'variables'}->{'MEDIA'} ) )
 379     {
 380         $media = 'default';
 381     }
 382     return  $Torrus::Renderer::styling{$media}{$object};
 383 }
 384
 385
 386
 387 sub userAttribute
 388 {
 389     my $self = shift;
 390     my $attr = shift;
 391
 392     if( $self->{'options'}->{'uid'} and $self->{'options'}->{'acl'} )
 393     {
 394         $self->{'options'}->{'acl'}->
 395             userAttribute( $self->{'options'}->{'uid'}, $attr );
 396     }
 397     else
 398     {
 399         return '';
 400     }
 401 }
 402
 403 sub hasPrivilege
 404 {
 405     my $self = shift;
 406     my $object = shift;
 407     my $privilege = shift;
 408
 409     if( $self->{'options'}->{'uid'} and $self->{'options'}->{'acl'} )
 410     {
 411         $self->{'options'}->{'acl'}->
 412             hasPrivilege( $self->{'options'}->{'uid'}, $object, $privilege );
 413     }
 414     else
 415     {
 416         return undef;
 417     }
 418 }
 419
 420
 421 sub translateMarkup
 422 {
 423     my $self = shift;
 424     my @strings = @_;
 425
 426     my $tt = new Template( TRIM => 1 );
 427
 428     my $ttvars =
 429     {
 430         'em'      =>  sub { return '<em>' . $_[0] . '</em>'; },
 431         'strong'  =>  sub { return '<strong>' . $_[0] . '</strong>'; }
 432     };
 433
 434     my $ret = '';
 435
 436     foreach my $str ( @strings )
 437     {
 438         my $output = '';
 439         my $result = $tt->process( \$str, $ttvars, \$output );
 440
 441         if( not $result )
 442         {
 443             Error('Error translating markup: ' . $tt->error());
 444         }
 445         else
 446         {
 447             $ret .= $output;
 448         }
 449     }
 450
 451     undef $tt;
 452
 453     return $ret;
 454 }
 455
 456
 457 sub verifyDate
 458 {
 459     my $input = shift;
 460
 461     my $time = str2time( $input );
 462     # rrdtool does not understand dates prior to 1980 (315529200)
 463     if( defined( $time ) and $time > 315529200 )
 464     {
 465         # Present the time in format understood by rrdtool
 466         return time2str('%H:%M %Y%m%d', $time);
 467     }
 468     else
 469     {
 470         return '';
 471     }
 472 }
 473
 474
 475 sub may_display_reports
 476 {
 477     my $self = shift;
 478     my $config_tree = shift;
 479
 480     if( $Torrus::Renderer::displayReports )
 481     {
 482         if( not $Torrus::CGI::authorizeUsers )
 483         {
 484             return 1;
 485         }
 486
 487         my $tree = $config_tree->treeName();
 488         if( $self->hasPrivilege( $tree, 'DisplayReports' ) and
 489             -r $Torrus::Global::reportsDir . '/' . $tree .
 490             '/html/index.html' )
 491         {
 492             return 1;
 493         }
 494     }
 495     return 0;
 496 }
 497
 498
 499 sub reportsUrl
 500 {
 501     my $self = shift;
 502     my $config_tree = shift;
 503
 504     return $Torrus::Renderer::rendererURL . '/' .
 505         $config_tree->treeName() . '?htmlreport=index.html';
 506 }
 507
 508
 509 sub doSearch
 510 {
 511     my $self = shift;
 512     my $config_tree = shift;
 513     my $string = shift;
 514
 515
 516     my $tree = $config_tree->treeName();
 517
 518     my $sr = new Torrus::Search;
 519     $sr->openTree( $tree );
 520     my $result = $sr->searchPrefix( $string, $tree );
 521     $sr->closeTree( $tree );
 522
 523     my $ret = [];
 524     push( @{$ret}, sort {$a->[0] cmp $b->[0]} @{$result} );
 525
 526     return $ret;
 527 }
 528
 529
 530 1;
 531
 532
 533 # Local Variables:
 534 # mode: perl
 535 # indent-tabs-mode: nil
 536 # perl-indent-level: 4
 537 # End: