rt/lib/RT.pm

   1 # BEGIN BPS TAGGED BLOCK {{{
   2 #
   3 # COPYRIGHT:
   4 #
   5 # This software is Copyright (c) 1996-2011 Best Practical Solutions, LLC
   6 #                                          <sales@bestpractical.com>
   7 #
   8 # (Except where explicitly superseded by other copyright notices)
   9 #
  10 #
  11 # LICENSE:
  12 #
  13 # This work is made available to you under the terms of Version 2 of
  14 # the GNU General Public License. A copy of that license should have
  15 # been provided with this software, but in any event can be snarfed
  16 # from www.gnu.org.
  17 #
  18 # This work is distributed in the hope that it will be useful, but
  19 # WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 # General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 # 02110-1301 or visit their web page on the internet at
  27 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  28 #
  29 #
  30 # CONTRIBUTION SUBMISSION POLICY:
  31 #
  32 # (The following paragraph is not intended to limit the rights granted
  33 # to you to modify and distribute this software under the terms of
  34 # the GNU General Public License and is only of importance to you if
  35 # you choose to contribute your changes and enhancements to the
  36 # community by submitting them to Best Practical Solutions, LLC.)
  37 #
  38 # By intentionally submitting any modifications, corrections or
  39 # derivatives to this work, or any other work intended for use with
  40 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  41 # you are the copyright holder for those contributions and you grant
  42 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  43 # royalty-free, perpetual, license to use, copy, create derivative
  44 # works based on those contributions, and sublicense and distribute
  45 # those contributions and any derivatives thereof.
  46 #
  47 # END BPS TAGGED BLOCK }}}
  48
  49 use strict;
  50 use warnings;
  51
  52 package RT;
  53
  54
  55 use File::Spec ();
  56 use Cwd ();
  57
  58 use vars qw($Config $System $SystemUser $Nobody $Handle $Logger $_INSTALL_MODE);
  59
  60 our $VERSION = '3.8.10';
  61
  62
  63
  64 our $BasePath = '/opt/rt3';
  65 our $EtcPath = 'etc';
  66 our $BinPath = 'bin';
  67 our $SbinPath = 'sbin';
  68 our $VarPath = 'var';
  69 our $PluginPath = 'plugins';
  70 our $LocalPath = 'local';
  71 our $LocalEtcPath = 'local/etc';
  72 our $LocalLibPath        =    'local/lib';
  73 our $LocalLexiconPath = 'local/po';
  74 our $LocalPluginPath = $LocalPath."/plugins";
  75
  76
  77 # $MasonComponentRoot is where your rt instance keeps its mason html files
  78
  79 our $MasonComponentRoot = 'share/html';
  80
  81 # $MasonLocalComponentRoot is where your rt instance keeps its site-local
  82 # mason html files.
  83
  84 our $MasonLocalComponentRoot = 'local/html';
  85
  86 # $MasonDataDir Where mason keeps its datafiles
  87
  88 our $MasonDataDir = 'var/mason_data';
  89
  90 # RT needs to put session data (for preserving state between connections
  91 # via the web interface)
  92 our $MasonSessionDir = 'var/session_data';
  93
  94 unless (  File::Spec->file_name_is_absolute($EtcPath) ) {
  95
  96 # if BasePath exists and is absolute, we won't infer it from $INC{'RT.pm'}.
  97 # otherwise RT.pm will make src dir(where we configure RT) be the BasePath
  98 # instead of the --prefix one
  99     unless ( -d $BasePath && File::Spec->file_name_is_absolute($BasePath) ) {
 100         my $pm_path = ( File::Spec->splitpath( $INC{'RT.pm'} ) )[1];
 101
 102        # need rel2abs here is to make sure path is absolute, since $INC{'RT.pm'}
 103        # is not always absolute
 104         $BasePath =
 105           File::Spec->rel2abs(
 106             File::Spec->catdir( $pm_path, File::Spec->updir ) );
 107     }
 108
 109     $BasePath = Cwd::realpath( $BasePath );
 110
 111     for my $path ( qw/EtcPath BinPath SbinPath VarPath LocalPath LocalEtcPath
 112             LocalLibPath LocalLexiconPath PluginPath LocalPluginPath
 113             MasonComponentRoot MasonLocalComponentRoot MasonDataDir
 114             MasonSessionDir/ ) {
 115         no strict 'refs';
 116         # just change relative ones
 117         $$path = File::Spec->catfile( $BasePath, $$path )
 118           unless File::Spec->file_name_is_absolute( $$path );
 119     }
 120 }
 121
 122
 123 =head1 NAME
 124
 125 RT - Request Tracker
 126
 127 =head1 SYNOPSIS
 128
 129 A fully featured request tracker package
 130
 131 =head1 DESCRIPTION
 132
 133 =head2 INITIALIZATION
 134
 135 =head2 LoadConfig
 136
 137 Load RT's config file.  First, the site configuration file
 138 (F<RT_SiteConfig.pm>) is loaded, in order to establish overall site
 139 settings like hostname and name of RT instance.  Then, the core
 140 configuration file (F<RT_Config.pm>) is loaded to set fallback values
 141 for all settings; it bases some values on settings from the site
 142 configuration file.
 143
 144 In order for the core configuration to not override the site's
 145 settings, the function C<Set> is used; it only sets values if they
 146 have not been set already.
 147
 148 =cut
 149
 150 sub LoadConfig {
 151     require RT::Config;
 152     $Config = new RT::Config;
 153     $Config->LoadConfigs;
 154     require RT::I18N;
 155
 156     # RT::Essentials mistakenly recommends that WebPath be set to '/'.
 157     # If the user does that, do what they mean.
 158     $RT::WebPath = '' if ($RT::WebPath eq '/');
 159
 160     # fix relative LogDir and GnuPG homedir
 161     unless ( File::Spec->file_name_is_absolute( $Config->Get('LogDir') ) ) {
 162         $Config->Set( LogDir =>
 163               File::Spec->catfile( $BasePath, $Config->Get('LogDir') ) );
 164     }
 165
 166     my $gpgopts = $Config->Get('GnuPGOptions');
 167     unless ( File::Spec->file_name_is_absolute( $gpgopts->{homedir} ) ) {
 168         $gpgopts->{homedir} = File::Spec->catfile( $BasePath, $gpgopts->{homedir} );
 169     }
 170
 171     RT::I18N->Init;
 172 }
 173
 174 =head2 Init
 175
 176 L<Connect to the database /ConnectToDatabase>, L<initilizes system objects /InitSystemObjects>,
 177 L<preloads classes /InitClasses> and L<set up logging /InitLogging>.
 178
 179 =cut
 180
 181 sub Init {
 182
 183     CheckPerlRequirements();
 184
 185     InitPluginPaths();
 186
 187     #Get a database connection
 188     ConnectToDatabase();
 189     InitSystemObjects();
 190     InitClasses();
 191     InitLogging();
 192     InitPlugins();
 193     RT->Config->PostLoadCheck;
 194
 195 }
 196
 197 =head2 ConnectToDatabase
 198
 199 Get a database connection. See also </Handle>.
 200
 201 =cut
 202
 203 sub ConnectToDatabase {
 204     require RT::Handle;
 205     $Handle = new RT::Handle unless $Handle;
 206     $Handle->Connect;
 207     return $Handle;
 208 }
 209
 210 =head2 InitLogging
 211
 212 Create the Logger object and set up signal handlers.
 213
 214 =cut
 215
 216 sub InitLogging {
 217
 218     # We have to set the record separator ($, man perlvar)
 219     # or Log::Dispatch starts getting
 220     # really pissy, as some other module we use unsets it.
 221     $, = '';
 222     use Log::Dispatch 1.6;
 223
 224     my %level_to_num = (
 225         map( { $_ => } 0..7 ),
 226         debug     => 0,
 227         info      => 1,
 228         notice    => 2,
 229         warning   => 3,
 230         error     => 4, 'err' => 4,
 231         critical  => 5, crit  => 5,
 232         alert     => 6,
 233         emergency => 7, emerg => 7,
 234     );
 235
 236     unless ( $RT::Logger ) {
 237
 238         $RT::Logger = Log::Dispatch->new;
 239
 240         my $stack_from_level;
 241         if ( $stack_from_level = RT->Config->Get('LogStackTraces') ) {
 242             # if option has old style '\d'(true) value
 243             $stack_from_level = 0 if $stack_from_level =~ /^\d+$/;
 244             $stack_from_level = $level_to_num{ $stack_from_level } || 0;
 245         } else {
 246             $stack_from_level = 99; # don't log
 247         }
 248
 249         my $simple_cb = sub {
 250             # if this code throw any warning we can get segfault
 251             no warnings;
 252             my %p = @_;
 253
 254             # skip Log::* stack frames
 255             my $frame = 0;
 256             $frame++ while caller($frame) && caller($frame) =~ /^Log::/;
 257             my ($package, $filename, $line) = caller($frame);
 258
 259             $p{'message'} =~ s/(?:\r*\n)+$//;
 260             return "[". gmtime(time) ."] [". $p{'level'} ."]: "
 261                 . $p{'message'} ." ($filename:$line)\n";
 262         };
 263
 264         my $syslog_cb = sub {
 265             # if this code throw any warning we can get segfault
 266             no warnings;
 267             my %p = @_;
 268
 269             my $frame = 0; # stack frame index
 270             # skip Log::* stack frames
 271             $frame++ while caller($frame) && caller($frame) =~ /^Log::/;
 272             my ($package, $filename, $line) = caller($frame);
 273
 274             # syswrite() cannot take utf8; turn it off here.
 275             Encode::_utf8_off($p{message});
 276
 277             $p{message} =~ s/(?:\r*\n)+$//;
 278             if ($p{level} eq 'debug') {
 279                 return "$p{message}\n";
 280             } else {
 281                 return "$p{message} ($filename:$line)\n";
 282             }
 283         };
 284
 285         my $stack_cb = sub {
 286             no warnings;
 287             my %p = @_;
 288             return $p{'message'} unless $level_to_num{ $p{'level'} } >= $stack_from_level;
 289
 290             require Devel::StackTrace;
 291             my $trace = Devel::StackTrace->new( ignore_class => [ 'Log::Dispatch', 'Log::Dispatch::Base' ] );
 292             return $p{'message'} . $trace->as_string;
 293
 294             # skip calling of the Log::* subroutins
 295             my $frame = 0;
 296             $frame++ while caller($frame) && caller($frame) =~ /^Log::/;
 297             $frame++ while caller($frame) && (caller($frame))[3] =~ /^Log::/;
 298
 299             $p{'message'} .= "\nStack trace:\n";
 300             while( my ($package, $filename, $line, $sub) = caller($frame++) ) {
 301                 $p{'message'} .= "\t$sub(...) called at $filename:$line\n";
 302             }
 303             return $p{'message'};
 304         };
 305
 306         if ( $Config->Get('LogToFile') ) {
 307             my ($filename, $logdir) = (
 308                 $Config->Get('LogToFileNamed') || 'rt.log',
 309                 $Config->Get('LogDir') || File::Spec->catdir( $VarPath, 'log' ),
 310             );
 311             if ( $filename =~ m![/\\]! ) { # looks like an absolute path.
 312                 ($logdir) = $filename =~ m{^(.*[/\\])};
 313             }
 314             else {
 315                 $filename = File::Spec->catfile( $logdir, $filename );
 316             }
 317
 318             unless ( -d $logdir && ( ( -f $filename && -w $filename ) || -w $logdir ) ) {
 319                 # localizing here would be hard when we don't have a current user yet
 320                 die "Log file '$filename' couldn't be written or created.\n RT can't run.";
 321             }
 322
 323             require Log::Dispatch::File;
 324             $RT::Logger->add( Log::Dispatch::File->new
 325                            ( name=>'file',
 326                              min_level=> $Config->Get('LogToFile'),
 327                              filename=> $filename,
 328                              mode=>'append',
 329                              callbacks => [ $simple_cb, $stack_cb ],
 330                            ));
 331         }
 332         if ( $Config->Get('LogToScreen') ) {
 333             require Log::Dispatch::Screen;
 334             $RT::Logger->add( Log::Dispatch::Screen->new
 335                          ( name => 'screen',
 336                            min_level => $Config->Get('LogToScreen'),
 337                            callbacks => [ $simple_cb, $stack_cb ],
 338                            stderr => 1,
 339                          ));
 340         }
 341         if ( $Config->Get('LogToSyslog') ) {
 342             require Log::Dispatch::Syslog;
 343             $RT::Logger->add(Log::Dispatch::Syslog->new
 344                          ( name => 'syslog',
 345                            ident => 'RT',
 346                            min_level => $Config->Get('LogToSyslog'),
 347                            callbacks => [ $syslog_cb, $stack_cb ],
 348                            stderr => 1,
 349                            $Config->Get('LogToSyslogConf'),
 350                          ));
 351         }
 352     }
 353     InitSignalHandlers();
 354 }
 355
 356 sub InitSignalHandlers {
 357
 358 # Signal handlers
 359 ## This is the default handling of warnings and die'ings in the code
 360 ## (including other used modules - maybe except for errors catched by
 361 ## Mason).  It will log all problems through the standard logging
 362 ## mechanism (see above).
 363
 364     $SIG{__WARN__} = sub {
 365         # The 'wide character' warnings has to be silenced for now, at least
 366         # until HTML::Mason offers a sane way to process both raw output and
 367         # unicode strings.
 368         # use 'goto &foo' syntax to hide ANON sub from stack
 369         if( index($_[0], 'Wide character in ') != 0 ) {
 370             unshift @_, $RT::Logger, qw(level warning message);
 371             goto &Log::Dispatch::log;
 372         }
 373     };
 374
 375 #When we call die, trap it and log->crit with the value of the die.
 376
 377     $SIG{__DIE__}  = sub {
 378         # if we are not in eval and perl is not parsing code
 379         # then rollback transactions and log RT error
 380         unless ($^S || !defined $^S ) {
 381             $RT::Handle->Rollback(1) if $RT::Handle;
 382             $RT::Logger->crit("$_[0]") if $RT::Logger;
 383         }
 384         die $_[0];
 385     };
 386 }
 387
 388
 389 sub CheckPerlRequirements {
 390     if ($^V < 5.008003) {
 391         die sprintf "RT requires Perl v5.8.3 or newer.  Your current Perl is v%vd\n", $^V;
 392     }
 393
 394     # use $error here so the following "die" can still affect the global $@
 395     my $error;
 396     {
 397         local $@;
 398         eval {
 399             my $x = '';
 400             my $y = \$x;
 401             require Scalar::Util;
 402             Scalar::Util::weaken($y);
 403         };
 404         $error = $@;
 405     }
 406
 407     if ($error) {
 408         die <<"EOF";
 409
 410 RT requires the Scalar::Util module be built with support for  the 'weaken'
 411 function.
 412
 413 It is sometimes the case that operating system upgrades will replace
 414 a working Scalar::Util with a non-working one. If your system was working
 415 correctly up until now, this is likely the cause of the problem.
 416
 417 Please reinstall Scalar::Util, being careful to let it build with your C
 418 compiler. Ususally this is as simple as running the following command as
 419 root.
 420
 421     perl -MCPAN -e'install Scalar::Util'
 422
 423 EOF
 424
 425     }
 426 }
 427
 428 =head2 InitClasses
 429
 430 Load all modules that define base classes.
 431
 432 =cut
 433
 434 sub InitClasses {
 435     shift if @_%2; # so we can call it as a function or method
 436     my %args = (@_);
 437     require RT::Tickets;
 438     require RT::Transactions;
 439     require RT::Attachments;
 440     require RT::Users;
 441     require RT::Principals;
 442     require RT::CurrentUser;
 443     require RT::Templates;
 444     require RT::Queues;
 445     require RT::ScripActions;
 446     require RT::ScripConditions;
 447     require RT::Scrips;
 448     require RT::Groups;
 449     require RT::GroupMembers;
 450     require RT::CustomFields;
 451     require RT::CustomFieldValues;
 452     require RT::ObjectCustomFields;
 453     require RT::ObjectCustomFieldValues;
 454     require RT::Attributes;
 455     require RT::Dashboard;
 456     require RT::Approval;
 457
 458     # on a cold server (just after restart) people could have an object
 459     # in the session, as we deserialize it so we never call constructor
 460     # of the class, so the list of accessible fields is empty and we die
 461     # with "Method xxx is not implemented in RT::SomeClass"
 462     $_->_BuildTableAttributes foreach qw(
 463         RT::Ticket
 464         RT::Transaction
 465         RT::Attachment
 466         RT::User
 467         RT::Principal
 468         RT::Template
 469         RT::Queue
 470         RT::ScripAction
 471         RT::ScripCondition
 472         RT::Scrip
 473         RT::Group
 474         RT::GroupMember
 475         RT::CustomField
 476         RT::CustomFieldValue
 477         RT::ObjectCustomField
 478         RT::ObjectCustomFieldValue
 479         RT::Attribute
 480     );
 481
 482     if ( $args{'Heavy'} ) {
 483         # load scrips' modules
 484         my $scrips = RT::Scrips->new($RT::SystemUser);
 485         $scrips->Limit( FIELD => 'Stage', OPERATOR => '!=', VALUE => 'Disabled' );
 486         while ( my $scrip = $scrips->Next ) {
 487             local $@;
 488             eval { $scrip->LoadModules } or
 489                 $RT::Logger->error("Invalid Scrip ".$scrip->Id.".  Unable to load the Action or Condition.  ".
 490                                    "You should delete or repair this Scrip in the admin UI.\n$@\n");
 491         }
 492
 493         foreach my $class ( grep $_, RT->Config->Get('CustomFieldValuesSources') ) {
 494             local $@;
 495             eval "require $class; 1" or $RT::Logger->error(
 496                 "Class '$class' is listed in CustomFieldValuesSources option"
 497                 ." in the config, but we failed to load it:\n$@\n"
 498             );
 499         }
 500
 501         RT::I18N->LoadLexicons;
 502     }
 503 }
 504
 505 =head2 InitSystemObjects
 506
 507 Initializes system objects: C<$RT::System>, C<$RT::SystemUser>
 508 and C<$RT::Nobody>.
 509
 510 =cut
 511
 512 sub InitSystemObjects {
 513
 514     #RT's system user is a genuine database user. its id lives here
 515     require RT::CurrentUser;
 516     $SystemUser = new RT::CurrentUser;
 517     $SystemUser->LoadByName('RT_System');
 518
 519     #RT's "nobody user" is a genuine database user. its ID lives here.
 520     $Nobody = new RT::CurrentUser;
 521     $Nobody->LoadByName('Nobody');
 522
 523     require RT::System;
 524     $System = RT::System->new( $SystemUser );
 525 }
 526
 527 =head1 CLASS METHODS
 528
 529 =head2 Config
 530
 531 Returns the current L<config object RT::Config>, but note that
 532 you must L<load config /LoadConfig> first otherwise this method
 533 returns undef.
 534
 535 Method can be called as class method.
 536
 537 =cut
 538
 539 sub Config { return $Config }
 540
 541 =head2 DatabaseHandle
 542
 543 Returns the current L<database handle object RT::Handle>.
 544
 545 See also L</ConnectToDatabase>.
 546
 547 =cut
 548
 549 sub DatabaseHandle { return $Handle }
 550
 551 =head2 Logger
 552
 553 Returns the logger. See also L</InitLogging>.
 554
 555 =cut
 556
 557 sub Logger { return $Logger }
 558
 559 =head2 System
 560
 561 Returns the current L<system object RT::System>. See also
 562 L</InitSystemObjects>.
 563
 564 =cut
 565
 566 sub System { return $System }
 567
 568 =head2 SystemUser
 569
 570 Returns the system user's object, it's object of
 571 L<RT::CurrentUser> class that represents the system. See also
 572 L</InitSystemObjects>.
 573
 574 =cut
 575
 576 sub SystemUser { return $SystemUser }
 577
 578 =head2 Nobody
 579
 580 Returns object of Nobody. It's object of L<RT::CurrentUser> class
 581 that represents a user who can own ticket and nothing else. See
 582 also L</InitSystemObjects>.
 583
 584 =cut
 585
 586 sub Nobody { return $Nobody }
 587
 588 =head2 Plugins
 589
 590 Returns a listref of all Plugins currently configured for this RT instance.
 591 You can define plugins by adding them to the @Plugins list in your RT_SiteConfig
 592
 593 =cut
 594
 595 our @PLUGINS = ();
 596 sub Plugins {
 597     my $self = shift;
 598     unless (@PLUGINS) {
 599         $self->InitPluginPaths;
 600         @PLUGINS = $self->InitPlugins;
 601     }
 602     return \@PLUGINS;
 603 }
 604
 605 =head2 PluginDirs
 606
 607 Takes optional subdir (e.g. po, lib, etc.) and return plugins' dirs that exist.
 608
 609 This code chacke plugins names or anything else and required when main config
 610 is loaded to load plugins' configs.
 611
 612 =cut
 613
 614 sub PluginDirs {
 615     my $self = shift;
 616     my $subdir = shift;
 617
 618     require RT::Plugin;
 619
 620     my @res;
 621     foreach my $plugin (grep $_, RT->Config->Get('Plugins')) {
 622         my $path = RT::Plugin->new( name => $plugin )->Path( $subdir );
 623         next unless -d $path;
 624         push @res, $path;
 625     }
 626     return @res;
 627 }
 628
 629 =head2 InitPluginPaths
 630
 631 Push plugins' lib paths into @INC right after F<local/lib>.
 632 In case F<local/lib> isn't in @INC, append them to @INC
 633
 634 =cut
 635
 636 sub InitPluginPaths {
 637     my $self = shift || __PACKAGE__;
 638
 639     my @lib_dirs = $self->PluginDirs('lib');
 640
 641     my @tmp_inc;
 642     my $added;
 643     for (@INC) {
 644         if ( Cwd::realpath($_) eq $RT::LocalLibPath) {
 645             push @tmp_inc, $_, @lib_dirs;
 646             $added = 1;
 647         } else {
 648             push @tmp_inc, $_;
 649         }
 650     }
 651
 652     # append @lib_dirs in case $RT::LocalLibPath isn't in @INC
 653     push @tmp_inc, @lib_dirs unless $added;
 654
 655     my %seen;
 656     @INC = grep !$seen{$_}++, @tmp_inc;
 657 }
 658
 659 =head2 InitPlugins
 660
 661 Initialze all Plugins found in the RT configuration file, setting up their lib and HTML::Mason component roots.
 662
 663 =cut
 664
 665 sub InitPlugins {
 666     my $self    = shift;
 667     my @plugins;
 668     require RT::Plugin;
 669     foreach my $plugin (grep $_, RT->Config->Get('Plugins')) {
 670         $plugin->require;
 671         die $UNIVERSAL::require::ERROR if ($UNIVERSAL::require::ERROR);
 672         push @plugins, RT::Plugin->new(name =>$plugin);
 673     }
 674     return @plugins;
 675 }
 676
 677
 678 sub InstallMode {
 679     my $self = shift;
 680     if (@_) {
 681          $_INSTALL_MODE = shift;
 682          if($_INSTALL_MODE) {
 683              require RT::CurrentUser;
 684             $SystemUser = RT::CurrentUser->new();
 685          }
 686     }
 687     return $_INSTALL_MODE;
 688 }
 689
 690
 691 =head1 BUGS
 692
 693 Please report them to rt-bugs@bestpractical.com, if you know what's
 694 broken and have at least some idea of what needs to be fixed.
 695
 696 If you're not sure what's going on, report them rt-devel@lists.bestpractical.com.
 697
 698 =head1 SEE ALSO
 699
 700 L<RT::StyleGuide>
 701 L<DBIx::SearchBuilder>
 702
 703
 704 =cut
 705
 706 require RT::Base;
 707 RT::Base->_ImportOverlays();
 708
 709 1;