httemplate/edit/process/quick-cust_pkg.cgi

   1 %if ($error) {
   2 %  $cgi->param('error', $error);
   3 <% $cgi->redirect(popurl(3). 'misc/order_pkg.html?'. $cgi->query_string ) %>
   4 %} else {
   5 %  my $frag = "cust_pkg". $cust_pkg->pkgnum;
   6 %  my $show = $curuser->default_customer_view =~ /^(jumbo|packages)$/
   7 %               ? ''
   8 %               : ';show=packages';
   9 %  my $redir_url = popurl(3)
  10 %            ."view/cust_main.cgi?custnum=$custnum$show;fragment=$frag#$frag";
  11 %
  12 % # for going right to a provision service after ordering a package
  13 % if ( $svcpart ) {
  14 %   $redir_url = popurl(3)."edit/".$part_svc->svcdb.".cgi?".
  15 %                  "pkgnum=".$cust_pkg->pkgnum. ";svcpart=$svcpart";
  16 %   $redir_url .= ";qualnum=$qualnum" if $qualnum;
  17 % }
  18 <% header('Package ordered') %>
  19   <SCRIPT TYPE="text/javascript">
  20     // XXX fancy ajax rebuild table at some point, but a page reload will do for now
  21
  22     // XXX chop off trailing #target and replace... ?
  23     window.top.location = '<% $redir_url %>';
  24
  25   </SCRIPT>
  26
  27   </BODY></HTML>
  28 %}
  29 <%init>
  30
  31 my $curuser = $FS::CurrentUser::CurrentUser;
  32
  33 die "access denied"
  34   unless $curuser->access_right('Order customer package');
  35
  36 #untaint custnum (probably not necessary, searching for it is escape enough)
  37 $cgi->param('custnum') =~ /^(\d+)$/
  38   or die 'illegal custnum '. $cgi->param('custnum');
  39 my $custnum = $1;
  40 my $cust_main = qsearchs({
  41   'table'     => 'cust_main',
  42   'hashref'   => { 'custnum' => $custnum },
  43   'extra_sql' => ' AND '. $FS::CurrentUser::CurrentUser->agentnums_sql,
  44 });
  45 die 'unknown custnum' unless $cust_main;
  46
  47 #probably not necessary, taken care of by cust_pkg::check
  48 $cgi->param('pkgpart') =~ /^(\d+)$/
  49   or die 'illegal pkgpart '. $cgi->param('pkgpart');
  50 my $pkgpart = $1;
  51 $cgi->param('refnum') =~ /^(\d*)$/
  52   or die 'illegal refnum '. $cgi->param('refnum');
  53 my $refnum = $1;
  54 $cgi->param('locationnum') =~ /^(\-?\d*)$/
  55   or die 'illegal locationnum '. $cgi->param('locationnum');
  56 my $locationnum = $1;
  57 $cgi->param('discountnum') =~ /^(\-?\d*)$/
  58   or die 'illegal discountnum '. $cgi->param('discountnum');
  59 my $discountnum = $1;
  60
  61 # for going right to a provision service after ordering a package
  62 my( $svcpart, $part_svc ) = ( '', '' );
  63 if ( $cgi->param('svcpart') ) {
  64   $cgi->param('svcpart') =~ /^(\-?\d*)$/
  65      or die 'illegal svcpart '. $cgi->param('svcpart');
  66   $svcpart = $1;
  67   $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } )
  68     or die "unknown svcpart $svcpart";
  69 }
  70
  71 my $qualnum = '';
  72 if ( $cgi->param('qualnum') ) {
  73   $cgi->param('qualnum') =~ /^(\d+)$/ or die 'illegal qualnum';
  74   $qualnum = $1;
  75 }
  76
  77
  78 my $cust_pkg = new FS::cust_pkg {
  79   'custnum'              => $custnum,
  80   'pkgpart'              => $pkgpart,
  81   'start_date'           => ( scalar($cgi->param('start_date'))
  82                                 ? parse_datetime($cgi->param('start_date'))
  83                                 : ''
  84                             ),
  85   'no_auto'              => scalar($cgi->param('no_auto')),
  86   'refnum'               => $refnum,
  87   'locationnum'          => $locationnum,
  88   'discountnum'          => $discountnum,
  89   #for the create a new discount case
  90   'discountnum__type'    => scalar($cgi->param('discountnum__type')),
  91   'discountnum_amount'   => scalar($cgi->param('discountnum_amount')),
  92   'discountnum_percent'  => scalar($cgi->param('discountnum_percent')),
  93   'discountnum_months'   => scalar($cgi->param('discountnum_months')),
  94   'contract_end'         => ( scalar($cgi->param('contract_end'))
  95                                 ? parse_datetime($cgi->param('contract_end'))
  96                                 : ''
  97                             ),
  98   #'discountnum_disabled' => scalar($cgi->param('discountnum_disabled')),
  99 };
 100
 101 my %opt = ( 'cust_pkg' => $cust_pkg );
 102
 103 if ( $locationnum == -1 ) {
 104   my $cust_location = new FS::cust_location {
 105     map { $_ => scalar($cgi->param($_)) }
 106         qw( custnum address1 address2 city county state zip country geocode )
 107   };
 108   $opt{'cust_location'} = $cust_location;
 109 }
 110
 111 my $error = $cust_main->order_pkg( \%opt );
 112
 113 </%init>