httemplate/misc/process/payment.cgi

   1 % if ( $cgi->param('batch') ) {
   2
   3   <% include( '/elements/header.html', ucfirst($type{$payby}). ' processing successful',
   4                  include('/elements/menubar.html'),
   5
   6             )
   7   %>
   8
   9   <% include( '/elements/small_custview.html', $cust_main, '', '', popurl(3). "view/cust_main.cgi" ) %>
  10
  11   <% include('/elements/footer.html') %>
  12
  13 % #2.5/2.7?# } elsif ( $curuser->access_right('View payments') ) {
  14 % } elsif ( $curuser->access_right(['View invoices', 'View payments']) ) {
  15 <% $cgi->redirect(popurl(3). "view/cust_pay.html?paynum=$paynum" ) %>
  16 % } else {
  17 <% $cgi->redirect(popurl(3). "view/cust_main.html?custnum=$custnum" ) %>
  18 % }
  19 <%init>
  20
  21 my $curuser = $FS::CurrentUser::CurrentUser;
  22 die "access denied" unless $curuser->access_right('Process payment');
  23
  24 my $conf = new FS::Conf;
  25
  26 ##
  27 # info for all payments, stored or unstored
  28 ##
  29
  30 #some false laziness w/MyAccount::process_payment
  31
  32 $cgi->param('custnum') =~ /^(\d+)$/
  33   or die "illegal custnum ". $cgi->param('custnum');
  34 my $custnum = $1;
  35
  36 my $cust_main = qsearchs({
  37   'table'     => 'cust_main',
  38   'hashref'   => { 'custnum' => $custnum },
  39   'extra_sql' => ' AND '. $curuser->agentnums_sql,
  40 }) or die "unknown custnum $custnum";
  41
  42 $cgi->param('amount') =~ /^\s*(\d*(\.\d\d)?)\s*$/
  43   or errorpage("illegal amount ". $cgi->param('amount'));
  44 my $amount = $1;
  45 errorpage("amount <= 0") unless $amount > 0;
  46
  47 if ( $cgi->param('fee') =~ /^\s*(\d*(\.\d\d)?)\s*$/ ) {
  48   my $fee = $1;
  49   $amount = sprintf('%.2f', $amount + $fee);
  50 }
  51
  52 $cgi->param('payby') =~ /^(CARD|CHEK)$/
  53   or errorpage("illegal payby ". $cgi->param('payby'));
  54 my $payby = $1;
  55 my %payby2fields = (
  56   'CARD' => [ qw( address1 address2 city county state zip country ) ],
  57   'CHEK' => [ qw( ss paytype paystate stateid stateid_state ) ],
  58 );
  59 my %type = ( 'CARD' => 'credit card',
  60              'CHEK' => 'electronic check (ACH)',
  61            );
  62
  63 $cgi->param('payunique') =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]*)$/
  64   or errorpage(gettext('illegal_text'). " payunique: ". $cgi->param('payunique'));
  65 my $payunique = $1;
  66
  67 $cgi->param('balance') =~ /^\s*(\-?\s*\d*(\.\d\d)?)\s*$/
  68   or errorpage("illegal balance");
  69 my $balance = $1;
  70
  71 $cgi->param('discount_term') =~ /^(\d*)$/
  72   or errorpage("illegal discount_term");
  73 my $discount_term = $1;
  74
  75 my( $cust_payby, $payinfo, $paycvv, $month, $year, $payname );
  76 my $paymask = '';
  77 if ( (my $custpaybynum = scalar($cgi->param('custpaybynum'))) > 0 ) {
  78
  79   ##
  80   # use stored cust_payby info
  81   ##
  82
  83   $cust_payby = qsearchs('cust_payby', { custnum      => $custnum,
  84                                             custpaybynum => $custpaybynum, } )
  85     or die "unknown custpaybynum $custpaybynum";
  86
  87   # not needed for realtime_bop, but still needed for batch_card
  88   $payinfo = $cust_payby->payinfo;
  89   $paymask = $cust_payby->paymask;
  90   $paycvv = $cust_payby->paycvv; # pass it if we got it, running a transaction will clear it
  91   ( $month, $year ) = $cust_payby->paydate_mon_year;
  92   $payname = $cust_payby->payname;
  93
  94 } else {
  95
  96   ##
  97   # use new info
  98   ##
  99
 100   $cgi->param('year') =~ /^(\d+)$/
 101     or errorpage("illegal year ". $cgi->param('year'));
 102   $year = $1;
 103
 104   $cgi->param('month') =~ /^(\d+)$/
 105     or errorpage("illegal month ". $cgi->param('month'));
 106   $month = $1;
 107
 108   $cgi->param('payname') =~ /^([\w \,\.\-\']+)$/
 109     or errorpage(gettext('illegal_name'). " payname: ". $cgi->param('payname'));
 110   $payname = $1;
 111
 112   if ( $payby eq 'CHEK' ) {
 113
 114     $cgi->param('payinfo1') =~ /^(\d+)$/
 115       or errorpage("Illegal account number ". $cgi->param('payinfo1'));
 116     my $payinfo1 = $1;
 117     $cgi->param('payinfo2') =~ /^(\d+)$/
 118       or errorpage("Illegal ABA/routing number ". $cgi->param('payinfo2'));
 119     my $payinfo2 = $1;
 120     if ( $conf->config('echeck-country') eq 'CA' ) {
 121       $cgi->param('payinfo3') =~ /^(\d{5})$/
 122         or errorpage("Illegal branch number ". $cgi->param('payinfo2'));
 123       $payinfo2 = "$1.$payinfo2";
 124     }
 125     $payinfo = $payinfo1. '@'. $payinfo2;
 126
 127   } elsif ( $payby eq 'CARD' ) {
 128
 129     $payinfo = $cgi->param('payinfo');
 130
 131     $payinfo =~ s/\D//g;
 132     $payinfo =~ /^(\d{13,16}|\d{8,9})$/
 133       or errorpage(gettext('invalid_card'));
 134     $payinfo = $1;
 135     validate($payinfo)
 136       or errorpage(gettext('invalid_card'));
 137
 138     unless ( $cust_main->tokenized($payinfo) ) { #token
 139
 140       my $cardtype = cardtype($payinfo);
 141
 142       errorpage(gettext('unknown_card_type'))
 143         if $cardtype eq "Unknown";
 144
 145       my %bop_card_types = map { $_=>1 } values %{ card_types() };
 146       errorpage("$cardtype not accepted") unless $bop_card_types{$cardtype};
 147
 148     }
 149
 150     if ( length($cgi->param('paycvv') ) ) {
 151       if ( cardtype($payinfo) eq 'American Express card' ) {
 152         $cgi->param('paycvv') =~ /^(\d{4})$/
 153           or errorpage("CVV2 (CID) for American Express cards is four digits.");
 154         $paycvv = $1;
 155       } else {
 156         $cgi->param('paycvv') =~ /^(\d{3})$/
 157           or errorpage("CVV2 (CVC2/CID) is three digits.");
 158         $paycvv = $1;
 159       }
 160     } elsif ( $conf->exists('backoffice-require_cvv') ){
 161       errorpage("CVV2 is required");
 162     }
 163
 164   } else {
 165     die "unknown payby $payby";
 166   }
 167
 168   # save first, for proper tokenization
 169   if ( $cgi->param('save') ) {
 170
 171     my %saveopt;
 172     if ( $payby eq 'CARD' ) {
 173       my $bill_location = FS::cust_location->new;
 174       $bill_location->set( $_ => scalar($cgi->param($_)) )
 175         foreach @{$payby2fields{$payby}};
 176       $saveopt{'bill_location'} = $bill_location;
 177       $saveopt{'paycvv'} = $paycvv; # save_cust_payby contains conf logic for when to use this
 178       $saveopt{'paydate'} = "$year-$month-01";
 179     } else {
 180       # ss/stateid/stateid_state won't be saved, but should be harmless to pass
 181       %saveopt = map { $_ => scalar($cgi->param($_)) } @{$payby2fields{$payby}};
 182     }
 183
 184     my $error = $cust_main->save_cust_payby(
 185       'saved_cust_payby' => \$cust_payby,
 186       'payment_payby' => $payby,
 187       'auto'          => scalar($cgi->param('auto')),
 188       'weight'        => scalar($cgi->param('weight')),
 189       'payinfo'       => $payinfo,
 190       'payname'       => $payname,
 191       %saveopt
 192     );
 193
 194     errorpage("error saving info, payment not processed: $error")
 195       if $error;
 196   }
 197
 198 }
 199
 200 ##
 201 # now run the payment
 202 ##
 203
 204 my $error = '';
 205 my $paynum = '';
 206 if ( $cgi->param('batch') ) {
 207
 208   $error = 'Prepayment discounts not supported with batched payments'
 209     if $discount_term;
 210
 211   $error ||= $cust_main->batch_card(
 212                                      'payby'    => $payby,
 213                                      'amount'   => $amount,
 214                                      'payinfo'  => $payinfo,
 215                                      'paydate'  => "$year-$month-01",
 216                                      'payname'  => $payname,
 217                                      map { $_ => scalar($cgi->param($_)) }
 218                                        @{$payby2fields{$payby}}
 219                                    );
 220   errorpage($error) if $error;
 221
 222 } else {
 223
 224   $error = $cust_main->realtime_bop( $FS::payby::payby2bop{$payby}, $amount,
 225     'cust_payby' => $cust_payby, # if defined, will override passed payinfo, etc
 226     'quiet'      => 1,
 227     'manual'     => 1,
 228     'balance'    => $balance,
 229     'payinfo'    => $payinfo,
 230     'paymask'    => $paymask,
 231     'paydate'    => "$year-$month-01",
 232     'payname'    => $payname,
 233     'payunique'  => $payunique,
 234     'paycvv'     => $paycvv,
 235     'paynum_ref' => \$paynum,
 236     'discount_term' => $discount_term,
 237     'no_auto_apply' => ($cgi->param('apply') eq 'never') ? 'Y' : '',
 238     'no_invnum'     => 1,
 239     map { $_ => scalar($cgi->param($_)) } @{$payby2fields{$payby}}
 240   );
 241   errorpage($error) if $error;
 242
 243   #no error, so order the fee package if applicable...
 244   if ( $cgi->param('fee_pkgpart') =~ /^(\d+)$/ ) {
 245
 246     my $cust_pkg = new FS::cust_pkg { 'pkgpart' => $1 };
 247
 248     my $error = $cust_main->order_pkg( 'cust_pkg' => $cust_pkg );
 249     errorpage("payment processed successfully, but error ordering fee: $error")
 250       if $error;
 251
 252     #and generate an invoice for it now too
 253     $error = $cust_main->bill( 'pkg_list' => [ $cust_pkg ] );
 254     errorpage("payment processed and fee ordered sucessfully, but error billing fee: $error")
 255       if $error;
 256
 257   }
 258
 259   $cust_main->apply_payments if ($cgi->param('apply') eq 'yes');
 260
 261 }
 262
 263 ##
 264 # success!  step 3: profit!
 265 ##
 266
 267 </%init>