FS/bin/freeside-cdr-asterisk_sql

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use vars qw( $DEBUG );
   5 use Date::Parse 'str2time';
   6 use Date::Format 'time2str';
   7 use FS::UID qw(adminsuidsetup dbh);
   8 use FS::Log;
   9 use FS::cdr;
  10 use FS::DBI;
  11 use Getopt::Std;
  12
  13 $DEBUG = 0;
  14
  15 my %opt;
  16 getopts('e:H:U:P:D:T:V:', \%opt);
  17 my $user = shift or die &usage;
  18
  19 my $engine = $opt{e} || 'mysql';
  20
  21 my $dsn = "dbi:$engine";
  22 $dsn .= ":database=$opt{D}"; # if $opt{D};
  23 $dsn .= ";host=$opt{H}" if $opt{H};
  24
  25 adminsuidsetup $user;
  26
  27 my $log = FS::Log->new( 'freeside-cdr-asterisk_sql' );
  28
  29 my $dbi = FS::DBI->connect($dsn, $opt{U}, $opt{P}) ;
  30
  31 if ( $dbi ) {
  32   log_msg( info => "Established connection to CDR database at dsn($dsn)" );
  33 } else {
  34   log_and_die( error =>
  35     sprintf 'Fatal error connecting to CDR database at dsn(%s): %s',
  36       $dsn,
  37       $FS::DBI::errstr
  38   );
  39 }
  40
  41 my $fsdbh = FS::UID::dbh;
  42
  43 my $table = $opt{T} || 'cdr';
  44
  45 # check for existence of freesidestatus
  46 if ( $engine =~ /^mysql/ ) {
  47   my $status = $dbi->selectall_arrayref("SHOW COLUMNS FROM $table WHERE Field = 'freesidestatus'");
  48   if( ! @$status ) {
  49     log_msg( warn => "Adding freesidestatus column" );
  50     $dbi->do("ALTER TABLE $table ADD COLUMN freesidestatus varchar(32)")
  51       or log_and_die( error => $dbi->errstr );
  52   } else {
  53     log_msg( info => "freesidestatus column present" );
  54   }
  55 }
  56
  57 my @cols = ();
  58 if ( $opt{V} >= 12 ) {
  59   push @cols, qw( id start answer );
  60   if ( $engine =~ /^Pg/ ) {
  61     push @cols, "'end'";
  62   } else {
  63     push @cols, "end";
  64   }
  65 } else {
  66   push @cols, qw( calldate );
  67 }
  68
  69 push @cols,  qw(
  70   clid src dst dcontext channel lastapp lastdata duration
  71   billsec disposition amaflags accountcode userfield
  72 );
  73
  74 # check for existence of uniqueid
  75 if ( $engine =~ /^mysql/ ) {
  76   my $status = $dbi->selectall_arrayref("SHOW COLUMNS FROM $table WHERE Field = 'uniqueid'");
  77   if( @$status ) {
  78     push @cols, 'uniqueid';
  79   }
  80 } else {
  81   #assume there's a uniqueid
  82   push @cols, 'uniqueid';
  83 }
  84
  85 my $sql =
  86   'SELECT '.join(',', @cols). " FROM $table WHERE freesidestatus IS NULL";
  87 my $sth = $dbi->prepare($sql);
  88 $sth->execute
  89   or log_and_die( error => $sth->errstr );
  90
  91 log_msg( info => sprintf 'Importing %s records', $sth->rows );
  92
  93 my $cdr_batch = new FS::cdr_batch({
  94     'cdrbatch' => 'sql-import-'. time2str('%Y/%m/%d-%T',time),
  95   });
  96 if ( my $error = $cdr_batch->insert ) {
  97   log_and_die( error => $error );
  98 } else {
  99   log_msg( info =>
 100       sprintf 'cdrbatch %s %s',
 101         $cdr_batch->cdrbatch,
 102         $cdr_batch->cdrbatchnum
 103   );
 104 }
 105
 106 my $cdrbatchnum = $cdr_batch->cdrbatchnum;
 107
 108 my $imports = 0;
 109 my $updates = 0;
 110
 111 while ( my $row = $sth->fetchrow_hashref ) {
 112
 113   my $cdr = FS::cdr->new($row);
 114
 115   if ( $opt{V} >= 12 ) {
 116     $cdr->calldate($cdr->start);
 117     $cdr->startdate(str2time($cdr->start));
 118     $cdr->answerdate(str2time($cdr->answer));
 119     $cdr->enddate(str2time($cdr->end));
 120     $cdr->cdrid($cdr->id);
 121   } else {
 122     $cdr->startdate(str2time($cdr->calldate));
 123   }
 124
 125   $cdr->cdrbatchnum($cdrbatchnum);
 126
 127   if ( my $error = $cdr->insert ) {
 128     log_msg( error =>
 129       sprintf 'Non-fatal failure to import acctid(%s) from table(%s): %s',
 130         $row->acctid,
 131         $table,
 132         $error
 133     );
 134   } else {
 135
 136     $imports++;
 137
 138     my $usql = "UPDATE $table SET freesidestatus = 'done' WHERE ";
 139     my @args = ();
 140     if ( $opt{V} >= 12 ) {
 141       $usql .= ' id = '. $row->{'id'};
 142       @args = ( undef );
 143     } else {
 144       $usql .= ' calldate = ? AND src = ? AND dst = ?';
 145       @args = ( undef, $row->{'calldate'}, $row->{'src'}, $row->{'dst'}, );
 146     }
 147
 148     if ( $dbi->do($usql, @args) ) {
 149       $updates++;
 150     } else {
 151       log_msg( error =>
 152         sprintf 'Non-fatal failure set status(done) acctid(%s) table(%s): %s',
 153           $row->acctid,
 154           $table,
 155           $dbi->errstr
 156       );
 157     }
 158
 159   }
 160
 161 }
 162
 163 log_and_warn(
 164   info => "Done.\nImported $imports CDRs, marked $updates CDRs as done"
 165 );
 166
 167 $dbi->disconnect;
 168
 169 sub log_and_die {
 170   my ( $level, $message ) = @_;
 171   $log->$level( $message );
 172   die "[$level] $message\n";
 173 }
 174
 175 sub log_msg {
 176   my ( $level, $message ) = @_;
 177   $log->$level( $message );
 178   warn "[$level] $message\n"
 179     if $opt{v};
 180 }
 181
 182 sub log_and_warn {
 183   my ( $level, $message ) = @_;
 184   $log->$level( $message );
 185   warn "$message\n";
 186 }
 187
 188
 189 sub usage {
 190   "Usage: \n  freeside-cdr-asterisk_sql\n\t-e mysql|Pg|... [ -H host ]\n\t-D database\n\t[ -T table ]\n\t[ -V asterisk_version]\n\t-U user\n\t-P password\n\tfreesideuser\n";
 191 }
 192
 193 =head1 NAME
 194
 195 freeside-cdr-asterisk_sql - Import CDRs from an Asterisk SQL database
 196
 197 =head1 SYNOPSIS
 198
 199   freeside-cdr-asterisk_sql -e mysql|Pg|... [ -H host ] -D database [ -T table ][ -V asterisk_version ] -U user -P password freesideuser
 200
 201 =head1 DESCRIPTION
 202
 203 Imports CDR records from an Asterisk SQL database.
 204
 205 -H: hostname
 206
 207 -e: Database engine (default mysql)
 208
 209 -D: database name
 210
 211 -T: table name (default cdr)
 212
 213 -U: username
 214
 215 -P: password
 216
 217 -V: Asterisk version.  Values of 12 or higher have a new database schema which no longer includes calldate.  Currently defaults to 11, but may default to 12+ or be required in a future, so best to always specify the version.
 218
 219 =cut
 220
 221 1;