FS/FS/tax_rate_location.pm

   1 package FS::tax_rate_location;
   2
   3 use strict;
   4 use base qw( FS::Record );
   5 use FS::Record qw( qsearch qsearchs dbh );
   6 use FS::Misc qw( csv_from_fixed );
   7
   8 =head1 NAME
   9
  10 FS::tax_rate_location - Object methods for tax_rate_location records
  11
  12 =head1 SYNOPSIS
  13
  14   use FS::tax_rate_location;
  15
  16   $record = new FS::tax_rate_location \%hash;
  17   $record = new FS::tax_rate_location { 'column' => 'value' };
  18
  19   $error = $record->insert;
  20
  21   $error = $new_record->replace($old_record);
  22
  23   $error = $record->delete;
  24
  25   $error = $record->check;
  26
  27 =head1 DESCRIPTION
  28
  29 An FS::tax_rate_location object represents an example.  FS::tax_rate_location inherits from
  30 FS::Record.  The following fields are currently supported:
  31
  32 =over 4
  33
  34 =item taxratelocationnum
  35
  36 Primary key (assigned automatically for new tax_rate_locations)
  37
  38 =item data_vendor
  39
  40 The tax data vendor
  41
  42 =item geocode
  43
  44 A unique geographic location code provided by the data vendor
  45
  46 =item city
  47
  48 City
  49
  50 =item county
  51
  52 County
  53
  54 =item state
  55
  56 State
  57
  58 =item disabled
  59
  60 If 'Y' this record is no longer active.
  61
  62
  63 =back
  64
  65 =head1 METHODS
  66
  67 =over 4
  68
  69 =item new HASHREF
  70
  71 Creates a new tax rate location.  To add the record to the database, see
  72  L<"insert">.
  73
  74 Note that this stores the hash reference, not a distinct copy of the hash it
  75 points to.  You can ask the object for a copy with the I<hash> method.
  76
  77 =cut
  78
  79 sub table { 'tax_rate_location'; }
  80
  81 =item insert
  82
  83 Adds this record to the database.  If there is an error, returns the error,
  84 otherwise returns false.
  85
  86 =cut
  87
  88 =item delete
  89
  90 Delete this record from the database.
  91
  92 =cut
  93
  94 sub delete {
  95   return "Can't delete tax rate locations.  Set disable to 'Y' instead.";
  96   # check that it is unused in any cust_bill_pkg_tax_location records instead?
  97 }
  98
  99 =item replace OLD_RECORD
 100
 101 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 102 returns the error, otherwise returns false.
 103
 104 =cut
 105
 106 =item check
 107
 108 Checks all fields to make sure this is a valid tax rate location.  If there is
 109 an error, returns the error, otherwise returns false.  Called by the insert
 110 and replace methods.
 111
 112 =cut
 113
 114 sub check {
 115   my $self = shift;
 116
 117   my $error =
 118     $self->ut_numbern('taxratelocationnum')
 119     || $self->ut_textn('data_vendor')
 120     || $self->ut_alpha('geocode')
 121     || $self->ut_textn('city')
 122     || $self->ut_textn('county')
 123     || $self->ut_textn('state')
 124     || $self->ut_enum('disabled', [ '', 'Y' ])
 125   ;
 126   return $error if $error;
 127
 128   my $t;
 129   $t = qsearchs( 'tax_rate_location',
 130                  { disabled => '',
 131                    ( map { $_ => $self->$_ } qw( data_vendor geocode ) ),
 132                  },
 133                )
 134     unless $self->disabled;
 135
 136   $t = $self->by_key( $self->taxratelocationnum )
 137     if ( !$t && $self->taxratelocationnum );
 138
 139   return "geocode ". $self->geocode. " already in use for this vendor"
 140     if ( $t && $t->taxratelocationnum != $self->taxratelocationnum );
 141
 142   return "may only be disabled"
 143     if ( $t && scalar( grep { $t->$_ ne $self->$_ }
 144                        grep { $_ ne 'disabled' }
 145                        $self->fields
 146                      )
 147        );
 148
 149   $self->SUPER::check;
 150 }
 151
 152 =back
 153
 154 =head1 SUBROUTINES
 155
 156 =over 4
 157
 158 =item batch_import
 159
 160 =cut
 161
 162 sub batch_import {
 163   my ($param, $job) = @_;
 164
 165   my $fh = $param->{filehandle};
 166   my $format = $param->{'format'};
 167
 168   my %insert = ();
 169   my %delete = ();
 170
 171   my @fields;
 172   my $hook;
 173
 174   my @column_lengths = ();
 175   my @column_callbacks = ();
 176   if ( $format eq 'cch-fixed' || $format eq 'cch-fixed-update' ) {
 177     $format =~ s/-fixed//;
 178     my $trim = sub { my $r = shift; $r =~ s/^\s*//; $r =~ s/\s*$//; $r };
 179     push @column_lengths, qw( 28 25 2 10 );
 180     push @column_lengths, 1 if $format eq 'cch-update';
 181     push @column_callbacks, $trim foreach (@column_lengths);
 182   }
 183
 184   my $line;
 185   my ( $count, $last, $min_sec ) = (0, time, 5); #progressbar
 186   if ( $job || scalar(@column_callbacks) ) {
 187     my $error =
 188       csv_from_fixed(\$fh, \$count, \@column_lengths, \@column_callbacks);
 189     return $error if $error;
 190   }
 191
 192   if ( $format eq 'cch' || $format eq 'cch-update' ) {
 193     @fields = qw( city county state geocode );
 194     push @fields, 'actionflag' if $format eq 'cch-update';
 195
 196     $hook = sub {
 197       my $hash = shift;
 198
 199       $hash->{'data_vendor'} ='cch';
 200
 201       if (exists($hash->{'actionflag'}) && $hash->{'actionflag'} eq 'D') {
 202         delete($hash->{actionflag});
 203
 204         $hash->{disabled} = '';
 205         my $tax_rate_location = qsearchs('tax_rate_location', $hash);
 206         return "Can't find tax_rate_location to delete: ".
 207                join(" ", map { "$_ => ". $hash->{$_} } @fields)
 208           unless $tax_rate_location;
 209
 210         $tax_rate_location->disabled('Y');
 211         my $error = $tax_rate_location->replace;
 212         return $error if $error;
 213
 214         delete($hash->{$_}) foreach (keys %$hash);
 215       }
 216
 217       delete($hash->{'actionflag'});
 218
 219       '';
 220
 221     };
 222
 223   } elsif ( $format eq 'extended' ) {
 224     die "unimplemented\n";
 225     @fields = qw( );
 226     $hook = sub {};
 227   } else {
 228     die "unknown format $format";
 229   }
 230
 231   eval "use Text::CSV_XS;";
 232   die $@ if $@;
 233
 234   my $csv = new Text::CSV_XS;
 235
 236   my $imported = 0;
 237
 238   local $SIG{HUP} = 'IGNORE';
 239   local $SIG{INT} = 'IGNORE';
 240   local $SIG{QUIT} = 'IGNORE';
 241   local $SIG{TERM} = 'IGNORE';
 242   local $SIG{TSTP} = 'IGNORE';
 243   local $SIG{PIPE} = 'IGNORE';
 244
 245   my $oldAutoCommit = $FS::UID::AutoCommit;
 246   local $FS::UID::AutoCommit = 0;
 247   my $dbh = dbh;
 248
 249   while ( defined($line=<$fh>) ) {
 250     $csv->parse($line) or do {
 251       $dbh->rollback if $oldAutoCommit;
 252       return "can't parse: ". $csv->error_input();
 253     };
 254
 255     if ( $job ) {  # progress bar
 256       if ( time - $min_sec > $last ) {
 257         my $error = $job->update_statustext(
 258           int( 100 * $imported / $count )
 259         );
 260         die $error if $error;
 261         $last = time;
 262       }
 263     }
 264
 265     my @columns = $csv->fields();
 266
 267     my %tax_rate_location = ();
 268     foreach my $field ( @fields ) {
 269       $tax_rate_location{$field} = shift @columns;
 270     }
 271     if ( scalar( @columns ) ) {
 272       $dbh->rollback if $oldAutoCommit;
 273       return "Unexpected trailing columns in line (wrong format?): $line";
 274     }
 275
 276     my $error = &{$hook}(\%tax_rate_location);
 277     if ( $error ) {
 278       $dbh->rollback if $oldAutoCommit;
 279       return $error;
 280     }
 281
 282     if (scalar(keys %tax_rate_location)) { #inserts only
 283
 284       my $tax_rate_location = new FS::tax_rate_location( \%tax_rate_location );
 285       $error = $tax_rate_location->insert;
 286
 287       if ( $error ) {
 288         $dbh->rollback if $oldAutoCommit;
 289         return "can't insert tax_rate_location for $line: $error";
 290       }
 291
 292     }
 293
 294     $imported++;
 295
 296   }
 297
 298   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 299
 300   return "Empty file!" unless ($imported || $format eq 'cch-update');
 301
 302   ''; #no error
 303
 304 }
 305
 306 =head1 BUGS
 307
 308 Currently somewhat specific to CCH supplied data.
 309
 310 =head1 SEE ALSO
 311
 312 L<FS::Record>, schema.html from the base documentation.
 313
 314 =cut
 315
 316 1;
 317