fs_signup/fs_signup_server

   1 #!/usr/bin/perl -Tw
   2 #
   3 # fs_signup_server
   4 #
   5
   6 use strict;
   7 use IO::Handle;
   8 use Storable qw(nstore_fd fd_retrieve);
   9 use Tie::RefHash;
  10 use Net::SSH qw(sshopen2);
  11 use FS::UID qw(adminsuidsetup);
  12 use FS::Conf;
  13 use FS::Record qw( qsearch qsearchs );
  14 use FS::cust_main_county;
  15 use FS::cust_main;
  16
  17 use vars qw( $opt $Debug );
  18
  19 $Debug = 2;
  20
  21 my @payby = qw(CARD PREPAY);
  22
  23 my $user = shift or die &usage;
  24 &adminsuidsetup( $user );
  25
  26 my $conf = new FS::Conf;
  27
  28 my $machine = shift or die &usage;
  29
  30 my $agentnum = shift or die &usage;
  31 my $agent = qsearchs( 'agent', { 'agentnum' => $agentnum } ) or die &usage;
  32 my $pkgpart_href = $agent->pkgpart_hashref;
  33
  34 my $refnum = shift or die &usage;
  35
  36 #causing trouble for some folks
  37 #$SIG{CHLD} = sub { wait() };
  38
  39 my($fs_signupd)="/usr/local/sbin/fs_signupd";
  40
  41 while (1) {
  42   my($reader,$writer)=(new IO::Handle, new IO::Handle);
  43   #seems to be broken - calling ->flush explicitly# $writer->autoflush(1);
  44   warn "[fs_signup_server] Connecting to $machine...\n" if $Debug;
  45   sshopen2($machine,$reader,$writer,$fs_signupd);
  46
  47   my $init_data = {
  48
  49     #'_protocol' => 'signup',
  50     #'_version' => '0.1',
  51     #'_packet' => 'init'
  52
  53     'cust_main_county' =>
  54       [ map { $_->hashref } qsearch('cust_main_county', {}) ],
  55
  56     'part_pkg' =>
  57       [
  58         map { $_->hashref }
  59           grep { $_->svcpart('svc_acct') && $pkgpart_href->{ $_->pkgpart } }
  60             qsearch( 'part_pkg', { 'disabled' => '' } )
  61       ],
  62
  63     'svc_acct_pop' => [ map { $_->hashref } qsearch ('svc_acct_pop',{} ) ],
  64
  65     'security_phrase' => $conf->exists('security_phrase'),
  66
  67   };
  68
  69   warn "[fs_signup_server] Sending init data...\n" if $Debug;
  70   nstore_fd($init_data, $writer) or die "can't send init data: $!";
  71   $writer->flush;
  72
  73   warn "[fs_signup_server] Entering main loop...\n" if $Debug;
  74   while (1) {
  75     warn "[fs_signup_server] Reading (waiting for) signup data...\n" if $Debug;
  76     my $signup_data = fd_retrieve($reader);
  77
  78     if ( $Debug > 1 ) {
  79       warn join('',
  80         map { "  $_ => ". $signup_data->{$_}. "\n" } keys %$signup_data );
  81     }
  82
  83     warn "[fs_signup_server] Processing signup...\n" if $Debug;
  84
  85     my $error = '';
  86
  87     #things that aren't necessary in base class, but are for signup server
  88       #return "Passwords don't match"
  89       #  if $hashref->{'_password'} ne $hashref->{'_password2'}
  90     $error ||= "Empty password" unless $signup_data->{'_password'};
  91     $error ||= "No POP selected" unless $signup_data->{'popnum'};
  92
  93     #shares some stuff with htdocs/edit/process/cust_main.cgi... take any
  94     # common that are still here and library them.
  95     my $cust_main = new FS::cust_main ( {
  96       #'custnum'          => '',
  97       'agentnum'         => $agentnum,
  98       'refnum'           => $refnum,
  99
 100       map { $_ => $signup_data->{$_} } qw(
 101         last first ss company address1 address2 city county state zip country
 102         daytime night fax payby payinfo paydate payname referral_custnum
 103       ),
 104
 105     } );
 106
 107     $error ||= "Illegal payment type"
 108       unless grep { $_ eq $signup_data->{'payby'} } @payby;
 109
 110     my @invoicing_list = split( /\s*\,\s*/, $signup_data->{'invoicing_list'} );
 111
 112     my $part_pkg =
 113       qsearchs( 'part_pkg', { 'pkgpart' => $signup_data->{'pkgpart'} } )
 114         or $error ||= "WARNING: unknown pkgpart ". $signup_data->{pkgpart};
 115     my $svcpart = $part_pkg->svcpart unless $error;
 116
 117     # this should wind up in FS::cust_pkg!
 118     my $agent = qsearchs( 'agent', { 'agentnum' => $agentnum } );
 119     #my $pkgpart_href = $agent->pkgpart_hashref;
 120     $error ||= "WARNING: agent $agentnum can't purchase pkgpart ".
 121                $signup_data->{pkgpart}
 122       unless $pkgpart_href->{ $signup_data->{pkgpart} };
 123
 124     my $cust_pkg = new FS::cust_pkg ( {
 125       #later#'custnum' => $custnum,
 126       'pkgpart' => $signup_data->{'pkgpart'},
 127     } );
 128     $error ||= $cust_pkg->check;
 129
 130     my $svc_acct = new FS::svc_acct ( {
 131       'svcpart'   => $svcpart,
 132       map { $_ => $signup_data->{$_} }
 133         qw( username _password sec_phrase popnum ),
 134     } );
 135
 136     my $y = $svc_acct->setdefault; # arguably should be in new method
 137     $error ||= $y unless ref($y);
 138
 139     $error ||= $svc_acct->check;
 140
 141     use Tie::RefHash;
 142     tie my %hash, 'Tie::RefHash';
 143     %hash = ( $cust_pkg => [ $svc_acct ] );
 144     $error ||= $cust_main->insert( \%hash, \@invoicing_list );
 145
 146     warn "[fs_signup_server] Sending results...\n" if $Debug;
 147     print $writer $error, "\n";
 148
 149   }
 150   close $writer;
 151   close $reader;
 152   warn "connection to $machine lost!  waiting 60 seconds...\n";
 153   sleep 60;
 154   warn "reconnecting...\n";
 155 }
 156
 157 sub usage {
 158   die "Usage:\n\n  fs_signup_server user machine agentnum refnum\n";
 159 }
 160