FS/bin/freeside-selfservice-server

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use vars qw( $FREESIDE_LOG $FREESIDE_LOCK );
   5 use vars qw( $Debug %kids $kids $max_kids $ssh_pid %old_ssh_pid $keepalives );
   6 use subs qw( lock_write unlock_write myshutdown usage );
   7 use Fcntl qw(:flock);
   8 use POSIX qw(:sys_wait_h);
   9 use IO::Handle;
  10 use IO::Select;
  11 use IO::File;
  12 use Storable 2.09 qw(nstore_fd fd_retrieve);
  13 use Net::SSH qw(sshopen2);
  14 use FS::Daemon qw(daemonize1 drop_root logfile daemonize2 sigint sigterm);
  15 use FS::UID qw(adminsuidsetup forksuidsetup);
  16 use FS::ClientAPI qw( load_clientapi_modules );
  17 use FS::ClientAPI_SessionCache;
  18 use FS::Record qw( qsearch qsearchs );
  19
  20 use FS::Conf;
  21 use FS::cust_svc;
  22 use FS::agent;
  23
  24 $FREESIDE_LOG = "%%%FREESIDE_LOG%%%";
  25 $FREESIDE_LOCK = "%%%FREESIDE_LOCK%%%";
  26
  27 $Debug = 1; # 2 will turn on more logging
  28             # 3 will log packet contents, including passwords
  29
  30 $max_kids = '10'; #?
  31 $keepalives = 0; #let clientd turn it on, so we don't barf on old ones
  32 $kids = 0;
  33
  34 my $user = shift or die &usage;
  35 my $machine = shift or die &usage;
  36 my $tag = scalar(@ARGV) ? shift : '';
  37
  38 my $lock_file = "$FREESIDE_LOCK/selfservice.$machine.writelock";
  39
  40 # to keep pid files unique w/multi machines (and installs!)
  41 # $FS::UID::datasrc not posible
  42 daemonize1("freeside-selfservice-server","$user.$machine");
  43
  44 #false laziness w/Daemon::drop_root
  45 my $freeside_gid = scalar(getgrnam('freeside'))
  46   or die "can't find freeside group\n";
  47
  48 open(LOCKFILE,">$lock_file") or die "can't open $lock_file: $!";
  49 chown $FS::UID::freeside_uid, $freeside_gid, $lock_file;
  50
  51 drop_root();
  52
  53 $ENV{HOME} = (getpwuid($>))[7]; #for ssh
  54
  55 load_clientapi_modules;
  56
  57 adminsuidsetup $user;
  58
  59 #logfile("/usr/local/etc/freeside/selfservice.". $FS::UID::datasrc); #MACHINE
  60 logfile("$FREESIDE_LOG/selfservice.$machine.log");
  61
  62 daemonize2();
  63
  64 my $conf = new FS::Conf;
  65 if ( $conf->exists('selfservice-ignore_quantity') ) {
  66   $FS::cust_svc::ignore_quantity = 1;
  67   $FS::cust_svc::ignore_quantity = 1; #now it is used twice.
  68 }
  69
  70 #clear the signup info cache so an "/etc/init.d/freeside restart" will pick
  71 #up new info... (better as a callback in Signup.pm?)
  72 my $cache = new FS::ClientAPI_SessionCache( {
  73   'namespace' => 'FS::ClientAPI::Signup',
  74 } );
  75 $cache->remove('signup_info_cache');
  76
  77 #and also clear the selfservice skin info cache, for the same reason
  78 my $ss_cache = new FS::ClientAPI_SessionCache( {
  79   'namespace' => 'FS::ClientAPI::MyAccount',
  80 } );
  81 $ss_cache->remove($_)
  82   foreach grep /^skin_info_cache_agent/, $ss_cache->get_keys();
  83
  84 my $clientd = "/usr/local/sbin/freeside-selfservice-clientd"; #better name?
  85
  86 my $warnkids=0;
  87 while (1) {
  88   my($writer,$reader,$error) = (new IO::Handle, new IO::Handle, new IO::Handle);
  89   warn "connecting to $machine\n" if $Debug;
  90
  91   $ssh_pid = sshopen2($machine,$reader,$writer,$clientd,$tag);
  92
  93 #  nstore_fd(\*writer, {'hi'=>'there'});
  94
  95   warn "entering main loop\n" if $Debug;
  96   my $undisp = 0;
  97   my $keepalive_count = 0;
  98   my $s = IO::Select->new( $reader );
  99   while (1) {
 100
 101     &reap_kids;
 102
 103     warn "waiting for packet from client\n" if $Debug && !$undisp;
 104     $undisp = 1;
 105     my @handles = $s->can_read(5);
 106     unless ( @handles ) {
 107       myshutdown() if sigint() || sigterm();
 108       if ( $keepalives && $keepalive_count++ > 10 ) {
 109         $keepalive_count = 0;
 110         lock_write;
 111         nstore_fd( { _token => '_keepalive' }, $writer );
 112         unlock_write;
 113       }
 114       next;
 115     }
 116
 117     $undisp = 0;
 118
 119     warn "receiving packet from client\n" if $Debug;
 120
 121     my $packet = eval { fd_retrieve($reader); };
 122     if ( $@ ) {
 123       warn "Storable error receiving packet from client".
 124            " (assuming lost connection): $@\n"
 125         if $Debug;
 126       if ( $ssh_pid ) {
 127         warn "sending TERM signal to ssh process $ssh_pid\n" if $Debug;
 128         kill 'TERM', $ssh_pid;
 129         $old_ssh_pid{$ssh_pid} = 1;
 130         $ssh_pid = 0;
 131       }
 132       last;
 133     }
 134     warn "packet received\n".
 135          join('', map { " $_=>$packet->{$_}\n" } keys %$packet )
 136       if $Debug > 2;
 137
 138     if ( $packet->{_packet} eq '_enable_keepalive' ) {
 139       warn "enabling keep alives\n" if $Debug;
 140       $keepalives=1;
 141       next;
 142     }
 143
 144     #prevent runaway forking
 145     my $warnkids = 0;
 146     while ( $kids >= $max_kids ) {
 147       warn "WARNING: maximum $kids children reached\n" unless $warnkids++;
 148       &reap_kids;
 149       sleep 1;
 150     }
 151
 152     warn "forking child\n" if $Debug;
 153     defined( my $pid = fork ) or die "can't fork: $!";
 154     if ( $pid ) {
 155       $kids++;
 156       $kids{$pid} = 1;
 157       warn "child $pid spawned\n" if $Debug;
 158     } else { #kid time
 159
 160       ##get new db handle
 161       $FS::UID::dbh->{InactiveDestroy} = 1;
 162       forksuidsetup($user);
 163
 164       #get db handle
 165       #adminsuidsetup($user);
 166
 167       my $type = $packet->{_packet};
 168       warn "calling $type handler\n" if $Debug;
 169       my $rv = eval { FS::ClientAPI->dispatch($type, $packet); };
 170       if ( $@ ) {
 171         warn my $error = "WARNING: error dispatching $type: $@";
 172         $rv = { _error => $error };
 173       }
 174       $rv->{_token} = $packet->{_token}; #identifier
 175
 176       open(LOCKFILE,">$lock_file") or die "can't open $lock_file: $!";
 177       lock_write;
 178       warn "sending response\n" if $Debug;
 179       nstore_fd($rv, $writer) or die "FATAL: can't send response: $!";
 180       $writer->flush or die "FATAL: can't flush: $!";
 181       unlock_write;
 182
 183       warn "child exiting\n" if $Debug;
 184       exit; #end-of-kid
 185     }
 186
 187   }
 188
 189   myshutdown if sigint() || sigterm();
 190   warn "connection lost, reconnecting\n" if $Debug;
 191   sleep 3;
 192
 193 }
 194
 195 ###
 196 # utility subroutines
 197 ###
 198
 199 sub reap_kids {
 200   #warn "reaping kids\n";
 201   foreach my $pid ( keys %kids ) {
 202     my $kid = waitpid($pid, WNOHANG);
 203     if ( $kid > 0 ) {
 204       $kids--;
 205       delete $kids{$kid};
 206     }
 207   }
 208
 209   foreach my $pid ( keys %old_ssh_pid ) {
 210     waitpid($pid, WNOHANG) and delete $old_ssh_pid{$pid};
 211   }
 212   #warn "done reaping\n";
 213 }
 214
 215 sub myshutdown {
 216   &reap_kids;
 217   my $wait = 12; #wait up to 1 minute
 218   while ( $kids > 0 && $wait-- ) {
 219     warn "waiting for $kids children to terminate";
 220     sleep 5;
 221     &reap_kids;
 222   }
 223   warn "abandoning $kids children" if $kids;
 224   kill 'TERM', $ssh_pid if $ssh_pid;
 225   die "exiting";
 226 }
 227
 228 sub lock_write {
 229   warn "locking $lock_file mutex for write to write stream\n" if $Debug > 1;
 230
 231   #broken on freebsd?
 232   #flock($writer, LOCK_EX) or die "FATAL: can't lock write stream: $!";
 233
 234   flock(LOCKFILE, LOCK_EX) or die "FATAL: can't lock $lock_file: $!";
 235
 236 }
 237
 238 sub unlock_write {
 239   warn "unlocking $lock_file mutex\n" if $Debug > 1;
 240
 241   #broken on freebsd?
 242   #flock($writer, LOCK_UN) or die "WARNING: can't release write lock: $!";
 243
 244   flock(LOCKFILE, LOCK_UN) or die "FATAL: can't unlock $lock_file: $!";
 245
 246 }
 247
 248 sub usage {
 249   die "Usage:\n\n  freeside-selfservice-server user machine\n";
 250 }
 251