fs_selfservice/FS-SelfService/cgi/selfservice.cgi

   1 #!/usr/bin/perl -Tw
   2
   3 use strict;
   4 use vars qw($DEBUG $cgi $session_id $form_max $template_dir);
   5 use subs qw(do_template);
   6 use CGI;
   7 use CGI::Carp qw(fatalsToBrowser);
   8 use Text::Template;
   9 use HTML::Entities;
  10 use FS::SelfService qw( login customer_info invoice
  11                         payment_info process_payment
  12                         process_prepay
  13                         list_pkgs order_pkg signup_info
  14                         part_svc_info provision_acct provision_external
  15                         unprovision_svc
  16                         list_svcs myaccount_passwd
  17                       );
  18
  19 $template_dir = '.';
  20
  21 $DEBUG = 1;
  22
  23 $form_max = 255;
  24
  25 $cgi = new CGI;
  26
  27 unless ( defined $cgi->param('session') ) {
  28   do_template('login',{});
  29   exit;
  30 }
  31
  32 if ( $cgi->param('session') eq 'login' ) {
  33
  34   $cgi->param('username') =~ /^\s*([a-z0-9_\-\.\&]{0,$form_max})\s*$/i
  35     or die "illegal username";
  36   my $username = $1;
  37
  38   $cgi->param('domain') =~ /^\s*([\w\-\.]{0,$form_max})\s*$/
  39     or die "illegal domain";
  40   my $domain = $1;
  41
  42   $cgi->param('password') =~ /^(.{0,$form_max})$/
  43     or die "illegal password";
  44   my $password = $1;
  45
  46   my $rv = login(
  47     'username' => $username,
  48     'domain'   => $domain,
  49     'password' => $password,
  50   );
  51   if ( $rv->{error} ) {
  52     do_template('login', {
  53       'error'    => $rv->{error},
  54       'username' => $username,
  55       'domain'   => $domain,
  56     } );
  57     exit;
  58   } else {
  59     $cgi->param('session' => $rv->{session_id} );
  60     $cgi->param('action'  => 'myaccount' );
  61   }
  62 }
  63
  64 $session_id = $cgi->param('session');
  65
  66 #order|pw_list XXX ???
  67 $cgi->param('action') =~
  68     /^(myaccount|view_invoice|make_payment|payment_results|recharge_prepay|recharge_results|logout|change_bill|change_ship|customer_order_pkg|process_order_pkg|provision|provision_svc|process_svc_acct|process_svc_external|delete_svc|change_password|process_change_password)$/
  69   or die "unknown action ". $cgi->param('action');
  70 my $action = $1;
  71
  72 warn "calling $action sub\n"
  73   if $DEBUG;
  74 $FS::SelfService::DEBUG = $DEBUG;
  75 my $result = eval "&$action();";
  76 die $@ if $@;
  77
  78 if ( $result->{error} eq "Can't resume session"
  79   || $result->{error} eq "Expired session" ) { #ick
  80
  81   do_template('login',{});
  82   exit;
  83 }
  84
  85 #warn $result->{'open_invoices'};
  86 #warn scalar(@{$result->{'open_invoices'}});
  87
  88 warn "processing template $action\n"
  89   if $DEBUG;
  90 do_template($action, {
  91   'session_id' => $session_id,
  92   'action'     => $action, #so the menu knows what tab we're on...
  93   %{$result}
  94 });
  95
  96 #--
  97
  98 sub myaccount { customer_info( 'session_id' => $session_id ); }
  99
 100 sub view_invoice {
 101
 102   $cgi->param('invnum') =~ /^(\d+)$/ or die "illegal invnum";
 103   my $invnum = $1;
 104
 105   invoice( 'session_id' => $session_id,
 106            'invnum'     => $invnum,
 107          );
 108
 109 }
 110
 111 sub customer_order_pkg {
 112   my $init_data = signup_info( 'customer_session_id' => $session_id );
 113   return $init_data if ( $init_data->{'error'} );
 114
 115   my $customer_info = customer_info( 'session_id' => $session_id );
 116   return $customer_info if ( $customer_info->{'error'} );
 117
 118   return {
 119     ( map { $_ => $init_data->{$_} }
 120           qw( part_pkg security_phrase svc_acct_pop ),
 121     ),
 122     %$customer_info,
 123   };
 124 }
 125
 126 sub process_order_pkg {
 127
 128   my $results = '';
 129
 130   unless ( length($cgi->param('_password')) ) {
 131     my $init_data = signup_info( 'customer_session_id' => $session_id );
 132     $results = { 'error' => $init_data->{msgcat}{empty_password} };
 133     $results = { 'error' => $init_data->{error} } if($init_data->{error});
 134   }
 135   if ( $cgi->param('_password') ne $cgi->param('_password2') ) {
 136     my $init_data = signup_info( 'customer_session_id' => $session_id );
 137     $results = { 'error' => $init_data->{msgcat}{passwords_dont_match} };
 138     $results = { 'error' => $init_data->{error} } if($init_data->{error});
 139     $cgi->param('_password', '');
 140     $cgi->param('_password2', '');
 141   }
 142
 143   $results ||= order_pkg (
 144     'session_id' => $session_id,
 145     map { $_ => $cgi->param($_) }
 146         qw( custnum pkgpart username _password _password2 sec_phrase popnum )
 147   );
 148
 149
 150   if ( $results->{'error'} ) {
 151     $action = 'customer_order_pkg';
 152     return {
 153       $cgi->Vars,
 154       %{customer_order_pkg()},
 155       'error' => '<FONT COLOR="#FF0000">'. $results->{'error'}. '</FONT>',
 156     };
 157   } else {
 158     return $results;
 159   }
 160
 161 }
 162
 163 sub make_payment {
 164   payment_info( 'session_id' => $session_id );
 165 }
 166
 167 sub payment_results {
 168
 169   use Business::CreditCard;
 170
 171   $cgi->param('amount') =~ /^\s*(\d+(\.\d{2})?)\s*$/
 172     or die "illegal amount"; #!!!
 173   my $amount = $1;
 174
 175   my $payinfo = $cgi->param('payinfo');
 176   $payinfo =~ s/\D//g;
 177   $payinfo =~ /^(\d{13,16})$/
 178     #or $error ||= $init_data->{msgcat}{invalid_card}; #. $self->payinfo;
 179     or die "illegal card"; #!!!
 180   $payinfo = $1;
 181   validate($payinfo)
 182     #or $error ||= $init_data->{msgcat}{invalid_card}; #. $self->payinfo;
 183     or die "invalid card"; #!!!
 184
 185   if ( $cgi->param('card_type') ) {
 186     cardtype($payinfo) eq $cgi->param('card_type')
 187       #or $error ||= $init_data->{msgcat}{not_a}. $cgi->param('CARD_type');
 188       or die "not a ". $cgi->param('card_type');
 189   }
 190
 191   $cgi->param('month') =~ /^(\d{2})$/ or die "illegal month";
 192   my $month = $1;
 193   $cgi->param('year') =~ /^(\d{4})$/ or die "illegal year";
 194   my $year = $1;
 195
 196   $cgi->param('payname') =~ /^(.{0,80})$/ or die "illegal payname";
 197   my $payname = $1;
 198
 199   $cgi->param('address1') =~ /^(.{0,80})$/ or die "illegal address1";
 200   my $address1 = $1;
 201
 202   $cgi->param('address2') =~ /^(.{0,80})$/ or die "illegal address2";
 203   my $address2 = $1;
 204
 205   $cgi->param('city') =~ /^(.{0,80})$/ or die "illegal city";
 206   my $city = $1;
 207
 208   $cgi->param('state') =~ /^(.{2})$/ or die "illegal state";
 209   my $state = $1;
 210
 211   $cgi->param('zip') =~ /^(.{0,10})$/ or die "illegal zip";
 212   my $zip = $1;
 213
 214   my $save = 0;
 215   $save = 1 if $cgi->param('save');
 216
 217   my $auto = 0;
 218   $auto = 1 if $cgi->param('auto');
 219
 220   $cgi->param('paybatch') =~ /^([\w\-\.]+)$/ or die "illegal paybatch";
 221   my $paybatch = $1;
 222
 223   process_payment(
 224     'session_id' => $session_id,
 225     'amount'     => $amount,
 226     'payinfo'    => $payinfo,
 227     'month'      => $month,
 228     'year'       => $year,
 229     'payname'    => $payname,
 230     'address1'   => $address1,
 231     'address2'   => $address2,
 232     'city'       => $city,
 233     'state'      => $state,
 234     'zip'        => $zip,
 235     'save'       => $save,
 236     'auto'       => $auto,
 237     'paybatch'   => $paybatch,
 238   );
 239
 240 }
 241
 242 sub recharge_prepay {
 243   customer_info( 'session_id' => $session_id );
 244 }
 245
 246 sub recharge_results {
 247
 248   my $prepaid_cardnum = $cgi->param('prepaid_cardnum');
 249   $prepaid_cardnum =~ s/\W//g;
 250   $prepaid_cardnum =~ /^(\w*)$/ or die "illegal prepaid card number";
 251   $prepaid_cardnum = $1;
 252
 253   process_prepay ( 'session_id'     => $session_id,
 254                    'prepaid_cardnum' => $prepaid_cardnum,
 255                  );
 256 }
 257
 258 sub logout {
 259   FS::SelfService::logout( 'session_id' => $session_id );
 260 }
 261
 262 sub provision {
 263   my $result = list_pkgs( 'session_id' => $session_id );
 264   die $result->{'error'} if exists $result->{'error'} && $result->{'error'};
 265   $result;
 266 }
 267
 268 sub provision_svc {
 269
 270   my $result = part_svc_info(
 271     'session_id' => $session_id,
 272     map { $_ => $cgi->param($_) } qw( pkgnum svcpart ),
 273   );
 274   die $result->{'error'} if exists $result->{'error'} && $result->{'error'};
 275
 276   $result->{'svcdb'} =~ /^svc_(.*)$/
 277     #or return { 'error' => 'Unknown svcdb '. $result->{'svcdb'} };
 278     or die 'Unknown svcdb '. $result->{'svcdb'};
 279   $action .= "_$1";
 280
 281   $result;
 282 }
 283
 284 sub process_svc_acct {
 285
 286   my $result = provision_acct (
 287     'session_id' => $session_id,
 288     map { $_ => $cgi->param($_) } qw(
 289       pkgnum svcpart username _password _password2 sec_phrase popnum )
 290   );
 291
 292   if ( exists $result->{'error'} && $result->{'error'} ) {
 293     #warn "$result $result->{'error'}";
 294     $action = 'provision_svc_acct';
 295     return {
 296       $cgi->Vars,
 297       %{ part_svc_info( 'session_id' => $session_id,
 298                         map { $_ => $cgi->param($_) } qw( pkgnum svcpart )
 299                       )
 300       },
 301       'error' => $result->{'error'},
 302     };
 303   } else {
 304     #warn "$result $result->{'error'}";
 305     return $result;
 306   }
 307
 308 }
 309
 310 sub process_svc_external {
 311   provision_external (
 312     'session_id' => $session_id,
 313     map { $_ => $cgi->param($_) } qw( pkgnum svcpart )
 314   );
 315 }
 316
 317 sub delete_svc {
 318   unprovision_svc(
 319     'session_id' => $session_id,
 320     'svcnum'     => $cgi->param('svcnum'),
 321   );
 322 }
 323
 324 sub change_password {
 325   list_svcs(
 326     'session_id' => $session_id,
 327     'svcdb'      => 'svc_acct',
 328   );
 329 };
 330
 331 sub process_change_password {
 332
 333   my $result = myaccount_passwd(
 334     'session_id'    => $session_id,
 335     map { $_ => $cgi->param($_) } qw( svcnum new_password new_password2 )
 336   );
 337
 338   if ( exists $result->{'error'} && $result->{'error'} ) {
 339
 340     $action = 'change_password';
 341     return {
 342       $cgi->Vars,
 343       %{ list_svcs( 'session_id' => $session_id,
 344                     'svcdb'      => 'svc_acct',
 345                   )
 346        },
 347       #'svcnum' => $cgi->param('svcnum'),
 348       'error'  => $result->{'error'}
 349     };
 350
 351  } else {
 352
 353    return $result;
 354
 355  }
 356
 357 }
 358
 359 #--
 360
 361 sub do_template {
 362   my $name = shift;
 363   my $fill_in = shift;
 364
 365   $cgi->delete_all();
 366   $fill_in->{'selfurl'} = $cgi->self_url;
 367   $fill_in->{'cgi'} = \$cgi;
 368
 369   my $template = new Text::Template( TYPE    => 'FILE',
 370                                      SOURCE  => "$template_dir/$name.html",
 371                                      DELIMITERS => [ '<%=', '%>' ],
 372                                      UNTAINT => 1,                    )
 373     or die $Text::Template::ERROR;
 374
 375   print $cgi->header( '-expires' => 'now' ),
 376         $template->fill_in( PACKAGE => 'FS::SelfService::_selfservicecgi',
 377                             HASH    => $fill_in
 378                           );
 379 }
 380
 381 #*FS::SelfService::_selfservicecgi::include = \&Text::Template::fill_in_file;
 382
 383 package FS::SelfService::_selfservicecgi;
 384
 385 #use FS::SelfService qw(regionselector expselect popselector);
 386 use HTML::Entities;
 387 use FS::SelfService qw(popselector);
 388
 389 #false laziness w/agent.cgi
 390 sub include {
 391   my $name = shift;
 392   my $template = new Text::Template( TYPE   => 'FILE',
 393                                      SOURCE => "$main::template_dir/$name.html",
 394                                      DELIMITERS => [ '<%=', '%>' ],
 395                                      UNTAINT => 1,
 396                                    )
 397     or die $Text::Template::ERROR;
 398
 399   $template->fill_in( PACKAGE => 'FS::SelfService::_selfservicecgi',
 400                       #HASH    => $fill_in
 401                     );
 402
 403 }
 404