FS/FS/pay_batch/RBC.pm

   1 package FS::pay_batch::RBC;
   2
   3 use strict;
   4 use vars qw(@ISA %import_info %export_info $name);
   5 use Date::Format 'time2str';
   6 use Date::Parse;
   7 use FS::Conf;
   8 use Encode 'encode';
   9 use feature 'state';
  10
  11 my $conf;
  12 my ($client_num, $shortname, $longname, $trans_code, $testmode, $i, $declined, $totaloffset);
  13
  14 $name = 'RBC';
  15 # Royal Bank of Canada ACH Direct Payments Service
  16
  17 # Meaning of initial characters in records:
  18 # 0 - header row, skipped by begin_condition
  19 # 1 - Debit Detail Record (only when subtype is 0)
  20 # 2 - Credit Detail Record, we die with a parse error (shouldn't appear in freeside-generated batches)
  21 # 3 - Account Trailer Record (appears after Returned items, we skip)
  22 # 4 - Client Trailer Record, indicates end of batch in end_condition
  23 #
  24 # Subtypes (27th char) indicate different kinds of Debit/Credit records
  25 # 0 - Credit/Debit Detail Record
  26 # 3 - Error Message Record
  27 # 4 - Foreign Currency Information Records
  28 # We skip all subtypes except 0
  29 #
  30 # additional info available at https://www.rbcroyalbank.com/ach/cid-213166.html
  31 %import_info = (
  32   'filetype'    => 'fixed',
  33   #this only really applies to Debit Detail, but we otherwise only need first char
  34   'formatre'    =>
  35   '^(.).{3}(.{10}).{5}(.{4}).{3}(.).{11}(.{19}).{6}(.{30})(.{2})(.{2})(.{4}).{9}(.{9})(.{18}).{6}(.{14}).{23}(.).{9}\r?$',
  36   'fields' => [ qw(
  37     recordtype
  38     clientnum
  39     batchnum
  40     subtype
  41     paybatchnum
  42     custname
  43     paydate_month
  44     paydate_day
  45     paydate_year
  46     bank
  47     payinfo
  48     paid
  49     status
  50     ) ],
  51   'hook' => sub {
  52     # pull client_num from config and check it against what's in the batch
  53     state $clientnum ||= do {
  54       my $conf = FS::Conf->new;
  55       my @config = $conf->config("batchconfig-RBC");
  56       $config[0];
  57     };
  58
  59     my $hash = shift;
  60     $hash->{'paid'} = sprintf("%.2f", $hash->{'paid'} / 100 );
  61     my $paydate = $hash->{'paydate_year'} . $hash->{'paydate_month'} . $hash->{'paydate_day'};
  62     $hash->{'_date'} = str2time($paydate, 'local');
  63     $hash->{'payinfo'} =~ s/^(\S+).*/$1/; # these often have trailing spaces
  64     $hash->{'payinfo'} = $hash->{'payinfo'} . '@' . $hash->{'bank'};
  65
  66     if ( $clientnum and $hash->{clientnum} ne $clientnum ) {
  67       die "RBC client number in batch (".$hash->{clientnum}.") does not ".
  68         "match configuration.\n";
  69     }
  70     '';
  71   },
  72   'approved'    => sub {
  73       my $hash = shift;
  74       ($hash->{'status'} eq ' ') || ($hash->{'status'} eq 'W');
  75   },
  76   'declined'    => sub {
  77       my $hash = shift;
  78       my $status = $hash->{'status'};
  79       my $message = '';
  80       if ($status eq 'E') {
  81         $message = 'Reversed payment';
  82       } elsif ($status eq 'R') {
  83         $message = 'Rejected payment';
  84       } elsif ($status eq 'U') {
  85         $message = 'Returned payment';
  86       } elsif ($status eq 'T') {
  87         $message = 'Error';
  88       } else {
  89         return 0;
  90       }
  91       $hash->{'error_message'} = $message;
  92       $declined->{$hash->{'paybatchnum'}} = 1;
  93       return 1;
  94   },
  95   'begin_condition' => sub {
  96       my $hash = shift;
  97       # Debit Detail Record
  98       if ($hash->{recordtype} eq '1') {
  99         $declined = {};
 100         $totaloffset = 0;
 101         return 1;
 102       # Credit Detail Record, will immediately trigger end condition & error
 103       } elsif ($hash->{recordtype} eq '2') {
 104         return 1;
 105       } else {
 106         return 0;
 107       }
 108   },
 109   'end_hook'    => sub {
 110       my( $hash, $total, $line ) = @_;
 111       return "Can't process Credit Detail Record, aborting import"
 112         if ($hash->{'recordtype'} eq '2');
 113       $total += $totaloffset;
 114       $total = sprintf("%.2f", $total);
 115       # We assume here that this is an 'All Records' or 'Input Records' report.
 116       my $batch_total = sprintf("%.2f", substr($line, 59, 18) / 100);
 117       return "Our total $total does not match bank total $batch_total!"
 118         if $total != $batch_total;
 119       return '';
 120   },
 121   'end_condition' => sub {
 122       my $hash = shift;
 123       return ($hash->{recordtype} eq '4')  # Client Trailer Record
 124           || ($hash->{recordtype} eq '2'); # Credit Detail Record, will throw error in end_hook
 125   },
 126   'skip_condition' => sub {
 127       my $hash = shift;
 128       #we already declined it this run, no takebacks
 129       if ($declined->{$hash->{'paybatchnum'}}) {
 130         #file counts this as part of total, but we skip
 131         $totaloffset += sprintf("%.2f", $hash->{'paid'} / 100 )
 132           if $hash->{'status'} eq ' '; #false laziness with 'approved' above
 133         return 1;
 134       }
 135       return
 136         ($hash->{'recordtype'} eq '3') || #Account Trailer Record, concludes returned items
 137         ($hash->{'subtype'} ne '0'); #error messages, etc, too late to apply to previous entry
 138   },
 139 );
 140
 141 %export_info = (
 142   init => sub {
 143     $conf = shift;
 144     ($client_num,
 145      $shortname,
 146      $longname,
 147      $trans_code,
 148      $testmode
 149      ) = $conf->config("batchconfig-RBC");
 150     $testmode = '' unless $testmode eq 'TEST';
 151     $i = 1;
 152   },
 153   header => sub {
 154     my $pay_batch = shift;
 155     my $mode = $testmode ? 'TEST' : 'PROD';
 156     my $filenum = $testmode ? 'TEST' : sprintf("%04u", $pay_batch->batchnum);
 157     my $qualifier = $pay_batch->type eq 'CREDIT' ? 'D' : 'A';
 158     '$$AAP'.$qualifier.'STD0152['.$mode.'[NL$$'."\n".
 159     '000001'.
 160     'A'.
 161     'HDR'.
 162     sprintf("%10s", $client_num).
 163     sprintf("%-30s", $longname).
 164     $filenum.
 165     time2str("%Y%j", $pay_batch->download).
 166     'CAD'.
 167     '1'.
 168     ' ' x 87  # filler/reserved fields
 169     ;
 170   },
 171   row => sub {
 172     my ($cust_pay_batch, $pay_batch) = @_;
 173     my ($account, $aba) = split('@', $cust_pay_batch->payinfo);
 174     my($bankno, $branch);
 175     if ( $aba =~ /^0(\d{3})(\d{5})$/ ) { # standard format for Canadian bank ID
 176       ($bankno, $branch) = ( $1, $2 );
 177     } elsif ( $aba =~ /^(\d{5})\.(\d{3})$/ ) { #how we store branches
 178       ($branch, $bankno) = ( $1, $2 );
 179     } else {
 180       die "invalid branch/routing number '$aba'\n";
 181     }
 182
 183     ## set custname to business name if business checking or savings account is used otherwise leave as first and last name.
 184     my $custname = $cust_pay_batch->cust_main->batch_payment_payname($cust_pay_batch);
 185
 186     $i++;
 187
 188     ## set to D for debit by default, then override to what cust_pay_batch has as payments may not have paycode.
 189     my $debitorcredit = 'D';
 190     $debitorcredit = $cust_pay_batch->paycode unless !$cust_pay_batch->paycode;
 191
 192     sprintf("%06u", $i).
 193     $debitorcredit.
 194     sprintf("%3s",$trans_code).
 195     sprintf("%10s",$client_num).
 196     ' '.
 197     sprintf("%-19s", $cust_pay_batch->paybatchnum).
 198     '00'.
 199     sprintf("%04s", $bankno).
 200     sprintf("%05s", $branch).
 201     sprintf("%-18s", $account).
 202     ' '.
 203     sprintf("%010.0f",$cust_pay_batch->amount*100).
 204     '      '.
 205     time2str("%Y%j", time + 86400).
 206     sprintf("%-30.30s", encode('utf8', $custname)).
 207     'E'. # English
 208     ' '.
 209     sprintf("%-15s", $shortname).
 210     'CAD'.
 211     ' '.
 212     'CAN'.
 213     '    '.
 214     'N' # no customer optional information follows
 215     ;
 216 # Note: IAT Address Information and Remittance records are not
 217 # supported. This means you probably can't process payments
 218 # destined to U.S. bank accounts.  If you need this feature, contact
 219 # Freeside Internet Services.
 220   },
 221   footer => sub {
 222     my ($pay_batch, $batchcount, $batchtotal) = @_;
 223
 224     my $batch_info = '0' x 20 . sprintf("%06u", $batchcount) . sprintf("%014.0f", $batchtotal*100);
 225     $batch_info = sprintf("%06u", $batchcount) . sprintf("%014.0f", $batchtotal*100) . '0' x 20 if ($pay_batch->type eq 'CREDIT');
 226
 227     sprintf("%06u", $i + 1).
 228     'Z'.
 229     'TRL'.
 230     sprintf("%10s", $client_num).
 231     $batch_info.
 232     '00' .
 233     '000000' . # total number of customer information records
 234     ' ' x 84
 235     ;
 236   },
 237 );
 238
 239 ## this format can handle credit transactions
 240 sub can_handle_credits {
 241   1;
 242 }
 243
 244 1;
 245