httemplate/edit/process/elements/process.html

   1 <%doc>
   2
   3 Example:
   4
   5  <& elements/process.html,
   6
   7    ###
   8    # required
   9    ###
  10
  11   'table' => 'tablename',
  12
  13    #? 'primary_key' => #required when the dbdef doesn't know...???
  14    #? 'fields' => []   #""
  15
  16    ###
  17    # optional
  18    ###
  19
  20    'viewall_dir'  => '', #'search' or 'browse', defaults to 'search'
  21    'viewall_ext'  => 'html', #'cgi' or 'html', defaults to 'html'
  22    OR
  23    'redirect'     => 'view/table.cgi?', # value of primary key is appended
  24                                         # (string or coderef returning a string)
  25    OR
  26    'popup_reload' => 'Momentary success message', #will reload parent window
  27
  28    'error_redirect' => popurl(2).'edit/table.cgi?', #query string appended
  29
  30    'edit_ext' => 'html', #defaults to 'html', you might want 'cgi' while the
  31                          #naming is still inconsistent
  32
  33    'copy_on_empty'  => [ 'old_field_name', 'another_old_field', ... ],
  34
  35    'clear_on_error' => [ 'form_field1', 'form_field2', ... ],
  36
  37                   #pass an arrayref of hashrefs for multiple m2ms or m2names
  38                   #be certain you incorporate m2m_Common if you see error: param
  39
  40    'process_m2m' => { 'link_table'   => 'link_table_name',
  41                       'target_table' => 'target_table_name',
  42                       #optional (see m2m_Common::process_m2m), if not specified
  43                       # all CGI params will be passed)
  44                       'params'       =>
  45                     },
  46    'process_m2name' => { 'link_table'   => 'link_table_name',
  47                          'link_static' => { 'column' => 'value' },
  48                          'num_col' => 'column', #if column name is different in
  49                                                 #link_table than source_table
  50                          'name_col' => 'name_column',
  51                          'names_list' => [ 'list', 'names' ],
  52
  53                          'param_style' => 'link_table.value checkboxes',
  54                          #or#
  55                          'param_style' => 'name_colN values',
  56
  57
  58                        },
  59    'process_o2m' => { 'table' => table_name',
  60                       'num_col' => 'column', #if column name is different in
  61                                              #link_table than source_table
  62                       'fields' => [qw( fieldname fieldname2 )],
  63                     },
  64
  65    'process_locale' => 'fieldname', # update entries in the _msgcat table
  66
  67    'process_upload' => {
  68                          'process'  => 'misc/mytable-import.html',
  69                           # fields to pass to the back end job, besides the
  70                           # primary key of the object
  71                          'fields'   => [qw( fieldname fieldname2 )],
  72                        },
  73
  74    'skip_process' => 0, #boolean, if set true, will skip the main table
  75                         #add/edit processing and only run any linked table
  76                         #process_ items
  77
  78    #checks CGI params and whatever else before much else runs
  79    #return an error string or empty for no error
  80    'precheck_callback' => sub { my( $cgi ) = @_; },
  81
  82    #after the new object is created
  83    #return an error string or empty for no error
  84    'post_new_object_callback' => sub { my( $cgi, $object ) = @_; },
  85
  86    #run right before replacing (not run for inserts)
  87    'edit_callback' => sub { my( $new, $old ) = @_; },
  88
  89    #after everything's inserted
  90    'noerror_callback' => sub { my( $cgi, $object ) = @_; },
  91
  92    #supplies arguments to insert() and replace()
  93    # for use with tables that are FS::option_Common (among other things)
  94    'args_callback' => sub { my( $cgi, $object ) = @_; },
  95
  96    # if no errors after package insert or replace will update services attached to package.
  97    'update_svc' => sub { my( $cgi, $object ) = @_; },
  98
  99    'debug' => 1, #turns on debugging output
 100
 101    #agent virtualization
 102    'agent_virt'       => 1,
 103    'agent_null_right' => 'Access Right Name',
 104
 105    #special bulk insert mode
 106    'bulk' => 'field',
 107
 108  &>
 109
 110 </%doc>
 111 %if ( $error ) {
 112 %  ## flatten any array refs so multi selects are sticky on error
 113 %  for my $param ($cgi->param) {
 114 %    if (ref($cgi->param($param)) eq "ARRAY") {
 115 %      $cgi->param($param, (join ",", @{$cgi->param($param)}));
 116 %    }
 117 %  }
 118 %
 119 %  #my $query = $m->scomp('/elements/create_uri_query');
 120 %  #$cgi->redirect("$url?$query");
 121 %  if ( length($cgi->query_string) > 1920 ) { #stupid IE 2083 URL limit
 122 %
 123 %    my $session = int(rand(4294967296)); #XXX
 124 %    my $pref = new FS::access_user_pref({
 125 %      'usernum'    => $FS::CurrentUser::CurrentUser->usernum,
 126 %      'prefname'   => "redirect$session",
 127 %      'prefvalue'  => $cgi->query_string,
 128 %      'expiration' => time + 3600, #1h?  1m?
 129 %    });
 130 %    my $pref_error = $pref->insert;
 131 %    if ( $pref_error ) {
 132 %      die "FATAL: couldn't even set redirect cookie: $pref_error".
 133 %          " attempting to set redirect$session to ". $cgi->query_string."\n";
 134 %    }
 135 %
 136 <% $cgi->redirect("$error_redirect?redirect=$session") %>
 137 %
 138 %  } else {
 139 %
 140 <% $cgi->redirect("$error_redirect?". $cgi->query_string ) %>
 141 %
 142 %  }
 143 %
 144 % #different ways of handling success
 145 %
 146 %} elsif ( $opt{'process_upload'} and @uploaded_files ) {
 147 %
 148 % # construct a form to pass all the requested fields, the
 149 %
 150 <& /elements/header.html &>
 151 <form name="UploadForm">
 152 %   my $job_fields = $opt{'process_upload'}{'fields'};
 153 %   foreach my $field ( @$job_fields ) {
 154   <input type="hidden" name="<% $field %>" value="<% $cgi->param($field) |h %>">
 155 %   }
 156 %   push @$job_fields, 'uploaded_files', $pkey;
 157 %
 158   <input type="hidden" name="uploaded_files" value="<% join(',', @uploaded_files) %>">
 159   <input type="hidden" name="<% $pkey %>" value="<% $new->get($pkey) %>">
 160 <& /elements/progress-init.html,
 161   'UploadForm',
 162   $job_fields,
 163   $fsurl . $opt{'process_upload'}{'process'},
 164   {
 165     url => $redirect,
 166     error_url => "$error_redirect?$new_pkey"
 167   },
 168 &>
 169 <input type="submit" style="display:none">
 170 </form>
 171 <script>
 172 <&| /elements/onload.js &>
 173 process();
 174 </&>
 175 </script>
 176 <& /elements/footer.html &>
 177
 178 % } elsif ( $opt{'progress_init'} ) {
 179 %   # some false laziness with the above
 180 %   my ($form_name, $job_fields) = @{ $opt{'progress_init'} };
 181 <form name="<% $form_name %>">
 182   <input type="hidden" name="<% $pkey %>" value="<% $new->get($pkey) %>">
 183 %   foreach my $field (@$job_fields) {
 184 %     next if $field eq $pkey;
 185   <input type="hidden" name="<% $field %>" value="<% $cgi->param($field) |h %>">
 186 %   }
 187 <& /elements/progress-init.html,
 188   @{ $opt{'progress_init'} }
 189 &>
 190 <input type="submit" style="display:none">
 191 </form>
 192 <script>
 193 <&| /elements/onload.js &>
 194 process();
 195 </&>
 196 </script>
 197 <& /elements/footer.html &>
 198
 199 % } elsif ( $opt{'popup_reload'} ) {
 200
 201   <% include('/elements/header-popup.html', $opt{'popup_reload'} ) %>
 202
 203   <SCRIPT TYPE="text/javascript">
 204     topreload();
 205   </SCRIPT>
 206
 207   </BODY>
 208   </HTML>
 209
 210 %} else {
 211 <% $cgi->redirect($redirect) %>
 212 %}
 213 <%init>
 214
 215 my $me = 'process.html:';
 216
 217 my(%opt) = @_;
 218
 219 my $curuser = $FS::CurrentUser::CurrentUser;
 220
 221 my $error = '';
 222 if ( $opt{'precheck_callback'} ) {
 223   $error = &{ $opt{'precheck_callback'} }( $cgi );
 224 }
 225
 226 #false laziness w/edit.html
 227 my $table = $opt{'table'};
 228 my $class = "FS::$table";
 229 my $pkey = dbdef->table($table)->primary_key; #? $opt{'primary_key'} ||
 230 my $fields = $opt{'fields'}
 231              #|| [ grep { $_ ne $pkey } dbdef->table($table)->columns ];
 232              || [ fields($table) ];
 233
 234 my $old_pkey = $cgi->param($pkey);
 235
 236 my $old = '';
 237 if ( $old_pkey ) {
 238   $old = qsearchs({
 239     'table'   => $table,
 240     'hashref' => { $pkey => $old_pkey },
 241     'extra_sql' => ( $opt{'agent_virt'}
 242                        ? ' AND '. $curuser->agentnums_sql(
 243                                     'null_right' => $opt{'agent_null_right'}
 244                                   )
 245                        : ''
 246                    ),
 247   });
 248 }
 249
 250 my $bfield = $opt{'bulk'};
 251
 252 my %hash =
 253   map { my @entry = ( $_ => scalar($cgi->param($_)) );
 254         $opt{'value_callback'} ? ( $_ => &{ $opt{'value_callback'} }( @entry ))
 255                                : ( @entry )
 256       } grep { $_ ne $bfield } @$fields;
 257
 258 my @values = ( 1 );
 259 if ( $bfield ) {
 260   @values = $cgi->param($bfield);
 261   #warn join(',', @values);
 262 }
 263
 264 my @uploaded_files;
 265
 266 my $new;
 267 my $new_pkey = '';
 268 foreach my $value ( @values ) {
 269
 270   if ($opt{'skip_process'}) {
 271
 272     $new = $old;
 273     $new_pkey = $old_pkey;
 274
 275   } else {
 276
 277     $new = $class->new( \%hash );
 278
 279     $new->$bfield($value) if $bfield;
 280
 281     if ($old && exists($opt{'copy_on_empty'})) {
 282       foreach my $field (@{$opt{'copy_on_empty'}}) {
 283         $new->set($field, $old->get($field))
 284           unless scalar($cgi->param($field));
 285       }
 286     }
 287
 288     if ( $opt{'post_new_object_callback'} ) {
 289       $error ||= &{ $opt{'post_new_object_callback'} }( $cgi, $new );
 290     }
 291
 292     if ( $opt{'agent_virt'} ) {
 293
 294       if ( ! $new->agentnum
 295            && (    ! $opt{'agent_null_right'}
 296                 || ! $curuser->access_right($opt{'agent_null_right'})
 297               )
 298          )
 299       {
 300
 301         $error ||= 'Select an agent';
 302
 303       } else {
 304
 305         die "illegal agentnum"
 306           unless $curuser->agentnums_href->{$new->agentnum}
 307               or $curuser->access_right('View customers of all agents')
 308               or $opt{'agent_null_right'}
 309                  && ! $new->agentnum
 310                  && $curuser->access_right($opt{'agent_null_right'});
 311
 312       }
 313
 314     }
 315
 316     my @args = ();
 317     if ( !$error && $opt{'args_callback'} ) {
 318       @args = &{ $opt{'args_callback'} }( $cgi, $new );
 319     }
 320
 321     if ( !$error && $opt{'debug'} ) {
 322       warn "$me updating record in $table table using $class class\n";
 323       warn Dumper(\%hash);
 324       warn "with args: \n". Dumper(\@args) if @args;
 325     }
 326
 327     if ( !$error ) {
 328       if ( $old_pkey ) {
 329
 330         &{ $opt{'edit_callback'} }( $new, $old ) if $opt{'edit_callback'};
 331
 332         $error = $new->replace($old, @args);
 333       } else {
 334         $error = $new->insert(@args);
 335       }
 336       $new_pkey = $new->getfield($pkey);
 337     }
 338
 339   } #unless $opt{'skip_process'}
 340
 341   if ( !$error && $opt{'process_m2m'} ) {
 342
 343     my @process_m2m = ref($opt{'process_m2m'}) eq 'ARRAY'
 344                         ? @{ $opt{'process_m2m'} }
 345                         :  ( $opt{'process_m2m'} );
 346
 347     foreach my $process_m2m (@process_m2m) {
 348
 349       $process_m2m->{'params'} ||= scalar($cgi->Vars);
 350
 351       warn "$me processing m2m:\n". Dumper( %$process_m2m )
 352         if $opt{'debug'};
 353
 354       $error ||= $new->process_m2m( %$process_m2m );
 355     }
 356
 357   }
 358
 359   if ( !$error && $opt{'process_m2name'} ) {
 360
 361     my @process_m2name = ref($opt{'process_m2name'}) eq 'ARRAY'
 362                            ? @{ $opt{'process_m2name'} }
 363                            :  ( $opt{'process_m2name'} );
 364
 365
 366     foreach my $process_m2name (@process_m2name) {
 367
 368       if ( $opt{'debug'} ) {
 369         warn "$me processing m2name:\n". Dumper( %{ $process_m2name },
 370                                                  'params' => scalar($cgi->Vars),
 371                                                );
 372       }
 373
 374       $error = $new->process_m2name( %{ $process_m2name },
 375                                      'params' => scalar($cgi->Vars),
 376                                    );
 377     }
 378
 379   }
 380
 381   my @process_o2m;
 382   if ( $opt{'process_o2m'} ) {
 383     @process_o2m = ref($opt{'process_o2m'}) eq 'ARRAY'
 384                         ? @{ $opt{'process_o2m'} }
 385                         :  ( $opt{'process_o2m'} );
 386   }
 387   if ( $opt{'process_locale'} ) {
 388     push @process_o2m,
 389     {
 390       'table'  => $table . '_msgcat',
 391       'fields' => [ 'locale', $opt{'process_locale'} ],
 392     };
 393   }
 394
 395   if ( !$error ) {
 396
 397     foreach my $process_o2m (@process_o2m) {
 398
 399       if ( $opt{'debug'} ) {
 400         warn "$me processing o2m:\n". Dumper( %{ $process_o2m },
 401                                                  'params' => scalar($cgi->Vars),
 402                                                );
 403       }
 404
 405       $error ||= $new->process_o2m( %{ $process_o2m },
 406                                      'params' => scalar($cgi->Vars),
 407                                    );
 408     }
 409
 410   }
 411
 412
 413   if ( !$error and $opt{'process_upload'} ) {
 414     # mostly duplicates misc/file-upload.html
 415     $cgi->param('upload_fields') =~ /^([,\w]+)$/
 416       or $error = "invalid upload_fields";
 417     my $fields = $1;
 418
 419     my $dir = $FS::UID::cache_dir. "/cache.". $FS::UID::datasrc;
 420
 421     foreach my $field (split /,/, $fields) {
 422       next if $error;
 423       my $source_name = $cgi->param($field);
 424
 425       if ( $opt{'debug'} ) {
 426         warn "$me processing upload: $source_name\n";
 427       }
 428       my $fh = $cgi->upload( $field ); # if no file provided, that's fine
 429       next if !$fh;
 430
 431       my $suffix = '';
 432       if ( $source_name =~ /(\.\w+)$/ ) {
 433         $suffix = lc($1);
 434       }
 435
 436       my $sh = File::Temp->new( TEMPLATE => 'upload.XXXXXXXX',
 437                                 SUFFIX   => $suffix,
 438                                 DIR      => $dir,
 439                                 UNLINK   => 0,
 440                               )
 441         or $error ||= "can't open temporary file to store upload: $!\n";
 442       next if $error;
 443       while(<$fh>) {
 444         print $sh $_;
 445       }
 446       $sh->filename =~ m!.*/([.\w]+)$!;
 447       push @uploaded_files, "$field:$1";
 448       if ( $opt{'debug'} ) {
 449         warn "uploaded as $1\n";
 450       }
 451     }
 452   }
 453
 454   if ( !$error and $opt{'update_svc'} ) {
 455     my @args = ();
 456     @args = &{ $opt{'args_callback'} }( $cgi, $new ) if $opt{'args_callback'};
 457    $error = &{ $opt{'update_svc'} }( $cgi, $new, @args );
 458   }
 459
 460   if ( $error ) {
 461
 462     $cgi->param('error', $error);
 463     if ( $opt{'clear_on_error'} && scalar(@{$opt{'clear_on_error'}}) ) {
 464       foreach my $field (@{$opt{'clear_on_error'}}) {
 465         $cgi->param($field, '')
 466       }
 467     }
 468
 469   } else {
 470
 471     if ( $opt{'noerror_callback'} ) {
 472       &{ $opt{'noerror_callback'} }( $cgi, $new );
 473     }
 474
 475   }
 476
 477   last if $error;
 478
 479 }
 480
 481 if ($class eq "FS::tower") {
 482   foreach my $part_svc_broadband_export ( FS::tower_sector->part_export_svc_broadband ) {
 483     if ($part_svc_broadband_export and $part_svc_broadband_export->can('export_tower_sector')) {
 484       my $export_tower = $part_svc_broadband_export->export_tower_sector($new);
 485       $error = $export_tower->{'error'} if $export_tower;
 486     }
 487   }
 488   $cgi->param('error', $error) if $error;
 489 }
 490
 491 # set up redirect URLs
 492
 493 my $redirect;
 494 if ( !$error ) {
 495   $opt{'redirect'} = &{$opt{'redirect'}}($cgi, $new)
 496     if ref($opt{'redirect'}) eq 'CODE';
 497
 498   if ( $opt{'redirect'} ) {
 499
 500     $redirect = $opt{'redirect'} . $new_pkey;
 501
 502   } else {
 503
 504     my $ext = $opt{'viewall_ext'} || 'html';
 505     my $viewall_dir = $opt{'viewall_dir'} || 'search';
 506     my $viewall_url = $opt{'viewall_url'} || ($viewall_dir . "/$table.$ext");
 507
 508     $redirect = popurl(3) . $viewall_url;
 509
 510   }
 511 }
 512
 513 my $edit_ext = $opt{'edit_ext'} || 'html';
 514 my $error_redirect = $opt{'error_redirect'}
 515                      || popurl(2)."$table.$edit_ext";
 516 </%init>