FS/bin/freeside-selfservice-server

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use vars qw( $FREESIDE_LOG $FREESIDE_LOCK );
   5 use vars qw( $Debug %kids $kids $max_kids $ssh_pid %old_ssh_pid $keepalives );
   6 use subs qw( lock_write unlock_write myshutdown usage );
   7 use Fcntl qw(:flock);
   8 use POSIX qw(:sys_wait_h);
   9 use IO::Handle;
  10 use IO::Select;
  11 use IO::File;
  12 use Storable 2.09 qw(nstore_fd fd_retrieve);
  13 use Net::SSH qw(sshopen2);
  14 use FS::Daemon qw(daemonize1 drop_root logfile daemonize2 sigint sigterm);
  15 use FS::UID qw(adminsuidsetup forksuidsetup);
  16 use FS::ClientAPI qw( load_clientapi_modules );
  17 use FS::ClientAPI_SessionCache;
  18 use FS::Record qw( qsearch qsearchs );
  19
  20 use FS::Conf;
  21 use FS::cust_svc;
  22 use FS::agent;
  23
  24 $FREESIDE_LOG = "%%%FREESIDE_LOG%%%";
  25 $FREESIDE_LOCK = "%%%FREESIDE_LOCK%%%";
  26
  27 $Debug = 1; # 2 will turn on more logging
  28             # 3 will log packet contents, including passwords
  29
  30 $max_kids = '10'; #?
  31 $keepalives = 0; #let clientd turn it on, so we don't barf on old ones
  32 $kids = 0;
  33
  34 my $user = shift or die &usage;
  35 my $machine = shift or die &usage;
  36 my $tag = scalar(@ARGV) ? shift : '';
  37
  38 my $lock_file = "$FREESIDE_LOCK/selfservice.$machine.writelock";
  39
  40 # to keep pid files unique w/multi machines (and installs!)
  41 # $FS::UID::datasrc not posible
  42 daemonize1("freeside-selfservice-server","$user.$machine");
  43
  44 #false laziness w/Daemon::drop_root
  45 my $freeside_gid = scalar(getgrnam('freeside'))
  46   or die "can't find freeside group\n";
  47
  48 open(LOCKFILE,">$lock_file") or die "can't open $lock_file: $!";
  49 chown $FS::UID::freeside_uid, $freeside_gid, $lock_file;
  50
  51 drop_root();
  52
  53 $ENV{HOME} = (getpwuid($>))[7]; #for ssh
  54
  55 load_clientapi_modules;
  56
  57 adminsuidsetup $user;
  58
  59 #logfile("/usr/local/etc/freeside/selfservice.". $FS::UID::datasrc); #MACHINE
  60 logfile("$FREESIDE_LOG/selfservice.$machine.log");
  61
  62 daemonize2();
  63
  64 my $conf = new FS::Conf;
  65 if ( $conf->exists('selfservice-ignore_quantity') ) {
  66   $FS::cust_svc::ignore_quantity = 1;
  67   $FS::cust_svc::ignore_quantity = 1; #now it is used twice.
  68 }
  69
  70 #clear the signup info cache so an "/etc/init.d/freeside restart" will pick
  71 #up new info... (better as a callback in Signup.pm?)
  72 my $cache = new FS::ClientAPI_SessionCache( {
  73   'namespace' => 'FS::ClientAPI::Signup',
  74 } );
  75 $cache->remove('signup_info_cache');
  76
  77 #and also clear the selfservice skin info cache, for the same reason
  78 my $ss_cache = new FS::ClientAPI_SessionCache( {
  79   'namespace' => 'FS::ClientAPI::MyAccount',
  80 } );
  81 $ss_cache->remove($_)
  82   foreach grep /^skin_info_cache_agent/, $ss_cache->get_keys();
  83
  84 my $clientd = "/usr/local/sbin/freeside-selfservice-clientd"; #better name?
  85
  86 my $warnkids=0;
  87 while (1) {
  88   my($writer,$reader,$error) = (new IO::Handle, new IO::Handle, new IO::Handle);
  89   warn "connecting to $machine\n" if $Debug;
  90
  91   $ssh_pid = sshopen2($machine,$reader,$writer,$clientd,$tag);
  92
  93 #  nstore_fd(\*writer, {'hi'=>'there'});
  94
  95   warn "entering main loop\n" if $Debug;
  96   my $undisp = 0;
  97   my $keepalive_count = 0;
  98   my $s = IO::Select->new( $reader );
  99   while (1) {
 100
 101     &reap_kids;
 102
 103     warn "waiting for packet from client\n" if $Debug && !$undisp;
 104     $undisp = 1;
 105     my @handles = $s->can_read(5);
 106     unless ( @handles ) {
 107       myshutdown() if sigint() || sigterm();
 108       if ( $keepalives && $keepalive_count++ > 10 ) {
 109         $keepalive_count = 0;
 110         lock_write;
 111
 112         nstore_fd( { _token => '_keepalive' }, $writer );
 113
 114 #commenting izoom stuff out until we can move it to a branch (or just remove)
 115 #        foreach my $agent ( qsearch( 'agent', { disabled => '' } ) ) {
 116 #          my $config = qsearchs( 'conf', { name  => 'selfservice-bulk_ftp_dir',
 117 #                                           agentnum => $agent->agentnum,
 118 #                               } )
 119 #            or next;
 120 #
 121 #          my $session =
 122 #            FS::ClientAPI->dispatch( 'Agent/agent_login',
 123 #                                     { username => $agent->username,
 124 #                                       password => $agent->_password,
 125 #                                     }
 126 #            );
 127 #
 128 #          nstore_fd( { _token     => '_ftp_scan',
 129 #                       dir        => $config->value,
 130 #                       session_id => $session->{session_id},
 131 #                     },
 132 #                     $writer
 133 #          );
 134 #        }
 135
 136         unlock_write;
 137       }
 138       next;
 139     }
 140
 141     $undisp = 0;
 142
 143     warn "receiving packet from client\n" if $Debug;
 144
 145     my $packet = eval { fd_retrieve($reader); };
 146     if ( $@ ) {
 147       warn "Storable error receiving packet from client".
 148            " (assuming lost connection): $@\n"
 149         if $Debug;
 150       if ( $ssh_pid ) {
 151         warn "sending TERM signal to ssh process $ssh_pid\n" if $Debug;
 152         kill 'TERM', $ssh_pid;
 153         $old_ssh_pid{$ssh_pid} = 1;
 154         $ssh_pid = 0;
 155       }
 156       last;
 157     }
 158     warn "packet received\n".
 159          join('', map { " $_=>$packet->{$_}\n" } keys %$packet )
 160       if $Debug > 2;
 161
 162     if ( $packet->{_packet} eq '_enable_keepalive' ) {
 163       warn "enabling keep alives\n" if $Debug;
 164       $keepalives=1;
 165       next;
 166     }
 167
 168     #prevent runaway forking
 169     my $warnkids = 0;
 170     while ( $kids >= $max_kids ) {
 171       warn "WARNING: maximum $kids children reached\n" unless $warnkids++;
 172       &reap_kids;
 173       sleep 1;
 174     }
 175
 176     warn "forking child\n" if $Debug;
 177     defined( my $pid = fork ) or die "can't fork: $!";
 178     if ( $pid ) {
 179       $kids++;
 180       $kids{$pid} = 1;
 181       warn "child $pid spawned\n" if $Debug;
 182     } else { #kid time
 183
 184       ##get new db handle
 185       $FS::UID::dbh->{InactiveDestroy} = 1;
 186       forksuidsetup($user);
 187
 188       #get db handle
 189       #adminsuidsetup($user);
 190
 191       my $type = $packet->{_packet};
 192       warn "calling $type handler\n" if $Debug;
 193       my $rv = eval { FS::ClientAPI->dispatch($type, $packet); };
 194       if ( $@ ) {
 195         warn my $error = "WARNING: error dispatching $type: $@";
 196         $rv = { _error => $error };
 197       }
 198       $rv->{_token} = $packet->{_token}; #identifier
 199
 200       open(LOCKFILE,">$lock_file") or die "can't open $lock_file: $!";
 201       lock_write;
 202       warn "sending response\n" if $Debug;
 203       nstore_fd($rv, $writer) or die "FATAL: can't send response: $!";
 204       $writer->flush or die "FATAL: can't flush: $!";
 205       unlock_write;
 206
 207       warn "child exiting\n" if $Debug;
 208       exit; #end-of-kid
 209     }
 210
 211   }
 212
 213   myshutdown if sigint() || sigterm();
 214   warn "connection lost, reconnecting\n" if $Debug;
 215   sleep 3;
 216
 217 }
 218
 219 ###
 220 # utility subroutines
 221 ###
 222
 223 sub reap_kids {
 224   #warn "reaping kids\n";
 225   foreach my $pid ( keys %kids ) {
 226     my $kid = waitpid($pid, WNOHANG);
 227     if ( $kid > 0 ) {
 228       $kids--;
 229       delete $kids{$kid};
 230     }
 231   }
 232
 233   foreach my $pid ( keys %old_ssh_pid ) {
 234     waitpid($pid, WNOHANG) and delete $old_ssh_pid{$pid};
 235   }
 236   #warn "done reaping\n";
 237 }
 238
 239 sub myshutdown {
 240   &reap_kids;
 241   my $wait = 12; #wait up to 1 minute
 242   while ( $kids > 0 && $wait-- ) {
 243     warn "waiting for $kids children to terminate";
 244     sleep 5;
 245     &reap_kids;
 246   }
 247   warn "abandoning $kids children" if $kids;
 248   kill 'TERM', $ssh_pid if $ssh_pid;
 249   die "exiting";
 250 }
 251
 252 sub lock_write {
 253   warn "locking $lock_file mutex for write to write stream\n" if $Debug > 1;
 254
 255   #broken on freebsd?
 256   #flock($writer, LOCK_EX) or die "FATAL: can't lock write stream: $!";
 257
 258   flock(LOCKFILE, LOCK_EX) or die "FATAL: can't lock $lock_file: $!";
 259
 260 }
 261
 262 sub unlock_write {
 263   warn "unlocking $lock_file mutex\n" if $Debug > 1;
 264
 265   #broken on freebsd?
 266   #flock($writer, LOCK_UN) or die "WARNING: can't release write lock: $!";
 267
 268   flock(LOCKFILE, LOCK_UN) or die "FATAL: can't unlock $lock_file: $!";
 269
 270 }
 271
 272 sub usage {
 273   die "Usage:\n\n  freeside-selfservice-server user machine\n";
 274 }
 275