FS/bin/freeside-paymentech-upload

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use Getopt::Std;
   5 use Date::Format qw(time2str);
   6 use File::Temp qw(tempdir); #0.19 for ->newdir() interface, not in 5.10.0
   7 use Net::SFTP::Foreign;
   8 use Expect;
   9 use FS::UID qw(adminsuidsetup datasrc);
  10 use FS::Record qw(qsearch qsearchs);
  11 use FS::pay_batch;
  12 use FS::cust_pay_batch;
  13 use FS::Conf;
  14 use FS::Log;
  15
  16 use vars qw( $opt_a $opt_t $opt_v $opt_p );
  17 getopts('avtp:');
  18
  19 #$Net::SFTP::Foreign::debug = -1;
  20
  21 sub log_and_die {
  22   my $message = shift;
  23   my $log = FS::Log->new('freeside-paymentech-upload');
  24   $log->error($message);
  25   die $message;
  26 }
  27
  28 sub usage { "
  29   Usage:
  30     freeside-paymentech-upload [ -v ] [ -t ] user batchnum
  31     freeside-paymentech-upload -a [ -p payby ] [ -v ] [ -t ] user\n
  32 " }
  33
  34 my $user = shift or die &usage;
  35 adminsuidsetup $user;
  36
  37 my $zip_check = `which zip` or log_and_die("can't find zip executable\n");
  38
  39 my @batches;
  40
  41 if($opt_a) {
  42   my %criteria = (status => 'O');
  43   $criteria{'payby'} = uc($opt_p) if $opt_p;
  44   $criteria{'type'} = 'DEBIT' unless FS::pay_batch->can_handle_electronic_refunds('paymentech');
  45   @batches = qsearch('pay_batch', \%criteria);
  46   log_and_die("No open batches found".($opt_p ? " of type '$opt_p'" : '').".\n")
  47     if !@batches;
  48 }
  49 else {
  50   my $batchnum = shift;
  51   log_and_die("batchnum not passed\n".&usage) if !$batchnum;
  52   @batches = qsearchs('pay_batch', { batchnum => $batchnum } );
  53   log_and_die("Can't find payment batch '$batchnum'\n") if !@batches;
  54 }
  55
  56 my $conf = new FS::Conf;
  57 my @batchconf = $conf->config('batchconfig-paymentech');
  58 # BIN, terminalID, merchantID, username, password
  59 my $username = $batchconf[3] or log_and_die("no Paymentech batch username configured\n");
  60 my $password = $batchconf[4] or log_and_die("no Paymentech batch password configured\n");
  61
  62 #my $tmpdir = File::Temp->newdir();
  63 my $tmpdir = tempdir( CLEANUP => 1 ); #DIR=>somewhere?
  64
  65 my @filenames;
  66
  67 foreach my $pay_batch (@batches) {
  68   my $batchnum = $pay_batch->batchnum;
  69   my $filename = sprintf('%06d',$batchnum) . '-' .time2str('%Y%m%d%H%M%S', time);
  70   print STDERR "Exporting batch $batchnum to $filename...\n" if $opt_v;
  71   my $text = $pay_batch->export_batch(format => 'paymentech');
  72   unless ($text) {
  73     print STDERR "Batch is empty, resolving..." if $opt_v;
  74     next;
  75   }
  76   $text =~ s!<fileID>FILEID</fileID>!<fileID>$filename</fileID>!
  77     or log_and_die("couldn't find FILEID tag\n");
  78   open OUT, ">$tmpdir/$filename.xml";
  79   print OUT $text;
  80   close OUT;
  81
  82   system('zip', '-P', $password, '-q', '-j',
  83            "$tmpdir/$filename.zip", "$tmpdir/$filename.xml");
  84
  85   log_and_die("failed to create zip file\n") if (! -f "$tmpdir/$filename.zip" );
  86   push @filenames, $filename;
  87 }
  88 log_and_die("All batches empty\n") if !@filenames;
  89
  90 my $host = ($opt_t ? 'orbitalbatchvar.paymentech.net'
  91                    : 'orbitalbatch.paymentech.net');
  92 print STDERR "Connecting to $username\@$host...\n" if $opt_v;
  93
  94 my $sftp;
  95 my $ssh_retry      = 25;   # number of times to try connection, needs to be >= 1
  96 my $ssh_retry_wait = 60*5; # seconds to wait between tries
  97 while ($ssh_retry > 0) {
  98   $sftp = Net::SFTP::Foreign->new( host => $host,
  99                                    user => $username,
 100                                    password => $password,
 101                                    timeout => 300,
 102                                  );
 103   last unless $sftp->error;
 104   $ssh_retry -= 1;
 105   sleep($ssh_retry_wait) if $ssh_retry > 0;
 106 }
 107
 108 log_and_die("failed to connect to '$username\@$host'\n(".$sftp->error.")\n")
 109     if $sftp->error;
 110
 111 foreach my $filename (@filenames) {
 112   $sftp->put("$tmpdir/$filename.zip", "$filename.zip")
 113     or log_and_die("failed to upload file (".$sftp->error.")\n");
 114 }
 115
 116 print STDERR "Finished!\n" if $opt_v;
 117
 118 =head1 NAME
 119
 120 freeside-paymentech-upload - Transmit a payment batch to Chase Paymentech via SFTP.
 121
 122 =head1 SYNOPSIS
 123
 124   freeside-paymentech-upload [ -a [ -p PAYBY ] ] [ -v ] [ -t ] user batchnum
 125
 126 =head1 DESCRIPTION
 127
 128 Command line tool to upload a payment batch to the Chase Paymentech gateway.
 129 The batch will be exported to the Paymentech XML format, packaged in a ZIP
 130 file, and transmitted via SFTP.  Use L<freeside-paymentech-download> to retrieve the
 131 response file.
 132
 133 -a: Send all open batches, instead of specifying a batchnum.
 134
 135 -p PAYBY: With -a, limit to batches of that payment type, e.g. -p CARD.
 136
 137 -v: Be verbose.
 138
 139 -t: Send the transaction to the test server.
 140
 141 user: freeside username
 142
 143 batchnum: pay_batch primary key
 144
 145 =head1 BUGS
 146
 147 Passing the zip password on the command line is slightly risky.
 148
 149 =head1 SEE ALSO
 150
 151 L<FS::pay_batch>
 152
 153 =cut
 154
 155 1;
 156