rt/lib/RT/Action/Notify.pm

   1 # BEGIN BPS TAGGED BLOCK {{{
   2 #
   3 # COPYRIGHT:
   4 #
   5 # This software is Copyright (c) 1996-2015 Best Practical Solutions, LLC
   6 #                                          <sales@bestpractical.com>
   7 #
   8 # (Except where explicitly superseded by other copyright notices)
   9 #
  10 #
  11 # LICENSE:
  12 #
  13 # This work is made available to you under the terms of Version 2 of
  14 # the GNU General Public License. A copy of that license should have
  15 # been provided with this software, but in any event can be snarfed
  16 # from www.gnu.org.
  17 #
  18 # This work is distributed in the hope that it will be useful, but
  19 # WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 # General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 # 02110-1301 or visit their web page on the internet at
  27 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  28 #
  29 #
  30 # CONTRIBUTION SUBMISSION POLICY:
  31 #
  32 # (The following paragraph is not intended to limit the rights granted
  33 # to you to modify and distribute this software under the terms of
  34 # the GNU General Public License and is only of importance to you if
  35 # you choose to contribute your changes and enhancements to the
  36 # community by submitting them to Best Practical Solutions, LLC.)
  37 #
  38 # By intentionally submitting any modifications, corrections or
  39 # derivatives to this work, or any other work intended for use with
  40 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  41 # you are the copyright holder for those contributions and you grant
  42 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  43 # royalty-free, perpetual, license to use, copy, create derivative
  44 # works based on those contributions, and sublicense and distribute
  45 # those contributions and any derivatives thereof.
  46 #
  47 # END BPS TAGGED BLOCK }}}
  48
  49 #
  50 package RT::Action::Notify;
  51
  52 use strict;
  53 use warnings;
  54
  55 use base qw(RT::Action::SendEmail);
  56
  57 use Email::Address;
  58
  59 =head2 Prepare
  60
  61 Set up the relevant recipients, then call our parent.
  62
  63 =cut
  64
  65
  66 sub Prepare {
  67     my $self = shift;
  68     $self->SetRecipients();
  69     $self->SUPER::Prepare();
  70 }
  71
  72 =head2 SetRecipients
  73
  74 Sets the recipients of this message to Owner, Requestor, AdminCc, Cc or All.
  75 Explicitly B<does not> notify the creator of the transaction by default.
  76
  77 =cut
  78
  79 sub SetRecipients {
  80     my $self = shift;
  81
  82     my $ticket = $self->TicketObj;
  83
  84     my $arg = $self->Argument;
  85     $arg =~ s/\bAll\b/Owner,Requestor,AdminCc,Cc/;
  86
  87     my ( @To, @PseudoTo, @Cc, @Bcc );
  88
  89
  90     if ( $arg =~ /\bRequestor\b/ ) {
  91         push @To, $ticket->Requestors->MemberEmailAddresses;
  92     }
  93
  94     if ( $arg =~ /\bCc\b/ ) {
  95
  96         #If we have a To, make the Ccs, Ccs, otherwise, promote them to To
  97         if (@To) {
  98             push ( @Cc, $ticket->Cc->MemberEmailAddresses );
  99             push ( @Cc, $ticket->QueueObj->Cc->MemberEmailAddresses  );
 100         }
 101         else {
 102             push ( @Cc, $ticket->Cc->MemberEmailAddresses  );
 103             push ( @To, $ticket->QueueObj->Cc->MemberEmailAddresses  );
 104         }
 105     }
 106
 107     if (   $arg =~ /\bOwner\b/
 108         && $ticket->OwnerObj->id != RT->Nobody->id
 109         && $ticket->OwnerObj->EmailAddress
 110         && not $ticket->OwnerObj->Disabled
 111     ) {
 112         # If we're not sending to Ccs or requestors,
 113         # then the Owner can be the To.
 114         if (@To) {
 115             push ( @Bcc, $ticket->OwnerObj->EmailAddress );
 116         }
 117         else {
 118             push ( @To, $ticket->OwnerObj->EmailAddress );
 119         }
 120
 121     }
 122
 123     if ( $arg =~ /\bAdminCc\b/ ) {
 124         push ( @Bcc, $ticket->AdminCc->MemberEmailAddresses  );
 125         push ( @Bcc, $ticket->QueueObj->AdminCc->MemberEmailAddresses  );
 126     }
 127
 128     if ( RT->Config->Get('UseFriendlyToLine') ) {
 129         unless (@To) {
 130             push @PseudoTo,
 131                 sprintf RT->Config->Get('FriendlyToLineFormat'), $arg, $ticket->id;
 132         }
 133     }
 134
 135     @{ $self->{'To'} }       = @To;
 136     @{ $self->{'Cc'} }       = @Cc;
 137     @{ $self->{'Bcc'} }      = @Bcc;
 138     @{ $self->{'PseudoTo'} } = @PseudoTo;
 139
 140     if ( $arg =~ /\bOtherRecipients\b/ ) {
 141         if ( my $attachment = $self->TransactionObj->Attachments->First ) {
 142             push @{ $self->{'NoSquelch'}{'Cc'} ||= [] }, map $_->address,
 143                 Email::Address->parse( $attachment->GetHeader('RT-Send-Cc') );
 144             push @{ $self->{'NoSquelch'}{'Bcc'} ||= [] }, map $_->address,
 145                 Email::Address->parse( $attachment->GetHeader('RT-Send-Bcc') );
 146         }
 147     }
 148 }
 149
 150 =head2 RemoveInappropriateRecipients
 151
 152 Remove transaction creator as appropriate for the NotifyActor setting.
 153
 154 To send email to the selected receipients regardless of RT's NotifyActor
 155 configuration, include AlwaysNotifyActor in the list of arguments.
 156
 157 =cut
 158
 159 sub RemoveInappropriateRecipients {
 160     my $self = shift;
 161
 162     my $creatorObj = $self->TransactionObj->CreatorObj;
 163     my $creator = $creatorObj->EmailAddress() || '';
 164     my $TransactionCurrentUser = RT::CurrentUser->new;
 165     $TransactionCurrentUser->LoadByName($creatorObj->Name);
 166
 167     $self->RecipientFilter(
 168         Callback => sub {
 169             return unless lc $_[0] eq lc $creator;
 170             return "not sending to $creator, creator of the transaction, due to NotifyActor setting";
 171         },
 172     ) unless RT->Config->Get('NotifyActor',$TransactionCurrentUser)
 173              || $self->Argument =~ /\bAlwaysNotifyActor\b/;
 174
 175     $self->SUPER::RemoveInappropriateRecipients();
 176 }
 177
 178 RT::Base->_ImportOverlays();
 179
 180 1;