FS/FS/svc_domain.pm

   1 package FS::svc_domain;
   2
   3 use strict;
   4 use base qw( FS::svc_Parent_Mixin FS::svc_CGP_Mixin FS::svc_CGPRule_Mixin
   5              FS::svc_Common );
   6 use vars qw( $whois_hack $conf
   7   @defaultrecords $soadefaultttl $soaemail $soaexpire $soamachine
   8   $soarefresh $soaretry
   9 );
  10 use Carp;
  11 use Scalar::Util qw( blessed );
  12 use Date::Format;
  13 #use Net::Whois::Raw;
  14 use Net::Domain::TLD qw(tld_exists);
  15 use FS::Record qw(fields qsearch qsearchs dbh);
  16 use FS::Conf;
  17 use FS::cust_svc;
  18 use FS::svc_acct;
  19 use FS::cust_pkg;
  20 use FS::cust_main;
  21 use FS::domain_record;
  22 use FS::queue;
  23
  24 #ask FS::UID to run this stuff for us later
  25 $FS::UID::callback{'FS::domain'} = sub {
  26   $conf = new FS::Conf;
  27
  28   @defaultrecords = $conf->config('defaultrecords');
  29   $soadefaultttl = $conf->config('soadefaultttl');
  30   $soaemail      = $conf->config('soaemail');
  31   $soaexpire     = $conf->config('soaexpire');
  32   $soamachine    = $conf->config('soamachine');
  33   $soarefresh    = $conf->config('soarefresh');
  34   $soaretry      = $conf->config('soaretry');
  35
  36 };
  37
  38 =head1 NAME
  39
  40 FS::svc_domain - Object methods for svc_domain records
  41
  42 =head1 SYNOPSIS
  43
  44   use FS::svc_domain;
  45
  46   $record = new FS::svc_domain \%hash;
  47   $record = new FS::svc_domain { 'column' => 'value' };
  48
  49   $error = $record->insert;
  50
  51   $error = $new_record->replace($old_record);
  52
  53   $error = $record->delete;
  54
  55   $error = $record->check;
  56
  57   $error = $record->suspend;
  58
  59   $error = $record->unsuspend;
  60
  61   $error = $record->cancel;
  62
  63 =head1 DESCRIPTION
  64
  65 An FS::svc_domain object represents a domain.  FS::svc_domain inherits from
  66 FS::svc_Common.  The following fields are currently supported:
  67
  68 =over 4
  69
  70 =item svcnum - primary key (assigned automatically for new accounts)
  71
  72 =item domain
  73
  74 =item catchall - optional svcnum of an svc_acct record, designating an email catchall account.
  75
  76 =item suffix -
  77
  78 =item parent_svcnum -
  79
  80 =item registrarnum - Registrar (see L<FS::registrar>)
  81
  82 =item registrarkey - Registrar key or password for this domain
  83
  84 =item setup_date - UNIX timestamp
  85
  86 =item renewal_interval - Number of days before expiration date to start renewal
  87
  88 =item expiration_date - UNIX timestamp
  89
  90 =item max_accounts
  91
  92 =back
  93
  94 =head1 METHODS
  95
  96 =over 4
  97
  98 =item new HASHREF
  99
 100 Creates a new domain.  To add the domain to the database, see L<"insert">.
 101
 102 =cut
 103
 104 sub table_info {
 105   {
 106     'name' => 'Domain',
 107     'sorts' => 'domain',
 108     'display_weight' => 20,
 109     'cancel_weight'  => 60,
 110     'fields' => {
 111       'domain' => 'Domain',
 112       'parent_svcnum' => {
 113                          label => 'Parent domain / Communigate administrator domain',
 114                          type  => 'select',
 115                          select_table => 'svc_domain',
 116                          select_key => 'svcnum',
 117                          select_label => 'domain',
 118                          disable_inventory => 1,
 119                          disable_select    => 1,
 120                        },
 121       'max_accounts' => { label => 'Maximum number of accounts',
 122                           'disable_inventory' => 1,
 123                         },
 124       'cgp_aliases' => {
 125                          label => 'Communigate aliases',
 126                          type  => 'text',
 127                          disable_inventory => 1,
 128                          disable_select    => 1,
 129                        },
 130       'cgp_accessmodes' => {
 131                              label => 'Communigate enabled services',
 132                              type  => 'communigate_pro-accessmodes',
 133                              disable_inventory => 1,
 134                              disable_select    => 1,
 135                            },
 136
 137       'acct_def_cgp_accessmodes' => {
 138                              label => 'Acct. default Communigate enabled services',
 139                              type  => 'communigate_pro-accessmodes',
 140                              disable_inventory => 1,
 141                              disable_select    => 1,
 142                            },
 143       'acct_def_password_selfchange' => { label => 'Acct. default Password modification',
 144                                  type  => 'checkbox',
 145                             disable_inventory => 1,
 146                             disable_select    => 1,
 147                                },
 148       'acct_def_password_recover'    => { label => 'Acct. default Password recovery',
 149                                  type  => 'checkbox',
 150                             disable_inventory => 1,
 151                             disable_select    => 1,
 152                                },
 153       'acct_def_cgp_deletemode' => {
 154                             label => 'Acct. default Communigate message delete method',
 155                             type  => 'select',
 156                             select_list => [ 'Move To Trash', 'Immediately', 'Mark' ],
 157                             disable_inventory => 1,
 158                             disable_select    => 1,
 159                           },
 160       'acct_def_cgp_emptytrash' => {
 161                             label => 'Acct. default Communigate on logout remove trash',
 162                             type        => 'select',
 163                             select_list => __PACKAGE__->cgp_emptytrash_values,
 164                             disable_inventory => 1,
 165                             disable_select    => 1,
 166                           },
 167       'acct_def_quota'     => {
 168                        label => 'Acct. default Quota', #Mail storage limit
 169                        type => 'text',
 170                        disable_inventory => 1,
 171                        disable_select => 1,
 172                      },
 173       'acct_def_file_quota'=> {
 174                        label => 'Acct. default File storage limit',
 175                        type => 'text',
 176                        disable_inventory => 1,
 177                        disable_select => 1,
 178                      },
 179       'acct_def_file_maxnum'=> {
 180                        label => 'Acct. default Number of files limit',
 181                        type => 'text',
 182                        disable_inventory => 1,
 183                        disable_select => 1,
 184                      },
 185       'acct_def_file_maxsize'=> {
 186                        label => 'Acct. default File size limit',
 187                        type => 'text',
 188                        disable_inventory => 1,
 189                        disable_select => 1,
 190                      },
 191       'acct_def_cgp_rulesallowed'   => {
 192         label       => 'Acct. default Allowed mail rules',
 193         type        => 'select',
 194         select_list => [ '', 'No', 'Filter Only', 'All But Exec', 'Any' ],
 195         disable_inventory => 1,
 196         disable_select    => 1,
 197       },
 198       'acct_def_cgp_rpopallowed'    => {
 199         label => 'Acct. default RPOP modifications',
 200         type  => 'checkbox',
 201       },
 202       'acct_def_cgp_mailtoall'      => {
 203         label => 'Acct. default Accepts mail to "all"',
 204         type  => 'checkbox',
 205       },
 206       'acct_def_cgp_addmailtrailer' => {
 207         label => 'Acct. default Add trailer to sent mail',
 208         type  => 'checkbox',
 209       },
 210       'acct_def_cgp_archiveafter'   => {
 211         label       => 'Archive messages after',
 212         type        => 'select',
 213         select_hash => [
 214                          -2 => 'default(730 days)',
 215                          0 => 'Never',
 216                          86400 => '24 hours',
 217                          172800 => '2 days',
 218                          259200 => '3 days',
 219                          432000 => '5 days',
 220                          604800 => '7 days',
 221                          1209600 => '2 weeks',
 222                          2592000 => '30 days',
 223                          7776000 => '90 days',
 224                          15552000 => '180 days',
 225                          31536000 => '365 days',
 226                          63072000 => '730 days',
 227                        ],
 228         disable_inventory => 1,
 229         disable_select    => 1,
 230       },
 231       'trailer' => {
 232         label => 'Mail trailer',
 233         type  => 'textarea',
 234         disable_inventory => 1,
 235         disable_select    => 1,
 236       },
 237       'acct_def_cgp_language' => {
 238                             label => 'Acct. default language',
 239                             type  => 'select',
 240                             select_list => [ '', qw( English Arabic Chinese Dutch French German Hebrew Italian Japanese Portuguese Russian Slovak Spanish Thai ) ],
 241                             disable_inventory => 1,
 242                             disable_select    => 1,
 243                         },
 244       'acct_def_cgp_timezone' => {
 245                             label       => 'Acct. default time zone',
 246                             type        => 'select',
 247                             select_list => __PACKAGE__->cgp_timezone_values,
 248                             disable_inventory => 1,
 249                             disable_select    => 1,
 250                         },
 251       'acct_def_cgp_skinname' => {
 252                             label => 'Acct. default layout',
 253                             type  => 'select',
 254                             select_list => [ '', '***', 'GoldFleece', 'Skin2' ],
 255                             disable_inventory => 1,
 256                             disable_select    => 1,
 257                         },
 258       'acct_def_cgp_prontoskinname' => {
 259                             label => 'Acct. default Pronto style',
 260                             type  => 'select',
 261                             select_list => [ '', 'Pronto', 'Pronto-darkflame', 'Pronto-steel', 'Pronto-twilight', ],
 262                             disable_inventory => 1,
 263                             disable_select    => 1,
 264                         },
 265       'acct_def_cgp_sendmdnmode' => {
 266         label => 'Acct. default send read receipts',
 267         type  => 'select',
 268         select_list => [ '', 'Never', 'Manually', 'Automatically' ],
 269         disable_inventory => 1,
 270         disable_select    => 1,
 271       },
 272     },
 273   };
 274 }
 275
 276 sub table { 'svc_domain'; }
 277
 278 sub search_sql {
 279   my($class, $string) = @_;
 280   $class->search_sql_field('domain', $string);
 281 }
 282
 283
 284 =item label
 285
 286 Returns the domain.
 287
 288 =cut
 289
 290 sub label {
 291   my $self = shift;
 292   $self->domain;
 293 }
 294
 295 =item insert [ , OPTION => VALUE ... ]
 296
 297 Adds this domain to the database.  If there is an error, returns the error,
 298 otherwise returns false.
 299
 300 The additional fields I<pkgnum> and I<svcpart> (see L<FS::cust_svc>) should be
 301 defined.  An FS::cust_svc record will be created and inserted.
 302
 303 The additional field I<action> should be set to I<N> for new domains, I<M>
 304 for transfers, or I<I> for no action (registered elsewhere).
 305
 306 The additional field I<email> can be used to manually set the admin contact
 307 email address on this email.  Otherwise, the svc_acct records for this package
 308 (see L<FS::cust_pkg>) are searched.  If there is exactly one svc_acct record
 309 in the same package, it is automatically used.  Otherwise an error is returned.
 310
 311 If any I<soamachine> configuration file exists, an SOA record is added to
 312 the domain_record table (see <FS::domain_record>).
 313
 314 If any records are defined in the I<defaultrecords> configuration file,
 315 appropriate records are added to the domain_record table (see
 316 L<FS::domain_record>).
 317
 318 Currently available options are: I<depend_jobnum>
 319
 320 If I<depend_jobnum> is set (to a scalar jobnum or an array reference of
 321 jobnums), all provisioning jobs will have a dependancy on the supplied
 322 jobnum(s) (they will not run until the specific job(s) complete(s)).
 323
 324 =cut
 325
 326 sub insert {
 327   my $self = shift;
 328   my $error;
 329
 330   local $SIG{HUP} = 'IGNORE';
 331   local $SIG{INT} = 'IGNORE';
 332   local $SIG{QUIT} = 'IGNORE';
 333   local $SIG{TERM} = 'IGNORE';
 334   local $SIG{TSTP} = 'IGNORE';
 335   local $SIG{PIPE} = 'IGNORE';
 336
 337   my $oldAutoCommit = $FS::UID::AutoCommit;
 338   local $FS::UID::AutoCommit = 0;
 339   my $dbh = dbh;
 340
 341   $error =  $self->SUPER::insert(@_)
 342          || $self->insert_defaultrecords;
 343   if ( $error ) {
 344     $dbh->rollback if $oldAutoCommit;
 345     return $error;
 346   }
 347
 348   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 349
 350   ''; #no error
 351 }
 352
 353 =item insert_defaultrecords
 354
 355 =cut
 356
 357 sub insert_defaultrecords {
 358   my $self = shift;
 359
 360   local $SIG{HUP} = 'IGNORE';
 361   local $SIG{INT} = 'IGNORE';
 362   local $SIG{QUIT} = 'IGNORE';
 363   local $SIG{TERM} = 'IGNORE';
 364   local $SIG{TSTP} = 'IGNORE';
 365   local $SIG{PIPE} = 'IGNORE';
 366
 367   my $oldAutoCommit = $FS::UID::AutoCommit;
 368   local $FS::UID::AutoCommit = 0;
 369   my $dbh = dbh;
 370
 371   if ( $soamachine ) {
 372     my $soa = new FS::domain_record {
 373       'svcnum'  => $self->svcnum,
 374       'reczone' => '@',
 375       'recaf'   => 'IN',
 376       'rectype' => 'SOA',
 377       'recdata' => "$soamachine $soaemail ( ". time2str("%Y%m%d", time). "00 ".
 378                    "$soarefresh $soaretry $soaexpire $soadefaultttl )"
 379     };
 380     my $error = $soa->insert;
 381     if ( $error ) {
 382       $dbh->rollback if $oldAutoCommit;
 383       return "couldn't insert SOA record: $error";
 384     }
 385
 386     foreach my $record ( @defaultrecords ) {
 387       my($zone,$af,$type,$data) = split(/\s+/,$record,4);
 388       my $domain_record = new FS::domain_record {
 389         'svcnum'  => $self->svcnum,
 390         'reczone' => $zone,
 391         'recaf'   => $af,
 392         'rectype' => $type,
 393         'recdata' => $data,
 394       };
 395       my $error = $domain_record->insert;
 396       if ( $error ) {
 397         $dbh->rollback if $oldAutoCommit;
 398         return "couldn't insert record: $error";
 399       }
 400     }
 401
 402   }
 403
 404   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 405
 406   ''; #no error
 407 }
 408
 409 =item delete
 410
 411 Deletes this domain from the database.  If there is an error, returns the
 412 error, otherwise returns false.
 413
 414 The corresponding FS::cust_svc record will be deleted as well.
 415
 416 =cut
 417
 418 sub delete {
 419   my $self = shift;
 420
 421   return "Can't delete a domain which has accounts!"
 422     if qsearch( 'svc_acct', { 'domsvc' => $self->svcnum } );
 423
 424   #return "Can't delete a domain with (domain_record) zone entries!"
 425   #  if qsearch('domain_record', { 'svcnum' => $self->svcnum } );
 426
 427   local $SIG{HUP} = 'IGNORE';
 428   local $SIG{INT} = 'IGNORE';
 429   local $SIG{QUIT} = 'IGNORE';
 430   local $SIG{TERM} = 'IGNORE';
 431   local $SIG{TSTP} = 'IGNORE';
 432   local $SIG{PIPE} = 'IGNORE';
 433
 434   my $oldAutoCommit = $FS::UID::AutoCommit;
 435   local $FS::UID::AutoCommit = 0;
 436   my $dbh = dbh;
 437
 438   foreach my $domain_record ( reverse $self->domain_record ) {
 439     my $error = $domain_record->delete;
 440     if ( $error ) {
 441       $dbh->rollback if $oldAutoCommit;
 442       return "can't delete DNS entry: ".
 443              join(' ', map $domain_record->$_(),
 444                            qw( reczone recaf rectype recdata )
 445                  ).
 446              ":$error";
 447     }
 448   }
 449
 450   my $error = $self->SUPER::delete(@_);
 451   if ( $error ) {
 452     $dbh->rollback if $oldAutoCommit;
 453     return $error;
 454   }
 455
 456   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 457 }
 458
 459 =item replace OLD_RECORD
 460
 461 Replaces OLD_RECORD with this one in the database.  If there is an error,
 462 returns the error, otherwise returns false.
 463
 464 =cut
 465
 466 sub replace {
 467   my $new = shift;
 468
 469   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
 470               ? shift
 471               : $new->replace_old;
 472
 473   return "Can't change domain - reorder."
 474     if $old->getfield('domain') ne $new->getfield('domain')
 475     && ! $conf->exists('svc_domain-edit_domain');
 476
 477   # Better to do it here than to force the caller to remember that svc_domain is weird.
 478   $new->setfield(action => 'I');
 479   my $error = $new->SUPER::replace($old, @_);
 480   return $error if $error;
 481 }
 482
 483 =item suspend
 484
 485 Just returns false (no error) for now.
 486
 487 Called by the suspend method of FS::cust_pkg (see L<FS::cust_pkg>).
 488
 489 =item unsuspend
 490
 491 Just returns false (no error) for now.
 492
 493 Called by the unsuspend method of FS::cust_pkg (see L<FS::cust_pkg>).
 494
 495 =item cancel
 496
 497 Just returns false (no error) for now.
 498
 499 Called by the cancel method of FS::cust_pkg (see L<FS::cust_pkg>).
 500
 501 =item check
 502
 503 Checks all fields to make sure this is a valid domain.  If there is an error,
 504 returns the error, otherwise returns false.  Called by the insert and replace
 505 methods.
 506
 507 Sets any fixed values; see L<FS::part_svc>.
 508
 509 =cut
 510
 511 sub check {
 512   my $self = shift;
 513
 514   my $x = $self->setfixed;
 515   return $x unless ref($x);
 516   #my $part_svc = $x;
 517
 518   my $error = $self->ut_numbern('svcnum')
 519               || $self->ut_numbern('catchall')
 520               || $self->ut_numbern('max_accounts')
 521               || $self->ut_anything('trailer') #well
 522               || $self->ut_textn('cgp_aliases') #well
 523               || $self->ut_enum('acct_def_password_selfchange', [ '', 'Y' ])
 524               || $self->ut_enum('acct_def_password_recover',    [ '', 'Y' ])
 525               || $self->ut_textn('acct_def_cgp_accessmodes')
 526               || $self->ut_alphan('acct_def_quota')
 527               || $self->ut_alphan('acct_def_file_quota')
 528               || $self->ut_alphan('acct_def_maxnum')
 529               || $self->ut_alphan('acct_def_maxsize')
 530               #settings
 531               || $self->ut_alphasn('acct_def_cgp_rulesallowed')
 532               || $self->ut_enum('acct_def_cgp_rpopallowed', [ '', 'Y' ])
 533               || $self->ut_enum('acct_def_cgp_mailtoall', [ '', 'Y' ])
 534               || $self->ut_enum('acct_def_cgp_addmailtrailer', [ '', 'Y' ])
 535               || $self->ut_snumbern('acct_def_cgp_archiveafter')
 536               #preferences
 537               || $self->ut_alphasn('acct_def_cgp_deletemode')
 538               || $self->ut_enum('acct_def_cgp_emptytrash',
 539                                    $self->cgp_emptytrash_values )
 540               || $self->ut_alphan('acct_def_cgp_language')
 541               || $self->ut_textn('acct_def_cgp_timezone')
 542               || $self->ut_textn('acct_def_cgp_skinname')
 543               || $self->ut_textn('acct_def_cgp_prontoskinname')
 544               || $self->ut_alphan('acct_def_cgp_sendmdnmode')
 545               #mail
 546   ;
 547   return $error if $error;
 548
 549   #hmm
 550   my $pkgnum;
 551   if ( $self->svcnum ) {
 552     my $cust_svc = qsearchs( 'cust_svc', { 'svcnum' => $self->svcnum } );
 553     $pkgnum = $cust_svc->pkgnum;
 554   } else {
 555     $pkgnum = $self->pkgnum;
 556   }
 557
 558   my($recref) = $self->hashref;
 559
 560   #if ( $recref->{domain} =~ /^([\w\-\.]{1,22})\.(com|net|org|edu)$/ ) {
 561   if ( $recref->{domain} =~ /^([\w\-]{1,63})\.(com|net|org|edu|tv|info|biz)$/ ) {
 562     $recref->{domain} = "$1.$2";
 563     $recref->{suffix} ||= $2;
 564   # hmmmmmmmm.
 565   } elsif ( $whois_hack && $recref->{domain} =~ /^([\w\-\.\/]+)\.(\w+)$/ ) {
 566     $recref->{domain} = "$1.$2";
 567     # need to match a list of suffixes - no guarantee they're top-level..
 568     # http://wiki.mozilla.org/TLD_List
 569     # but this will have to do for now...
 570     $recref->{suffix} ||= $2;
 571   } else {
 572     return "Illegal domain ". $recref->{domain}.
 573            " (or unknown registry - try \$whois_hack)";
 574   }
 575
 576   $self->suffix =~ /(^|\.)(\w+)$/
 577     or return "can't parse suffix for TLD: ". $self->suffix;
 578   my $tld = $2;
 579   return "No such TLD: .$tld" unless tld_exists($tld);
 580
 581   if ( $recref->{catchall} ne '' ) {
 582     my $svc_acct = qsearchs( 'svc_acct', { 'svcnum' => $recref->{catchall} } );
 583     return "Unknown catchall" unless $svc_acct;
 584   }
 585
 586   $self->ut_alphan('suffix')
 587     or $self->ut_foreign_keyn('registrarnum', 'registrar', 'registrarnum')
 588     or $self->ut_textn('registrarkey')
 589     or $self->ut_numbern('setup_date')
 590     or $self->ut_numbern('renewal_interval')
 591     or $self->ut_numbern('expiration_date')
 592     or $self->SUPER::check;
 593
 594 }
 595
 596 sub _check_duplicate {
 597   my $self = shift;
 598
 599   $self->lock_table;
 600
 601   if ( qsearchs( 'svc_domain', { 'domain' => $self->domain } ) ) {
 602     return "Domain in use (here)";
 603   } else {
 604     return '';
 605   }
 606 }
 607
 608 =item domain_record
 609
 610 =cut
 611
 612 sub domain_record {
 613   my $self = shift;
 614
 615   my %order = (
 616     'SOA'   => 1,
 617     'NS'    => 2,
 618     'MX'    => 3,
 619     'CNAME' => 4,
 620     'A'     => 5,
 621     'TXT'   => 6,
 622     'PTR'   => 7,
 623     'SRV'   => 8,
 624   );
 625
 626   my %sort = (
 627     #'SOA'   => sub { $_[0]->recdata cmp $_[1]->recdata }, #sure hope not though
 628 #    'SOA'   => sub { 0; },
 629 #    'NS'    => sub { 0; },
 630     'MX'    => sub { my( $a_weight, $a_name ) = split(/\s+/, $_[0]->recdata);
 631                      my( $b_weight, $b_name ) = split(/\s+/, $_[1]->recdata);
 632                      $a_weight <=> $b_weight or $a_name cmp $b_name;
 633                    },
 634     'CNAME' => sub { $_[0]->reczone cmp $_[1]->reczone },
 635     'A'     => sub { $_[0]->reczone cmp $_[1]->reczone },
 636
 637 #    'TXT'   => sub { 0; },
 638     'PTR'   => sub { $_[0]->reczone <=> $_[1]->reczone },
 639   );
 640
 641   map { $_ } #return $self->num_domain_record( PARAMS ) unless wantarray;
 642   sort {    $order{$a->rectype} <=> $order{$b->rectype}
 643          or &{ $sort{$a->rectype} || sub { 0; } }($a, $b)
 644        }
 645        qsearch('domain_record', { svcnum => $self->svcnum } );
 646
 647 }
 648
 649 sub catchall_svc_acct {
 650   my $self = shift;
 651   if ( $self->catchall ) {
 652     qsearchs( 'svc_acct', { 'svcnum' => $self->catchall } );
 653   } else {
 654     '';
 655   }
 656 }
 657
 658 =item whois
 659
 660 # Returns the Net::Whois::Domain object (see L<Net::Whois>) for this domain, or
 661 # undef if the domain is not found in whois.
 662
 663 (If $FS::svc_domain::whois_hack is true, returns that in all cases instead.)
 664
 665 =cut
 666
 667 sub whois {
 668   #$whois_hack or new Net::Whois::Domain $_[0]->domain;
 669   #$whois_hack or die "whois_hack not set...\n";
 670 }
 671
 672 =back
 673
 674 =head1 BUGS
 675
 676 Delete doesn't send a registration template.
 677
 678 All registries should be supported.
 679
 680 Should change action to a real field.
 681
 682 The $recref stuff in sub check should be cleaned up.
 683
 684 =head1 SEE ALSO
 685
 686 L<FS::svc_Common>, L<FS::Record>, L<FS::Conf>, L<FS::cust_svc>,
 687 L<FS::part_svc>, L<FS::cust_pkg>, L<Net::Whois>, schema.html from the base
 688 documentation, config.html from the base documentation.
 689
 690 =cut
 691
 692 1;
 693
 694