FS/FS/svc_hardware.pm

   1 package FS::svc_hardware;
   2 use base qw( FS::svc_Common );
   3
   4 use strict;
   5 use vars qw( $conf );
   6 use FS::Record qw( qsearchs ); #qsearch qsearchs );
   7 use FS::hardware_status;
   8 use FS::Conf;
   9
  10 FS::UID->install_callback(sub { $conf = FS::Conf->new; });
  11
  12 =head1 NAME
  13
  14 FS::svc_hardware - Object methods for svc_hardware records
  15
  16 =head1 SYNOPSIS
  17
  18   use FS::svc_hardware;
  19
  20   $record = new FS::svc_hardware \%hash;
  21   $record = new FS::svc_hardware { 'column' => 'value' };
  22
  23   $error = $record->insert;
  24
  25   $error = $new_record->replace($old_record);
  26
  27   $error = $record->delete;
  28
  29   $error = $record->check;
  30
  31 =head1 DESCRIPTION
  32
  33 An FS::svc_hardware object represents an equipment installation, such as
  34 a wireless broadband receiver, satellite antenna, or DVR.  FS::svc_hardware
  35 inherits from FS::svc_Common.
  36
  37 The following fields are currently supported:
  38
  39 =over 4
  40
  41 =item svcnum - Primary key
  42
  43 =item typenum - Device type number (see L<FS::hardware_type>)
  44
  45 =item ip_addr - IP address
  46
  47 =item hw_addr - Hardware address
  48
  49 =item serial - Serial number
  50
  51 =item smartcard - Smartcard number, for devices that use a smartcard
  52
  53 =item statusnum - Service status (see L<FS::hardware_status>)
  54
  55 =item note - Installation notes: location on property, physical access, etc.
  56
  57 =back
  58
  59 =head1 METHODS
  60
  61 =over 4
  62
  63 =item new HASHREF
  64
  65 Creates a new svc_hardware object.
  66
  67 =cut
  68
  69 sub table { 'svc_hardware'; }
  70
  71 sub table_info {
  72   my %opts = ( 'type' => 'text', 'disable_select' => 1 );
  73   {
  74     'name'           => 'Hardware', #?
  75     'name_plural'    => 'Hardware',
  76     'display_weight' => 59,
  77     'cancel_weight'  => 86,
  78     'manual_require' => 1,
  79     'fields' => {
  80       'svcnum'    => { label => 'Service' },
  81       'typenum'   => { label => 'Device type',
  82                        type  => 'select-hardware',
  83                        disable_select    => 1,
  84                        disable_fixed     => 1,
  85                        disable_default   => 1,
  86                        disable_inventory => 1,
  87                        required => 1,
  88                      },
  89       'serial'    => { label => 'Serial number', %opts },
  90       'hw_addr'   => { label => 'Hardware address', %opts },
  91       'ip_addr'   => { label => 'IP address', %opts },
  92       'smartcard' => { label => 'Smartcard #', %opts },
  93       'statusnum' => { label => 'Service status',
  94                        type  => 'select',
  95                        select_table => 'hardware_status',
  96                        select_key   => 'statusnum',
  97                        select_label => 'label',
  98                        disable_inventory => 1,
  99                      },
 100       'note'      => { label => 'Installation notes', %opts },
 101     }
 102   }
 103 }
 104
 105 sub search_sql {
 106   my ($class, $string) = @_;
 107   my @where = ();
 108
 109   if ( $string =~ /^[\d\.:]+$/ ) {
 110     # if the string isn't an IP address, this will waste several seconds
 111     # attempting a DNS lookup.  so try to filter those out.
 112     my $ip = NetAddr::IP->new($string);
 113     if ( $ip ) {
 114       push @where, $class->search_sql_field('ip_addr', $ip->addr);
 115     }
 116   }
 117
 118   if ( $string =~ /^(\w+)$/ ) {
 119     push @where, 'LOWER(svc_hardware.serial) LIKE \'%'.lc($string).'%\'';
 120   }
 121
 122   if ( $string =~ /^([0-9A-Fa-f]|\W)+$/ ) {
 123     my $hex = uc($string);
 124     $hex =~ s/\W//g;
 125     push @where, 'svc_hardware.hw_addr LIKE \'%'.$hex.'%\'';
 126   }
 127
 128   if ( @where ) {
 129     '(' . join(' OR ', @where) . ')';
 130   } else {
 131     '1 = 0'; #false
 132   }
 133 }
 134
 135 sub label {
 136   my $self = shift;
 137   my $part_svc = $self->cust_svc->part_svc;
 138   my @label = ();
 139   if (my $type = $self->hardware_type) {
 140     push @label, ($part_svc->part_svc_column('typenum') || 'Type:').
 141                  $type->description;
 142   }
 143   if (my $ser = $self->serial) {
 144     push @label, ($part_svc->part_svc_column('serial') || 'Serial#'). $ser;
 145   }
 146   if (my $mac = $self->display_hw_addr) {
 147     push @label, ($part_svc->part_svc_column('hw_addr') || 'MAC:'). $mac;
 148   }
 149   return join(', ', @label);
 150 }
 151
 152 =item insert
 153
 154 Adds this record to the database.  If there is an error, returns the error,
 155 otherwise returns false.
 156
 157 =item delete
 158
 159 Delete this record from the database.
 160
 161 =item replace OLD_RECORD
 162
 163 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 164 returns the error, otherwise returns false.
 165
 166 # the replace method can be inherited from FS::Record
 167
 168 =item check
 169
 170 Checks all fields to make sure this is a valid service.  If there is
 171 an error, returns the error, otherwise returns false.  Called by the insert
 172 and replace methods.
 173
 174 =cut
 175
 176 sub check {
 177   my $self = shift;
 178   my $conf = FS::Conf->new;
 179
 180   my $x = $self->setfixed;
 181   return $x unless ref $x;
 182
 183   my $hw_addr = $self->getfield('hw_addr');
 184   $hw_addr = join('', split(/[_\W]/, $hw_addr));
 185   if ( $conf->exists('svc_hardware-check_mac_addr') ) {
 186     $hw_addr = uc($hw_addr);
 187     $hw_addr =~ /^[0-9A-F]{12}$/
 188       or return "Illegal (MAC address) '".$self->getfield('hw_addr')."'";
 189   }
 190   $self->setfield('hw_addr', $hw_addr);
 191
 192   my $error =
 193     $self->ut_numbern('svcnum')
 194     || $self->ut_foreign_key('typenum', 'hardware_type', 'typenum')
 195     || $self->ut_ip46n('ip_addr')
 196     || $self->ut_alphan('hw_addr')
 197     || $self->ut_alphan('serial')
 198     || $self->ut_alphan('smartcard')
 199     || $self->ut_foreign_keyn('statusnum', 'hardware_status', 'statusnum')
 200     || $self->ut_anything('note')
 201   ;
 202   return $error if $error;
 203
 204   if ( !length($self->getfield('hw_addr'))
 205         and !length($self->getfield('serial')) ) {
 206     return 'Serial number or hardware address required';
 207   }
 208
 209   $self->SUPER::check;
 210 }
 211
 212 =item hardware_type
 213
 214 Returns the L<FS::hardware_type> object associated with this installation.
 215
 216 =item status_label
 217
 218 Returns the 'label' field of the L<FS::hardware_status> object associated
 219 with this installation.
 220
 221 =cut
 222
 223 sub status_label {
 224   my $self = shift;
 225   my $status = qsearchs('hardware_status', { 'statusnum' => $self->statusnum })
 226     or return '';
 227   $status->label;
 228 }
 229
 230 =item display_hw_addr
 231
 232 Returns the 'hw_addr' field, formatted as a MAC address if the
 233 'svc_hardware-check_mac_addr' option is enabled.
 234
 235 =cut
 236
 237 sub display_hw_addr {
 238   my $self = shift;
 239   ($conf->exists('svc_hardware-check_mac_addr') ?
 240     join(':', $self->hw_addr =~ /../g) : $self->hw_addr)
 241 }
 242
 243 =back
 244
 245 =head1 SEE ALSO
 246
 247 L<FS::Record>, L<FS::svc_Common>, schema.html from the base documentation.
 248
 249 =cut
 250
 251 1;
 252