rt/lib/RT/Record/Role/Rights.pm

   1 # BEGIN BPS TAGGED BLOCK {{{
   2 #
   3 # COPYRIGHT:
   4 #
   5 # This software is Copyright (c) 1996-2019 Best Practical Solutions, LLC
   6 #                                          <sales@bestpractical.com>
   7 #
   8 # (Except where explicitly superseded by other copyright notices)
   9 #
  10 #
  11 # LICENSE:
  12 #
  13 # This work is made available to you under the terms of Version 2 of
  14 # the GNU General Public License. A copy of that license should have
  15 # been provided with this software, but in any event can be snarfed
  16 # from www.gnu.org.
  17 #
  18 # This work is distributed in the hope that it will be useful, but
  19 # WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 # General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 # 02110-1301 or visit their web page on the internet at
  27 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  28 #
  29 #
  30 # CONTRIBUTION SUBMISSION POLICY:
  31 #
  32 # (The following paragraph is not intended to limit the rights granted
  33 # to you to modify and distribute this software under the terms of
  34 # the GNU General Public License and is only of importance to you if
  35 # you choose to contribute your changes and enhancements to the
  36 # community by submitting them to Best Practical Solutions, LLC.)
  37 #
  38 # By intentionally submitting any modifications, corrections or
  39 # derivatives to this work, or any other work intended for use with
  40 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  41 # you are the copyright holder for those contributions and you grant
  42 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  43 # royalty-free, perpetual, license to use, copy, create derivative
  44 # works based on those contributions, and sublicense and distribute
  45 # those contributions and any derivatives thereof.
  46 #
  47 # END BPS TAGGED BLOCK }}}
  48
  49 use strict;
  50 use warnings;
  51
  52 package RT::Record::Role::Rights;
  53 use Role::Basic;
  54 use Scalar::Util qw(blessed);
  55
  56 =head1 NAME
  57
  58 RT::Record::Role::Rights - Common methods for records which can provide rights
  59
  60 =head1 DESCRIPTION
  61
  62 =head1 REQUIRES
  63
  64 =head2 L<RT::Record::Role>
  65
  66 =cut
  67
  68 with 'RT::Record::Role';
  69
  70 =head1 PROVIDES
  71
  72 =cut
  73
  74 =head2 AddRight C<CATEGORY>, C<RIGHT>, C<DESCRIPTION>
  75
  76 Adds the given rights to the list of possible rights.  This method
  77 should be called during server startup, not at runtime.
  78
  79 =cut
  80
  81 sub AddRight {
  82     my $class = shift;
  83     $class = ref($class) || $class;
  84     my ($category, $name, $description) = @_;
  85
  86     require RT::ACE;
  87     if (exists $RT::ACE::RIGHTS{$class}{lc $name}) {
  88         warn "Duplicate right '$name' found";
  89         return;
  90     }
  91
  92     $RT::ACE::RIGHTS{$class}{lc $name} = {
  93         Name        => $name,
  94         Category    => $category,
  95         Description => $description,
  96     };
  97 }
  98
  99 =head2 AvailableRights
 100
 101 Returns a hashref of available rights for this object. The keys are the
 102 right names and the values are a description of what the rights do.
 103
 104 =cut
 105
 106 sub AvailableRights {
 107     my $self = shift;
 108     my $class = ref($self) || $self;
 109
 110     my %rights;
 111     $rights{$_->{Name}} = $_->{Description}
 112         for values %{$RT::ACE::RIGHTS{$class} || {} };
 113     return \%rights;
 114 }
 115
 116 =head2 RightCategories
 117
 118 Returns a hashref where the keys are rights for this type of object and the
 119 values are the category (General, Staff, Admin) the right falls into.
 120
 121 =cut
 122
 123 sub RightCategories {
 124     my $self = shift;
 125     my $class = ref($self) || $self;
 126
 127     my %rights;
 128     $rights{$_->{Name}} = $_->{Category}
 129         for values %{ $RT::ACE::RIGHTS{$class} || {} };
 130     return \%rights;
 131 }
 132
 133 1;