FS/bin/freeside-selfservice-server

   1 #!/usr/bin/perl -w
   2 #
   3 # freeside-selfservice-server
   4
   5 # alas, much false laziness with freeside-queued and fs_signup_server.  at
   6 # least it is slated to replace fs_{signup,passwd,mailadmin}_server
   7 # should probably generalize the version in here, or better yet use
   8 # Proc::Daemon or somesuch
   9
  10 use strict;
  11 use vars qw( $Debug %kids $kids $max_kids $shutdown $log_file $ssh_pid );
  12 use subs qw( lock_write unlock_write );
  13 use Fcntl qw(:flock);
  14 use POSIX qw(:sys_wait_h setsid);
  15 use IO::Handle;
  16 use IO::Select;
  17 use IO::File;
  18 use Storable qw(nstore_fd fd_retrieve);
  19 use Net::SSH qw(sshopen2);
  20 use FS::UID qw(adminsuidsetup forksuidsetup);
  21 use FS::ClientAPI;
  22
  23 use FS::Conf;
  24 use FS::cust_bill;
  25 use FS::cust_pkg;
  26
  27 $Debug = 2; # >= 2 will log packet contents, including potentially compromising
  28             # information
  29
  30 $shutdown = 0;
  31 $max_kids = '10'; #?
  32 $kids = 0;
  33
  34 my $user = shift or die &usage;
  35 my $machine = shift or die &usage;
  36 my $tag = scalar(@ARGV) ? shift : '';
  37 my $pid_file = "/var/run/freeside-selfservice-server.$user.pid";
  38 #my $pid_file = "/var/run/freeside-selfservice-server.$user.pid"; $FS::UID::datasrc not posible, but should include machine name at least, hmm
  39
  40 my $lock_file = "/usr/local/etc/freeside/selfservice.$machine.writelock";
  41 open(LOCKFILE,">$lock_file") or die "can't open $lock_file: $!";
  42
  43 &init($user);
  44
  45 my $conf = new FS::Conf;
  46
  47 my $clientd = "/usr/local/sbin/freeside-selfservice-clientd"; #better name?
  48
  49 my $warnkids=0;
  50 while (1) {
  51   my($writer,$reader,$error) = (new IO::Handle, new IO::Handle, new IO::Handle);
  52   warn "connecting to $machine\n" if $Debug;
  53
  54   $ssh_pid = sshopen2($machine,$reader,$writer,$clientd,$tag);
  55
  56 #  nstore_fd(\*writer, {'hi'=>'there'});
  57
  58   warn "entering main loop\n" if $Debug;
  59   my $undisp = 0;
  60   my $s = IO::Select->new( $reader );
  61   while (1) {
  62
  63     &reap_kids;
  64
  65     warn "waiting for packet from client\n" if $Debug && !$undisp;
  66     $undisp = 1;
  67     my @handles = $s->can_read(5);
  68     unless ( @handles ) {
  69       &shutdown if $shutdown;
  70       next;
  71     }
  72
  73     $undisp = 0;
  74
  75     warn "receiving packet from client\n" if $Debug;
  76
  77     my $packet = eval { fd_retrieve($reader); };
  78     if ( $@ ) {
  79       warn "Storable error receiving packet from client".
  80            " (assuming lost connection): $@\n"
  81         if $Debug;
  82       last;
  83     }
  84     warn "packet received\n".
  85          join('', map { " $_=>$packet->{$_}\n" } keys %$packet )
  86       if $Debug > 1;
  87
  88     #prevent runaway forking
  89     my $warnkids = 0;
  90     while ( $kids >= $max_kids ) {
  91       warn "WARNING: maximum $kids children reached\n" unless $warnkids++;
  92       &reap_kids;
  93       sleep 1;
  94     }
  95
  96     warn "forking child\n" if $Debug;
  97     defined( my $pid = fork ) or die "can't fork: $!";
  98     if ( $pid ) {
  99       $kids++;
 100       $kids{$pid} = 1;
 101       warn "child $pid spawned\n" if $Debug;
 102     } else { #kid time
 103
 104       #get new db handle
 105       $FS::UID::dbh->{InactiveDestroy} = 1;
 106       forksuidsetup($user);
 107
 108       my $type = $packet->{_packet};
 109       warn "calling $type handler\n" if $Debug;
 110       my $rv = eval { FS::ClientAPI->dispatch($type, $packet); };
 111       if ( $@ ) {
 112         warn my $error = "WARNING: error dispatching $type: $@";
 113         $rv = { _error => $error };
 114       }
 115       $rv->{_token} = $packet->{_token}; #identifier
 116
 117       warn "sending response\n" if $Debug;
 118       lock_write;
 119       nstore_fd($rv, $writer) or die "FATAL: can't send response: $!";
 120       $writer->flush or die "FATAL: can't flush: $!";
 121       unlock_write;
 122
 123       warn "child exiting\n" if $Debug;
 124       exit; #end-of-kid
 125     }
 126
 127   }
 128
 129   warn "connection lost, reconnecting\n" if $Debug;
 130   sleep 3;
 131
 132 }
 133
 134 ###
 135 # utility subroutines
 136 ###
 137
 138 sub reap_kids {
 139   #warn "reaping kids\n";
 140   foreach my $pid ( keys %kids ) {
 141     my $kid = waitpid($pid, WNOHANG);
 142     if ( $kid > 0 ) {
 143       $kids--;
 144       delete $kids{$kid};
 145     }
 146   }
 147   #warn "done reaping\n";
 148 }
 149
 150 sub init {
 151   my $user = shift;
 152
 153   chdir "/" or die "Can't chdir to /: $!";
 154   open STDIN, '/dev/null' or die "Can't read /dev/null: $!";
 155   defined(my $pid = fork) or die "Can't fork: $!";
 156   if ( $pid ) {
 157     print "freeside-selfservice-server to $machine started with pid $pid\n"; #logging to $log_file
 158     exit unless $pid_file;
 159     my $pidfh = new IO::File ">$pid_file" or exit;
 160     print $pidfh "$pid\n";
 161     exit;
 162   }
 163
 164 #  sub REAPER { my $pid = wait; $SIG{CHLD} = \&REAPER; $kids--; }
 165 #  #sub REAPER { my $pid = wait; $kids--; $SIG{CHLD} = \&REAPER; }
 166 #  $SIG{CHLD} =  \&REAPER;
 167
 168   $shutdown = 0;
 169   $SIG{HUP} = sub { warn "SIGHUP received; shutting down\n"; $shutdown++; };
 170   $SIG{INT} = sub { warn "SIGINT received; shutting down\n"; $shutdown++; };
 171   $SIG{TERM} = sub { warn "SIGTERM received; shutting down\n"; $shutdown++; };
 172   $SIG{QUIT} = sub { warn "SIGQUIT received; shutting down\n"; $shutdown++; };
 173   $SIG{PIPE} = sub { warn "SIGPIPE received; shutting down\n"; $shutdown++; };
 174
 175   #false laziness w/freeside-queued
 176   my $freeside_gid = scalar(getgrnam('freeside'))
 177     or die "can't setgid to freeside group\n";
 178   $) = $freeside_gid;
 179   $( = $freeside_gid;
 180   #if freebsd can't setuid(), presumably it can't setgid() either.  grr fleabsd
 181   ($(,$)) = ($),$();
 182   $) = $freeside_gid;
 183
 184   $> = $FS::UID::freeside_uid;
 185   $< = $FS::UID::freeside_uid;
 186   #freebsd is sofa king broken, won't setuid()
 187   ($<,$>) = ($>,$<);
 188   $> = $FS::UID::freeside_uid;
 189   #eslaf
 190
 191   $ENV{HOME} = (getpwuid($>))[7]; #for ssh
 192   adminsuidsetup $user;
 193
 194   #$log_file = "/usr/local/etc/freeside/selfservice.". $FS::UID::datasrc; #MACHINE NAME
 195   $log_file = "/usr/local/etc/freeside/selfservice.$machine.log";
 196
 197   open STDOUT, '>/dev/null'
 198                             or die "Can't write to /dev/null: $!";
 199   setsid                  or die "Can't start a new session: $!";
 200   open STDERR, '>&STDOUT' or die "Can't dup stdout: $!";
 201
 202   $SIG{__DIE__} = \&_die;
 203   $SIG{__WARN__} = \&_logmsg;
 204
 205   warn "freeside-selfservice-server starting\n";
 206
 207 }
 208
 209 sub shutdown {
 210   my $wait = 12; #wait up to 1 minute
 211   while ( $kids > 0 && $wait-- ) {
 212     warn "waiting for $kids children to terminate";
 213     sleep 5;
 214   }
 215   warn "abandoning $kids children" if $kids;
 216   kill 'TERM', $ssh_pid if $ssh_pid;
 217   die "exiting";
 218 }
 219
 220 sub _die {
 221   my $msg = shift;
 222   unlink $pid_file if -e $pid_file;
 223   _logmsg($msg);
 224 }
 225
 226 sub _logmsg {
 227   chomp( my $msg = shift );
 228   _do_logmsg( "[server] [". scalar(localtime). "] [$$] $msg\n" );
 229 }
 230
 231 sub _do_logmsg {
 232   chomp( my $msg = shift );
 233   my $log = new IO::File ">>$log_file";
 234   flock($log, LOCK_EX);
 235   seek($log, 0, 2);
 236   print $log "$msg\n";
 237   flock($log, LOCK_UN);
 238   close $log;
 239 }
 240
 241 sub lock_write {
 242   #broken on freebsd?
 243   #flock($writer, LOCK_EX) or die "FATAL: can't lock write stream: $!";
 244
 245   flock(LOCKFILE, LOCK_EX) or die "FATAL: can't lock $lock_file: $!";
 246
 247 }
 248
 249 sub unlock_write {
 250   #broken on freebsd?
 251   #flock($writer, LOCK_UN) or die "WARNING: can't release write lock: $!";
 252
 253   flock(LOCKFILE, LOCK_UN) or die "FATAL: can't unlock $lock_file: $!";
 254
 255 }
 256
 257 sub usage {
 258   die "Usage:\n\n  freeside-selfservice-server user machine\n";
 259 }
 260