torrus/perllib/Torrus/Renderer/HTML.pm

   1 #  Copyright (C) 2002  Stanislav Sinyagin
   2 #
   3 #  This program is free software; you can redistribute it and/or modify
   4 #  it under the terms of the GNU General Public License as published by
   5 #  the Free Software Foundation; either version 2 of the License, or
   6 #  (at your option) any later version.
   7 #
   8 #  This program is distributed in the hope that it will be useful,
   9 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 #  GNU General Public License for more details.
  12 #
  13 #  You should have received a copy of the GNU General Public License
  14 #  along with this program; if not, write to the Free Software
  15 #  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307, USA.
  16
  17 # $Id: HTML.pm,v 1.6 2011-02-05 06:32:36 levinse Exp $
  18 # Stanislav Sinyagin <ssinyagin@yahoo.com>
  19
  20 package Torrus::Renderer::HTML;
  21
  22 use strict;
  23
  24 use Torrus::ConfigTree;
  25 use Torrus::Search;
  26 use Torrus::Log;
  27
  28 use URI::Escape;
  29 use Template;
  30 use POSIX qw(abs log floor pow);
  31 use Date::Parse;
  32 use Date::Format;
  33
  34 Torrus::SiteConfig::loadStyling();
  35
  36 # All our methods are imported by Torrus::Renderer;
  37
  38 sub render_html
  39 {
  40     my $self = shift;
  41     my $config_tree = shift;
  42     my $token = shift;
  43     my $view = shift;
  44     my $outfile = shift;
  45
  46     my $tmplfile = $config_tree->getParam($view, 'html-template');
  47
  48     my $expires = $config_tree->getParam($view, 'expires');
  49
  50     # Create the Template Toolkit processor once, and reuse
  51     # it in subsequent render() calls
  52
  53     if( not defined( $self->{'tt'} ) )
  54     {
  55         $self->{'tt'} =
  56             new Template(INCLUDE_PATH => $Torrus::Global::templateDirs,
  57                          TRIM => 1);
  58     }
  59     my $ttvars =
  60     {
  61         'treeName'   => $config_tree->treeName(),
  62         'token'      => $token,
  63         'view'       => $view,
  64         'expires'    => $expires,
  65         'path'       => sub { return $config_tree->path($_[0]); },
  66         'pathToken'  => sub { return $config_tree->token($_[0]); },
  67         'nodeExists' => sub { return $config_tree->nodeExists($_[0]); },
  68         'children'   => sub { return $config_tree->getChildren($_[0]); },
  69         'isLeaf'     => sub { return $config_tree->isLeaf($_[0]); },
  70         'isAlias'    => sub { return $config_tree->isAlias($_[0]); },
  71         'sortTokens' => sub { return $self->sortTokens($config_tree,
  72                                                        $_[0]); },
  73         'nodeName'   => sub { return $self->nodeName($config_tree, $_[0]); },
  74         'parent'     => sub { return $config_tree->getParent($_[0]); },
  75         'nodeParam'  => sub { return $config_tree->getNodeParam(@_); },
  76         'param'      => sub { return $config_tree->getParam(@_); },
  77         'url'        => sub { return $self->makeURL($config_tree, 0, @_); },
  78         'persistentUrl' => sub { return $self->makeURL($config_tree, 1, @_); },
  79         'clearVar'   => sub { delete $self->{'options'}{'variables'}{$_[0]};
  80                               return undef;},
  81         'plainURL'   => $Torrus::Renderer::plainURL,
  82         'splitUrls'  => sub { return $self->makeSplitURLs($config_tree,
  83                                                           $_[0], $_[1]); },
  84         'topURL'     => ($Torrus::Renderer::rendererURL ne '' ?
  85                          $Torrus::Renderer::rendererURL : '/'),
  86         'rrprint'    => sub { return $self->rrPrint($config_tree,
  87                                                     $_[0], $_[1]); },
  88         'scale'      => sub { return $self->scale($_[0], $_[1]); },
  89         'tsetMembers' => sub { $config_tree->tsetMembers($_[0]); },
  90         'tsetList'   => sub { $config_tree->getTsets(); },
  91         'style'      => sub { return $self->style($_[0]); },
  92         'companyName'=> $Torrus::Renderer::companyName,
  93         'companyLogo'=> $Torrus::Renderer::companyLogo,
  94         'companyURL' => $Torrus::Renderer::companyURL,
  95         'siteInfo'   => $Torrus::Renderer::siteInfo,
  96         'treeInfo'   => sub { return $Torrus::Global::treeConfig{
  97             $config_tree->treeName()}{'info'}; },
  98         'version'    => $Torrus::Global::version,
  99         'xmlnorm'    => \&Torrus::Renderer::xmlnormalize,
 100         'userAuth'   => $Torrus::CGI::authorizeUsers,
 101         'uid'        => $self->{'options'}->{'uid'},
 102         'userAttr'   => sub { return $self->userAttribute( $_[0] ) },
 103         'mayDisplayAdmInfo' => sub {
 104             return $self->may_display_adminfo( $config_tree, $_[0] ) },
 105         'adminfo' => $self->{'adminfo'},
 106         'mayDisplayReports' => sub {
 107             return $self->may_display_reports($config_tree) },
 108         'reportsUrl' => sub {
 109             return $self->reportsUrl($config_tree); },
 110         'timestamp'  => sub { return time2str($Torrus::Renderer::timeFormat,
 111                                               time()); },
 112         'verifyDate'  => sub { return verifyDate($_[0]); },
 113         'markup'     => sub{ return $self->translateMarkup( @_ ); },
 114         'searchEnabled' => $Torrus::Renderer::searchEnabled,
 115         'searchResults' => sub { return $self->doSearch($config_tree, $_[0]); },
 116
 117         #Freeside
 118         'freesideHeader' => sub { return $self->freesideHeader(@_); },
 119         'freesideFooter' => sub { return $self->freesideFooter(); },
 120         'freesideComponent' => sub { return $self->freesideComponent(@_); },
 121         'uri_escape'        => sub { return uri_escape(@_); },
 122         'matches'        => sub { return $_[0] =~ $_[1]; },
 123         'popup_link'     => sub {
 124                                    my $type = shift;
 125
 126                                    if($type eq 'nms-add_iface.html') {
 127                                        my $host = shift;
 128                                        my $iface = shift;
 129                                         return
 130                                             $self->freesideComponent('/elements/popup_link.html',
 131                                                 'action' => "/freeside/misc/".
 132                                                         $type."?host=$host;iface=$iface",
 133                                                  'label' => 'Monitor for billing',
 134                                                  'actionlabel' => 'Monitor interface',
 135                                             );
 136                                    }
 137                                    elsif($type eq 'nms-add_router.html') {
 138                                         return
 139                                             $self->freesideComponent('/elements/popup_link.html',
 140                                                 'action' => "/freeside/misc/$type",
 141                                                  'label' => 'Add Router',
 142                                                  'actionlabel' => 'Add Router',
 143                                             );
 144                                    }
 145
 146                                    '';
 147                                 },
 148
 149     };
 150
 151
 152     # Pass the options from Torrus::Renderer::render() to Template
 153     while( my( $opt, $val ) = each( %{$self->{'options'}} ) )
 154     {
 155         $ttvars->{$opt} = $val;
 156     }
 157
 158     my $result = $self->{'tt'}->process( $tmplfile, $ttvars, $outfile );
 159
 160     undef $ttvars;
 161
 162     if( not $result )
 163     {
 164         if( $config_tree->isTset( $token ) )
 165         {
 166             Error("Error while rendering tokenset $token: " .
 167                   $self->{'tt'}->error());
 168         }
 169         else
 170         {
 171             my $path = $config_tree->path($token);
 172             Error("Error while rendering $path: " .
 173                   $self->{'tt'}->error());
 174         }
 175         return undef;
 176     }
 177
 178     return ($expires+time(), 'text/html; charset=UTF-8');
 179 }
 180
 181
 182 sub nodeName
 183 {
 184     my $self = shift;
 185     my $config_tree = shift;
 186     my $token = shift;
 187
 188     my $n = $config_tree->getNodeParam($token, 'node-display-name', 1);
 189     if( defined( $n ) and length( $n ) > 0 )
 190     {
 191         return $n;
 192     }
 193
 194     return $config_tree->nodeName($config_tree->path($token));
 195 }
 196
 197
 198 sub sortTokens
 199 {
 200     my $self = shift;
 201     my $config_tree = shift;
 202     my $tokenlist = shift;
 203
 204     my @sorted = ();
 205     if( ref($tokenlist) and scalar(@{$tokenlist}) > 0 )
 206     {
 207         @sorted = sort
 208         {
 209             my $p_a = $config_tree->getNodeParam($a, 'precedence', 1);
 210             $p_a = 0 unless defined $p_a;
 211             my $p_b = $config_tree->getNodeParam($b, 'precedence', 1);
 212             $p_b = 0 unless defined $p_b;
 213             if( $p_a == $p_b )
 214             {
 215                 my $n_a = $config_tree->path($a);
 216                 my $n_b = $config_tree->path($b);
 217                 return $n_a cmp $n_b;
 218             }
 219             else
 220             {
 221                 return $p_b <=> $p_a;
 222             }
 223         } @{$tokenlist};
 224     }
 225     else
 226     {
 227         push(@sorted, $tokenlist);
 228     }
 229     return @sorted;
 230 }
 231
 232
 233 # compose an URL for a node.
 234 # $persistent defines if the link should be persistent
 235 # Persistent link is done with nodeid if available, or with path
 236
 237 sub makeURL
 238 {
 239     my $self = shift;
 240     my $config_tree = shift;
 241     my $persistent = shift;
 242     my $token = shift;
 243     my $view = shift;
 244     my @add_vars = @_;
 245
 246     my $ret = $Torrus::Renderer::rendererURL . '/' . $config_tree->treeName();
 247
 248     if( $persistent )
 249     {
 250         my $nodeid = $config_tree->getNodeParam($token, 'nodeid', 1);
 251         if( defined( $nodeid ) )
 252         {
 253             $ret .= '?nodeid=' .
 254                 uri_escape($nodeid, $Torrus::Renderer::uriEscapeExceptions);
 255         }
 256         else
 257         {
 258             $ret .= '?path=' .
 259                 uri_escape($config_tree->path($token),
 260                            $Torrus::Renderer::uriEscapeExceptions);
 261         }
 262     }
 263     else
 264     {
 265         $ret .= '?token=' . uri_escape($token);
 266     }
 267
 268     if( $view )
 269     {
 270         $ret .= '&amp;view=' . uri_escape($view);
 271     }
 272
 273     my %vars = ();
 274     # This could be array or a reference to array
 275     my $add_vars_size = scalar( @add_vars );
 276     if( $add_vars_size == 1 and ref( $add_vars[0] ) )
 277     {
 278         %vars = @{$add_vars[0]};
 279     }
 280     elsif( $add_vars_size > 0 and ($add_vars_size % 2 == 0) )
 281     {
 282         %vars = @add_vars;
 283     }
 284
 285     if( ref( $self->{'options'}->{'variables'} ) )
 286     {
 287         foreach my $name ( sort keys %{$self->{'options'}->{'variables'}} )
 288         {
 289             my $val = $self->{'options'}->{'variables'}->{$name};
 290             if( not defined( $vars{$name} ) )
 291             {
 292                 $vars{$name} = $val;
 293             }
 294         }
 295     }
 296
 297     foreach my $name ( sort keys %vars )
 298     {
 299         if( $vars{$name} ne '' )
 300         {
 301             $ret .= '&amp;' . $name . '=' .
 302                 uri_escape( $vars{$name},
 303                             $Torrus::Renderer::uriEscapeExceptions );
 304         }
 305     }
 306
 307     return $ret;
 308 }
 309
 310 sub makeSplitURLs
 311 {
 312     my $self = shift;
 313     my $config_tree = shift;
 314     my $token = shift;
 315     my $view = shift;
 316
 317     my $ret = '';
 318     while( defined( $token ) )
 319     {
 320         my $path = $config_tree->path($token);
 321
 322         my $str = '<SPAN CLASS="PathElement">';
 323         $str .=
 324             sprintf('<A HREF="%s">%s%s</A>',
 325                     $self->makeURL($config_tree, 0, $token, $view),
 326                     $config_tree->nodeName($path),
 327                     ( $config_tree->isSubtree($token) and
 328                       $path ne '/') ? '/':'' );
 329         $str .= "</SPAN>\n";
 330
 331         $ret = $str . $ret;
 332
 333         $token = $config_tree->getParent( $token );
 334     }
 335
 336     return $ret;
 337 }
 338
 339
 340 sub rrPrint
 341 {
 342     my $self = shift;
 343     my $config_tree = shift;
 344     my $token = shift;
 345     my $view = shift;
 346
 347     my @ret = ();
 348     my($fname, $mimetype) = $self->render( $config_tree, $token, $view );
 349
 350     if( $mimetype ne 'text/plain' )
 351     {
 352         Error("View $view does not produce text/plain for token $token");
 353     }
 354     else
 355     {
 356         if( not open(IN, $fname) )
 357         {
 358             Error("Cannot open $fname for reading: $!");
 359         }
 360         else
 361         {
 362             chomp(my $values = <IN>);
 363             @ret = split(':', $values);
 364             close IN;
 365         }
 366     }
 367     return @ret;
 368 }
 369
 370 # This subroutine is taken from Dave Plonka's Flowscan
 371
 372 sub scale
 373 {
 374     my $self = shift;
 375     # This is based somewhat on Tobi Oetiker's code in rrd_graph.c:
 376     my $fmt = shift;
 377     my $value = shift;
 378     my @symbols = ("a", # 10e-18 Ato
 379                    "f", # 10e-15 Femto
 380                    "p", # 10e-12 Pico
 381                    "n", # 10e-9  Nano
 382                    "u", # 10e-6  Micro
 383                    "m", # 10e-3  Milli
 384                    " ", # Base
 385                    "k", # 10e3   Kilo
 386                    "M", # 10e6   Mega
 387                    "G", # 10e9   Giga
 388                    "T", # 10e12  Terra
 389                    "P", # 10e15  Peta
 390                    "E"); # 10e18  Exa
 391
 392     my $symbcenter = 6;
 393     my $digits = (0 == $value)? 0 : floor(log(abs($value))/log(1000));
 394     return sprintf( $fmt . " %s", $value/pow(1000, $digits),
 395                     $symbols[ $symbcenter+$digits ] );
 396 }
 397
 398 sub style
 399 {
 400     my $self = shift;
 401     my $object = shift;
 402
 403     my $media;
 404     if( not defined( $media = $self->{'options'}->{'variables'}->{'MEDIA'} ) )
 405     {
 406         $media = 'default';
 407     }
 408     return  $Torrus::Renderer::styling{$media}{$object};
 409 }
 410
 411
 412
 413 sub userAttribute
 414 {
 415     my $self = shift;
 416     my $attr = shift;
 417
 418     if( $self->{'options'}->{'uid'} and $self->{'options'}->{'acl'} )
 419     {
 420         $self->{'options'}->{'acl'}->
 421             userAttribute( $self->{'options'}->{'uid'}, $attr );
 422     }
 423     else
 424     {
 425         return '';
 426     }
 427 }
 428
 429 sub hasPrivilege
 430 {
 431     my $self = shift;
 432     my $object = shift;
 433     my $privilege = shift;
 434
 435     if( $self->{'options'}->{'uid'} and $self->{'options'}->{'acl'} )
 436     {
 437         $self->{'options'}->{'acl'}->
 438             hasPrivilege( $self->{'options'}->{'uid'}, $object, $privilege );
 439     }
 440     else
 441     {
 442         return undef;
 443     }
 444 }
 445
 446
 447 sub translateMarkup
 448 {
 449     my $self = shift;
 450     my @strings = @_;
 451
 452     my $tt = new Template( TRIM => 1 );
 453
 454     my $ttvars =
 455     {
 456         'em'      =>  sub { return '<em>' . $_[0] . '</em>'; },
 457         'strong'  =>  sub { return '<strong>' . $_[0] . '</strong>'; }
 458     };
 459
 460     my $ret = '';
 461
 462     foreach my $str ( @strings )
 463     {
 464         my $output = '';
 465         my $result = $tt->process( \$str, $ttvars, \$output );
 466
 467         if( not $result )
 468         {
 469             Error('Error translating markup: ' . $tt->error());
 470         }
 471         else
 472         {
 473             $ret .= $output;
 474         }
 475     }
 476
 477     undef $tt;
 478
 479     return $ret;
 480 }
 481
 482
 483 sub verifyDate
 484 {
 485     my $input = shift;
 486
 487     my $time = str2time( $input );
 488     # rrdtool does not understand dates prior to 1980 (315529200)
 489     if( defined( $time ) and $time > 315529200 )
 490     {
 491         # Present the time in format understood by rrdtool
 492         return time2str('%H:%M %Y%m%d', $time);
 493     }
 494     else
 495     {
 496         return '';
 497     }
 498 }
 499
 500
 501 sub may_display_reports
 502 {
 503     my $self = shift;
 504     my $config_tree = shift;
 505
 506     if( $Torrus::Renderer::displayReports )
 507     {
 508         if( not $Torrus::CGI::authorizeUsers )
 509         {
 510             return 1;
 511         }
 512
 513         my $tree = $config_tree->treeName();
 514         if( $self->hasPrivilege( $tree, 'DisplayReports' ) and
 515             -r $Torrus::Global::reportsDir . '/' . $tree .
 516             '/html/index.html' )
 517         {
 518             return 1;
 519         }
 520     }
 521     return 0;
 522 }
 523
 524
 525 sub reportsUrl
 526 {
 527     my $self = shift;
 528     my $config_tree = shift;
 529
 530     return $Torrus::Renderer::rendererURL . '/' .
 531         $config_tree->treeName() . '?htmlreport=index.html';
 532 }
 533
 534
 535 sub doSearch
 536 {
 537     my $self = shift;
 538     my $config_tree = shift;
 539     my $string = shift;
 540
 541
 542     my $tree = $config_tree->treeName();
 543
 544     my $sr = new Torrus::Search;
 545     $sr->openTree( $tree );
 546     my $result = $sr->searchPrefix( $string, $tree );
 547     $sr->closeTree( $tree );
 548
 549     my $ret = [];
 550     push( @{$ret}, sort {$a->[0] cmp $b->[0]} @{$result} );
 551
 552     return $ret;
 553 }
 554
 555
 556 1;
 557
 558
 559 # Local Variables:
 560 # mode: perl
 561 # indent-tabs-mode: nil
 562 # perl-indent-level: 4
 563 # End: