FS/bin/freeside-selfservice-server

   1 #!/usr/bin/perl -w
   2 #
   3 # freeside-selfservice-server
   4
   5 # alas, much false laziness with freeside-queued and fs_signup_server.  at
   6 # least it is slated to replace fs_{signup,passwd,mailadmin}_server
   7 # should probably generalize the version in here, or better yet use
   8 # Proc::Daemon or somesuch
   9
  10 use strict;
  11 use vars qw( $Debug %kids $kids $max_kids $shutdown $log_file $ssh_pid );
  12 use subs qw( lock_write unlock_write );
  13 use Fcntl qw(:flock);
  14 use POSIX qw(:sys_wait_h setsid);
  15 use IO::Handle;
  16 use IO::Select;
  17 use IO::File;
  18 use Storable qw(nstore_fd fd_retrieve);
  19 use Net::SSH qw(sshopen2);
  20 use FS::UID qw(adminsuidsetup forksuidsetup);
  21 use FS::ClientAPI;
  22
  23 use FS::Conf;
  24 use FS::cust_bill;
  25 use FS::cust_pkg;
  26
  27 $Debug = 1; # >= 2 will log packet contents, including potentially compromising
  28             # information
  29
  30 $shutdown = 0;
  31 $max_kids = '10'; #?
  32 $kids = 0;
  33
  34 my $user = shift or die &usage;
  35 my $machine = shift or die &usage;
  36 my $tag = scalar(@ARGV) ? shift : '';
  37
  38 # $FS::UID::datasrc not posible
  39 my $pid_file = "/var/run/freeside-selfservice-server.$user.$machine.pid";
  40
  41 my $lock_file = "/usr/local/etc/freeside/selfservice.$machine.writelock";
  42 open(LOCKFILE,">$lock_file") or die "can't open $lock_file: $!";
  43
  44 &init($user);
  45
  46 my $conf = new FS::Conf;
  47
  48 my $clientd = "/usr/local/sbin/freeside-selfservice-clientd"; #better name?
  49
  50 my $warnkids=0;
  51 while (1) {
  52   my($writer,$reader,$error) = (new IO::Handle, new IO::Handle, new IO::Handle);
  53   warn "connecting to $machine\n" if $Debug;
  54
  55   $ssh_pid = sshopen2($machine,$reader,$writer,$clientd,$tag);
  56
  57 #  nstore_fd(\*writer, {'hi'=>'there'});
  58
  59   warn "entering main loop\n" if $Debug;
  60   my $undisp = 0;
  61   my $s = IO::Select->new( $reader );
  62   while (1) {
  63
  64     &reap_kids;
  65
  66     warn "waiting for packet from client\n" if $Debug && !$undisp;
  67     $undisp = 1;
  68     my @handles = $s->can_read(5);
  69     unless ( @handles ) {
  70       &shutdown if $shutdown;
  71       next;
  72     }
  73
  74     $undisp = 0;
  75
  76     warn "receiving packet from client\n" if $Debug;
  77
  78     my $packet = eval { fd_retrieve($reader); };
  79     if ( $@ ) {
  80       warn "Storable error receiving packet from client".
  81            " (assuming lost connection): $@\n"
  82         if $Debug;
  83       if ( $ssh_pid ) {
  84         warn "sending TERM signal to ssh process $ssh_pid\n" if $Debug;
  85         kill 'TERM', $ssh_pid;
  86         $ssh_pid = 0;
  87       }
  88       last;
  89     }
  90     warn "packet received\n".
  91          join('', map { " $_=>$packet->{$_}\n" } keys %$packet )
  92       if $Debug > 1;
  93
  94     #prevent runaway forking
  95     my $warnkids = 0;
  96     while ( $kids >= $max_kids ) {
  97       warn "WARNING: maximum $kids children reached\n" unless $warnkids++;
  98       &reap_kids;
  99       sleep 1;
 100     }
 101
 102     warn "forking child\n" if $Debug;
 103     defined( my $pid = fork ) or die "can't fork: $!";
 104     if ( $pid ) {
 105       $kids++;
 106       $kids{$pid} = 1;
 107       warn "child $pid spawned\n" if $Debug;
 108     } else { #kid time
 109
 110       #get new db handle
 111       $FS::UID::dbh->{InactiveDestroy} = 1;
 112       forksuidsetup($user);
 113
 114       my $type = $packet->{_packet};
 115       warn "calling $type handler\n" if $Debug;
 116       my $rv = eval { FS::ClientAPI->dispatch($type, $packet); };
 117       if ( $@ ) {
 118         warn my $error = "WARNING: error dispatching $type: $@";
 119         $rv = { _error => $error };
 120       }
 121       $rv->{_token} = $packet->{_token}; #identifier
 122
 123       warn "sending response\n" if $Debug;
 124       lock_write;
 125       nstore_fd($rv, $writer) or die "FATAL: can't send response: $!";
 126       $writer->flush or die "FATAL: can't flush: $!";
 127       unlock_write;
 128
 129       warn "child exiting\n" if $Debug;
 130       exit; #end-of-kid
 131     }
 132
 133   }
 134
 135   warn "connection lost, reconnecting\n" if $Debug;
 136   sleep 3;
 137
 138 }
 139
 140 ###
 141 # utility subroutines
 142 ###
 143
 144 sub reap_kids {
 145   #warn "reaping kids\n";
 146   foreach my $pid ( keys %kids ) {
 147     my $kid = waitpid($pid, WNOHANG);
 148     if ( $kid > 0 ) {
 149       $kids--;
 150       delete $kids{$kid};
 151     }
 152   }
 153   #warn "done reaping\n";
 154 }
 155
 156 sub init {
 157   my $user = shift;
 158
 159   chdir "/" or die "Can't chdir to /: $!";
 160   open STDIN, '/dev/null' or die "Can't read /dev/null: $!";
 161   defined(my $pid = fork) or die "Can't fork: $!";
 162   if ( $pid ) {
 163     print "freeside-selfservice-server to $machine started with pid $pid\n"; #logging to $log_file
 164     exit unless $pid_file;
 165     my $pidfh = new IO::File ">$pid_file" or exit;
 166     print $pidfh "$pid\n";
 167     exit;
 168   }
 169
 170 #  sub REAPER { my $pid = wait; $SIG{CHLD} = \&REAPER; $kids--; }
 171 #  #sub REAPER { my $pid = wait; $kids--; $SIG{CHLD} = \&REAPER; }
 172 #  $SIG{CHLD} =  \&REAPER;
 173
 174   $shutdown = 0;
 175   $SIG{HUP} = sub { warn "SIGHUP received; shutting down\n"; $shutdown++; };
 176   $SIG{INT} = sub { warn "SIGINT received; shutting down\n"; $shutdown++; };
 177   $SIG{TERM} = sub { warn "SIGTERM received; shutting down\n"; $shutdown++; };
 178   $SIG{QUIT} = sub { warn "SIGQUIT received; shutting down\n"; $shutdown++; };
 179   $SIG{PIPE} = sub { warn "SIGPIPE received; shutting down\n"; $shutdown++; };
 180
 181   #false laziness w/freeside-queued
 182   my $freeside_gid = scalar(getgrnam('freeside'))
 183     or die "can't setgid to freeside group\n";
 184   $) = $freeside_gid;
 185   $( = $freeside_gid;
 186   #if freebsd can't setuid(), presumably it can't setgid() either.  grr fleabsd
 187   ($(,$)) = ($),$();
 188   $) = $freeside_gid;
 189
 190   $> = $FS::UID::freeside_uid;
 191   $< = $FS::UID::freeside_uid;
 192   #freebsd is sofa king broken, won't setuid()
 193   ($<,$>) = ($>,$<);
 194   $> = $FS::UID::freeside_uid;
 195   #eslaf
 196
 197   $ENV{HOME} = (getpwuid($>))[7]; #for ssh
 198   adminsuidsetup $user;
 199
 200   #$log_file = "/usr/local/etc/freeside/selfservice.". $FS::UID::datasrc; #MACHINE NAME
 201   $log_file = "/usr/local/etc/freeside/selfservice.$machine.log";
 202
 203   open STDOUT, '>/dev/null'
 204                             or die "Can't write to /dev/null: $!";
 205   setsid                  or die "Can't start a new session: $!";
 206   open STDERR, '>&STDOUT' or die "Can't dup stdout: $!";
 207
 208   $SIG{__DIE__} = \&_die;
 209   $SIG{__WARN__} = \&_logmsg;
 210
 211   warn "freeside-selfservice-server starting\n";
 212
 213 }
 214
 215 sub shutdown {
 216   my $wait = 12; #wait up to 1 minute
 217   while ( $kids > 0 && $wait-- ) {
 218     warn "waiting for $kids children to terminate";
 219     sleep 5;
 220   }
 221   warn "abandoning $kids children" if $kids;
 222   kill 'TERM', $ssh_pid if $ssh_pid;
 223   die "exiting";
 224 }
 225
 226 sub _die {
 227   my $msg = shift;
 228   unlink $pid_file if -e $pid_file;
 229   _logmsg($msg);
 230 }
 231
 232 sub _logmsg {
 233   chomp( my $msg = shift );
 234   _do_logmsg( "[server] [". scalar(localtime). "] [$$] $msg\n" );
 235 }
 236
 237 sub _do_logmsg {
 238   chomp( my $msg = shift );
 239   my $log = new IO::File ">>$log_file";
 240   flock($log, LOCK_EX);
 241   seek($log, 0, 2);
 242   print $log "$msg\n";
 243   flock($log, LOCK_UN);
 244   close $log;
 245 }
 246
 247 sub lock_write {
 248   #broken on freebsd?
 249   #flock($writer, LOCK_EX) or die "FATAL: can't lock write stream: $!";
 250
 251   flock(LOCKFILE, LOCK_EX) or die "FATAL: can't lock $lock_file: $!";
 252
 253 }
 254
 255 sub unlock_write {
 256   #broken on freebsd?
 257   #flock($writer, LOCK_UN) or die "WARNING: can't release write lock: $!";
 258
 259   flock(LOCKFILE, LOCK_UN) or die "FATAL: can't unlock $lock_file: $!";
 260
 261 }
 262
 263 sub usage {
 264   die "Usage:\n\n  freeside-selfservice-server user machine\n";
 265 }
 266