httemplate/search/elements/search.html

   1 <%doc>
   2
   3 Example:
   4
   5   <& elements/search.html,
   6
   7     ###
   8     # required
   9     ###
  10
  11     'title'         => 'Page title',
  12
  13     'name_singular' => 'item',  #singular name for the records returned
  14        #OR#                     # (preferred, will be pluralized automatically)
  15     'name'          => 'items', #plural name for the records returned
  16                                 # (deprecated, will be singularlized
  17                                 #  simplisticly)
  18
  19     #literal SQL query string (deprecated?) or qsearch hashref or arrayref
  20     #of qsearch hashrefs for a union of qsearches
  21     'query'       => {
  22                        'table'     => 'tablename',
  23                        #everything else is optional...
  24                        'hashref'   => { 'field' => 'value',
  25                                         'field' => { 'op'    => '<',
  26                                                      'value' => '54',
  27                                                    },
  28                                       },
  29                        'select'    => '*',
  30                        'addl_from' => '', #'LEFT JOIN othertable USING ( key )',
  31                        'extra_sql' => '', #'AND otherstuff', #'WHERE onlystuff',
  32                        'order_by'  => 'ORDER BY something',
  33
  34                      },
  35                      # "select * from tablename";
  36
  37     #required unless 'query' is an SQL query string (shouldn't be...)
  38     'count_query' => 'SELECT COUNT(*) FROM tablename',
  39
  40     ###
  41     # recommended / common
  42     ###
  43
  44     #listref of column labels, <TH>
  45     #recommended unless 'query' is an SQL query string
  46     # (if not specified the database column names will be used)
  47     'header'      => [ '#',
  48                        'Item',
  49                        { 'label' => 'Another Item',
  50
  51                        },
  52                      ],
  53
  54     #listref - each item is a literal column name (or method) or coderef
  55     #if not specified all columns will be shown
  56     'fields'      => [
  57                        'column',
  58                        sub { my $row = shift; $row->column; },
  59                      ],
  60
  61     #redirect if there's only one item...
  62     # listref of URL base and column name (or method)
  63     # or a coderef that returns the same
  64     'redirect' => sub { my( $record, $cgi ) = @_;
  65                         [ popurl(2).'view/item.html', 'primary_key' ];
  66                       },
  67
  68     #redirect if there's no items
  69     # scalar URL or a coderef that returns a URL
  70     'redirect_empty' => sub { my( $cgi ) = @_;
  71                               popurl(2).'view/item.html';
  72                             },
  73
  74     ###
  75     # optional
  76     ###
  77
  78     # some HTML callbacks...
  79     'menubar'          => '', #menubar arrayref
  80     'html_init'        => '', #after the header/menubar and before the pager
  81     'html_form'        => '', #after the pager, right before the results
  82                               # (only shown if there are results)
  83                               # (use this for any form-opening tag rather than
  84                               #  html_init, to avoid a nested form)
  85     'html_foot'        => '', #at the bottom
  86     'html_posttotal'   => '', #at the bottom
  87                               # (these three can be strings or coderefs)
  88
  89     'count_addl' => [], #additional count fields listref of sprintf strings or coderefs
  90                         # [ $money_char.'%.2f total paid', ],
  91
  92     #second (smaller) header line, currently only for HTML
  93     'header2      => [ '#',
  94                        'Item',
  95                        { 'label' => 'Another Item',
  96
  97                        },
  98                      ],
  99
 100     #listref of column footers
 101     'footer'      => [],
 102
 103     #disabling things
 104     'disable_download'  => '', # set true to hide the CSV/Excel download links
 105     'disable_total'     => '', # set true to hide the total"
 106     'disable_maxselect' => '', # set true to disable record/page selection
 107     'disable_nonefound' => '', # set true to disable the "No matching Xs found"
 108                                # message
 109
 110     #handling "disabled" fields in the records
 111     'disableable' => 1,  # set set to 1 (or column position for "disabled"
 112                          # status col) to enable if this table has a "disabled"
 113                          # field, to hide disabled records & have
 114                          # "show disabled/hide disabled" links
 115                          #(can't be used with a literal query)
 116     'disabled_statuspos' => 3, #optional position (starting from 0) to insert
 117                                #a Status column when showing disabled records
 118                                #(query needs to be a qsearch hashref and
 119                                # header & fields need to be defined)
 120
 121     #handling agent virtualization
 122     'agent_virt'            => 1, # set true if this search should be
 123                                   # agent-virtualized
 124     'agent_null'            => 1, # set true to view global records always
 125     'agent_null_right'      => 'Access Right', # optional right to view global
 126                                                # records
 127     'agent_null_right_link' => 'Access Right'  # optional right to link to
 128                                                # global records; defaults to
 129                                                # same as agent_null_right
 130     'agent_pos'             => 3, # optional position (starting from 0) to
 131                                   # insert an Agent column (query needs to be a
 132                                   # qsearch hashref and header & fields need to
 133                                   # be defined)
 134
 135     # sort, link & display properties for fields
 136
 137     'sort_fields' => [], #optional list of field names or SQL expressions for
 138                          # sorts
 139
 140     #listref - each item is the empty string,
 141     #          or a listref of link and method name to append,
 142     #          or a listref of link and coderef to run and append
 143     #          or a coderef that returns such a listref
 144     'links'       => [],`
 145
 146     #listref - each item is the empty string,
 147     #          or a string onClick handler for the corresponding link
 148     #          or a coderef that returns string onClick handler
 149     'link_onclicks' => [],
 150
 151     #one letter for each column, left/right/center/none
 152     # or pass a listref with full values: [ 'left', 'right', 'center', '' ]
 153     'align'       => 'lrc.',
 154
 155     #listrefs of ( scalars or coderefs )
 156     # currently only HTML, maybe eventually Excel too
 157     'color'       => [],
 158     'size'        => [],
 159     'style'       => [], #<B> or <I>, etc.
 160     'cell_style'  => [], #STYLE= attribute of TR, very HTML-specific...
 161
 162     # Excel-specific listref of ( hashrefs or coderefs )
 163     # each hashref: http://search.cpan.org/dist/Spreadsheet-WriteExcel/lib/Spreadsheet/WriteExcel.pm#Format_methods_and_Format_properties
 164     'xls_format' => => [],
 165
 166
 167     # miscellany
 168    'download_label' => 'Download this report',
 169                         # defaults to 'Download full results'
 170   &>
 171
 172 </%doc>
 173 % if ( $type eq 'csv' ) {
 174 %
 175 <% include('search-csv.html',  header=>$header, rows=>$rows, opt=>\%opt ) %>
 176 %
 177 % } elsif ( $type =~ /\.xls$/ ) {
 178 %
 179 <& 'search-xls.html',  header=>$header, rows=>$rows, opt=>\%opt &>\
 180 % # prevent the caller from polluting our output stream
 181 % $m->abort;
 182 %
 183 % } elsif ( $type eq 'xml' ) {
 184 %
 185 <% include('search-xml.html',  rows=>$rows, opt=>\%opt ) %>
 186 %
 187 % } else {
 188 %
 189 <% include('search-html.html',
 190              type           => $type,
 191              header         => $header,
 192              rows           => $rows,
 193              link_agentnums => \@link_agentnums,
 194              null_link      => $null_link,
 195              confmax        => $confmax,
 196              maxrecords     => $maxrecords,
 197              offset         => $offset,
 198              opt            => \%opt
 199           )
 200 %>
 201 %
 202 % }
 203 <%init>
 204
 205 my(%opt) = @_;
 206 #warn join(' / ', map { "$_ => $opt{$_}" } keys %opt ). "\n";
 207
 208 my $curuser = $FS::CurrentUser::CurrentUser;
 209
 210 my $type = $cgi->param('_type') =~ /^(csv|\w*\.xls|xml|select|html(-print)?)$/
 211            ? $1 : 'html' ;
 212
 213 if ( !$curuser->access_right('Download report data') ) {
 214   $opt{'disable_download'} = 1;
 215   $type = 'html';
 216 }
 217
 218 my %align = (
 219   'l' => 'left',
 220   'r' => 'right',
 221   'c' => 'center',
 222   ' ' => '',
 223   '.' => '',
 224 );
 225 $opt{align} = [ map $align{$_}, split(//, $opt{align}) ],
 226   unless !$opt{align} || ref($opt{align});
 227
 228 if($type =~ /csv|xls/) {
 229   my $h = $opt{'header'};
 230   my @del;
 231   my $i = 0;
 232   do {
 233     if( ref($h->[$i]) and exists($h->[$i]->{'nodownload'}) ) {
 234       splice(@{$opt{$_}}, $i, 1) foreach
 235         qw(header footer fields links link_onclicks
 236            align color size style cell_style xls_format);
 237     }
 238     else {
 239       $i++;
 240     }
 241   } while ( exists($h->[$i]) );
 242 }
 243
 244 # wtf?
 245 $opt{disable_download} = 0
 246   if $opt{disable_download} && $curuser->access_right('Configuration download');
 247
 248 $opt{disable_download} = 1
 249   if $opt{really_disable_download};
 250
 251 my @link_agentnums = ();
 252 my $null_link = '';
 253 if ( $opt{'agent_virt'} ) {
 254
 255   @link_agentnums = $curuser->agentnums;
 256   $null_link = $curuser->access_right(    $opt{'agent_null_right_link'}
 257                                        || $opt{'agent_null_right'}      );
 258
 259   my $agentnums_sql = $curuser->agentnums_sql(
 260                         'null'       => $opt{'agent_null'},
 261                         'null_right' => $opt{'agent_null_right'},
 262                         'table'      => $opt{'query'}{'table'},
 263                       );
 264
 265   $opt{'query'}{'extra_sql'} .=
 266     ( $opt{'query'}{'extra_sql'} =~ /WHERE/i || keys %{$opt{'query'}{'hashref'}}
 267       ? ' AND '
 268       : ' WHERE ' ). $agentnums_sql;
 269
 270   $opt{'count_query'} .=
 271     ( $opt{'count_query'} =~ /WHERE/i ? ' AND ' : ' WHERE ' ).  $agentnums_sql;
 272
 273   if ( $opt{'agent_pos'} || $opt{'agent_pos'} eq '0'
 274        and scalar($curuser->agentnums) > 1           ) {
 275     #false laziness w/statuspos above
 276     my $pos = $opt{'agent_pos'};
 277
 278     foreach my $att (qw( align color size style cell_style xls_format )) {
 279       $opt{$att} ||= [ map '', @{ $opt{'fields'} } ];
 280     }
 281
 282     splice @{ $opt{'header'} }, $pos, 0, 'Agent';
 283     splice @{ $opt{'align'}  }, $pos, 0, 'c';
 284     splice @{ $opt{'style'}  }, $pos, 0, '';
 285     splice @{ $opt{'size'}   }, $pos, 0, '';
 286     splice @{ $opt{'fields'} }, $pos, 0,
 287       sub { $_[0]->agentnum ? $_[0]->agent->agent : '(global)'; };
 288     splice @{ $opt{'color'}  }, $pos, 0, '';
 289     splice @{ $opt{'links'}  }, $pos, 0, '' #[ 'agent link?', 'agentnum' ]
 290       if $opt{'links'};
 291     splice @{ $opt{'link_onclicks'}  }, $pos, 0, ''
 292       if $opt{'link_onclicks'};
 293
 294   }
 295
 296 }
 297
 298 if ( $opt{'disableable'} ) {
 299
 300   unless ( $cgi->param('showdisabled') ) { #modify searches
 301
 302     $opt{'query'}{'hashref'}{'disabled'} = '';
 303     $opt{'query'}{'extra_sql'} =~ s/^\s*WHERE/ AND/i;
 304
 305     $opt{'count_query'} .=
 306       ( $opt{'count_query'} =~ /WHERE/i ? ' AND ' : ' WHERE ' ).
 307       "( disabled = '' OR disabled IS NULL )";
 308
 309   } elsif (    $opt{'disabled_statuspos'}
 310             || $opt{'disabled_statuspos'} eq '0' ) { #add status column
 311
 312     my $pos = $opt{'disabled_statuspos'};
 313
 314     foreach my $att (qw( align style color size )) {
 315       $opt{$att} ||= [ map '', @{ $opt{'fields'} } ];
 316     }
 317
 318     splice @{ $opt{'header'} }, $pos, 0, 'Status';
 319     splice @{ $opt{'align'}  }, $pos, 0, 'c';
 320     splice @{ $opt{'style'}  }, $pos, 0, 'b';
 321     splice @{ $opt{'size'}   }, $pos, 0, '';
 322     splice @{ $opt{'fields'} }, $pos, 0,
 323       sub { shift->disabled ? 'DISABLED' : 'Active'; };
 324     splice @{ $opt{'color'}  }, $pos, 0,
 325       sub { shift->disabled ? 'FF0000'   : '00CC00'; };
 326     splice @{ $opt{'links'}  }, $pos, 0, ''
 327       if $opt{'links'};
 328     splice @{ $opt{'link_onlicks'}  }, $pos, 0, ''
 329       if $opt{'link_onlicks'};
 330   }
 331
 332   #add show/hide disabled links
 333   my $items = $opt{'name'} || PL($opt{'name_singular'});
 334   if ( $cgi->param('showdisabled') ) {
 335     $cgi->param('showdisabled', 0);
 336     $opt{'html_posttotal'} .=
 337       '( <a href="'. $cgi->self_url. qq!">hide disabled $items</a> )!; #"
 338     $cgi->param('showdisabled', 1);
 339   } else {
 340     $cgi->param('showdisabled', 1);
 341     $opt{'html_posttotal'} .=
 342       '( <a href="'. $cgi->self_url. qq!">show disabled $items</a> )!; #"
 343     $cgi->param('showdisabled', 0);
 344   }
 345
 346 }
 347
 348 my $limit = '';
 349 my($confmax, $maxrecords, $offset );
 350
 351 unless ( $type =~ /^(csv|\w*.xls)$/) {
 352 # html mode
 353   unless (exists($opt{count_query}) && length($opt{count_query})) {
 354     ( $opt{count_query} = $opt{query} ) =~
 355       s/^\s*SELECT\s*(.*?)\s+FROM\s/SELECT COUNT(*) FROM /i; #silly vim:/
 356   }
 357
 358   if ( $opt{disableable} && ! $cgi->param('showdisabled') ) {
 359     $opt{count_query} .=
 360       ( ( $opt{count_query} =~ /WHERE/i ) ? ' AND ' : ' WHERE ' ).
 361       "( disabled = '' OR disabled IS NULL )";
 362   }
 363
 364   unless ( $type eq 'html-print' ) {
 365
 366     #setup some pagination things if we're in html mode
 367
 368     my $conf = new FS::Conf;
 369     $confmax = $conf->config('maxsearchrecordsperpage');
 370     if ( $cgi->param('maxrecords') =~ /^(\d+)$/ ) {
 371       $maxrecords = $1;
 372     } else {
 373       $maxrecords ||= $confmax;
 374     }
 375
 376     $opt{'disable_maxselect'} ||= $conf->exists('disable_maxselect');
 377
 378     $limit = $maxrecords ? "LIMIT $maxrecords" : '';
 379
 380     $offset = $cgi->param('offset') =~ /^(\d+)$/ ? $1 : 0;
 381     $limit .= " OFFSET $offset" if $offset;
 382
 383   }
 384
 385 }
 386
 387 #order by override
 388 my $order_by = '';
 389 #if ( $cgi->param('order_by') =~ /^([\w\, ]+)$/ ) {
 390 #  $order_by = $1;
 391 #}
 392 $order_by = $cgi->param('order_by') if $cgi->param('order_by');
 393
 394 # run the query
 395
 396 my $header = [ map { ref($_) ? $_->{'label'} : $_ } @{$opt{header}} ];
 397 my $rows;
 398 if ( ref($opt{query}) ) {
 399
 400   my @query;
 401   if (ref($opt{query}) eq 'HASH') {
 402     @query = ( $opt{query} );
 403
 404     if ( $order_by ) {
 405       if ( $opt{query}->{'order_by'} ) {
 406         if ( $opt{query}->{'order_by'} =~ /^(\s*ORDER\s+BY\s+)?(\S.*)$/is ) {
 407           $opt{query}->{'order_by'} = "ORDER BY $order_by, $2";
 408         } else {
 409           warn "unparsable query order_by: ". $opt{query}->{'order_by'};
 410           die "unparsable query order_by: ". $opt{query}->{'order_by'};
 411         }
 412       } else {
 413         $opt{query}->{'order_by'} = "ORDER BY $order_by";
 414       }
 415     }
 416
 417   } elsif (ref($opt{query}) eq 'ARRAY') {
 418     @query = @{ $opt{query} };
 419   } else {
 420     die "invalid query reference";
 421   }
 422
 423   if ( $opt{disableable} && ! $cgi->param('showdisabled') ) {
 424     #%search = ( 'disabled' => '' );
 425     $opt{'query'}->{'hashref'}->{'disabled'} = '';
 426     $opt{'query'}->{'extra_sql'} =~ s/^\s*WHERE/ AND/i;
 427   }
 428
 429   #eval "use FS::$opt{'query'};";
 430   my @param = qw( select table addl_from hashref extra_sql order_by );
 431   $rows = [ qsearch( [ map { my $query = $_;
 432                              ({ map { $_ => $query->{$_} } @param });
 433                            }
 434                        @query
 435                      ],
 436                      'order_by' => $opt{order_by}. " ". $limit,
 437                    )
 438           ];
 439 } else {
 440   my $sth = dbh->prepare("$opt{'query'} $limit")
 441     or die "Error preparing $opt{'query'}: ". dbh->errstr;
 442   $sth->execute
 443     or die "Error executing $opt{'query'}: ". $sth->errstr;
 444
 445   #can get # of rows without fetching them all?
 446   $rows = $sth->fetchall_arrayref;
 447
 448   $header ||= $sth->{NAME};
 449 }
 450
 451 </%init>