httemplate/search/cdr.html

   1 <% include( 'elements/search.html',
   2                'title' => $title,
   3                'name'  => 'call detail records',
   4                'query' => $query,
   5                'count_query' => $count_query,
   6                'count_addl' => $nototalminutes ? '' : [ $totalminutes_sub ],
   7                'disable_total' => $topmode ? 1 : '',
   8                'header' => \@header,
   9                'fields' => \@fields,
  10                'links' => \@links,
  11                'html_form'   => qq!<FORM NAME="cdrForm" ACTION="$p/misc/cdr.cgi" METHOD="POST">!,
  12                #false laziness w/queue.html
  13                'html_foot' => sub {
  14                                 if ( $areboxes ) {
  15                                   '<BR><INPUT TYPE="button" VALUE="select all" onClick="setAll(true)">'.
  16                                   '<INPUT TYPE="button" VALUE="unselect all" onClick="setAll(false)">'.
  17                                   qq!<BR><INPUT TYPE="submit" NAME="action" VALUE="reprocess selected" onClick="return confirm('Are you sure you want to reprocess the selected CDRs?')">!.
  18                                   qq!<INPUT TYPE="submit" NAME="action" VALUE="delete selected" onClick="return confirm('Are you sure you want to delete the selected CDRs?')"><BR>!.
  19                                   '<SCRIPT TYPE="text/javascript">'.
  20                                   '  function setAll(setTo) { '.
  21                                   '    theForm = document.cdrForm;'.
  22                                   '    for (i=0,n=theForm.elements.length;i<n;i++)'.
  23                                   '      if (theForm.elements[i].name.indexOf("acctid") != -1)'.
  24                                   '        theForm.elements[i].checked = setTo;'.
  25                                   '  }'.
  26                                   '</SCRIPT>';
  27                                 } else {
  28                                   '';
  29                                 }
  30                               },
  31              )
  32 %>
  33 <%init>
  34
  35 die "access denied"
  36   unless $FS::CurrentUser::CurrentUser->access_right('List rating data');
  37
  38 my $edit_data = $FS::CurrentUser::CurrentUser->access_right('Edit rating data');
  39
  40 my $totalminutes_sub = sub {
  41     my $billsec = shift;
  42     sprintf("%.2f",$billsec/60) . ' total minutes';
  43 };
  44
  45 my $conf = new FS::Conf;
  46
  47 my $areboxes = 0;
  48
  49 my $title = 'Call Detail Records';
  50 my $hashref = {};
  51
  52 #process params for CDR search, populate $hashref...
  53 # and fixup $count_query
  54
  55 my @search = ();
  56
  57 ###
  58 # dates
  59 ###
  60
  61 my $str2time_sql = str2time_sql;
  62 my $closing      = str2time_sql_closing;
  63
  64 my($beginning, $ending) = FS::UI::Web::parse_beginning_ending($cgi);
  65 push @search, "$str2time_sql calldate $closing >= $beginning ",
  66               "$str2time_sql calldate $closing <= $ending";
  67
  68 ###
  69 # duration / billsec
  70 ###
  71
  72 push @search, FS::UI::Web::parse_lt_gt($cgi, 'duration');
  73 push @search, FS::UI::Web::parse_lt_gt($cgi, 'billsec');
  74
  75 #above here things just push @search
  76 #below here things also have to define $hashref->{} or push @qsearch
  77 my @qsearch = @search;
  78
  79 ###
  80 # freesidestatus
  81 ###
  82
  83 my $status = $cgi->param('freesidestatus');
  84 if ( $status eq 'NULL' ) {
  85
  86   $title = "Unprocessed $title";
  87   $hashref->{'freesidestatus'} = ''; # Record.pm will take care of it
  88   push @search, "( freesidestatus IS NULL OR freesidestatus = '' )";
  89
  90 } elsif ( $status =~ /^([\w ]+)$/ ) {
  91
  92   if ( $status eq 'done' ) {
  93     $title = "Processed $title";
  94   }
  95   elsif ( $status eq 'failed' ) {
  96     $title = "Skipped $title";
  97   }
  98   $hashref->{'freesidestatus'} = $1;
  99   push @search, "freesidestatus = '$1'";
 100
 101 }
 102
 103 ###
 104 # cdrtypenum
 105 ###
 106
 107 if ( $cgi->param('cdrtypenum') =~ /^(\d+)$/ ) {
 108     $hashref->{'cdrtypenum'} = $1;
 109     push @search, "cdrtypenum = $1";
 110 }
 111 elsif ( $cgi->param('cdrtypenum') eq 'none' ) {
 112     $hashref->{'cdrtypenum'} = '';
 113     push @search, "cdrtypenum is null";
 114 }
 115
 116 ###
 117 # termpartNstatus
 118 ###
 119
 120 foreach my $param ( grep /^termpart\d+status$/, $cgi->param ) {
 121
 122   my $status = $cgi->param($param);
 123
 124   $param =~ /^termpart(\d+)status$/ or die 'guru meditation 54something';
 125   my $termpart = $1;
 126
 127   my $search = '';
 128   if ( $status eq 'NULL' ) {
 129
 130     #false lazienss w/cdr_termination.pm (i should be a part_termination method)
 131     my $where_term =
 132       "( cdr.acctid = cdr_termination.acctid AND termpart = $termpart ) ";
 133     #my $join_term = "LEFT JOIN cdr_termination ON ( $where_term )";
 134     $search =
 135       "NOT EXISTS ( SELECT 1 FROM cdr_termination WHERE $where_term )";
 136
 137   } elsif ( $status =~ /^([\w ]+)$/ ) {
 138
 139     #false lazienss w/cdr_termination.pm (i should be a part_termination method)
 140     my $where_term =
 141       "( cdr.acctid = cdr_termination.acctid AND termpart = $termpart AND status = '$1' ) ";
 142     #my $join_term = "LEFT JOIN cdr_termination ON ( $where_term )";
 143     $search =
 144       "EXISTS ( SELECT 1 FROM cdr_termination WHERE $where_term )";
 145
 146   }
 147
 148   if ( $search ) {
 149     push @search,  $search;
 150     push @qsearch, $search;
 151   }
 152
 153 }
 154
 155 ###
 156 # src/dest/charged_party/svcnum
 157 ###
 158
 159 my $phonenum = qr/^\s*([\d\-\+\ ]+)\s*$/;
 160 my $x = qr/\D/;
 161 if ( $conf->exists('svc_phone-allow_alpha_phonenum') ) {
 162   $phonenum = qr/^\s*([\d\-\+\ A-Za-z]+)\s*$/;
 163   $x = qr/[^\dA-Za-z]/;
 164 }
 165
 166 if ( $cgi->param('src') =~ $phonenum ) {
 167   ( my $src = $1 ) =~ s/$x//g;
 168   $hashref->{'src'} = $src;
 169   push @search, "src = '$src'";
 170 }
 171
 172 if ( $cgi->param('dst') ) {
 173
 174   my @d = map { $_, "1$_" } split(/\s*,\s*/, $cgi->param('dst') );
 175
 176   my $search = 'dst IN ('. join(',', map dbh->quote($_), @d). ')';
 177
 178   push @search,  $search;
 179   push @qsearch, $search;
 180
 181 }
 182
 183 if ( $cgi->param('dcontext') =~ /^\s*(.+)\s*$/ ) {
 184   my $dcontext = $1;
 185   $hashref->{'dcontext'} = $dcontext;
 186   push @search, 'dcontext = '. dbh->quote($dcontext);
 187 }
 188
 189 if ( $cgi->param('charged_party') ) {
 190
 191   my @cp = map { $_, "1$_" }
 192              split(/\s*,\s*/, $cgi->param('charged_party') );
 193
 194   my $search = 'charged_party IN ('. join(',', map dbh->quote($_), @cp). ')';
 195
 196   push @search,  $search;
 197   push @qsearch, $search;
 198 }
 199
 200 if ( $cgi->param('charged_party_or_src') ) {
 201
 202   my @cp = map { $_, "1$_" }
 203              split(/\s*,\s*/, $cgi->param('charged_party_or_src') );
 204   my $in = join(',', map dbh->quote($_), @cp);
 205
 206   my $search = "( charged_party IN ($in) OR src IN ($in) )";
 207
 208   push @search,  $search;
 209   push @qsearch, $search;
 210 }
 211
 212 if ( $cgi->param('lastapp') =~ /^\s*(.+)\s*$/ ) {
 213   my $lastapp = $1;
 214   $hashref->{'lastapp'} = $lastapp;
 215   push @search, 'lastapp = '. dbh->quote($lastapp);
 216 }
 217
 218 if ( $cgi->param('svcnum') =~ /^([\d, ]+)$/ ) {
 219   my $svcnum = $1;
 220   my $search = "svcnum IN ($svcnum)";
 221   push @search,  $search;
 222   push @qsearch, $search;
 223 }
 224
 225 ###
 226 # cdrbatchnum (or legacy cdrbatch)
 227 ###
 228
 229 if ( $cgi->param('cdrbatch') ) {
 230
 231   my $cdr_batch =
 232     qsearchs('cdr_batch', { 'cdrbatch' => scalar($cgi->param('cdrbatch')) } );
 233   if ( $cdr_batch ) {
 234     $hashref->{cdrbatchnum} = $cdr_batch->cdrbatchnum;
 235     push @search, 'cdrbatchnum = '. $cdr_batch->cdrbatchnum;
 236   } else {
 237     die "unknown cdrbatch ". $cgi->param('cdrbatch');
 238   }
 239
 240 } elsif ( $cgi->param('cdrbatchnum') ne '__ALL__' ) {
 241
 242   if ( $cgi->param('cdrbatchnum') eq '' ) {
 243     my $search = "( cdrbatchnum IS NULL )";
 244     push @qsearch, $search;
 245     push @search,  $search;
 246   } elsif ( $cgi->param('cdrbatchnum') =~ /^(\d+)$/ ) {
 247     $hashref->{cdrbatchnum} = $1;
 248     push @search, "cdrbatchnum = $1";
 249   }
 250
 251 }
 252
 253 ###
 254 # acctid
 255 ###
 256
 257 if ( $cgi->param('acctid') =~ /\d/ ) {
 258   my $acctid = $cgi->param('acctid');
 259   $acctid =~ s/\r\n/\n/g; #browsers?
 260   my @acctid = map  { /^\s*(\d+)\s*$/ or die "guru meditation #4"; $1; }
 261                grep { /^\s*(\d+)\s*$/ }
 262                split(/\n/, $acctid);
 263   if ( @acctid ) {
 264     my $search = 'acctid IN ( '. join(',', @acctid). ' )';
 265     push @qsearch, $search;
 266     push @search,  $search;
 267   }
 268 }
 269
 270 ###
 271 # finish it up
 272 ###
 273
 274 my $nototalminutes = 0;
 275
 276 my $search = join(' AND ', @search);
 277 $search = "WHERE $search" if $search;
 278
 279 my $count_query = "SELECT COUNT(*), sum(billsec) FROM cdr $search";
 280
 281 my $qsearch = join(' AND ', @qsearch);
 282 $qsearch = ( scalar(keys %$hashref) ? ' AND ' : ' WHERE ' ) . $qsearch
 283   if $qsearch;
 284
 285 my $query =     {   'table'     => 'cdr',
 286                     'hashref'   => $hashref,
 287                                 'extra_sql' => $qsearch,
 288                                 'order_by'  => 'ORDER BY calldate',
 289                 };
 290
 291 if ( $cgi->param('longest') =~ /^(\d+)$/ && $cgi->param('longest') > 0 ) {
 292     $cgi->param('maxrecords',$1);
 293     $count_query = "SELECT $1";
 294     $query->{'order_by'} = 'ORDER BY billsec desc';
 295     $nototalminutes = 1;
 296 }
 297
 298
 299 ###
 300 # display fields
 301 ###
 302
 303 my %header = %{ FS::cdr->table_info->{'fields'} };
 304
 305 my @first = qw( acctid calldate clid charged_party src dst dcontext );
 306 my %first = map { $_=>1 } @first;
 307
 308 my @fields = ( @first, grep !$first{$_}, fields('cdr') );
 309
 310 if ( $cgi->param('show') ) {
 311   @fields = grep $cgi->param("show_$_"), @fields;
 312 }
 313
 314 my @header = map {
 315                    if ( exists($header{$_}) ) {
 316                      $header{$_};
 317                    } else {
 318                      my $header = $_;
 319                      $header =~ s/\_/ /g; #//wtf
 320                      ucfirst($header);
 321                    }
 322                  } @fields;
 323 unshift @header, ' ';
 324
 325 my $date_sub_factory = sub {
 326   my $column = shift;
 327   sub {
 328     #my $cdr = shift;
 329     my $date = shift->$column();
 330     $date ? time2str( '%Y-%m-%d %T', $date ) : ''; #config time2str format?
 331   };
 332 };
 333
 334 my %fields = (
 335   #any other formatters?
 336   map { $_ => &{ $date_sub_factory }($_) } qw( startdate answerdate enddate )
 337 );
 338
 339 my %links = (
 340   'svcnum' =>
 341     sub { $_[0]->svcnum ? [ $p.'view/svc_phone.cgi?', 'svcnum' ] : ''; },
 342 );
 343
 344 @fields = map { exists($fields{$_}) ? $fields{$_} : $_ } @fields;
 345 unshift @fields, sub {
 346                        return '' unless $edit_data;
 347                        $areboxes = 1;
 348                        my $cdr = shift;
 349                        my $acctid = $cdr->acctid;
 350                        qq!<INPUT NAME="acctid$acctid" TYPE="checkbox" VALUE="1">!;
 351                      };
 352
 353 my @links = ( map { exists($links{$_}) ? $links{$_} : '' } @fields );
 354
 355
 356 ###
 357 # top dst / top src
 358 ###
 359
 360 my $topmode = 0;
 361
 362 if ( $cgi->param('top_dst') =~ /^(\d+)$/ && $cgi->param('top_dst') > 0 ) {
 363         $topmode = $1;
 364         @fields = ('dst');
 365         @header = ('Destination');
 366 }
 367 elsif ( $cgi->param('top_src') =~ /^(\d+)$/ && $cgi->param('top_src') > 0 ) {
 368         $topmode = $1;
 369         @fields = ('src');
 370         @header = ('Source');
 371 }
 372
 373 if ( $topmode ) {
 374     my $whichfield = $fields[0];
 375     $query = {  'select'    => "$whichfield, count(1) as cnt",
 376                 'table'     => 'cdr',
 377                 'hashref'   => {},
 378                 'extra_sql' => "$search
 379                                 group by $whichfield
 380                                 order by cnt desc",
 381              };
 382     $count_query = "SELECT $topmode";
 383
 384     # this is weird, maybe we should change search.html
 385     $cgi->param('maxrecords',$topmode);
 386
 387     # kind of hacked
 388     my $link = "${p}search/cdr.html?".$cgi->query_string;
 389     $link =~ s/;top_(dst|src)=(\d+|)//g;
 390     $link =~ s/;maxrecords=(\d+|)//;
 391     $link =~ s/;(src|dst)=(\d+|)//g;
 392     $link = [ "$link;$whichfield=", sub { shift->$whichfield } ];
 393     @links = ($link);
 394
 395     push @fields, 'cnt';
 396     push @header, '# Calls';
 397
 398     $nototalminutes = 1;
 399 }
 400
 401 </%init>