rt/bin/rt-mailgate.in

   1 #!@PERL@
   2 # BEGIN BPS TAGGED BLOCK {{{
   3 #
   4 # COPYRIGHT:
   5 #
   6 # This software is Copyright (c) 1996-2014 Best Practical Solutions, LLC
   7 #                                          <sales@bestpractical.com>
   8 #
   9 # (Except where explicitly superseded by other copyright notices)
  10 #
  11 #
  12 # LICENSE:
  13 #
  14 # This work is made available to you under the terms of Version 2 of
  15 # the GNU General Public License. A copy of that license should have
  16 # been provided with this software, but in any event can be snarfed
  17 # from www.gnu.org.
  18 #
  19 # This work is distributed in the hope that it will be useful, but
  20 # WITHOUT ANY WARRANTY; without even the implied warranty of
  21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  22 # General Public License for more details.
  23 #
  24 # You should have received a copy of the GNU General Public License
  25 # along with this program; if not, write to the Free Software
  26 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  27 # 02110-1301 or visit their web page on the internet at
  28 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  29 #
  30 #
  31 # CONTRIBUTION SUBMISSION POLICY:
  32 #
  33 # (The following paragraph is not intended to limit the rights granted
  34 # to you to modify and distribute this software under the terms of
  35 # the GNU General Public License and is only of importance to you if
  36 # you choose to contribute your changes and enhancements to the
  37 # community by submitting them to Best Practical Solutions, LLC.)
  38 #
  39 # By intentionally submitting any modifications, corrections or
  40 # derivatives to this work, or any other work intended for use with
  41 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  42 # you are the copyright holder for those contributions and you grant
  43 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  44 # royalty-free, perpetual, license to use, copy, create derivative
  45 # works based on those contributions, and sublicense and distribute
  46 # those contributions and any derivatives thereof.
  47 #
  48 # END BPS TAGGED BLOCK }}}
  49 =head1 NAME
  50
  51 rt-mailgate - Mail interface to RT.
  52
  53 =cut
  54
  55 use strict;
  56 use warnings;
  57
  58 use Getopt::Long;
  59
  60 my $opts = { };
  61 GetOptions( $opts,   "queue=s", "action=s", "url=s",
  62             "jar=s", "help",    "debug",    "extension=s",
  63             "timeout=i", "verify-ssl!", "ca-file=s",
  64           );
  65
  66 my $gateway = RT::Client::MailGateway->new();
  67
  68 $gateway->run($opts);
  69
  70 package RT::Client::MailGateway;
  71
  72 use LWP::UserAgent;
  73 use HTTP::Request::Common qw($DYNAMIC_FILE_UPLOAD);
  74 use File::Temp qw(tempfile tempdir);
  75 $DYNAMIC_FILE_UPLOAD = 1;
  76
  77 use constant EX_TEMPFAIL => 75;
  78 use constant BUFFER_SIZE => 8192;
  79
  80 sub new {
  81     my $class = shift;
  82     my $self = bless {}, $class;
  83     return $self;
  84 }
  85
  86 sub run {
  87     my $self = shift;
  88     my $opts = shift;
  89
  90     if ( $opts->{running_in_test_harness} ) {
  91         $self->{running_in_test_harness} = 1;
  92     }
  93
  94     $self->validate_cli_flags($opts);
  95
  96     my $ua          = $self->get_useragent($opts);
  97     my $post_params = $self->setup_session($opts);
  98     $self->upload_message( $ua => $post_params );
  99     $self->exit_with_success();
 100 }
 101
 102 sub exit_with_success {
 103     my $self = shift;
 104     if ( $self->{running_in_test_harness} ) {
 105         return 1;
 106     } else {
 107         exit 0;
 108     }
 109 }
 110
 111 sub tempfail {
 112     my $self = shift;
 113     if ( $self->{running_in_test_harness} ) {
 114         die "tempfail";
 115     } else {
 116
 117         exit EX_TEMPFAIL;
 118     }
 119 }
 120
 121 sub permfail {
 122     my $self = shift;
 123     if ( $self->{running_in_test_harness} ) {
 124         die "permfail";
 125     } else {
 126
 127         exit 1;
 128     }
 129 }
 130
 131 sub validate_cli_flags {
 132     my $self = shift;
 133     my $opts = shift;
 134     if ( $opts->{'help'} ) {
 135         require Pod::Usage;
 136         Pod::Usage::pod2usage( { verbose => 2 } );
 137         return $self->permfail()
 138             ;    # Don't want to succeed if this is really an email!
 139     }
 140
 141     unless ( $opts->{'url'} ) {
 142         print STDERR
 143             "$0 invoked improperly\n\nNo 'url' provided to mail gateway!\n";
 144         return $self->permfail();
 145     }
 146
 147     if (($opts->{'ca-file'} or $opts->{"verify-ssl"})
 148             and not LWP::UserAgent->can("ssl_opts")) {
 149         print STDERR "Verifying SSL certificates requires LWP::UserAgent 6.0 or higher.\n";
 150         return $self->tempfail();
 151     }
 152
 153     $opts->{"verify-ssl"} = 1 unless defined $opts->{"verify-ssl"};
 154 }
 155
 156 sub get_useragent {
 157     my $self = shift;
 158     my $opts = shift;
 159     my $ua   = LWP::UserAgent->new();
 160     $ua->cookie_jar( { file => $opts->{'jar'} } ) if $opts->{'jar'};
 161
 162     if ( $ua->can("ssl_opts") ) {
 163         $ua->ssl_opts( verify_hostname => $opts->{'verify-ssl'} );
 164         $ua->ssl_opts( SSL_ca_file => $opts->{'ca-file'} )
 165             if $opts->{'ca-file'};
 166     }
 167
 168     return $ua;
 169 }
 170
 171 sub setup_session {
 172     my $self = shift;
 173     my $opts = shift;
 174     my %post_params;
 175     foreach (qw(queue action)) {
 176         $post_params{$_} = $opts->{$_} if defined $opts->{$_};
 177     }
 178
 179     if ( ( $opts->{'extension'} || '' ) =~ /^(?:action|queue|ticket)$/i ) {
 180         $post_params{ lc $opts->{'extension'} } = $ENV{'EXTENSION'}
 181             || $opts->{ $opts->{'extension'} };
 182     } elsif ( $opts->{'extension'} && $ENV{'EXTENSION'} ) {
 183         print STDERR
 184             "Value of the --extension argument is not action, queue or ticket"
 185             . ", but environment variable EXTENSION is also defined. The former is ignored.\n";
 186     }
 187
 188     # add ENV{'EXTENSION'} as X-RT-MailExtension to the message header
 189     if ( my $value = ( $ENV{'EXTENSION'} || $opts->{'extension'} ) ) {
 190
 191         # prepare value to avoid MIME format breakage
 192         # strip trailing newline symbols
 193         $value =~ s/(\r*\n)+$//;
 194
 195         # make a correct multiline header field,
 196         # with tabs in the beginning of each line
 197         $value =~ s/(\r*\n)/$1\t/g;
 198         $opts->{'headers'} .= "X-RT-Mail-Extension: $value\n";
 199     }
 200
 201     # Read the message in from STDIN
 202     # _raw_message is used for testing
 203     my $message = $opts->{'_raw_message'} || $self->slurp_message();
 204     unless ( $message->{'filename'} ) {
 205         $post_params{'message'} = [
 206                                  undef, '',
 207                                  'Content-Type' => 'application/octet-stream',
 208                                  Content        => ${ $message->{'content'} },
 209         ];
 210     } else {
 211         $post_params{'message'} = [
 212                                  $message->{'filename'}, '',
 213                                  'Content-Type' => 'application/octet-stream',
 214         ];
 215     }
 216
 217     return \%post_params;
 218 }
 219
 220 sub upload_message {
 221     my $self        = shift;
 222     my $ua          = shift;
 223     my $post_params = shift;
 224     my $full_url    = $opts->{'url'} . "/REST/1.0/NoAuth/mail-gateway";
 225     print STDERR "$0: connecting to $full_url\n" if $opts->{'debug'};
 226
 227     $ua->timeout( exists( $opts->{'timeout'} ) ? $opts->{'timeout'} : 180 );
 228     my $r = $ua->post( $full_url, $post_params, Content_Type => 'form-data' );
 229     $self->check_failure($r);
 230
 231     my $content = $r->content;
 232     print STDERR $content . "\n" if $opts->{'debug'};
 233
 234     return if ( $content =~ /^(ok|not ok)/ );
 235
 236  # It's not the server's fault if the mail is bogus. We just want to know that
 237  # *something* came out of the server.
 238     print STDERR <<EOF;
 239 RT server error.
 240
 241 The RT server which handled your email did not behave as expected. It
 242 said:
 243
 244 $content
 245 EOF
 246
 247     return $self->tempfail();
 248 }
 249
 250 sub check_failure {
 251     my $self = shift;
 252     my $r    = shift;
 253     return if $r->is_success;
 254
 255     # XXX TODO 4.2: Remove the multi-line error strings in favor of something more concise
 256     print STDERR <<"    ERROR";
 257 An Error Occurred
 258 =================
 259
 260 @{[ $r->status_line ]}
 261     ERROR
 262     print STDERR "\n$0: undefined server error\n" if $opts->{'debug'};
 263     return $self->tempfail();
 264 }
 265
 266 sub slurp_message {
 267     my $self = shift;
 268
 269     local $@;
 270
 271     my %message;
 272     my ( $fh, $filename )
 273         = eval { tempfile( DIR => tempdir( CLEANUP => 1 ) ) };
 274     if ( !$fh || $@ ) {
 275         print STDERR "$0: Couldn't create temp file, using memory\n";
 276         print STDERR "error: $@\n" if $@;
 277
 278         my $message = \do { local ( @ARGV, $/ ); <STDIN> };
 279         unless ( $$message =~ /\S/ ) {
 280             print STDERR "$0: no message passed on STDIN\n";
 281             $self->exit_with_success;
 282         }
 283         $$message = $opts->{'headers'} . $$message if $opts->{'headers'};
 284         return ( { content => $message } );
 285     }
 286
 287     binmode $fh;
 288     binmode \*STDIN;
 289
 290     print $fh $opts->{'headers'} if $opts->{'headers'};
 291
 292     my $buf;
 293     my $empty = 1;
 294     while (1) {
 295         my $status = read \*STDIN, $buf, BUFFER_SIZE;
 296         unless ( defined $status ) {
 297             print STDERR "$0: couldn't read message: $!\n";
 298             return $self->tempfail();
 299         } elsif ( !$status ) {
 300             last;
 301         }
 302         $empty = 0 if $buf =~ /\S/;
 303         print $fh $buf;
 304     }
 305     close $fh;
 306
 307     if ($empty) {
 308         print STDERR "$0: no message passed on STDIN\n";
 309         $self->exit_with_success;
 310     }
 311     print STDERR "$0: temp file is '$filename'\n" if $opts->{'debug'};
 312     return ( { filename => $filename } );
 313 }
 314
 315 =head1 SYNOPSIS
 316
 317     rt-mailgate --help : this text
 318
 319 Usual invocation (from MTA):
 320
 321     rt-mailgate --action (correspond|comment|...) --queue queuename
 322                 --url http://your.rt.server/
 323                 [ --debug ]
 324                 [ --extension (queue|action|ticket) ]
 325                 [ --timeout seconds ]
 326
 327
 328
 329 =head1 OPTIONS
 330
 331 =over 3
 332
 333 =item C<--action>
 334
 335 Specifies what happens to email sent to this alias.  The avaliable
 336 basic actions are: C<correspond>, C<comment>.
 337
 338
 339 If you've set the RT configuration variable B<< C<UnsafeEmailCommands> >>,
 340 C<take> and C<resolve> are also available.  You can execute two or more
 341 actions on a single message using a C<-> separated list.  RT will execute
 342 the actions in the listed order.  For example you can use C<take-comment>,
 343 C<correspond-resolve> or C<take-comment-resolve> as actions.
 344
 345 Note that C<take> and C<resolve> actions ignore message text if used
 346 alone.  Include a  C<comment> or C<correspond> action if you want RT
 347 to record the incoming message.
 348
 349 The default action is C<correspond>.
 350
 351 =item C<--queue>
 352
 353 This flag determines which queue this alias should create a ticket in if no ticket identifier
 354 is found.
 355
 356 =item C<--url>
 357
 358 This flag tells the mail gateway where it can find your RT server. You should
 359 probably use the same URL that users use to log into RT.
 360
 361 If your RT server uses SSL, you will need to install additional Perl
 362 libraries. RT will detect and install these dependencies if you pass the
 363 C<--enable-ssl-mailgate> flag to configure as documented in RT's README.
 364
 365 If you have a self-signed SSL certificate, you may also need to pass
 366 C<--ca-file> or C<--no-verify-ssl>, below.
 367
 368 =item C<--ca-file> I<path>
 369
 370 Specifies the path to the public SSL certificate for the certificate
 371 authority that should be used to verify the website's SSL certificate.
 372 If your webserver uses a self-signed certificate, you should
 373 preferentially use this option over C<--no-verify-ssl>, as it will
 374 ensure that the self-signed certificate that the mailgate is seeing the
 375 I<right> self-signed certificate.
 376
 377 =item C<--no-verify-ssl>
 378
 379 This flag tells the mail gateway to trust all SSL certificates,
 380 regardless of if their hostname matches the certificate, and regardless
 381 of CA.  This is required if you have a self-signed certificate, or some
 382 other certificate which is not traceable back to an certificate your
 383 system ultimitely trusts.
 384
 385 Verifying SSL certificates requires L<LWP::UserAgent> version 6.0 or
 386 higher; explicitly passing C<--verify-ssl> on prior versions will error.
 387
 388 =item C<--extension> OPTIONAL
 389
 390 Some MTAs will route mail sent to user-foo@host or user+foo@host to user@host
 391 and present "foo" in the environment variable $EXTENSION. By specifying
 392 the value "queue" for this parameter, the queue this message should be
 393 submitted to will be set to the value of $EXTENSION. By specifying
 394 "ticket", $EXTENSION will be interpreted as the id of the ticket this message
 395 is related to.  "action" will allow the user to specify either "comment" or
 396 "correspond" in the address extension.
 397
 398 =item C<--debug> OPTIONAL
 399
 400 Print debugging output to standard error
 401
 402
 403 =item C<--timeout> OPTIONAL
 404
 405 Configure the timeout for posting the message to the web server.  The
 406 default timeout is 3 minutes (180 seconds).
 407
 408 =back
 409
 410
 411 =head1 DESCRIPTION
 412
 413 The RT mail gateway is the primary mechanism for communicating with RT
 414 via email. This program simply directs the email to the RT web server,
 415 which handles filing correspondence and sending out any required mail.
 416 It is designed to be run as part of the mail delivery process, either
 417 called directly by the MTA or C<procmail>, or in a F<.forward> or
 418 equivalent.
 419
 420 =head1 SETUP
 421
 422 Much of the set up of the mail gateway depends on your MTA and mail
 423 routing configuration. However, you will need first of all to create an
 424 RT user for the mail gateway and assign it a password; this helps to
 425 ensure that mail coming into the web server did originate from the
 426 gateway.
 427
 428 Next, you need to route mail to C<rt-mailgate> for the queues you're
 429 monitoring. For instance, if you're using F</etc/aliases> and you have a
 430 "bugs" queue, you will want something like this:
 431
 432     bugs:         "|/opt/rt4/bin/rt-mailgate --queue bugs --action correspond
 433               --url http://rt.mycorp.com/"
 434
 435     bugs-comment: "|/opt/rt4/bin/rt-mailgate --queue bugs --action comment
 436               --url http://rt.mycorp.com/"
 437
 438 Note that you don't have to run your RT server on your mail server, as
 439 the mail gateway will happily relay to a different machine.
 440
 441 =head1 CUSTOMIZATION
 442
 443 By default, the mail gateway will accept mail from anyone. However,
 444 there are situations in which you will want to authenticate users
 445 before allowing them to communicate with the system. You can do this
 446 via a plug-in mechanism in the RT configuration.
 447
 448 You can set the array C<@MailPlugins> to be a list of plugins. The
 449 default plugin, if this is not given, is C<Auth::MailFrom> - that is,
 450 authentication of the person is done based on the C<From> header of the
 451 email. If you have additional filters or authentication mechanisms, you
 452 can list them here and they will be called in order:
 453
 454     Set( @MailPlugins =>
 455         "Filter::SpamAssassin",
 456         "Auth::LDAP",
 457         # ...
 458     );
 459
 460 See the documentation for any additional plugins you have.
 461
 462 You may also put Perl subroutines into the C<@MailPlugins> array, if
 463 they behave as described below.
 464
 465 =head1 WRITING PLUGINS
 466
 467 What's actually going on in the above is that C<@MailPlugins> is a
 468 list of Perl modules; RT prepends C<RT::Interface::Email::> to the name,
 469 to form a package name, and then C<use>'s this module. The module is
 470 expected to provide a C<GetCurrentUser> subroutine, which takes a hash of
 471 several parameters:
 472
 473 =over 4
 474
 475 =item Message
 476
 477 A C<MIME::Entity> object representing the email
 478
 479 =item CurrentUser
 480
 481 An C<RT::CurrentUser> object
 482
 483 =item AuthStat
 484
 485 The authentication level returned from the previous plugin.
 486
 487 =item Ticket [OPTIONAL]
 488
 489 The ticket under discussion
 490
 491 =item Queue [OPTIONAL]
 492
 493 If we don't already have a ticket id, we need to know which queue we're talking about
 494
 495 =item Action
 496
 497 The action being performed. At the moment, it's one of "comment" or "correspond"
 498
 499 =back
 500
 501 It returns two values, the new C<RT::CurrentUser> object, and the new
 502 authentication level. The authentication level can be zero, not allowed
 503 to communicate with RT at all, (a "permission denied" error is mailed to
 504 the correspondent) or one, which is the normal mode of operation.
 505 Additionally, if C<-1> is returned, then the processing of the plug-ins
 506 stops immediately and the message is ignored.
 507
 508 =head1 ENVIRONMENT
 509
 510 =over 4
 511
 512 =item EXTENSION
 513
 514 Some MTAs will route mail sent to user-foo@host or user+foo@host to user@host
 515 and present "foo" in the environment variable C<EXTENSION>. Mailgate adds value
 516 of this variable to message in the C<X-RT-Mail-Extension> field of the message
 517 header.
 518
 519 See also C<--extension> option. Note that value of the environment variable is
 520 always added to the message header when it's not empty even if C<--extension>
 521 option is not provided.
 522
 523 =back
 524
 525 =cut
 526