rt/lib/RT/Shredder.pm

   1 # BEGIN BPS TAGGED BLOCK {{{
   2 #
   3 # COPYRIGHT:
   4 #
   5 # This software is Copyright (c) 1996-2015 Best Practical Solutions, LLC
   6 #                                          <sales@bestpractical.com>
   7 #
   8 # (Except where explicitly superseded by other copyright notices)
   9 #
  10 #
  11 # LICENSE:
  12 #
  13 # This work is made available to you under the terms of Version 2 of
  14 # the GNU General Public License. A copy of that license should have
  15 # been provided with this software, but in any event can be snarfed
  16 # from www.gnu.org.
  17 #
  18 # This work is distributed in the hope that it will be useful, but
  19 # WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 # General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 # 02110-1301 or visit their web page on the internet at
  27 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  28 #
  29 #
  30 # CONTRIBUTION SUBMISSION POLICY:
  31 #
  32 # (The following paragraph is not intended to limit the rights granted
  33 # to you to modify and distribute this software under the terms of
  34 # the GNU General Public License and is only of importance to you if
  35 # you choose to contribute your changes and enhancements to the
  36 # community by submitting them to Best Practical Solutions, LLC.)
  37 #
  38 # By intentionally submitting any modifications, corrections or
  39 # derivatives to this work, or any other work intended for use with
  40 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  41 # you are the copyright holder for those contributions and you grant
  42 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  43 # royalty-free, perpetual, license to use, copy, create derivative
  44 # works based on those contributions, and sublicense and distribute
  45 # those contributions and any derivatives thereof.
  46 #
  47 # END BPS TAGGED BLOCK }}}
  48
  49 package RT::Shredder;
  50
  51 use strict;
  52 use warnings;
  53
  54
  55
  56 =head1 NAME
  57
  58 RT::Shredder - Permanently wipeout data from RT
  59
  60
  61 =head1 SYNOPSIS
  62
  63 =head2 CLI
  64
  65   rt-shredder --force --plugin 'Tickets=query,Queue="General" and Status="deleted"'
  66
  67 =head1 DESCRIPTION
  68
  69 RT::Shredder is extension to RT which allows you to permanently wipeout
  70 data from the RT database.  Shredder supports the wiping of almost
  71 all RT objects (Tickets, Transactions, Attachments, Users...).
  72
  73
  74 =head2 "Delete" vs "Wipeout"
  75
  76 RT uses the term "delete" to mean "deactivate".  To avoid confusion,
  77 RT::Shredder uses the term "Wipeout" to mean "permanently erase" (or
  78 what most people would think of as "delete").
  79
  80
  81 =head2 Why do you want this?
  82
  83 Normally in RT, "deleting" an item simply deactivates it and makes it
  84 invisible from view.  This is done to retain full history and
  85 auditability of your tickets.  For most RT users this is fine and they
  86 have no need of RT::Shredder.
  87
  88 But in some large and heavily used RT instances the database can get
  89 clogged up with junk, particularly spam.  This can slow down searches
  90 and bloat the size of the database.  For these users, RT::Shredder
  91 allows them to completely clear the database of this unwanted junk.
  92
  93 An additional use of Shredder is to obliterate sensitive information
  94 (passwords, credit card numbers, ...) which might have made their way
  95 into RT.
  96
  97
  98 =head2 Command line tools (CLI)
  99
 100 L<rt-shredder> is a program which allows you to wipe objects from
 101 command line or with system tasks scheduler (cron, for example).
 102 See also 'rt-shredder --help'.
 103
 104
 105 =head2 Web based interface (WebUI)
 106
 107 Shredder's WebUI integrates into RT's WebUI.  You can find it in the
 108 Admin->Tools->Shredder tab.  The interface is similar to the
 109 CLI and gives you the same functionality. You can find 'Shredder' link
 110 at the bottom of tickets search results, so you could wipeout tickets
 111 in the way similar to the bulk update.
 112
 113
 114 =head1 DATA STORAGE AND BACKUPS
 115
 116 Shredder allows you to store data you wiped in files as scripts with SQL
 117 commands.
 118
 119 =head3 Restoring from backup
 120
 121 Should you wipeout something you did not intend to the objects can be
 122 restored by using the storage files.  These files are a simple set of
 123 SQL commands to re-insert your objects into the RT database.
 124
 125 1) Locate the appropriate shredder SQL dump file.  In the WebUI, when
 126    you use shredder, the path to the dump file is displayed.  It also
 127    gives the option to download the dump file after each wipeout.  Or
 128    it can be found in your C<$ShredderStoragePath>.
 129
 130 2) Load the shredder SQL dump into your RT database.  The details will
 131    be different for each database and RT configuration, consult your
 132    database manual and RT config.  For example, in MySQL...
 133
 134     mysql -u your_rt_user -p your_rt_database < /path/to/rt/var/data/shredder/dump.sql
 135
 136 That's it.i This will restore everything you'd deleted during a
 137 shredding session when the file had been created.
 138
 139 =head1 CONFIGURATION
 140
 141 =head2 $DependenciesLimit
 142
 143 Shredder stops with an error if the object has more than
 144 C<$DependenciesLimit> dependencies. For example: a ticket has 1000
 145 transactions or a transaction has 1000 attachments. This is protection
 146 from bugs in shredder from wiping out your whole database, but
 147 sometimes when you have big mail loops you may hit it.
 148
 149 Defaults to 1000.  To change this (for example, to 10000) add the
 150 following to your F<RT_SiteConfig.pm>:
 151
 152     Set( $DependenciesLimit, 10_000 );>
 153
 154
 155 =head2 $ShredderStoragePath
 156
 157 Directory containing Shredder backup dumps; defaults to
 158 F</opt/rt4/var/data/RT-Shredder> (assuming an /opt/rt4 installation).
 159
 160 To change this (for example, to /some/backup/path) add the following to
 161 your F<RT_SiteConfig.pm>:
 162
 163     Set( $ShredderStoragePath, "/some/backup/path" );>
 164
 165 Be sure to specify an absolute path.
 166
 167 =head1 Database Indexes
 168
 169 We have found that the following indexes significantly speed up
 170 shredding on most databases.
 171
 172     CREATE INDEX SHREDDER_CGM1 ON CachedGroupMembers(MemberId, GroupId, Disabled);
 173     CREATE INDEX SHREDDER_CGM2 ON CachedGroupMembers(ImmediateParentId,MemberId);
 174     CREATE INDEX SHREDDER_CGM3 on CachedGroupMembers (Via, Id);
 175
 176     CREATE UNIQUE INDEX SHREDDER_GM1 ON GroupMembers(MemberId, GroupId);
 177
 178     CREATE INDEX SHREDDER_TXN1 ON Transactions(ReferenceType, OldReference);
 179     CREATE INDEX SHREDDER_TXN2 ON Transactions(ReferenceType, NewReference);
 180     CREATE INDEX SHREDDER_TXN3 ON Transactions(Type, OldValue);
 181     CREATE INDEX SHREDDER_TXN4 ON Transactions(Type, NewValue);
 182
 183     CREATE INDEX SHREDDER_ATTACHMENTS1 ON Attachments(Creator);
 184
 185 =head1 INFORMATION FOR DEVELOPERS
 186
 187 =head2 General API
 188
 189 L<RT::Shredder> is an extension to RT which adds shredder methods to
 190 RT objects and classes.  The API is not well documented yet, but you
 191 can find usage examples in L<rt-shredder> and the
 192 F<lib/t/regression/shredder/*.t> test files.
 193
 194 However, here is a small example that do the same action as in CLI
 195 example from L</SYNOPSIS>:
 196
 197   use RT::Shredder;
 198   RT::Shredder::Init( force => 1 );
 199   my $deleted = RT::Tickets->new( RT->SystemUser );
 200   $deleted->{'allow_deleted_search'} = 1;
 201   $deleted->LimitQueue( VALUE => 'general' );
 202   $deleted->LimitStatus( VALUE => 'deleted' );
 203   while( my $t = $deleted->Next ) {
 204       $t->Wipeout;
 205   }
 206
 207
 208 =head2 RT::Shredder class' API
 209
 210 L<RT::Shredder> implements interfaces to objects cache, actions on the
 211 objects in the cache and backups storage.
 212
 213 =cut
 214
 215 use File::Spec ();
 216
 217
 218 BEGIN {
 219 # I can't use 'use lib' here since it breakes tests
 220 # because test suite uses old RT::Shredder setup from
 221 # RT lib path
 222
 223 ### after:     push @INC, qw(@RT_LIB_PATH@);
 224     use RT::Shredder::Constants;
 225     use RT::Shredder::Exceptions;
 226 }
 227
 228 our @SUPPORTED_OBJECTS = qw(
 229     ACE
 230     Attachment
 231     CachedGroupMember
 232     CustomField
 233     CustomFieldValue
 234     GroupMember
 235     Group
 236     Link
 237     Principal
 238     Queue
 239     Scrip
 240     ScripAction
 241     ScripCondition
 242     Template
 243     ObjectCustomFieldValue
 244     Ticket
 245     Transaction
 246     User
 247 );
 248
 249 =head3 GENERIC
 250
 251 =head4 Init
 252
 253     RT::Shredder::Init( %default_options );
 254
 255 C<RT::Shredder::Init()> should be called before creating an
 256 RT::Shredder object.  It iniitalizes RT and loads the RT
 257 configuration.
 258
 259 %default_options are passed to every C<<RT::Shredder->new>> call.
 260
 261 =cut
 262
 263 our %opt = ();
 264
 265 sub Init
 266 {
 267     %opt = @_;
 268     RT::LoadConfig();
 269     RT::Init();
 270     return;
 271 }
 272
 273 =head4 new
 274
 275   my $shredder = RT::Shredder->new(%options);
 276
 277 Construct a new RT::Shredder object.
 278
 279 There currently are no %options.
 280
 281 =cut
 282
 283 sub new
 284 {
 285     my $proto = shift;
 286     my $self = bless( {}, ref $proto || $proto );
 287     return $self->_Init( @_ );
 288 }
 289
 290 sub _Init
 291 {
 292     my $self = shift;
 293     $self->{'opt'}          = { %opt, @_ };
 294     $self->{'cache'}        = {};
 295     $self->{'resolver'}     = {};
 296     $self->{'dump_plugins'} = [];
 297     return $self;
 298 }
 299
 300 =head4 CastObjectsToRecords( Objects => undef )
 301
 302 Cast objects to the C<RT::Record> objects or its ancesstors.
 303 Objects can be passed as SCALAR (format C<< <class>-<id> >>),
 304 ARRAY, C<RT::Record> ancesstors or C<RT::SearchBuilder> ancesstor.
 305
 306 Most methods that takes C<Objects> argument use this method to
 307 cast argument value to list of records.
 308
 309 Returns an array of records.
 310
 311 For example:
 312
 313     my @objs = $shredder->CastObjectsToRecords(
 314         Objects => [             # ARRAY reference
 315             'RT::Attachment-10', # SCALAR or SCALAR reference
 316             $tickets,            # RT::Tickets object (isa RT::SearchBuilder)
 317             $user,               # RT::User object (isa RT::Record)
 318         ],
 319     );
 320
 321 =cut
 322
 323 sub CastObjectsToRecords
 324 {
 325     my $self = shift;
 326     my %args = ( Objects => undef, @_ );
 327
 328     my @res;
 329     my $targets = delete $args{'Objects'};
 330     unless( $targets ) {
 331         RT::Shredder::Exception->throw( "Undefined Objects argument" );
 332     }
 333
 334     if( UNIVERSAL::isa( $targets, 'RT::SearchBuilder' ) ) {
 335         #XXX: try to use ->_DoSearch + ->ItemsArrayRef in feature
 336         #     like we do in Record with links, but change only when
 337         #     more tests would be available
 338         while( my $tmp = $targets->Next ) { push @res, $tmp };
 339     } elsif ( UNIVERSAL::isa( $targets, 'RT::Record' ) ) {
 340         push @res, $targets;
 341     } elsif ( UNIVERSAL::isa( $targets, 'ARRAY' ) ) {
 342         foreach( @$targets ) {
 343             push @res, $self->CastObjectsToRecords( Objects => $_ );
 344         }
 345     } elsif ( UNIVERSAL::isa( $targets, 'SCALAR' ) || !ref $targets ) {
 346         $targets = $$targets if ref $targets;
 347         my ($class, $org, $id);
 348         if ($targets =~ /-.*-/) {
 349             ($class, $org, $id) = split /-/, $targets;
 350             RT::Shredder::Exception->throw( "Can't wipeout remote object $targets" )
 351                   unless $org eq RT->Config->Get('Organization');
 352         } else {
 353             ($class, $id) = split /-/, $targets;
 354         }
 355         RT::Shredder::Exception->throw( "Unsupported class $class" )
 356               unless $class =~ /^\w+(::\w+)*$/;
 357         $class = 'RT::'. $class unless $class =~ /^RTx?::/i;
 358         $class->require or die "Failed to load $class: $@";
 359         my $obj = $class->new( RT->SystemUser );
 360         die "Couldn't construct new '$class' object" unless $obj;
 361         $obj->Load( $id );
 362         unless ( $obj->id ) {
 363             $RT::Logger->error( "Couldn't load '$class' object with id '$id'" );
 364             RT::Shredder::Exception::Info->throw( 'CouldntLoadObject' );
 365         }
 366         die "Loaded object has different id" unless( $id eq $obj->id );
 367         push @res, $obj;
 368     } else {
 369         RT::Shredder::Exception->throw( "Unsupported type ". ref $targets );
 370     }
 371     return @res;
 372 }
 373
 374 =head3 OBJECTS CACHE
 375
 376 =head4 PutObjects( Objects => undef )
 377
 378 Puts objects into cache.
 379
 380 Returns array of the cache entries.
 381
 382 See C<CastObjectsToRecords> method for supported types of the C<Objects>
 383 argument.
 384
 385 =cut
 386
 387 sub PutObjects
 388 {
 389     my $self = shift;
 390     my %args = ( Objects => undef, @_ );
 391
 392     my @res;
 393     for( $self->CastObjectsToRecords( Objects => delete $args{'Objects'} ) ) {
 394         push @res, $self->PutObject( %args, Object => $_ )
 395     }
 396
 397     return @res;
 398 }
 399
 400 =head4 PutObject( Object => undef )
 401
 402 Puts record object into cache and returns its cache entry.
 403
 404 B<NOTE> that this method support B<only C<RT::Record> object or its ancesstor
 405 objects>, if you want put mutliple objects or objects represented by different
 406 classes then use C<PutObjects> method instead.
 407
 408 =cut
 409
 410 sub PutObject
 411 {
 412     my $self = shift;
 413     my %args = ( Object => undef, @_ );
 414
 415     my $obj = $args{'Object'};
 416     unless( UNIVERSAL::isa( $obj, 'RT::Record' ) ) {
 417         RT::Shredder::Exception->throw( "Unsupported type '". (ref $obj || $obj || '(undef)')."'" );
 418     }
 419
 420     my $str = $obj->UID;
 421     return ($self->{'cache'}->{ $str } ||= {
 422         State  => RT::Shredder::Constants::ON_STACK,
 423         Object => $obj
 424     } );
 425 }
 426
 427 =head4 GetObject, GetState, GetRecord( String => ''| Object => '' )
 428
 429 Returns record object from cache, cache entry state or cache entry accordingly.
 430
 431 All three methods takes C<String> (format C<< <class>-<id> >>) or C<Object> argument.
 432 C<String> argument has more priority than C<Object> so if it's not empty then methods
 433 leave C<Object> argument unchecked.
 434
 435 You can read about possible states and their meanings in L<RT::Shredder::Constants> docs.
 436
 437 =cut
 438
 439 sub _ParseRefStrArgs
 440 {
 441     my $self = shift;
 442     my %args = (
 443         String => '',
 444         Object => undef,
 445         @_
 446     );
 447     if( $args{'String'} && $args{'Object'} ) {
 448         require Carp;
 449         Carp::croak( "both String and Object args passed" );
 450     }
 451     return $args{'String'} if $args{'String'};
 452     return $args{'Object'}->UID if UNIVERSAL::can($args{'Object'}, 'UID' );
 453     return '';
 454 }
 455
 456 sub GetObject { return (shift)->GetRecord( @_ )->{'Object'} }
 457 sub GetState { return (shift)->GetRecord( @_ )->{'State'} }
 458 sub GetRecord
 459 {
 460     my $self = shift;
 461     my $str = $self->_ParseRefStrArgs( @_ );
 462     return $self->{'cache'}->{ $str };
 463 }
 464
 465 =head3 Dependencies resolvers
 466
 467 =head4 PutResolver, GetResolvers and ApplyResolvers
 468
 469 TODO: These methods have no documentation.
 470
 471 =cut
 472
 473 sub PutResolver
 474 {
 475     my $self = shift;
 476     my %args = (
 477         BaseClass => '',
 478         TargetClass => '',
 479         Code => undef,
 480         @_,
 481     );
 482     unless( UNIVERSAL::isa( $args{'Code'} => 'CODE' ) ) {
 483         die "Resolver '$args{Code}' is not code reference";
 484     }
 485
 486     my $resolvers = (
 487         (
 488             $self->{'resolver'}->{ $args{'BaseClass'} } ||= {}
 489         )->{  $args{'TargetClass'} || '' } ||= []
 490     );
 491     unshift @$resolvers, $args{'Code'};
 492     return;
 493 }
 494
 495 sub GetResolvers
 496 {
 497     my $self = shift;
 498     my %args = (
 499         BaseClass => '',
 500         TargetClass => '',
 501         @_,
 502     );
 503
 504     my @res;
 505     if( $args{'TargetClass'} && exists $self->{'resolver'}->{ $args{'BaseClass'} }->{ $args{'TargetClass'} } ) {
 506         push @res, @{ $self->{'resolver'}->{ $args{'BaseClass'} }->{ $args{'TargetClass'} || '' } };
 507     }
 508     if( exists $self->{'resolver'}->{ $args{'BaseClass'} }->{ '' } ) {
 509         push @res, @{ $self->{'resolver'}->{ $args{'BaseClass'} }->{''} };
 510     }
 511
 512     return @res;
 513 }
 514
 515 sub ApplyResolvers
 516 {
 517     my $self = shift;
 518     my %args = ( Dependency => undef, @_ );
 519     my $dep = $args{'Dependency'};
 520
 521     my @resolvers = $self->GetResolvers(
 522         BaseClass   => $dep->BaseClass,
 523         TargetClass => $dep->TargetClass,
 524     );
 525
 526     unless( @resolvers ) {
 527         RT::Shredder::Exception::Info->throw(
 528             tag   => 'NoResolver',
 529             error => "Couldn't find resolver for dependency '". $dep->AsString ."'",
 530         );
 531     }
 532     $_->(
 533         Shredder     => $self,
 534         BaseObject   => $dep->BaseObject,
 535         TargetObject => $dep->TargetObject,
 536     ) foreach @resolvers;
 537
 538     return;
 539 }
 540
 541 sub WipeoutAll
 542 {
 543     my $self = $_[0];
 544
 545     foreach my $cache_val ( values %{ $self->{'cache'} } ) {
 546         next if $cache_val->{'State'} & (RT::Shredder::Constants::WIPED | RT::Shredder::Constants::IN_WIPING);
 547         $self->Wipeout( Object => $cache_val->{'Object'} );
 548     }
 549     return;
 550 }
 551
 552 sub Wipeout
 553 {
 554     my $self = shift;
 555     my $mark;
 556     eval {
 557         die "Couldn't begin transaction" unless $RT::Handle->BeginTransaction;
 558         $mark = $self->PushDumpMark or die "Couldn't get dump mark";
 559         $self->_Wipeout( @_ );
 560         $self->PopDumpMark( Mark => $mark );
 561         die "Couldn't commit transaction" unless $RT::Handle->Commit;
 562     };
 563     if( $@ ) {
 564         my $error = $@;
 565         $RT::Handle->Rollback('force');
 566         $self->RollbackDumpTo( Mark => $mark ) if $mark;
 567         die $error if RT::Shredder::Exception::Info->caught;
 568         die "Couldn't wipeout object: $error";
 569     }
 570     return;
 571 }
 572
 573 sub _Wipeout
 574 {
 575     my $self = shift;
 576     my %args = ( CacheRecord => undef, Object => undef, @_ );
 577
 578     my $record = $args{'CacheRecord'};
 579     $record = $self->PutObject( Object => $args{'Object'} ) unless $record;
 580     return if $record->{'State'} & (RT::Shredder::Constants::WIPED | RT::Shredder::Constants::IN_WIPING);
 581
 582     $record->{'State'} |= RT::Shredder::Constants::IN_WIPING;
 583     my $object = $record->{'Object'};
 584
 585     $self->DumpObject( Object => $object, State => 'before any action' );
 586
 587     unless( $object->BeforeWipeout ) {
 588         RT::Shredder::Exception->throw( "BeforeWipeout check returned error" );
 589     }
 590
 591     my $deps = $object->Dependencies( Shredder => $self );
 592     $deps->List(
 593         WithFlags => RT::Shredder::Constants::DEPENDS_ON | RT::Shredder::Constants::VARIABLE,
 594         Callback  => sub { $self->ApplyResolvers( Dependency => $_[0] ) },
 595     );
 596     $self->DumpObject( Object => $object, State => 'after resolvers' );
 597
 598     $deps->List(
 599         WithFlags    => RT::Shredder::Constants::DEPENDS_ON,
 600         WithoutFlags => RT::Shredder::Constants::WIPE_AFTER | RT::Shredder::Constants::VARIABLE,
 601         Callback     => sub { $self->_Wipeout( Object => $_[0]->TargetObject ) },
 602     );
 603     $self->DumpObject( Object => $object, State => 'after wiping dependencies' );
 604
 605     $object->__Wipeout;
 606     $record->{'State'} |= RT::Shredder::Constants::WIPED; delete $record->{'Object'};
 607     $self->DumpObject( Object => $object, State => 'after wipeout' );
 608
 609     $deps->List(
 610         WithFlags => RT::Shredder::Constants::DEPENDS_ON | RT::Shredder::Constants::WIPE_AFTER,
 611         WithoutFlags => RT::Shredder::Constants::VARIABLE,
 612         Callback => sub { $self->_Wipeout( Object => $_[0]->TargetObject ) },
 613     );
 614     $self->DumpObject( Object => $object, State => 'after late dependencies' );
 615
 616     return;
 617 }
 618
 619 =head3 Data storage and backups
 620
 621 =head4 GetFileName( FileName => '<ISO DATETIME>-XXXX.sql', FromStorage => 1 )
 622
 623 Takes desired C<FileName> and flag C<FromStorage> then translate file name to absolute
 624 path by next rules:
 625
 626 * Default value of the C<FileName> option is C<< <ISO DATETIME>-XXXX.sql >>;
 627
 628 * if C<FileName> has C<XXXX> (exactly four uppercase C<X> letters) then it would be changed with digits from 0000 to 9999 range, with first one free value;
 629
 630 * if C<FileName> has C<%T> then it would be replaced with the current date and time in the C<YYYY-MM-DDTHH:MM:SS> format. Note that using C<%t> may still generate not unique names, using C<XXXX> recomended.
 631
 632 * if C<FromStorage> argument is true (default behaviour) then result path would always be relative to C<StoragePath>;
 633
 634 * if C<FromStorage> argument is false then result would be relative to the current dir unless it's already absolute path.
 635
 636 Returns an absolute path of the file.
 637
 638 Examples:
 639     # file from storage with default name format
 640     my $fname = $shredder->GetFileName;
 641
 642     # file from storage with custom name format
 643     my $fname = $shredder->GetFileName( FileName => 'shredder-XXXX.backup' );
 644
 645     # file with path relative to the current dir
 646     my $fname = $shredder->GetFileName(
 647         FromStorage => 0,
 648         FileName => 'backups/shredder.sql',
 649     );
 650
 651     # file with absolute path
 652     my $fname = $shredder->GetFileName(
 653         FromStorage => 0,
 654         FileName => '/var/backups/shredder-XXXX.sql'
 655     );
 656
 657 =cut
 658
 659 sub GetFileName
 660 {
 661     my $self = shift;
 662     my %args = ( FileName => '', FromStorage => 1, @_ );
 663
 664     # default value
 665     my $file = $args{'FileName'} || '%t-XXXX.sql';
 666     if( $file =~ /\%t/i ) {
 667         require POSIX;
 668         my $date_time = POSIX::strftime( "%Y%m%dT%H%M%S", gmtime );
 669         $file =~ s/\%t/$date_time/gi;
 670     }
 671
 672     # convert to absolute path
 673     if( $args{'FromStorage'} ) {
 674         $file = File::Spec->catfile( $self->StoragePath, $file );
 675     } elsif( !File::Spec->file_name_is_absolute( $file ) ) {
 676         $file = File::Spec->rel2abs( $file );
 677     }
 678
 679     # check mask
 680     if( $file =~ /XXXX[^\/\\]*$/ ) {
 681         my( $tmp, $i ) = ( $file, 0 );
 682         do {
 683             $i++;
 684             $tmp = $file;
 685             $tmp =~ s/XXXX([^\/\\]*)$/sprintf("%04d", $i).$1/e;
 686         } while( -e $tmp && $i < 9999 );
 687         $file = $tmp;
 688     }
 689
 690     if( -f $file ) {
 691         unless( -w _ ) {
 692             die "File '$file' exists, but is read-only";
 693         }
 694     } elsif( !-e _ ) {
 695         unless( File::Spec->file_name_is_absolute( $file ) ) {
 696             $file = File::Spec->rel2abs( $file );
 697         }
 698
 699         # check base dir
 700         my $dir = File::Spec->join( (File::Spec->splitpath( $file ))[0,1] );
 701         unless( -e $dir && -d _) {
 702             die "Base directory '$dir' for file '$file' doesn't exist";
 703         }
 704         unless( -w $dir ) {
 705             die "Base directory '$dir' is not writable";
 706         }
 707     } else {
 708         die "'$file' is not regular file";
 709     }
 710
 711     return $file;
 712 }
 713
 714 =head4 StoragePath
 715
 716 Returns an absolute path to the storage dir.  See
 717 L</$ShredderStoragePath>.
 718
 719 See also description of the L</GetFileName> method.
 720
 721 =cut
 722
 723 sub StoragePath
 724 {
 725     return scalar( RT->Config->Get('ShredderStoragePath') )
 726         || File::Spec->catdir( $RT::VarPath, qw(data RT-Shredder) );
 727 }
 728
 729 my %active_dump_state = ();
 730 sub AddDumpPlugin {
 731     my $self = shift;
 732     my %args = ( Object => undef, Name => 'SQLDump', Arguments => undef, @_ );
 733
 734     my $plugin = $args{'Object'};
 735     unless ( $plugin ) {
 736         require RT::Shredder::Plugin;
 737         $plugin = RT::Shredder::Plugin->new;
 738         my( $status, $msg ) = $plugin->LoadByName( $args{'Name'} );
 739         die "Couldn't load dump plugin: $msg\n" unless $status;
 740     }
 741     die "Plugin is not of correct type" unless lc $plugin->Type eq 'dump';
 742
 743     if ( my $pargs = $args{'Arguments'} ) {
 744         my ($status, $msg) = $plugin->TestArgs( %$pargs );
 745         die "Couldn't set plugin args: $msg\n" unless $status;
 746     }
 747
 748     my @applies_to = $plugin->AppliesToStates;
 749     die "Plugin doesn't apply to any state" unless @applies_to;
 750     $active_dump_state{ lc $_ } = 1 foreach @applies_to;
 751
 752     push @{ $self->{'dump_plugins'} }, $plugin;
 753
 754     return $plugin;
 755 }
 756
 757 sub DumpObject {
 758     my $self = shift;
 759     my %args = (Object => undef, State => undef, @_);
 760     die "No state passed" unless $args{'State'};
 761     return unless $active_dump_state{ lc $args{'State'} };
 762
 763     foreach (@{ $self->{'dump_plugins'} }) {
 764         next unless grep lc $args{'State'} eq lc $_, $_->AppliesToStates;
 765         my ($state, $msg) = $_->Run( %args );
 766         die "Couldn't run plugin: $msg" unless $state;
 767     }
 768     return;
 769 }
 770
 771 { my $mark = 1; # XXX: integer overflows?
 772 sub PushDumpMark {
 773     my $self = shift;
 774     $mark++;
 775     foreach (@{ $self->{'dump_plugins'} }) {
 776         my ($state, $msg) = $_->PushMark( Mark => $mark );
 777         die "Couldn't push mark: $msg" unless $state;
 778     }
 779     return $mark;
 780 }
 781 sub PopDumpMark {
 782     my $self = shift;
 783     foreach (@{ $self->{'dump_plugins'} }) {
 784         my ($state, $msg) = $_->PopMark( @_ );
 785         die "Couldn't pop mark: $msg" unless $state;
 786     }
 787     return;
 788 }
 789 sub RollbackDumpTo {
 790     my $self = shift;
 791     foreach (@{ $self->{'dump_plugins'} }) {
 792         my ($state, $msg) = $_->RollbackTo( @_ );
 793         die "Couldn't rollback to mark: $msg" unless $state;
 794     }
 795     return;
 796 }
 797 }
 798
 799 1;
 800 __END__
 801
 802 =head1 NOTES
 803
 804 =head2 Database transactions support
 805
 806 Since 0.03_01 RT::Shredder uses database transactions and should be
 807 much safer to run on production servers.
 808
 809 =head2 Foreign keys
 810
 811 Mainstream RT doesn't use FKs, but at least I posted DDL script that creates them
 812 in mysql DB, note that if you use FKs then this two valid keys don't allow delete
 813 Tickets because of bug in MySQL:
 814
 815   ALTER TABLE Tickets ADD FOREIGN KEY (EffectiveId) REFERENCES Tickets(id);
 816   ALTER TABLE CachedGroupMembers ADD FOREIGN KEY (Via) REFERENCES CachedGroupMembers(id);
 817
 818 L<http://bugs.mysql.com/bug.php?id=4042>
 819
 820 =head1 BUGS AND HOW TO CONTRIBUTE
 821
 822 We need your feedback in all cases: if you use it or not,
 823 is it works for you or not.
 824
 825 =head2 Testing
 826
 827 Don't skip C<make test> step while install and send me reports if it's fails.
 828 Add your own tests, it's easy enough if you've writen at list one perl script
 829 that works with RT. Read more about testing in F<t/utils.pl>.
 830
 831 =head2 Reporting
 832
 833 Send reports to L</AUTHOR> or to the RT mailing lists.
 834
 835 =head2 Documentation
 836
 837 Many bugs in the docs: insanity, spelling, gramar and so on.
 838 Patches are wellcome.
 839
 840 =head2 Todo
 841
 842 Please, see Todo file, it has some technical notes
 843 about what I plan to do, when I'll do it, also it
 844 describes some problems code has.
 845
 846 =head2 Repository
 847
 848 Since RT-3.7 shredder is a part of the RT distribution.
 849 Versions of the RTx::Shredder extension could
 850 be downloaded from the CPAN. Those work with older
 851 RT versions or you can find repository at
 852 L<https://opensvn.csie.org/rtx_shredder>
 853
 854 =head1 AUTHOR
 855
 856     Ruslan U. Zakirov <Ruslan.Zakirov@gmail.com>
 857
 858 =head1 COPYRIGHT
 859
 860 This program is free software; you can redistribute
 861 it and/or modify it under the same terms as Perl itself.
 862
 863 The full text of the license can be found in the
 864 Perl distribution.
 865
 866 =head1 SEE ALSO
 867
 868 L<rt-shredder>, L<rt-validator>
 869
 870 =cut