FS/bin/freeside-cdr-asterisk_sql

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use vars qw( $DEBUG );
   5 use Date::Parse 'str2time';
   6 use Date::Format 'time2str';
   7 use FS::UID qw(adminsuidsetup dbh);
   8 use FS::cdr;
   9 use DBI;
  10 use Getopt::Std;
  11
  12 my %opt;
  13 getopts('e:H:U:P:D:T:', \%opt);
  14 my $user = shift or die &usage;
  15
  16 my $engine = $opt{e} || 'mysql';
  17
  18 my $dsn = "dbi:$engine";
  19 $dsn .= ":database=$opt{D}"; # if $opt{D};
  20 $dsn .= ";host=$opt{H}" if $opt{H};
  21
  22 my $dbi = DBI->connect($dsn, $opt{U}, $opt{P})
  23   or die $DBI::errstr;
  24
  25 adminsuidsetup $user;
  26
  27 my $fsdbh = FS::UID::dbh;
  28
  29 my $table = $opt{T} || 'cdr';
  30
  31 # check for existence of freesidestatus
  32 if ( $engine =~ /^mysql/ ) {
  33   my $status = $dbi->selectall_arrayref("SHOW COLUMNS FROM $table WHERE Field = 'freesidestatus'");
  34   if( ! @$status ) {
  35     print "Adding freesidestatus column...\n";
  36     $dbi->do("ALTER TABLE $table ADD COLUMN freesidestatus varchar(32)")
  37       or die $dbi->errstr;
  38   } else {
  39     print "freesidestatus column present\n";
  40   }
  41 }
  42
  43 my @cols = ( qw(
  44 calldate clid src dst dcontext channel lastapp lastdata duration
  45     billsec disposition amaflags accountcode uniqueid userfield) );
  46 my $sql = 'SELECT '.join(',', @cols). " FROM $table WHERE freesidestatus IS NULL";
  47 my $sth = $dbi->prepare($sql);
  48 $sth->execute;
  49 print "Importing ".$sth->rows." records...\n";
  50
  51 my $cdr_batch = new FS::cdr_batch({
  52     'cdrbatch' => 'sql-import-'. time2str('%Y/%m/%d-%T',time),
  53   });
  54 my $error = $cdr_batch->insert;
  55 die $error if $error;
  56 my $cdrbatchnum = $cdr_batch->cdrbatchnum;
  57 my $imports = 0;
  58 my $updates = 0;
  59
  60 my $row;
  61 while ( $row = $sth->fetchrow_hashref ) {
  62   my $cdr = FS::cdr->new($row);
  63   $cdr->startdate(str2time($cdr->calldate));
  64   $cdr->cdrbatchnum($cdrbatchnum);
  65   my $error = $cdr->insert;
  66   if($error) {
  67     print "failed import: $error\n";
  68   }
  69   else {
  70     $imports++;
  71     if( $dbi->do("UPDATE cdr SET freesidestatus = 'done'
  72         WHERE calldate = ? AND src = ? AND dst = ?",
  73                 undef,
  74                 $row->{'calldate'},
  75                 $row->{'src'},
  76                 $row->{'dst'},
  77
  78       ) ) {
  79         $updates++;
  80     }
  81     else {
  82       print "failed to set status: ".$dbi->errstr."\n";
  83     }
  84   }
  85 }
  86 print "Done.\nImported $imports CDRs, marked $updates CDRs as done.\n";
  87 $dbi->disconnect;
  88
  89 sub usage {
  90   "Usage: \n  freeside-cdr-asterisk_sql\n\t-e mysql|Pg|... [ -H host ]\n\t-D database\n\t-U user\n\t-P password\n\tfreesideuser\n";
  91 }
  92
  93 =head1 NAME
  94
  95 freeside-cdr-asterisk_sql - Import CDRs from an Asterisk SQL database
  96
  97 =head1 SYNOPSIS
  98
  99   freeside-cdr-asterisk_sql -e mysql|Pg|... [ -H host ] -D database -U user -P password freesideuser
 100
 101 =head1 DESCRIPTION
 102
 103 Imports CDR records from an Asterisk SQL database.
 104
 105 =cut
 106
 107 1;