FS/FS/svc_domain.pm

   1 package FS::svc_domain;
   2
   3 use strict;
   4 use base qw( FS::svc_Parent_Mixin FS::svc_CGP_Mixin FS::svc_CGPRule_Mixin
   5              FS::svc_Common );
   6 use vars qw( $whois_hack $conf
   7   @defaultrecords $soadefaultttl $soaemail $soaexpire $soamachine
   8   $soarefresh $soaretry
   9 );
  10 use Carp;
  11 use Scalar::Util qw( blessed );
  12 use Date::Format;
  13 #use Net::Whois::Raw;
  14 use Net::Domain::TLD qw(tld_exists);
  15 use FS::Record qw(fields qsearch qsearchs dbh);
  16 use FS::Conf;
  17 use FS::cust_svc;
  18 use FS::svc_acct;
  19 use FS::cust_pkg;
  20 use FS::cust_main;
  21 use FS::domain_record;
  22 use FS::queue;
  23
  24 #ask FS::UID to run this stuff for us later
  25 $FS::UID::callback{'FS::domain'} = sub {
  26   $conf = new FS::Conf;
  27
  28   @defaultrecords = $conf->config('defaultrecords');
  29   $soadefaultttl = $conf->config('soadefaultttl');
  30   $soaemail      = $conf->config('soaemail');
  31   $soaexpire     = $conf->config('soaexpire');
  32   $soamachine    = $conf->config('soamachine');
  33   $soarefresh    = $conf->config('soarefresh');
  34   $soaretry      = $conf->config('soaretry');
  35
  36 };
  37
  38 =head1 NAME
  39
  40 FS::svc_domain - Object methods for svc_domain records
  41
  42 =head1 SYNOPSIS
  43
  44   use FS::svc_domain;
  45
  46   $record = new FS::svc_domain \%hash;
  47   $record = new FS::svc_domain { 'column' => 'value' };
  48
  49   $error = $record->insert;
  50
  51   $error = $new_record->replace($old_record);
  52
  53   $error = $record->delete;
  54
  55   $error = $record->check;
  56
  57   $error = $record->suspend;
  58
  59   $error = $record->unsuspend;
  60
  61   $error = $record->cancel;
  62
  63 =head1 DESCRIPTION
  64
  65 An FS::svc_domain object represents a domain.  FS::svc_domain inherits from
  66 FS::svc_Common.  The following fields are currently supported:
  67
  68 =over 4
  69
  70 =item svcnum - primary key (assigned automatically for new accounts)
  71
  72 =item domain
  73
  74 =item catchall - optional svcnum of an svc_acct record, designating an email catchall account.
  75
  76 =item suffix -
  77
  78 =item parent_svcnum -
  79
  80 =item registrarnum - Registrar (see L<FS::registrar>)
  81
  82 =item registrarkey - Registrar key or password for this domain
  83
  84 =item setup_date - UNIX timestamp
  85
  86 =item renewal_interval - Number of days before expiration date to start renewal
  87
  88 =item expiration_date - UNIX timestamp
  89
  90 =item max_accounts
  91
  92 =back
  93
  94 =head1 METHODS
  95
  96 =over 4
  97
  98 =item new HASHREF
  99
 100 Creates a new domain.  To add the domain to the database, see L<"insert">.
 101
 102 =cut
 103
 104 sub table_info {
 105   {
 106     'name' => 'Domain',
 107     'sorts' => 'domain',
 108     'display_weight' => 20,
 109     'cancel_weight'  => 60,
 110     'fields' => {
 111       'domain' => 'Domain',
 112       'parent_svcnum' => {
 113                          label => 'Parent domain / Communigate administrator domain',
 114                          type  => 'select',
 115                          select_table => 'svc_domain',
 116                          select_key => 'svcnum',
 117                          select_label => 'domain',
 118                          disable_inventory => 1,
 119                          disable_select    => 1,
 120                        },
 121       'max_accounts' => { label => 'Maximum number of accounts',
 122                           'disable_inventory' => 1,
 123                         },
 124       'cgp_aliases' => {
 125                          label => 'Communigate aliases',
 126                          type  => 'text',
 127                          disable_inventory => 1,
 128                          disable_select    => 1,
 129                        },
 130       'cgp_accessmodes' => {
 131                              label => 'Communigate enabled services',
 132                              type  => 'communigate_pro-accessmodes',
 133                              disable_inventory => 1,
 134                              disable_select    => 1,
 135                            },
 136
 137       'acct_def_cgp_accessmodes' => {
 138                              label => 'Acct. default Communigate enabled services',
 139                              type  => 'communigate_pro-accessmodes',
 140                              disable_inventory => 1,
 141                              disable_select    => 1,
 142                            },
 143       'acct_def_password_selfchange' => { label => 'Acct. default Password modification',
 144                                  type  => 'checkbox',
 145                             disable_inventory => 1,
 146                             disable_select    => 1,
 147                                },
 148       'acct_def_password_recover'    => { label => 'Acct. default Password recovery',
 149                                  type  => 'checkbox',
 150                             disable_inventory => 1,
 151                             disable_select    => 1,
 152                                },
 153       'acct_def_cgp_deletemode' => {
 154                             label => 'Acct. default Communigate message delete method',
 155                             type  => 'select',
 156                             select_list => [ 'Move To Trash', 'Immediately', 'Mark' ],
 157                             disable_inventory => 1,
 158                             disable_select    => 1,
 159                           },
 160       'acct_def_cgp_emptytrash' => {
 161                             label => 'Acct. default Communigate on logout remove trash',
 162                             type        => 'select',
 163                             select_list => __PACKAGE__->cgp_emptytrash_values,
 164                             disable_inventory => 1,
 165                             disable_select    => 1,
 166                           },
 167       'acct_def_quota'     => {
 168                        label => 'Acct. default Quota', #Mail storage limit
 169                        type => 'text',
 170                        disable_inventory => 1,
 171                        disable_select => 1,
 172                      },
 173       'acct_def_file_quota'=> {
 174                        label => 'Acct. default File storage limit',
 175                        type => 'text',
 176                        disable_inventory => 1,
 177                        disable_select => 1,
 178                      },
 179       'acct_def_file_maxnum'=> {
 180                        label => 'Acct. default Number of files limit',
 181                        type => 'text',
 182                        disable_inventory => 1,
 183                        disable_select => 1,
 184                      },
 185       'acct_def_file_maxsize'=> {
 186                        label => 'Acct. default File size limit',
 187                        type => 'text',
 188                        disable_inventory => 1,
 189                        disable_select => 1,
 190                      },
 191       'acct_def_cgp_rulesallowed'   => {
 192         label       => 'Acct. default Allowed mail rules',
 193         type        => 'select',
 194         select_list => [ '', 'No', 'Filter Only', 'All But Exec', 'Any' ],
 195         disable_inventory => 1,
 196         disable_select    => 1,
 197       },
 198       'acct_def_cgp_rpopallowed'    => {
 199         label => 'Acct. default RPOP modifications',
 200         type  => 'checkbox',
 201       },
 202       'acct_def_cgp_mailtoall'      => {
 203         label => 'Acct. default Accepts mail to "all"',
 204         type  => 'checkbox',
 205       },
 206       'acct_def_cgp_addmailtrailer' => {
 207         label => 'Acct. default Add trailer to sent mail',
 208         type  => 'checkbox',
 209       },
 210       'trailer' => {
 211         label => 'Mail trailer',
 212         type  => 'textarea',
 213         disable_inventory => 1,
 214         disable_select    => 1,
 215       },
 216       'acct_def_cgp_language' => {
 217                             label => 'Acct. default language',
 218                             type  => 'select',
 219                             select_list => [ '', qw( English Arabic Chinese Dutch French German Hebrew Italian Japanese Portuguese Russian Slovak Spanish Thai ) ],
 220                             disable_inventory => 1,
 221                             disable_select    => 1,
 222                         },
 223       'acct_def_cgp_timezone' => {
 224                             label       => 'Acct. default time zone',
 225                             type        => 'select',
 226                             select_list => __PACKAGE__->cgp_timezone_values,
 227                             disable_inventory => 1,
 228                             disable_select    => 1,
 229                         },
 230       'acct_def_cgp_skinname' => {
 231                             label => 'Acct. default layout',
 232                             type  => 'select',
 233                             select_list => [ '', '***', 'GoldFleece', 'Skin2' ],
 234                             disable_inventory => 1,
 235                             disable_select    => 1,
 236                         },
 237       'acct_def_cgp_prontoskinname' => {
 238                             label => 'Acct. default Pronto style',
 239                             type  => 'select',
 240                             select_list => [ '', 'Pronto', 'Pronto-darkflame', 'Pronto-steel', 'Pronto-twilight', ],
 241                             disable_inventory => 1,
 242                             disable_select    => 1,
 243                         },
 244       'acct_def_cgp_sendmdnmode' => {
 245         label => 'Acct. default send read receipts',
 246         type  => 'select',
 247         select_list => [ '', 'Never', 'Manually', 'Automatically' ],
 248         disable_inventory => 1,
 249         disable_select    => 1,
 250       },
 251     },
 252   };
 253 }
 254
 255 sub table { 'svc_domain'; }
 256
 257 sub search_sql {
 258   my($class, $string) = @_;
 259   $class->search_sql_field('domain', $string);
 260 }
 261
 262
 263 =item label
 264
 265 Returns the domain.
 266
 267 =cut
 268
 269 sub label {
 270   my $self = shift;
 271   $self->domain;
 272 }
 273
 274 =item insert [ , OPTION => VALUE ... ]
 275
 276 Adds this domain to the database.  If there is an error, returns the error,
 277 otherwise returns false.
 278
 279 The additional fields I<pkgnum> and I<svcpart> (see L<FS::cust_svc>) should be
 280 defined.  An FS::cust_svc record will be created and inserted.
 281
 282 The additional field I<action> should be set to I<N> for new domains, I<M>
 283 for transfers, or I<I> for no action (registered elsewhere).
 284
 285 A registration or transfer email will be submitted unless
 286 $FS::svc_domain::whois_hack is true.
 287
 288 The additional field I<email> can be used to manually set the admin contact
 289 email address on this email.  Otherwise, the svc_acct records for this package
 290 (see L<FS::cust_pkg>) are searched.  If there is exactly one svc_acct record
 291 in the same package, it is automatically used.  Otherwise an error is returned.
 292
 293 If any I<soamachine> configuration file exists, an SOA record is added to
 294 the domain_record table (see <FS::domain_record>).
 295
 296 If any records are defined in the I<defaultrecords> configuration file,
 297 appropriate records are added to the domain_record table (see
 298 L<FS::domain_record>).
 299
 300 Currently available options are: I<depend_jobnum>
 301
 302 If I<depend_jobnum> is set (to a scalar jobnum or an array reference of
 303 jobnums), all provisioning jobs will have a dependancy on the supplied
 304 jobnum(s) (they will not run until the specific job(s) complete(s)).
 305
 306 =cut
 307
 308 sub insert {
 309   my $self = shift;
 310   my $error;
 311
 312   local $SIG{HUP} = 'IGNORE';
 313   local $SIG{INT} = 'IGNORE';
 314   local $SIG{QUIT} = 'IGNORE';
 315   local $SIG{TERM} = 'IGNORE';
 316   local $SIG{TSTP} = 'IGNORE';
 317   local $SIG{PIPE} = 'IGNORE';
 318
 319   my $oldAutoCommit = $FS::UID::AutoCommit;
 320   local $FS::UID::AutoCommit = 0;
 321   my $dbh = dbh;
 322
 323   $error = $self->SUPER::insert(@_);
 324   if ( $error ) {
 325     $dbh->rollback if $oldAutoCommit;
 326     return $error;
 327   }
 328
 329   if ( $soamachine ) {
 330     my $soa = new FS::domain_record {
 331       'svcnum'  => $self->svcnum,
 332       'reczone' => '@',
 333       'recaf'   => 'IN',
 334       'rectype' => 'SOA',
 335       'recdata' => "$soamachine $soaemail ( ". time2str("%Y%m%d", time). "00 ".
 336                    "$soarefresh $soaretry $soaexpire $soadefaultttl )"
 337     };
 338     $error = $soa->insert;
 339     if ( $error ) {
 340       $dbh->rollback if $oldAutoCommit;
 341       return "couldn't insert SOA record for new domain: $error";
 342     }
 343
 344     foreach my $record ( @defaultrecords ) {
 345       my($zone,$af,$type,$data) = split(/\s+/,$record,4);
 346       my $domain_record = new FS::domain_record {
 347         'svcnum'  => $self->svcnum,
 348         'reczone' => $zone,
 349         'recaf'   => $af,
 350         'rectype' => $type,
 351         'recdata' => $data,
 352       };
 353       my $error = $domain_record->insert;
 354       if ( $error ) {
 355         $dbh->rollback if $oldAutoCommit;
 356         return "couldn't insert record for new domain: $error";
 357       }
 358     }
 359
 360   }
 361
 362   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 363
 364   ''; #no error
 365 }
 366
 367 =item delete
 368
 369 Deletes this domain from the database.  If there is an error, returns the
 370 error, otherwise returns false.
 371
 372 The corresponding FS::cust_svc record will be deleted as well.
 373
 374 =cut
 375
 376 sub delete {
 377   my $self = shift;
 378
 379   return "Can't delete a domain which has accounts!"
 380     if qsearch( 'svc_acct', { 'domsvc' => $self->svcnum } );
 381
 382   #return "Can't delete a domain with (domain_record) zone entries!"
 383   #  if qsearch('domain_record', { 'svcnum' => $self->svcnum } );
 384
 385   local $SIG{HUP} = 'IGNORE';
 386   local $SIG{INT} = 'IGNORE';
 387   local $SIG{QUIT} = 'IGNORE';
 388   local $SIG{TERM} = 'IGNORE';
 389   local $SIG{TSTP} = 'IGNORE';
 390   local $SIG{PIPE} = 'IGNORE';
 391
 392   my $oldAutoCommit = $FS::UID::AutoCommit;
 393   local $FS::UID::AutoCommit = 0;
 394   my $dbh = dbh;
 395
 396   foreach my $domain_record ( reverse $self->domain_record ) {
 397     my $error = $domain_record->delete;
 398     if ( $error ) {
 399       $dbh->rollback if $oldAutoCommit;
 400       return "can't delete DNS entry: ".
 401              join(' ', map $domain_record->$_(),
 402                            qw( reczone recaf rectype recdata )
 403                  ).
 404              ":$error";
 405     }
 406   }
 407
 408   my $error = $self->SUPER::delete(@_);
 409   if ( $error ) {
 410     $dbh->rollback if $oldAutoCommit;
 411     return $error;
 412   }
 413
 414   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 415 }
 416
 417 =item replace OLD_RECORD
 418
 419 Replaces OLD_RECORD with this one in the database.  If there is an error,
 420 returns the error, otherwise returns false.
 421
 422 =cut
 423
 424 sub replace {
 425   my $new = shift;
 426
 427   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
 428               ? shift
 429               : $new->replace_old;
 430
 431   return "Can't change domain - reorder."
 432     if $old->getfield('domain') ne $new->getfield('domain')
 433     && ! $conf->exists('svc_domain-edit_domain');
 434
 435   # Better to do it here than to force the caller to remember that svc_domain is weird.
 436   $new->setfield(action => 'I');
 437   my $error = $new->SUPER::replace($old, @_);
 438   return $error if $error;
 439 }
 440
 441 =item suspend
 442
 443 Just returns false (no error) for now.
 444
 445 Called by the suspend method of FS::cust_pkg (see L<FS::cust_pkg>).
 446
 447 =item unsuspend
 448
 449 Just returns false (no error) for now.
 450
 451 Called by the unsuspend method of FS::cust_pkg (see L<FS::cust_pkg>).
 452
 453 =item cancel
 454
 455 Just returns false (no error) for now.
 456
 457 Called by the cancel method of FS::cust_pkg (see L<FS::cust_pkg>).
 458
 459 =item check
 460
 461 Checks all fields to make sure this is a valid domain.  If there is an error,
 462 returns the error, otherwise returns false.  Called by the insert and replace
 463 methods.
 464
 465 Sets any fixed values; see L<FS::part_svc>.
 466
 467 =cut
 468
 469 sub check {
 470   my $self = shift;
 471
 472   my $x = $self->setfixed;
 473   return $x unless ref($x);
 474   #my $part_svc = $x;
 475
 476   my $error = $self->ut_numbern('svcnum')
 477               || $self->ut_numbern('catchall')
 478               || $self->ut_numbern('max_accounts')
 479               || $self->ut_anything('trailer') #well
 480               || $self->ut_textn('cgp_aliases') #well
 481               || $self->ut_enum('acct_def_password_selfchange', [ '', 'Y' ])
 482               || $self->ut_enum('acct_def_password_recover',    [ '', 'Y' ])
 483               || $self->ut_textn('acct_def_cgp_accessmodes')
 484               || $self->ut_alphan('acct_def_quota')
 485               || $self->ut_alphan('acct_def_file_quota')
 486               || $self->ut_alphan('acct_def_maxnum')
 487               || $self->ut_alphan('acct_def_maxsize')
 488               #settings
 489               || $self->ut_alphasn('acct_def_cgp_rulesallowed')
 490               || $self->ut_enum('acct_def_cgp_rpopallowed', [ '', 'Y' ])
 491               || $self->ut_enum('acct_def_cgp_mailtoall', [ '', 'Y' ])
 492               || $self->ut_enum('acct_def_cgp_addmailtrailer', [ '', 'Y' ])
 493               #XXX archive messages
 494               #preferences
 495               || $self->ut_alphasn('acct_def_cgp_deletemode')
 496               || $self->ut_enum('acct_def_cgp_emptytrash',
 497                                    $self->cgp_emptytrash_values )
 498               || $self->ut_alphan('acct_def_cgp_language')
 499               || $self->ut_textn('acct_def_cgp_timezone')
 500               || $self->ut_textn('acct_def_cgp_skinname')
 501               || $self->ut_textn('acct_def_cgp_prontoskinname')
 502               || $self->ut_alphan('acct_def_cgp_sendmdnmode')
 503               #mail
 504               #XXX rules, archive rule, spam foldering rule(s)
 505   ;
 506   return $error if $error;
 507
 508   #hmm
 509   my $pkgnum;
 510   if ( $self->svcnum ) {
 511     my $cust_svc = qsearchs( 'cust_svc', { 'svcnum' => $self->svcnum } );
 512     $pkgnum = $cust_svc->pkgnum;
 513   } else {
 514     $pkgnum = $self->pkgnum;
 515   }
 516
 517   my($recref) = $self->hashref;
 518
 519   #if ( $recref->{domain} =~ /^([\w\-\.]{1,22})\.(com|net|org|edu)$/ ) {
 520   if ( $recref->{domain} =~ /^([\w\-]{1,63})\.(com|net|org|edu|tv|info|biz)$/ ) {
 521     $recref->{domain} = "$1.$2";
 522     $recref->{suffix} ||= $2;
 523   # hmmmmmmmm.
 524   } elsif ( $whois_hack && $recref->{domain} =~ /^([\w\-\.]+)\.(\w+)$/ ) {
 525     $recref->{domain} = "$1.$2";
 526     # need to match a list of suffixes - no guarantee they're top-level..
 527     # http://wiki.mozilla.org/TLD_List
 528     # but this will have to do for now...
 529     $recref->{suffix} ||= $2;
 530   } else {
 531     return "Illegal domain ". $recref->{domain}.
 532            " (or unknown registry - try \$whois_hack)";
 533   }
 534
 535   $self->suffix =~ /(^|\.)(\w+)$/
 536     or return "can't parse suffix for TLD: ". $self->suffix;
 537   my $tld = $2;
 538   return "No such TLD: .$tld" unless tld_exists($tld);
 539
 540   if ( $recref->{catchall} ne '' ) {
 541     my $svc_acct = qsearchs( 'svc_acct', { 'svcnum' => $recref->{catchall} } );
 542     return "Unknown catchall" unless $svc_acct;
 543   }
 544
 545   $self->ut_alphan('suffix')
 546     or $self->ut_foreign_keyn('registrarnum', 'registrar', 'registrarnum')
 547     or $self->ut_textn('registrarkey')
 548     or $self->ut_numbern('setup_date')
 549     or $self->ut_numbern('renewal_interval')
 550     or $self->ut_numbern('expiration_date')
 551     or $self->SUPER::check;
 552
 553 }
 554
 555 sub _check_duplicate {
 556   my $self = shift;
 557
 558   $self->lock_table;
 559
 560   if ( qsearchs( 'svc_domain', { 'domain' => $self->domain } ) ) {
 561     return "Domain in use (here)";
 562   } else {
 563     return '';
 564   }
 565 }
 566
 567 =item domain_record
 568
 569 =cut
 570
 571 sub domain_record {
 572   my $self = shift;
 573
 574   my %order = (
 575     'SOA'   => 1,
 576     'NS'    => 2,
 577     'MX'    => 3,
 578     'CNAME' => 4,
 579     'A'     => 5,
 580     'TXT'   => 6,
 581     'PTR'   => 7,
 582   );
 583
 584   my %sort = (
 585     #'SOA'   => sub { $_[0]->recdata cmp $_[1]->recdata }, #sure hope not though
 586 #    'SOA'   => sub { 0; },
 587 #    'NS'    => sub { 0; },
 588     'MX'    => sub { my( $a_weight, $a_name ) = split(/\s+/, $_[0]->recdata);
 589                      my( $b_weight, $b_name ) = split(/\s+/, $_[1]->recdata);
 590                      $a_weight <=> $b_weight or $a_name cmp $b_name;
 591                    },
 592     'CNAME' => sub { $_[0]->reczone cmp $_[1]->reczone },
 593     'A'     => sub { $_[0]->reczone cmp $_[1]->reczone },
 594
 595 #    'TXT'   => sub { 0; },
 596     'PTR'   => sub { $_[0]->reczone <=> $_[1]->reczone },
 597   );
 598
 599   map { $_ } #return $self->num_domain_record( PARAMS ) unless wantarray;
 600   sort {    $order{$a->rectype} <=> $order{$b->rectype}
 601          or &{ $sort{$a->rectype} || sub { 0; } }($a, $b)
 602        }
 603        qsearch('domain_record', { svcnum => $self->svcnum } );
 604
 605 }
 606
 607 sub catchall_svc_acct {
 608   my $self = shift;
 609   if ( $self->catchall ) {
 610     qsearchs( 'svc_acct', { 'svcnum' => $self->catchall } );
 611   } else {
 612     '';
 613   }
 614 }
 615
 616 =item whois
 617
 618 # Returns the Net::Whois::Domain object (see L<Net::Whois>) for this domain, or
 619 # undef if the domain is not found in whois.
 620
 621 (If $FS::svc_domain::whois_hack is true, returns that in all cases instead.)
 622
 623 =cut
 624
 625 sub whois {
 626   #$whois_hack or new Net::Whois::Domain $_[0]->domain;
 627   #$whois_hack or die "whois_hack not set...\n";
 628 }
 629
 630 =back
 631
 632 =head1 BUGS
 633
 634 Delete doesn't send a registration template.
 635
 636 All registries should be supported.
 637
 638 Should change action to a real field.
 639
 640 The $recref stuff in sub check should be cleaned up.
 641
 642 =head1 SEE ALSO
 643
 644 L<FS::svc_Common>, L<FS::Record>, L<FS::Conf>, L<FS::cust_svc>,
 645 L<FS::part_svc>, L<FS::cust_pkg>, L<Net::Whois>, schema.html from the base
 646 documentation, config.html from the base documentation.
 647
 648 =cut
 649
 650 1;
 651
 652