FS/bin/freeside-queued

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use vars qw( $log_file $sigterm $sigint );
   5 use subs qw( _die _logmsg );
   6 use Fcntl qw(:flock);
   7 use POSIX qw(setsid);
   8 use Date::Format;
   9 use IO::File;
  10 use FS::UID qw(adminsuidsetup forksuidsetup driver_name);
  11 use FS::Record qw(qsearchs);
  12 use FS::queue;
  13
  14 # no autoloading just yet
  15 use FS::cust_main;
  16 use FS::svc_acct;
  17 use Net::SSH 0.05;
  18 use FS::part_export;
  19
  20 my $pid_file = '/var/run/freeside-queued.pid';
  21
  22 my $user = shift or die &usage;
  23
  24 &daemonize1;
  25
  26 sub REAPER { my $pid = wait; $SIG{CHLD} = \&REAPER; }
  27 $SIG{CHLD} =  \&REAPER;
  28
  29  $sigterm = 0;
  30  $sigint = 0;
  31 $SIG{INT} = sub { warn "SIGINT received; shutting down\n"; $sigint++; };
  32 $SIG{TERM} = sub { warn "SIGTERM received; shutting down\n"; $sigterm++; };
  33
  34 $> = $FS::UID::freeside_uid unless $>;
  35 $< = $>;
  36 $ENV{HOME} = (getpwuid($>))[7]; #for ssh
  37 adminsuidsetup $user;
  38
  39 $log_file = "/usr/local/etc/freeside/queuelog.". $FS::UID::datasrc;
  40
  41 &daemonize2;
  42
  43 $SIG{__DIE__} = \&_die;
  44 $SIG{__WARN__} = \&_logmsg;
  45
  46 warn "freeside-queued starting\n";
  47
  48 while (1) {
  49
  50   my $job = qsearchs(
  51     'queue',
  52     { 'status' => 'new' },
  53     '',
  54     driver_name =~ /^mysql$/i
  55       ? 'ORDER BY jobnum LIMIT 1 FOR UPDATE'
  56       : 'ORDER BY jobnum FOR UPDATE LIMIT 1'
  57   ) or do {
  58     sleep 5;
  59     next;
  60   };
  61
  62   my %hash = $job->hash;
  63   $hash{'status'} = 'locked';
  64   my $ljob = new FS::queue ( \%hash );
  65   my $error = $ljob->replace($job);
  66   die $error if $error;
  67
  68   my @args = $ljob->args;
  69
  70   # number of children limit?
  71   defined( my $pid = fork ) or do {
  72     warn "WARNING: can't fork: $!\n";
  73     my %hash = $job->hash;
  74     $hash{'status'} = 'failed';
  75     $hash{'statustext'} = "[freeside-queued] can't fork: $!";
  76     my $ljob = new FS::queue ( \%hash );
  77     my $error = $ljob->replace($job);
  78     die $error if $error;
  79   };
  80
  81   unless ( $pid ) { #kid time
  82
  83     #get new db handles
  84     $FS::UID::dbh->{InactiveDestroy} = 1;
  85     $FS::svc_acct::icradius_dbh->{InactiveDestroy} = 1
  86       if $FS::svc_acct::icradius_dbh;
  87     forksuidsetup($user);
  88
  89     my $eval = "&". $ljob->job. '(@args);';
  90     warn "running $eval";
  91     eval $eval; #throw away return value?  suppose so
  92     if ( $@ ) {
  93       warn "job $eval failed";
  94       my %hash = $ljob->hash;
  95       $hash{'status'} = 'failed';
  96       $hash{'statustext'} = $@;
  97       my $fjob = new FS::queue( \%hash );
  98       my $error = $fjob->replace($ljob);
  99       die $error if $error;
 100     } else {
 101       $ljob->delete;
 102     }
 103
 104     exit;
 105     #end-of-kid
 106   }
 107
 108 } continue {
 109   if ( $sigterm ) {
 110     warn "received TERM signal; exiting\n";
 111     exit;
 112   }
 113   if ( $sigint ) {
 114     warn "received INT signal; exiting\n";
 115     exit;
 116   }
 117 }
 118
 119 sub usage {
 120   die "Usage:\n\n  freeside-queued user\n";
 121 }
 122
 123 sub _die {
 124   my $msg = shift;
 125   unlink $pid_file if -e $pid_file;
 126   _logmsg($msg);
 127 }
 128
 129 sub _logmsg {
 130   chomp( my $msg = shift );
 131   my $log = new IO::File ">>$log_file";
 132   flock($log, LOCK_EX);
 133   seek($log, 0, 2);
 134   print $log "[". time2str("%a %b %e %T %Y",time). "] [$$] $msg\n";
 135   flock($log, LOCK_UN);
 136   close $log;
 137 }
 138
 139 sub daemonize1 {
 140
 141   chdir "/" or die "Can't chdir to /: $!";
 142   open STDIN, '/dev/null'   or die "Can't read /dev/null: $!";
 143   defined(my $pid = fork) or die "Can't fork: $!";
 144   if ( $pid ) {
 145     print "freeside-queued started with pid $pid\n"; #logging to $log_file\n";
 146     exit unless $pid_file;
 147     my $pidfh = new IO::File ">$pid_file" or exit;
 148     print $pidfh "$pid\n";
 149     exit;
 150   }
 151   #open STDOUT, '>/dev/null'
 152   #                          or die "Can't write to /dev/null: $!";
 153   #setsid                  or die "Can't start a new session: $!";
 154   #open STDERR, '>&STDOUT' or die "Can't dup stdout: $!";
 155
 156 }
 157
 158 sub daemonize2 {
 159   open STDOUT, '>/dev/null'
 160                             or die "Can't write to /dev/null: $!";
 161   setsid                  or die "Can't start a new session: $!";
 162   open STDERR, '>&STDOUT' or die "Can't dup stdout: $!";
 163 }
 164
 165 =head1 NAME
 166
 167 freeside-queued - Job queue daemon
 168
 169 =head1 SYNOPSIS
 170
 171   freeside-queued user
 172
 173 =head1 DESCRIPTION
 174
 175 Job queue daemon.  Should be running at all times.
 176
 177 user: from the mapsecrets file - see config.html from the base documentation
 178
 179 =head1 VERSION
 180
 181 =head1 BUGS
 182
 183 =head1 SEE ALSO
 184
 185 =cut
 186