fs_selfservice/FS-SelfService/cgi/selfservice.cgi

   1 #!/usr/bin/perl -Tw
   2
   3 use strict;
   4 use vars qw($DEBUG $cgi $session_id $form_max $template_dir);
   5 use subs qw(do_template);
   6 use CGI;
   7 use CGI::Carp qw(fatalsToBrowser);
   8 use Text::Template;
   9 use HTML::Entities;
  10 use Date::Format;
  11 use Number::Format 1.50;
  12 use FS::SelfService qw( login customer_info invoice
  13                         payment_info process_payment
  14                         process_prepay
  15                         list_pkgs order_pkg signup_info order_recharge
  16                         part_svc_info provision_acct provision_external
  17                         unprovision_svc change_pkg
  18                         list_svcs list_svc_usage myaccount_passwd
  19                       );
  20
  21 $template_dir = '.';
  22
  23 $DEBUG = 1;
  24
  25 $form_max = 255;
  26
  27 $cgi = new CGI;
  28
  29 unless ( defined $cgi->param('session') ) {
  30   do_template('login',{});
  31   exit;
  32 }
  33
  34 if ( $cgi->param('session') eq 'login' ) {
  35
  36   $cgi->param('username') =~ /^\s*([a-z0-9_\-\.\&]{0,$form_max})\s*$/i
  37     or die "illegal username";
  38   my $username = $1;
  39
  40   $cgi->param('domain') =~ /^\s*([\w\-\.]{0,$form_max})\s*$/
  41     or die "illegal domain";
  42   my $domain = $1;
  43
  44   $cgi->param('password') =~ /^(.{0,$form_max})$/
  45     or die "illegal password";
  46   my $password = $1;
  47
  48   my $rv = login(
  49     'username' => $username,
  50     'domain'   => $domain,
  51     'password' => $password,
  52   );
  53   if ( $rv->{error} ) {
  54     do_template('login', {
  55       'error'    => $rv->{error},
  56       'username' => $username,
  57       'domain'   => $domain,
  58     } );
  59     exit;
  60   } else {
  61     $cgi->param('session' => $rv->{session_id} );
  62     $cgi->param('action'  => 'myaccount' );
  63   }
  64 }
  65
  66 $session_id = $cgi->param('session');
  67
  68 #order|pw_list XXX ???
  69 $cgi->param('action') =~
  70     /^(myaccount|view_invoice|make_payment|make_ach_payment|payment_results|ach_payment_results|recharge_prepay|recharge_results|logout|change_bill|change_ship|customer_order_pkg|process_order_pkg|customer_change_pkg|process_change_pkg|process_order_recharge|provision|provision_svc|process_svc_acct|process_svc_external|delete_svc|view_usage|view_usage_details|change_password|process_change_password)$/
  71   or die "unknown action ". $cgi->param('action');
  72 my $action = $1;
  73
  74 warn "calling $action sub\n"
  75   if $DEBUG;
  76 $FS::SelfService::DEBUG = $DEBUG;
  77 my $result = eval "&$action();";
  78 die $@ if $@;
  79
  80 if ( $result->{error} eq "Can't resume session"
  81   || $result->{error} eq "Expired session" ) { #ick
  82
  83   do_template('login',{});
  84   exit;
  85 }
  86
  87 #warn $result->{'open_invoices'};
  88 #warn scalar(@{$result->{'open_invoices'}});
  89
  90 warn "processing template $action\n"
  91   if $DEBUG;
  92 do_template($action, {
  93   'session_id' => $session_id,
  94   'action'     => $action, #so the menu knows what tab we're on...
  95   %{$result}
  96 });
  97
  98 #--
  99
 100 sub myaccount { customer_info( 'session_id' => $session_id ); }
 101
 102 sub view_invoice {
 103
 104   $cgi->param('invnum') =~ /^(\d+)$/ or die "illegal invnum";
 105   my $invnum = $1;
 106
 107   invoice( 'session_id' => $session_id,
 108            'invnum'     => $invnum,
 109          );
 110
 111 }
 112
 113 sub customer_order_pkg {
 114   my $init_data = signup_info( 'customer_session_id' => $session_id );
 115   return $init_data if ( $init_data->{'error'} );
 116
 117   my $customer_info = customer_info( 'session_id' => $session_id );
 118   return $customer_info if ( $customer_info->{'error'} );
 119
 120   return {
 121     ( map { $_ => $init_data->{$_} }
 122           qw( part_pkg security_phrase svc_acct_pop ),
 123     ),
 124     %$customer_info,
 125   };
 126 }
 127
 128 sub customer_change_pkg {
 129   my $init_data = signup_info( 'customer_session_id' => $session_id );
 130   return $init_data if ( $init_data->{'error'} );
 131
 132   my $customer_info = customer_info( 'session_id' => $session_id );
 133   return $customer_info if ( $customer_info->{'error'} );
 134
 135   return {
 136     ( map { $_ => $init_data->{$_} }
 137           qw( part_pkg security_phrase svc_acct_pop ),
 138     ),
 139     ( map { $_ => $cgi->param($_) }
 140         qw( pkgnum pkg )
 141     ),
 142     %$customer_info,
 143   };
 144 }
 145
 146 sub process_order_pkg {
 147
 148   my $results = '';
 149
 150   unless ( length($cgi->param('_password')) ) {
 151     my $init_data = signup_info( 'customer_session_id' => $session_id );
 152     $results = { 'error' => $init_data->{msgcat}{empty_password} };
 153     $results = { 'error' => $init_data->{error} } if($init_data->{error});
 154   }
 155   if ( $cgi->param('_password') ne $cgi->param('_password2') ) {
 156     my $init_data = signup_info( 'customer_session_id' => $session_id );
 157     $results = { 'error' => $init_data->{msgcat}{passwords_dont_match} };
 158     $results = { 'error' => $init_data->{error} } if($init_data->{error});
 159     $cgi->param('_password', '');
 160     $cgi->param('_password2', '');
 161   }
 162
 163   $results ||= order_pkg (
 164     'session_id' => $session_id,
 165     map { $_ => $cgi->param($_) }
 166         qw( custnum pkgpart username _password _password2 sec_phrase popnum )
 167   );
 168
 169
 170   if ( $results->{'error'} ) {
 171     $action = 'customer_order_pkg';
 172     return {
 173       $cgi->Vars,
 174       %{customer_order_pkg()},
 175       'error' => '<FONT COLOR="#FF0000">'. $results->{'error'}. '</FONT>',
 176     };
 177   } else {
 178     return $results;
 179   }
 180
 181 }
 182
 183 sub process_change_pkg {
 184
 185   my $results = '';
 186
 187   $results ||= change_pkg (
 188     'session_id' => $session_id,
 189     map { $_ => $cgi->param($_) }
 190         qw( pkgpart pkgnum )
 191   );
 192
 193
 194   if ( $results->{'error'} ) {
 195     $action = 'customer_change_pkg';
 196     return {
 197       $cgi->Vars,
 198       %{customer_change_pkg()},
 199       'error' => '<FONT COLOR="#FF0000">'. $results->{'error'}. '</FONT>',
 200     };
 201   } else {
 202     return $results;
 203   }
 204
 205 }
 206
 207 sub process_order_recharge {
 208
 209   my $results = '';
 210
 211   $results ||= order_recharge (
 212     'session_id' => $session_id,
 213     map { $_ => $cgi->param($_) }
 214         qw( svcnum )
 215   );
 216
 217
 218   if ( $results->{'error'} ) {
 219     $action = 'view_usage';
 220     if ($results->{'error'} eq '_decline') {
 221       $results->{'error'} = "There has been an error processing your account.  Please contact customer support."
 222     }
 223     return {
 224       $cgi->Vars,
 225       %{view_usage()},
 226       'error' => '<FONT COLOR="#FF0000">'. $results->{'error'}. '</FONT>',
 227     };
 228   } else {
 229     return $results;
 230   }
 231
 232 }
 233
 234 sub make_payment {
 235   payment_info( 'session_id' => $session_id );
 236 }
 237
 238 sub payment_results {
 239
 240   use Business::CreditCard;
 241
 242   #we should only do basic checking here for DoS attacks and things
 243   #that couldn't be constructed by the web form...  let process_payment() do
 244   #the rest, it gives better error messages
 245
 246   $cgi->param('amount') =~ /^\s*(\d+(\.\d{2})?)\s*$/
 247     or die "illegal amount"; #!!!
 248   my $amount = $1;
 249
 250   my $payinfo = $cgi->param('payinfo');
 251   $payinfo =~ s/\D//g;
 252   $payinfo =~ /^(\d{13,16})$/
 253     #or $error ||= $init_data->{msgcat}{invalid_card}; #. $self->payinfo;
 254     or die "illegal card"; #!!!
 255   $payinfo = $1;
 256   validate($payinfo)
 257     #or $error ||= $init_data->{msgcat}{invalid_card}; #. $self->payinfo;
 258     or die "invalid card"; #!!!
 259
 260   if ( $cgi->param('card_type') ) {
 261     cardtype($payinfo) eq $cgi->param('card_type')
 262       #or $error ||= $init_data->{msgcat}{not_a}. $cgi->param('CARD_type');
 263       or die "not a ". $cgi->param('card_type');
 264   }
 265
 266   $cgi->param('paycvv') =~ /^\s*(.{0,4})\s*$/ or die "illegal CVV2";
 267   my $paycvv = $1;
 268
 269   $cgi->param('month') =~ /^(\d{2})$/ or die "illegal month";
 270   my $month = $1;
 271   $cgi->param('year') =~ /^(\d{4})$/ or die "illegal year";
 272   my $year = $1;
 273
 274   $cgi->param('payname') =~ /^(.{0,80})$/ or die "illegal payname";
 275   my $payname = $1;
 276
 277   $cgi->param('address1') =~ /^(.{0,80})$/ or die "illegal address1";
 278   my $address1 = $1;
 279
 280   $cgi->param('address2') =~ /^(.{0,80})$/ or die "illegal address2";
 281   my $address2 = $1;
 282
 283   $cgi->param('city') =~ /^(.{0,80})$/ or die "illegal city";
 284   my $city = $1;
 285
 286   $cgi->param('state') =~ /^(.{2})$/ or die "illegal state";
 287   my $state = $1;
 288
 289   $cgi->param('zip') =~ /^(.{0,10})$/ or die "illegal zip";
 290   my $zip = $1;
 291
 292   my $save = 0;
 293   $save = 1 if $cgi->param('save');
 294
 295   my $auto = 0;
 296   $auto = 1 if $cgi->param('auto');
 297
 298   $cgi->param('paybatch') =~ /^([\w\-\.]+)$/ or die "illegal paybatch";
 299   my $paybatch = $1;
 300
 301   process_payment(
 302     'session_id' => $session_id,
 303     'payby'      => 'CARD',
 304     'amount'     => $amount,
 305     'payinfo'    => $payinfo,
 306     'paycvv'     => $paycvv,
 307     'month'      => $month,
 308     'year'       => $year,
 309     'payname'    => $payname,
 310     'address1'   => $address1,
 311     'address2'   => $address2,
 312     'city'       => $city,
 313     'state'      => $state,
 314     'zip'        => $zip,
 315     'save'       => $save,
 316     'auto'       => $auto,
 317     'paybatch'   => $paybatch,
 318   );
 319
 320 }
 321
 322 sub make_ach_payment {
 323   payment_info( 'session_id' => $session_id );
 324 }
 325
 326 sub ach_payment_results {
 327
 328   #we should only do basic checking here for DoS attacks and things
 329   #that couldn't be constructed by the web form...  let process_payment() do
 330   #the rest, it gives better error messages
 331
 332   $cgi->param('amount') =~ /^\s*(\d+(\.\d{2})?)\s*$/
 333     or die "illegal amount"; #!!!
 334   my $amount = $1;
 335
 336   my $payinfo1 = $cgi->param('payinfo1');
 337   $payinfo1=~ /^(\d+)$/
 338     or die "illegal account"; #!!!
 339   $payinfo1= $1;
 340
 341   my $payinfo2 = $cgi->param('payinfo2');
 342   $payinfo2=~ /^(\d+)$/
 343     or die "illegal ABA/routing code"; #!!!
 344   $payinfo2= $1;
 345
 346   $cgi->param('payname') =~ /^(.{0,80})$/ or die "illegal payname";
 347   my $payname = $1;
 348
 349   $cgi->param('paystate') =~ /^(.{0,2})$/ or die "illegal paystate";
 350   my $paystate = $1;
 351
 352   $cgi->param('paytype') =~ /^(.{0,80})$/ or die "illegal paytype";
 353   my $paytype = $1;
 354
 355   $cgi->param('ss') =~ /^(.{0,80})$/ or die "illegal ss";
 356   my $ss = $1;
 357
 358   $cgi->param('stateid') =~ /^(.{0,80})$/ or die "illegal stateid";
 359   my $stateid = $1;
 360
 361   $cgi->param('stateid_state') =~ /^(.{0,2})$/ or die "illegal stateid_state";
 362   my $stateid_state = $1;
 363
 364   my $save = 0;
 365   $save = 1 if $cgi->param('save');
 366
 367   my $auto = 0;
 368   $auto = 1 if $cgi->param('auto');
 369
 370   $cgi->param('paybatch') =~ /^([\w\-\.]+)$/ or die "illegal paybatch";
 371   my $paybatch = $1;
 372
 373   process_payment(
 374     'session_id' => $session_id,
 375     'payby'      => 'CHEK',
 376     'amount'     => $amount,
 377     'payinfo1'   => $payinfo1,
 378     'payinfo2'   => $payinfo2,
 379     'month'      => '12',
 380     'year'       => '2037',
 381     'payname'    => $payname,
 382     'paytype'    => $paytype,
 383     'paystate'   => $paystate,
 384     'ss'         => $ss,
 385     'stateid'    => $stateid,
 386     'stateid_state' => $stateid_state,
 387     'save'       => $save,
 388     'auto'       => $auto,
 389     'paybatch'   => $paybatch,
 390   );
 391
 392 }
 393
 394 sub recharge_prepay {
 395   customer_info( 'session_id' => $session_id );
 396 }
 397
 398 sub recharge_results {
 399
 400   my $prepaid_cardnum = $cgi->param('prepaid_cardnum');
 401   $prepaid_cardnum =~ s/\W//g;
 402   $prepaid_cardnum =~ /^(\w*)$/ or die "illegal prepaid card number";
 403   $prepaid_cardnum = $1;
 404
 405   process_prepay ( 'session_id'     => $session_id,
 406                    'prepaid_cardnum' => $prepaid_cardnum,
 407                  );
 408 }
 409
 410 sub logout {
 411   FS::SelfService::logout( 'session_id' => $session_id );
 412 }
 413
 414 sub provision {
 415   my $result = list_pkgs( 'session_id' => $session_id );
 416   die $result->{'error'} if exists $result->{'error'} && $result->{'error'};
 417   $result;
 418 }
 419
 420 sub provision_svc {
 421
 422   my $result = part_svc_info(
 423     'session_id' => $session_id,
 424     map { $_ => $cgi->param($_) } qw( pkgnum svcpart ),
 425   );
 426   die $result->{'error'} if exists $result->{'error'} && $result->{'error'};
 427
 428   $result->{'svcdb'} =~ /^svc_(.*)$/
 429     #or return { 'error' => 'Unknown svcdb '. $result->{'svcdb'} };
 430     or die 'Unknown svcdb '. $result->{'svcdb'};
 431   $action .= "_$1";
 432
 433   $result;
 434 }
 435
 436 sub process_svc_acct {
 437
 438   my $result = provision_acct (
 439     'session_id' => $session_id,
 440     map { $_ => $cgi->param($_) } qw(
 441       pkgnum svcpart username _password _password2 sec_phrase popnum )
 442   );
 443
 444   if ( exists $result->{'error'} && $result->{'error'} ) {
 445     #warn "$result $result->{'error'}";
 446     $action = 'provision_svc_acct';
 447     return {
 448       $cgi->Vars,
 449       %{ part_svc_info( 'session_id' => $session_id,
 450                         map { $_ => $cgi->param($_) } qw( pkgnum svcpart )
 451                       )
 452       },
 453       'error' => $result->{'error'},
 454     };
 455   } else {
 456     #warn "$result $result->{'error'}";
 457     return $result;
 458   }
 459
 460 }
 461
 462 sub process_svc_external {
 463   provision_external (
 464     'session_id' => $session_id,
 465     map { $_ => $cgi->param($_) } qw( pkgnum svcpart )
 466   );
 467 }
 468
 469 sub delete_svc {
 470   unprovision_svc(
 471     'session_id' => $session_id,
 472     'svcnum'     => $cgi->param('svcnum'),
 473   );
 474 }
 475
 476 sub view_usage {
 477   list_svcs(
 478     'session_id'  => $session_id,
 479     'svcdb'       => 'svc_acct',
 480     'ncancelled'  => 1,
 481   );
 482 }
 483
 484 sub view_usage_details {
 485   list_svc_usage(
 486     'session_id'  => $session_id,
 487     'svcnum'      => $cgi->param('svcnum'),
 488     'beginning'   => $cgi->param('beginning') || '',
 489     'ending'      => $cgi->param('ending') || '',
 490   );
 491 }
 492
 493 sub change_password {
 494   list_svcs(
 495     'session_id' => $session_id,
 496     'svcdb'      => 'svc_acct',
 497   );
 498 };
 499
 500 sub process_change_password {
 501
 502   my $result = myaccount_passwd(
 503     'session_id'    => $session_id,
 504     map { $_ => $cgi->param($_) } qw( svcnum new_password new_password2 )
 505   );
 506
 507   if ( exists $result->{'error'} && $result->{'error'} ) {
 508
 509     $action = 'change_password';
 510     return {
 511       $cgi->Vars,
 512       %{ list_svcs( 'session_id' => $session_id,
 513                     'svcdb'      => 'svc_acct',
 514                   )
 515        },
 516       #'svcnum' => $cgi->param('svcnum'),
 517       'error'  => $result->{'error'}
 518     };
 519
 520  } else {
 521
 522    return $result;
 523
 524  }
 525
 526 }
 527
 528 #--
 529
 530 sub do_template {
 531   my $name = shift;
 532   my $fill_in = shift;
 533
 534   $cgi->delete_all();
 535   $fill_in->{'selfurl'} = $cgi->self_url;
 536   $fill_in->{'cgi'} = \$cgi;
 537
 538   my $template = new Text::Template( TYPE    => 'FILE',
 539                                      SOURCE  => "$template_dir/$name.html",
 540                                      DELIMITERS => [ '<%=', '%>' ],
 541                                      UNTAINT => 1,                    )
 542     or die $Text::Template::ERROR;
 543
 544   print $cgi->header( '-expires' => 'now' ),
 545         $template->fill_in( PACKAGE => 'FS::SelfService::_selfservicecgi',
 546                             HASH    => $fill_in
 547                           );
 548 }
 549
 550 #*FS::SelfService::_selfservicecgi::include = \&Text::Template::fill_in_file;
 551
 552 package FS::SelfService::_selfservicecgi;
 553
 554 #use FS::SelfService qw(regionselector expselect popselector);
 555 use HTML::Entities;
 556 use FS::SelfService qw(popselector);
 557
 558 #false laziness w/agent.cgi
 559 sub include {
 560   my $name = shift;
 561   my $template = new Text::Template( TYPE   => 'FILE',
 562                                      SOURCE => "$main::template_dir/$name.html",
 563                                      DELIMITERS => [ '<%=', '%>' ],
 564                                      UNTAINT => 1,
 565                                    )
 566     or die $Text::Template::ERROR;
 567
 568   $template->fill_in( PACKAGE => 'FS::SelfService::_selfservicecgi',
 569                       #HASH    => $fill_in
 570                     );
 571
 572 }
 573