rt/bin/webmux.pl

   1 #!/usr/bin/perl
   2 # BEGIN BPS TAGGED BLOCK {{{
   3 #
   4 # COPYRIGHT:
   5 #
   6 # This software is Copyright (c) 1996-2011 Best Practical Solutions, LLC
   7 #                                          <sales@bestpractical.com>
   8 #
   9 # (Except where explicitly superseded by other copyright notices)
  10 #
  11 #
  12 # LICENSE:
  13 #
  14 # This work is made available to you under the terms of Version 2 of
  15 # the GNU General Public License. A copy of that license should have
  16 # been provided with this software, but in any event can be snarfed
  17 # from www.gnu.org.
  18 #
  19 # This work is distributed in the hope that it will be useful, but
  20 # WITHOUT ANY WARRANTY; without even the implied warranty of
  21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  22 # General Public License for more details.
  23 #
  24 # You should have received a copy of the GNU General Public License
  25 # along with this program; if not, write to the Free Software
  26 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  27 # 02110-1301 or visit their web page on the internet at
  28 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  29 #
  30 #
  31 # CONTRIBUTION SUBMISSION POLICY:
  32 #
  33 # (The following paragraph is not intended to limit the rights granted
  34 # to you to modify and distribute this software under the terms of
  35 # the GNU General Public License and is only of importance to you if
  36 # you choose to contribute your changes and enhancements to the
  37 # community by submitting them to Best Practical Solutions, LLC.)
  38 #
  39 # By intentionally submitting any modifications, corrections or
  40 # derivatives to this work, or any other work intended for use with
  41 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  42 # you are the copyright holder for those contributions and you grant
  43 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  44 # royalty-free, perpetual, license to use, copy, create derivative
  45 # works based on those contributions, and sublicense and distribute
  46 # those contributions and any derivatives thereof.
  47 #
  48 # END BPS TAGGED BLOCK }}}
  49 use strict;
  50 local $ENV{'PATH'}   = '/bin:/usr/bin';                   # or whatever you need
  51 local $ENV{'CDPATH'} = '' if defined $ENV{'CDPATH'};
  52 local $ENV{'SHELL'}  = '/bin/sh' if defined $ENV{'SHELL'};
  53 local $ENV{'ENV'}    = '' if defined $ENV{'ENV'};
  54 local $ENV{'IFS'}    = '' if defined $ENV{'IFS'};
  55
  56 package HTML::Mason::Commands;
  57 our %session;
  58
  59 package RT::Mason;
  60
  61 our ($Nobody, $SystemUser, $Handler, $r);
  62
  63 my $protect_fd;
  64
  65 sub handler {
  66     ($r) = @_;
  67
  68     if ( !$protect_fd && $ENV{'MOD_PERL'} && exists $ENV{'MOD_PERL_API_VERSION'}
  69         && $ENV{'MOD_PERL_API_VERSION'} >= 2 && fileno(STDOUT) != 1
  70     ) {
  71         # under mod_perl2, STDOUT gets closed and re-opened, however new STDOUT
  72         # is not on FD #1. In this case next IO operation will occupy this FD
  73         # and make all system() and open "|-" dangerouse, for example DBI
  74         # can get this FD for DB connection and system() call will close
  75         # by putting grabage into the socket
  76         open( $protect_fd, '>', '/dev/null' )
  77           or die "Couldn't open /dev/null: $!";
  78         unless ( fileno($protect_fd) == 1 ) {
  79             warn "We opened /dev/null to protect FD #1, but descriptor #1 is already occupied";
  80         }
  81     }
  82
  83     local $SIG{__WARN__};
  84     local $SIG{__DIE__};
  85     RT::InitSignalHandlers();
  86
  87     if ($r->content_type =~ m/^httpd\b.*\bdirectory/i) {
  88         use File::Spec::Unix;
  89         # Our DirectoryIndex is always index.html, regardless of httpd settings
  90         $r->filename( File::Spec::Unix->catfile( $r->filename, 'index.html' ) );
  91     }
  92
  93     Module::Refresh->refresh if RT->Config->Get('DevelMode');
  94
  95     RT::ConnectToDatabase();
  96
  97     # none of the methods in $r gives us the information we want (most
  98     # canonicalize /foo/../bar to /bar which is exactly what we want to avoid)
  99     my (undef, $requested) = split ' ', $r->the_request, 3;
 100     my $uri = URI->new("http://".$r->hostname.$requested);
 101     my $path = URI::Escape::uri_unescape($uri->path);
 102
 103     ## Each environment has its own way of handling .. and so on in paths,
 104     ## so RT consistently forbids such paths.
 105     if ( $path =~ m{/\.} ) {
 106         $RT::Logger->crit("Invalid request for ".$path." aborting");
 107         RT::Interface::Web::Handler->CleanupRequest();
 108         return 400;
 109     }
 110
 111     my (%session, $status);
 112     {
 113         local $@;
 114         $status = eval { $Handler->handle_request($r) };
 115         $RT::Logger->crit( $@ ) if $@;
 116     }
 117     undef %session;
 118
 119     RT::Interface::Web::Handler->CleanupRequest();
 120
 121     return $status;
 122 }
 123
 124 package main;
 125
 126 # check mod_perl version if it's mod_perl
 127 BEGIN {
 128     die "RT does not support mod_perl 1.99. Please upgrade to mod_perl 2.0"
 129         if $ENV{'MOD_PERL'}
 130         and $ENV{'MOD_PERL'} =~ m{mod_perl/(?:1\.9)};
 131 }
 132
 133 require CGI;
 134 CGI->import(qw(-private_tempfiles));
 135
 136 # fix lib paths, some may be relative
 137 BEGIN {
 138     require File::Spec;
 139     my @libs = ("lib", "local/lib");
 140     my $bin_path;
 141
 142     for my $lib (@libs) {
 143         unless ( File::Spec->file_name_is_absolute($lib) ) {
 144             unless ($bin_path) {
 145                 if ( File::Spec->file_name_is_absolute(__FILE__) ) {
 146                     $bin_path = ( File::Spec->splitpath(__FILE__) )[1];
 147                 }
 148                 else {
 149                     require FindBin;
 150                     no warnings "once";
 151                     $bin_path = $FindBin::Bin;
 152                 }
 153             }
 154             $lib = File::Spec->catfile( $bin_path, File::Spec->updir, $lib );
 155         }
 156         unshift @INC, $lib;
 157     }
 158
 159 }
 160
 161 require RT;
 162 die "Wrong version of RT $RT::Version found; need 3.8.*"
 163     unless $RT::VERSION =~ /^3\.8\./;
 164 RT::LoadConfig();
 165 if ( RT->Config->Get('DevelMode') ) {
 166     require Module::Refresh;
 167 }
 168 RT::Init();
 169
 170 # check compatibility of the DB
 171 {
 172     my $dbh = $RT::Handle->dbh;
 173     if ( $dbh ) {
 174         my ($status, $msg) = $RT::Handle->CheckCompatibility( $dbh, 'post' );
 175         die $msg unless $status;
 176     }
 177 }
 178
 179 require RT::Interface::Web::Handler;
 180 $RT::Mason::Handler = RT::Interface::Web::Handler->new(
 181     RT->Config->Get('MasonParameters')
 182 );
 183
 184 # load more for mod_perl before forking
 185 RT::InitClasses( Heavy => 1 ) if $ENV{'MOD_PERL'} || $ENV{RT_WEBMUX_HEAVY_LOAD};
 186
 187 # we must disconnect DB before fork
 188 $RT::Handle->dbh(undef);
 189 undef $RT::Handle;
 190
 191 if ( $ENV{'MOD_PERL'} && !RT->Config->Get('DevelMode')) {
 192     # Under static_source, we need to purge the component cache
 193     # each time we restart, so newer components may be reloaded.
 194     #
 195     # We can't do this in FastCGI or we'll blow away the component
 196     # root _every_ time a new server starts which happens every few
 197     # hits.
 198
 199     require File::Path;
 200     require File::Glob;
 201     my @files = File::Glob::bsd_glob("$RT::MasonDataDir/obj/*");
 202     File::Path::rmtree([ @files ], 0, 1) if @files;
 203 }
 204
 205 1;