rt/share/html/Dashboards/Queries.html

   1 %# BEGIN BPS TAGGED BLOCK {{{
   2 %#
   3 %# COPYRIGHT:
   4 %#
   5 %# This software is Copyright (c) 1996-2015 Best Practical Solutions, LLC
   6 %#                                          <sales@bestpractical.com>
   7 %#
   8 %# (Except where explicitly superseded by other copyright notices)
   9 %#
  10 %#
  11 %# LICENSE:
  12 %#
  13 %# This work is made available to you under the terms of Version 2 of
  14 %# the GNU General Public License. A copy of that license should have
  15 %# been provided with this software, but in any event can be snarfed
  16 %# from www.gnu.org.
  17 %#
  18 %# This work is distributed in the hope that it will be useful, but
  19 %# WITHOUT ANY WARRANTY; without even the implied warranty of
  20 %# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 %# General Public License for more details.
  22 %#
  23 %# You should have received a copy of the GNU General Public License
  24 %# along with this program; if not, write to the Free Software
  25 %# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 %# 02110-1301 or visit their web page on the internet at
  27 %# http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  28 %#
  29 %#
  30 %# CONTRIBUTION SUBMISSION POLICY:
  31 %#
  32 %# (The following paragraph is not intended to limit the rights granted
  33 %# to you to modify and distribute this software under the terms of
  34 %# the GNU General Public License and is only of importance to you if
  35 %# you choose to contribute your changes and enhancements to the
  36 %# community by submitting them to Best Practical Solutions, LLC.)
  37 %#
  38 %# By intentionally submitting any modifications, corrections or
  39 %# derivatives to this work, or any other work intended for use with
  40 %# Request Tracker, to Best Practical Solutions, LLC, you confirm that
  41 %# you are the copyright holder for those contributions and you grant
  42 %# Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  43 %# royalty-free, perpetual, license to use, copy, create derivative
  44 %# works based on those contributions, and sublicense and distribute
  45 %# those contributions and any derivatives thereof.
  46 %#
  47 %# END BPS TAGGED BLOCK }}}
  48 <& /Elements/Header, Title => $title &>
  49 <& /Elements/Tabs &>
  50
  51 <& /Widgets/SelectionBox:header, nojs => 1 &>
  52
  53 <& /Elements/ListActions, actions => \@results &>
  54
  55 <& Elements/Deleted, searches => \@deleted, Dashboard => $Dashboard &>
  56
  57 <& Elements/HiddenSearches, searches => \@hidden_searches, Dashboard => $Dashboard &>
  58
  59 <table width="100%" border="0">
  60 % for my $pane (@panes) {
  61 <tr><td valign="top" class="boxcontainer">
  62 <form action="Queries.html" name="Dashboard-<%$pane->{Name}%>" method="post" enctype="multipart/form-data">
  63 <input type="hidden" class="hidden" name="id" value="<%$Dashboard->Id%>" />
  64 <input type="hidden" class="hidden" name="Privacy" value="<%$Dashboard->Privacy%>" />
  65
  66 <&| /Widgets/TitleBox, title => $pane->{DisplayName} &>
  67 % my ( $pane_name ) = $pane->{Name} =~ /Searches-(.+)/;
  68     <& /Widgets/SelectionBox:show, self => $pane, nojs => 1, grep( {
  69             $_->{pane} eq $pane_name} @deleted ) ? ( ShowUpdate => 1 ) : () &>
  70 </&>
  71 </form>
  72 </td></tr>
  73 % }
  74 </table>
  75
  76 <%INIT>
  77
  78 my @results;
  79
  80 use RT::Dashboard;
  81 my $Dashboard = RT::Dashboard->new($session{'CurrentUser'});
  82 my ($ok, $msg) = $Dashboard->LoadById($id);
  83 $ok || Abort(loc("Couldn't load dashboard [_1]: [_2]", $id, $msg));
  84 my $title = loc("Modify the content of dashboard [_1]", $Dashboard->Name);
  85
  86 my %desc_of;
  87 my @items;
  88 my %selected;
  89 my %still_exists;
  90
  91 # add portlets (homepage componenets)
  92 my @components = @{ RT->Config->Get('HomepageComponents') };
  93
  94 for my $desc (@components) {
  95     my $name = "component-$desc";
  96     push @items, [$name, loc($desc)];
  97     $desc_of{$name} = loc($desc);
  98     $still_exists{$name} = 1;
  99 }
 100
 101 # add dashboards
 102 my @dashboards = $m->comp("/Dashboards/Elements/ListOfDashboards");
 103 for my $dashboard (@dashboards) {
 104     # Users *can* set up mutually recursive dashboards, but don't make it THIS
 105     # easy for them to shoot themselves in the foot.
 106     next if $dashboard->Id == $Dashboard->Id;
 107
 108     my $name = 'dashboard-' . $dashboard->Id . '-' . $dashboard->Privacy;
 109     my $type = loc('Dashboard'); # loc
 110     my $desc = "$type: " . $dashboard->Name;
 111     push @items, [$name, $desc];
 112     $desc_of{$name} = $desc;
 113     $still_exists{$name} = 1;
 114 }
 115
 116 # add saved searches
 117 my @objs = RT::System->new($session{'CurrentUser'});
 118
 119 push @objs, RT::SavedSearch->new( $session{CurrentUser} )->ObjectsForLoading
 120     if $session{'CurrentUser'}->HasRight( Right  => 'LoadSavedSearch',
 121                                           Object => $RT::System );
 122
 123 for my $object (@objs) {
 124     for ($m->comp("/Search/Elements/SearchesForObject", Object => $object)) {
 125         my ($desc, $loc_desc, $search) = @$_;
 126         my $SearchType = $search->Content->{'SearchType'} || 'Ticket';
 127         my $type = ( $SearchType eq 'Ticket' )
 128           ? 'Saved Search'    # loc
 129           : $SearchType;
 130         $desc = loc($type) . ": $loc_desc";
 131         my $privacy = $Dashboard->_build_privacy($object);
 132         my $name = 'search-' . $search->Id . '-' . $privacy;
 133         push @items, [$name, $desc];
 134         $desc_of{$name} = $desc;
 135         $still_exists{$name} = 1;
 136     }
 137 }
 138
 139 # Get the list of portlets already in use
 140 my @deleted;
 141 do {
 142     my $panes = $Dashboard->Panes;
 143     for my $pane (keys %$panes) {
 144         for my $portlet (@{ $panes->{$pane} }) {
 145             my $name;
 146             my $type = $portlet->{portlet_type};
 147
 148             if ($type eq 'search' || $type eq 'dashboard') {
 149                 $name = join '-', $type, $portlet->{id}, $portlet->{privacy};
 150             }
 151             elsif ($type eq 'component') {
 152                 $name = join '-', 'component', $portlet->{component};
 153             }
 154
 155             if (!$still_exists{$name}) {
 156                 push @deleted, {
 157                     pane => $pane,
 158                     name => $name,
 159                     description => $portlet->{description},
 160                 };
 161                 next;
 162             }
 163
 164             push @{ $selected{$pane} }, $name;
 165             $desc_of{$name} = $portlet->{description};
 166         }
 167     }
 168 };
 169
 170 $m->callback(
 171     CallbackName => 'PopulatePossibilities',
 172     Dashboard    => $Dashboard,
 173     items        => \@items,
 174     desc_of      => \%desc_of,
 175     still_exists => \%still_exists,
 176     selected     => \%selected,
 177 );
 178
 179 # Create selectionbox widgets for those portlets
 180
 181 my %pane_name = (
 182     'body'    => loc('Body'),
 183     'sidebar' => loc('Sidebar'),
 184 );
 185
 186 $m->callback(
 187     CallbackName => 'Panes',
 188     Dashboard    => $Dashboard,
 189     panes        => \%pane_name,
 190 );
 191
 192 my @panes;
 193 for my $pane (sort keys %pane_name) {
 194     my $sel = $m->comp(
 195         '/Widgets/SelectionBox:new',
 196         Action      => 'Queries.html',
 197         Name        => "Searches-$pane",
 198         DisplayName => $pane_name{$pane},
 199         Available   => \@items,
 200         Selected    => $selected{$pane},
 201         AutoSave    => 1,
 202         OnSubmit    => sub {
 203             my $self = shift;
 204
 205             $m->callback(
 206                 CallbackName => 'Submit',
 207                 Dashboard    => $Dashboard,
 208                 Selected     => $self->{Current},
 209                 pane         => $pane,
 210             );
 211
 212             my @portlets;
 213             for (@{ $self->{Current} }) {
 214                 my $item = $_;
 215                 my $desc = $desc_of{$item};
 216                 my $portlet_type = $1 if $item =~ s/^(\w+)-//;
 217
 218                 if ($portlet_type eq 'search' || $portlet_type eq 'dashboard') {
 219                     my ($id, $privacy) = split '-', $item, 2;
 220                     push @portlets, {
 221                         portlet_type => $portlet_type,
 222                         privacy      => $privacy,
 223                         id           => $id,
 224                         description  => $desc,
 225                         pane         => $pane,
 226                     };
 227                 }
 228                 elsif ($portlet_type eq 'component') {
 229                     # Absolute paths stay absolute, relative paths go into
 230                     # /Elements. This way, extensions that add portlets work.
 231                     my $path = $item;
 232                     $path = "/Elements/$path" if substr($path, 0, 1) ne '/';
 233
 234                     push @portlets, {
 235                         portlet_type => $portlet_type,
 236                         component    => $item,
 237                         path         => $path,
 238                         description  => $item,
 239                         pane         => $pane,
 240                     };
 241                 }
 242             }
 243
 244             # we want to keep all the other panes the same
 245             my $panes = $Dashboard->Panes;
 246             $panes->{$pane} = \@portlets;
 247
 248             # remove "deleted" warnings about this pane
 249             @deleted = grep { $_->{pane} ne $pane } @deleted;
 250
 251             $m->callback(
 252                 CallbackName => 'BeforeUpdate',
 253                 Dashboard    => $Dashboard,
 254                 panes        => $panes,
 255             );
 256
 257             my ($ok, $msg) = $Dashboard->Update(Panes => $panes);
 258
 259             if ($ok) {
 260                 push @results, loc("Dashboard updated");
 261             }
 262             else {
 263                 push @results, loc("Dashboard could not be updated: [_1]", $msg);
 264             }
 265         },
 266     );
 267
 268     push @panes, $sel;
 269 }
 270
 271 $m->comp('/Widgets/SelectionBox:process', %ARGS, self => $_, nojs => 1)
 272     for @panes;
 273
 274 my @hidden_searches = $Dashboard->PossibleHiddenSearches;
 275 </%INIT>
 276 <%ARGS>
 277 $id => '' unless defined $id
 278 </%ARGS>
 279