FS/FS/part_svc.pm

   1 package FS::part_svc;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG );
   5 use Tie::IxHash;
   6 use FS::Record qw( qsearch qsearchs fields dbh );
   7 use FS::Schema qw( dbdef );
   8 use FS::part_svc_column;
   9 use FS::part_export;
  10 use FS::export_svc;
  11 use FS::cust_svc;
  12
  13 @ISA = qw(FS::Record);
  14
  15 $DEBUG = 0;
  16
  17 =head1 NAME
  18
  19 FS::part_svc - Object methods for part_svc objects
  20
  21 =head1 SYNOPSIS
  22
  23   use FS::part_svc;
  24
  25   $record = new FS::part_svc \%hash
  26   $record = new FS::part_svc { 'column' => 'value' };
  27
  28   $error = $record->insert;
  29   $error = $record->insert( [ 'pseudofield' ] );
  30   $error = $record->insert( [ 'pseudofield' ], \%exportnums );
  31
  32   $error = $new_record->replace($old_record);
  33   $error = $new_record->replace($old_record, '1.3-COMPAT', [ 'pseudofield' ] );
  34   $error = $new_record->replace($old_record, '1.3-COMPAT', [ 'pseudofield' ], \%exportnums );
  35
  36   $error = $record->delete;
  37
  38   $error = $record->check;
  39
  40 =head1 DESCRIPTION
  41
  42 An FS::part_svc represents a service definition.  FS::part_svc inherits from
  43 FS::Record.  The following fields are currently supported:
  44
  45 =over 4
  46
  47 =item svcpart - primary key (assigned automatically for new service definitions)
  48
  49 =item svc - text name of this service definition
  50
  51 =item svcdb - table used for this service.  See L<FS::svc_acct>,
  52 L<FS::svc_domain>, and L<FS::svc_forward>, among others.
  53
  54 =item disabled - Disabled flag, empty or `Y'
  55
  56 =item preserve - Preserve after cancellation, empty or 'Y'
  57
  58 =back
  59
  60 =head1 METHODS
  61
  62 =over 4
  63
  64 =item new HASHREF
  65
  66 Creates a new service definition.  To add the service definition to the
  67 database, see L<"insert">.
  68
  69 =cut
  70
  71 sub table { 'part_svc'; }
  72
  73 =item insert [ EXTRA_FIELDS_ARRAYREF [ , EXPORTNUMS_HASHREF [ , JOB ] ] ]
  74
  75 Adds this service definition to the database.  If there is an error, returns
  76 the error, otherwise returns false.
  77
  78 The following pseudo-fields may be defined, and will be maintained in
  79 the part_svc_column table appropriately (see L<FS::part_svc_column>).
  80
  81 =over 4
  82
  83 =item I<svcdb>__I<field> - Default or fixed value for I<field> in I<svcdb>.
  84
  85 =item I<svcdb>__I<field>_flag - defines I<svcdb>__I<field> action: null or empty (no default), `D' for default, `F' for fixed (unchangeable), `M' for manual selection from inventory, or `A' for automatic selection from inventory.  For virtual fields, can also be 'X' for excluded.
  86
  87 =back
  88
  89 If you want to add part_svc_column records for fields that do not exist as
  90 (real or virtual) fields in the I<svcdb> table, make sure to list then in
  91 EXTRA_FIELDS_ARRAYREF also.
  92
  93 If EXPORTNUMS_HASHREF is specified (keys are exportnums and values are
  94 boolean), the appopriate export_svc records will be inserted.
  95
  96 TODOC: JOB
  97
  98 =cut
  99
 100 sub insert {
 101   my $self = shift;
 102   my @fields = ();
 103   my @exportnums = ();
 104   @fields = @{shift(@_)} if @_;
 105   if ( @_ ) {
 106     my $exportnums = shift;
 107     @exportnums = grep $exportnums->{$_}, keys %$exportnums;
 108   }
 109   my $job = '';
 110   $job = shift if @_;
 111
 112   local $SIG{HUP} = 'IGNORE';
 113   local $SIG{INT} = 'IGNORE';
 114   local $SIG{QUIT} = 'IGNORE';
 115   local $SIG{TERM} = 'IGNORE';
 116   local $SIG{TSTP} = 'IGNORE';
 117   local $SIG{PIPE} = 'IGNORE';
 118
 119   my $oldAutoCommit = $FS::UID::AutoCommit;
 120   local $FS::UID::AutoCommit = 0;
 121   my $dbh = dbh;
 122
 123   my $error = $self->SUPER::insert;
 124   if ( $error ) {
 125     $dbh->rollback if $oldAutoCommit;
 126     return $error;
 127   }
 128
 129   # add part_svc_column records
 130
 131   my $svcdb = $self->svcdb;
 132 #  my @rows = map { /^${svcdb}__(.*)$/; $1 }
 133 #    grep ! /_flag$/,
 134 #      grep /^${svcdb}__/,
 135 #        fields('part_svc');
 136   foreach my $field (
 137     grep { $_ ne 'svcnum'
 138            && ( defined( $self->getfield($svcdb.'__'.$_.'_flag') )
 139                 || $self->getfield($svcdb.'__'.$_.'_label') !~ /^\s*$/ )
 140          } (fields($svcdb), @fields)
 141   ) {
 142     my $part_svc_column = $self->part_svc_column($field);
 143     my $previous = qsearchs('part_svc_column', {
 144       'svcpart'    => $self->svcpart,
 145       'columnname' => $field,
 146     } );
 147
 148     my $flag  = $self->getfield($svcdb.'__'.$field.'_flag');
 149     my $label = $self->getfield($svcdb.'__'.$field.'_label');
 150     if ( uc($flag) =~ /^([A-Z])$/ || $label !~ /^\s*$/ ) {
 151
 152       if ( uc($flag) =~ /^([A-Z])$/ ) {
 153         my $parser = FS::part_svc->svc_table_fields($svcdb)->{$field}->{parse}
 154                      || sub { shift };
 155         $part_svc_column->setfield('columnflag', $1);
 156         $part_svc_column->setfield('columnvalue',
 157           &$parser($self->getfield($svcdb.'__'.$field))
 158         );
 159       }
 160
 161       $part_svc_column->setfield('columnlabel', $label)
 162         if $label !~ /^\s*$/;
 163
 164       if ( $previous ) {
 165         $error = $part_svc_column->replace($previous);
 166       } else {
 167         $error = $part_svc_column->insert;
 168       }
 169
 170     } else {
 171       $error = $previous ? $previous->delete : '';
 172     }
 173     if ( $error ) {
 174       $dbh->rollback if $oldAutoCommit;
 175       return $error;
 176     }
 177
 178   }
 179
 180   # add export_svc records
 181   my $slice = 100/scalar(@exportnums) if @exportnums;
 182   my $done = 0;
 183   foreach my $exportnum ( @exportnums ) {
 184     my $export_svc = new FS::export_svc ( {
 185       'exportnum' => $exportnum,
 186       'svcpart'   => $self->svcpart,
 187     } );
 188     $error = $export_svc->insert($job, $slice*$done++, $slice);
 189     if ( $error ) {
 190       $dbh->rollback if $oldAutoCommit;
 191       return $error;
 192     }
 193   }
 194
 195   # XXX shouldn't this update fixed values?
 196
 197   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 198
 199   '';
 200 }
 201
 202 =item delete
 203
 204 Currently unimplemented.  Set the "disabled" field instead.
 205
 206 =cut
 207
 208 sub delete {
 209   return "Can't (yet?) delete service definitions.";
 210 # check & make sure the svcpart isn't in cust_svc or pkg_svc (in any packages)?
 211 }
 212
 213 =item replace OLD_RECORD [ '1.3-COMPAT' [ , EXTRA_FIELDS_ARRAYREF [ , EXPORTNUMS_HASHREF [ , JOB ] ] ] ]
 214
 215 Replaces OLD_RECORD with this one in the database.  If there is an error,
 216 returns the error, otherwise returns false.
 217
 218 TODOC: 1.3-COMPAT
 219
 220 TODOC: EXTRA_FIELDS_ARRAYREF (same as insert method)
 221
 222 TODOC: JOB
 223
 224 =cut
 225
 226 sub replace {
 227   my ( $new, $old ) = ( shift, shift );
 228   my $compat = '';
 229   my @fields = ();
 230   my $exportnums;
 231   my $job = '';
 232   if ( @_ && $_[0] eq '1.3-COMPAT' ) {
 233     shift;
 234     $compat = '1.3';
 235     @fields = @{shift(@_)} if @_;
 236     $exportnums = @_ ? shift : '';
 237     $job = shift if @_;
 238   } else {
 239     return 'non-1.3-COMPAT interface not yet written';
 240     #not yet implemented
 241   }
 242
 243   return "Can't change svcdb for an existing service definition!"
 244     unless $old->svcdb eq $new->svcdb;
 245
 246   local $SIG{HUP} = 'IGNORE';
 247   local $SIG{INT} = 'IGNORE';
 248   local $SIG{QUIT} = 'IGNORE';
 249   local $SIG{TERM} = 'IGNORE';
 250   local $SIG{TSTP} = 'IGNORE';
 251   local $SIG{PIPE} = 'IGNORE';
 252
 253   my $oldAutoCommit = $FS::UID::AutoCommit;
 254   local $FS::UID::AutoCommit = 0;
 255   my $dbh = dbh;
 256
 257   my $error = $new->SUPER::replace( $old );
 258   if ( $error ) {
 259     $dbh->rollback if $oldAutoCommit;
 260     return $error;
 261   }
 262
 263   if ( $compat eq '1.3' ) {
 264
 265    # maintain part_svc_column records
 266
 267     my $svcdb = $new->svcdb;
 268     foreach my $field (
 269       grep { $_ ne 'svcnum'
 270              && ( defined( $new->getfield($svcdb.'__'.$_.'_flag') )
 271                   || $new->getfield($svcdb.'__'.$_.'_label') !~ /^\s*$/ )
 272            } (fields($svcdb),@fields)
 273     ) {
 274
 275       my $part_svc_column = $new->part_svc_column($field);
 276       my $previous = qsearchs('part_svc_column', {
 277         'svcpart'    => $new->svcpart,
 278         'columnname' => $field,
 279       } );
 280
 281       my $flag  = $new->getfield($svcdb.'__'.$field.'_flag');
 282       my $label = $new->getfield($svcdb.'__'.$field.'_label');
 283
 284       if ( uc($flag) =~ /^([A-Z])$/ || $label !~ /^\s*$/ ) {
 285
 286         if ( uc($flag) =~ /^([A-Z])$/ ) {
 287           $part_svc_column->setfield('columnflag', $1);
 288           my $parser = FS::part_svc->svc_table_fields($svcdb)->{$field}->{parse}
 289                      || sub { shift };
 290           $part_svc_column->setfield('columnvalue',
 291             &$parser($new->getfield($svcdb.'__'.$field))
 292           );
 293         } else {
 294           $part_svc_column->setfield('columnflag',  '');
 295           $part_svc_column->setfield('columnvalue', '');
 296         }
 297
 298         $part_svc_column->setfield('columnlabel', $label)
 299           if $label !~ /^\s*$/;
 300
 301         if ( $previous ) {
 302           $error = $part_svc_column->replace($previous);
 303         } else {
 304           $error = $part_svc_column->insert;
 305         }
 306       } else {
 307         $error = $previous ? $previous->delete : '';
 308       }
 309       if ( $error ) {
 310         $dbh->rollback if $oldAutoCommit;
 311         return $error;
 312       }
 313     }
 314
 315     # maintain export_svc records
 316
 317     if ( $exportnums ) {
 318
 319       #false laziness w/ edit/process/agent_type.cgi
 320       my @new_export_svc = ();
 321       foreach my $part_export ( qsearch('part_export', {}) ) {
 322         my $exportnum = $part_export->exportnum;
 323         my $hashref = {
 324           'exportnum' => $exportnum,
 325           'svcpart'   => $new->svcpart,
 326         };
 327         my $export_svc = qsearchs('export_svc', $hashref);
 328
 329         if ( $export_svc && ! $exportnums->{$exportnum} ) {
 330           $error = $export_svc->delete;
 331           if ( $error ) {
 332             $dbh->rollback if $oldAutoCommit;
 333             return $error;
 334           }
 335         } elsif ( ! $export_svc && $exportnums->{$exportnum} ) {
 336           push @new_export_svc, new FS::export_svc ( $hashref );
 337         }
 338
 339       }
 340
 341       my $slice = 100/scalar(@new_export_svc) if @new_export_svc;
 342       my $done = 0;
 343       foreach my $export_svc (@new_export_svc) {
 344         $error = $export_svc->insert($job, $slice*$done++, $slice);
 345         if ( $error ) {
 346           $dbh->rollback if $oldAutoCommit;
 347           return $error;
 348         }
 349         if ( $job ) {
 350           $error = $job->update_statustext( int( $slice * $done ) );
 351           if ( $error ) {
 352             $dbh->rollback if $oldAutoCommit;
 353             return $error;
 354           }
 355         }
 356       }
 357
 358     }
 359
 360   } else {
 361     $dbh->rollback if $oldAutoCommit;
 362     return 'non-1.3-COMPAT interface not yet written';
 363     #not yet implemented
 364   }
 365
 366   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 367
 368   '';
 369 }
 370
 371 =item check
 372
 373 Checks all fields to make sure this is a valid service definition.  If there is
 374 an error, returns the error, otherwise returns false.  Called by the insert
 375 and replace methods.
 376
 377 =cut
 378
 379 sub check {
 380   my $self = shift;
 381
 382   my $error;
 383   $error=
 384     $self->ut_numbern('svcpart')
 385     || $self->ut_text('svc')
 386     || $self->ut_alpha('svcdb')
 387     || $self->ut_enum('disabled', [ '', 'Y' ] )
 388     || $self->ut_enum('preserve', [ '', 'Y' ] )
 389   ;
 390   return $error if $error;
 391
 392   my @fields = eval { fields( $self->svcdb ) }; #might die
 393   return "Unknown svcdb: ". $self->svcdb. " (Error: $@)"
 394     unless @fields;
 395
 396   $self->SUPER::check;
 397 }
 398
 399 =item part_svc_column COLUMNNAME
 400
 401 Returns the part_svc_column object (see L<FS::part_svc_column>) for the given
 402 COLUMNNAME, or a new part_svc_column object if none exists.
 403
 404 =cut
 405
 406 sub part_svc_column {
 407   my( $self, $columnname) = @_;
 408   $self->svcpart &&
 409     qsearchs('part_svc_column',  {
 410                                    'svcpart'    => $self->svcpart,
 411                                    'columnname' => $columnname,
 412                                  }
 413   ) or new FS::part_svc_column {
 414                                  'svcpart'    => $self->svcpart,
 415                                  'columnname' => $columnname,
 416                                };
 417 }
 418
 419 =item all_part_svc_column
 420
 421 =cut
 422
 423 sub all_part_svc_column {
 424   my $self = shift;
 425   qsearch('part_svc_column', { 'svcpart' => $self->svcpart } );
 426 }
 427
 428 =item part_export [ EXPORTTYPE ]
 429
 430 Returns a list of all exports (see L<FS::part_export>) for this service, or,
 431 if an export type is specified, only returns exports of the given type.
 432
 433 =cut
 434
 435 sub part_export {
 436   my $self = shift;
 437   my %search;
 438   $search{'exporttype'} = shift if @_;
 439   sort { $a->weight <=> $b->weight }
 440   map { qsearchs('part_export', { 'exportnum' => $_->exportnum, %search } ) }
 441     qsearch('export_svc', { 'svcpart' => $self->svcpart } );
 442 }
 443
 444 =item part_export_usage
 445
 446 Returns a list of any exports (see L<FS::part_export>) for this service that
 447 are capable of reporting usage information.
 448
 449 =cut
 450
 451 sub part_export_usage {
 452   my $self = shift;
 453   grep $_->can('usage_sessions'), $self->part_export;
 454 }
 455
 456 =item part_export_did
 457
 458 Returns a list of any exports (see L<FS::part_export>) for this service that
 459 are capable of returing available DID (phone number) information.
 460
 461 =cut
 462
 463 sub part_export_did {
 464   my $self = shift;
 465   grep $_->can('get_dids'), $self->part_export;
 466 }
 467
 468 =item part_export_dsl_pull
 469
 470 Returns a list of any exports (see L<FS::part_export>) for this service that
 471 are capable of pulling/pushing DSL orders.
 472
 473 =cut
 474
 475 sub part_export_dsl_pull {
 476     my $self = shift;
 477     grep $_->can('dsl_pull'), $self->part_export;
 478 }
 479
 480 =item cust_svc [ PKGPART ]
 481
 482 Returns a list of associated customer services (FS::cust_svc records).
 483
 484 If a PKGPART is specified, returns the customer services which are contained
 485 within packages of that type (see L<FS::part_pkg>).  If PKGPARTis specified as
 486 B<0>, returns unlinked customer services.
 487
 488 =cut
 489
 490 sub cust_svc {
 491   my $self = shift;
 492
 493   my $hashref = { 'svcpart' => $self->svcpart };
 494
 495   my( $addl_from, $extra_sql ) = ( '', '' );
 496   if ( @_ ) {
 497     my $pkgpart = shift;
 498     if ( $pkgpart =~ /^(\d+)$/ ) {
 499       $addl_from = 'LEFT JOIN cust_pkg USING ( pkgnum )';
 500       $extra_sql = "AND pkgpart = $1";
 501     } elsif ( $pkgpart eq '0' ) {
 502       $hashref->{'pkgnum'} = '';
 503     }
 504   }
 505
 506   qsearch({
 507     'table'     => 'cust_svc',
 508     'addl_from' => $addl_from,
 509     'hashref'   => $hashref,
 510     'extra_sql' => $extra_sql,
 511   });
 512 }
 513
 514 =item num_cust_svc [ PKGPART ]
 515
 516 Returns the number of associated customer services (FS::cust_svc records).
 517
 518 If a PKGPART is specified, returns the number of customer services which are
 519 contained within packages of that type (see L<FS::part_pkg>).  If PKGPART
 520 is specified as B<0>, returns the number of unlinked customer services.
 521
 522 =cut
 523
 524 sub num_cust_svc {
 525   my $self = shift;
 526
 527   my @param = ( $self->svcpart );
 528
 529   my( $join, $and ) = ( '', '' );
 530   if ( @_ ) {
 531     my $pkgpart = shift;
 532     if ( $pkgpart ) {
 533       $join = 'LEFT JOIN cust_pkg USING ( pkgnum )';
 534       $and = 'AND pkgpart = ?';
 535       push @param, $pkgpart;
 536     } elsif ( $pkgpart eq '0' ) {
 537       $and = 'AND pkgnum IS NULL';
 538     }
 539   }
 540
 541   my $sth = dbh->prepare(
 542     "SELECT COUNT(*) FROM cust_svc $join WHERE svcpart = ? $and"
 543   ) or die dbh->errstr;
 544   $sth->execute(@param)
 545     or die $sth->errstr;
 546   $sth->fetchrow_arrayref->[0];
 547 }
 548
 549 =item svc_x
 550
 551 Returns a list of associated FS::svc_* records.
 552
 553 =cut
 554
 555 sub svc_x {
 556   my $self = shift;
 557   map { $_->svc_x } $self->cust_svc;
 558 }
 559
 560 =back
 561
 562 =head1 CLASS METHODS
 563
 564 =over 4
 565
 566 =cut
 567
 568 my $svc_defs;
 569 sub _svc_defs {
 570
 571   return $svc_defs if $svc_defs; #cache
 572
 573   my $conf = new FS::Conf;
 574
 575   #false laziness w/part_pkg.pm::plan_info
 576
 577   my %info;
 578   foreach my $INC ( @INC ) {
 579     warn "globbing $INC/FS/svc_*.pm\n" if $DEBUG;
 580     foreach my $file ( glob("$INC/FS/svc_*.pm") ) {
 581
 582       warn "attempting to load service table info from $file\n" if $DEBUG;
 583       $file =~ /\/(\w+)\.pm$/ or do {
 584         warn "unrecognized file in $INC/FS/: $file\n";
 585         next;
 586       };
 587       my $mod = $1;
 588
 589       if ( $mod =~ /^svc_[A-Z]/ or $mod =~ /^svc_acct_pop$/ ) {
 590         warn "skipping FS::$mod" if $DEBUG;
 591         next;
 592       }
 593
 594       eval "use FS::$mod;";
 595       if ( $@ ) {
 596         die "error using FS::$mod (skipping): $@\n" if $@;
 597         next;
 598       }
 599       unless ( UNIVERSAL::can("FS::$mod", 'table_info') ) {
 600         warn "FS::$mod has no table_info method; skipping";
 601         next;
 602       }
 603
 604       my $info = "FS::$mod"->table_info;
 605       unless ( keys %$info ) {
 606         warn "FS::$mod->table_info doesn't return info, skipping\n";
 607         next;
 608       }
 609       warn "got info from FS::$mod: $info\n" if $DEBUG;
 610       if ( exists($info->{'disabled'}) && $info->{'disabled'} ) {
 611         warn "skipping disabled service FS::$mod" if $DEBUG;
 612         next;
 613       }
 614       $info{$mod} = $info;
 615     }
 616   }
 617
 618   tie my %svc_defs, 'Tie::IxHash',
 619     map  { $_ => $info{$_}->{'fields'} }
 620     sort { $info{$a}->{'display_weight'} <=> $info{$b}->{'display_weight'} }
 621     keys %info,
 622   ;
 623
 624   # yuck.  maybe this won't be so bad when virtual fields become real fields
 625   my %vfields;
 626   foreach my $svcdb (grep dbdef->table($_), keys %svc_defs ) {
 627     eval "use FS::$svcdb;";
 628     my $self = "FS::$svcdb"->new;
 629     $vfields{$svcdb} = {};
 630     foreach my $field ($self->virtual_fields) { # svc_Common::virtual_fields with a null svcpart returns all of them
 631       my $pvf = $self->pvf($field);
 632       my @list = $pvf->list;
 633       if (scalar @list) {
 634         $svc_defs{$svcdb}->{$field} = { desc        => $pvf->label,
 635                                         type        => 'select',
 636                                         select_list => \@list };
 637       } else {
 638         $svc_defs{$svcdb}->{$field} = $pvf->label;
 639       } #endif
 640       $vfields{$svcdb}->{$field} = $pvf;
 641       warn "\$vfields{$svcdb}->{$field} = $pvf"
 642         if $DEBUG;
 643     } #next $field
 644   } #next $svcdb
 645
 646   $svc_defs = \%svc_defs; #cache
 647
 648 }
 649
 650 =item svc_tables
 651
 652 Returns a list of all svc_ tables.
 653
 654 =cut
 655
 656 sub svc_tables {
 657   my $class = shift;
 658   my $svc_defs = $class->_svc_defs;
 659   grep { defined( dbdef->table($_) ) } keys %$svc_defs;
 660 }
 661
 662 =item svc_table_fields TABLE
 663
 664 Given a table name, returns a hashref of field names.  The field names
 665 returned are those with additional (service-definition related) information,
 666 not necessarily all database fields of the table.  Pseudo-fields may also
 667 be returned (i.e. svc_acct.usergroup).
 668
 669 Each value of the hashref is another hashref, which can have one or more of
 670 the following keys:
 671
 672 =over 4
 673
 674 =item label - Description of the field
 675
 676 =item def_label - Optional description of the field in the context of service definitions
 677
 678 =item type - Currently "text", "select", "checkbox", "textarea", "disabled",
 679 some components specified by "select-.*.html", and a bunch more...
 680
 681 =item disable_default - This field should not allow a default value in service definitions
 682
 683 =item disable_fixed - This field should not allow a fixed value in service definitions
 684
 685 =item disable_inventory - This field should not allow inventory values in service definitions
 686
 687 =item select_list - If type is "text", this can be a listref of possible values.
 688
 689 =item select_table - An alternative to select_list, this defines a database table with the possible choices.
 690
 691 =item select_key - Used with select_table, this is the field name of keys
 692
 693 =item select_label - Used with select_table, this is the field name of labels
 694
 695 =back
 696
 697 =cut
 698
 699 #maybe this should move and be a class method in svc_Common.pm
 700 sub svc_table_fields {
 701   my($class, $table) = @_;
 702   my $svc_defs = $class->_svc_defs;
 703   my $def = $svc_defs->{$table};
 704
 705   foreach ( grep !ref($def->{$_}), keys %$def ) {
 706
 707     #normalize the shortcut in %info hash
 708     $def->{$_} = { 'label' => $def->{$_} };
 709
 710     $def->{$_}{'type'} ||= 'text';
 711
 712   }
 713
 714   $def;
 715 }
 716
 717 =back
 718
 719 =head1 SUBROUTINES
 720
 721 =over 4
 722
 723 =item process
 724
 725 Job-queue processor for web interface adds/edits
 726
 727 =cut
 728
 729 use Storable qw(thaw);
 730 use Data::Dumper;
 731 use MIME::Base64;
 732 sub process {
 733   my $job = shift;
 734
 735   my $param = thaw(decode_base64(shift));
 736   warn Dumper($param) if $DEBUG;
 737
 738   my $old = qsearchs('part_svc', { 'svcpart' => $param->{'svcpart'} })
 739     if $param->{'svcpart'};
 740
 741   #unmunge cgp_accessmodes (falze laziness-ish w/edit/process/svc_acct.cgi)
 742   $param->{'svc_acct__cgp_accessmodes'} ||=
 743     join(' ', sort
 744       grep { $_ !~ /^(flag|label)$/ }
 745            map { /^svc_acct__cgp_accessmodes_([\w\/]+)$/ or die "no way"; $1; }
 746                grep $param->{$_},
 747                     grep /^svc_acct__cgp_accessmodes_([\w\/]+)$/,
 748                          keys %$param
 749         );
 750
 751
 752   my $new = new FS::part_svc ( {
 753     map {
 754       $_ => $param->{$_};
 755   #  } qw(svcpart svc svcdb)
 756     } ( fields('part_svc'),
 757         map { my $svcdb = $_;
 758               my @fields = fields($svcdb);
 759               push @fields, 'usergroup' if $svcdb eq 'svc_acct'
 760                                         or $svcdb eq 'svc_broadband'; #kludge
 761
 762               map {
 763                     my $f = $svcdb.'__'.$_;
 764                     my $flag = $param->{ $f.'_flag' } || ''; #silence warnings
 765                     if ( $flag =~ /^[MAH]$/ ) {
 766                       $param->{ $f } = delete( $param->{ $f.'_classnum' } );
 767                     }
 768                     if ( $flag =~ /^S$/
 769                           or $_ eq 'usergroup' ) {
 770                       $param->{ $f } = ref($param->{ $f })
 771                                          ? join(',', @{$param->{ $f }} )
 772                                          : $param->{ $f };
 773                     }
 774                     ( $f, $f.'_flag', $f.'_label' );
 775                   }
 776                   @fields;
 777
 778             } FS::part_svc->svc_tables()
 779       )
 780   } );
 781
 782   my %exportnums =
 783     map { $_->exportnum => ( $param->{'exportnum'.$_->exportnum} || '') }
 784         qsearch('part_export', {} );
 785
 786   my $error;
 787   if ( $param->{'svcpart'} ) {
 788     $error = $new->replace( $old,
 789                             '1.3-COMPAT',    #totally bunk, as jeff noted
 790                             [ 'usergroup' ],
 791                             \%exportnums,
 792                             $job
 793                           );
 794   } else {
 795     $error = $new->insert( [ 'usergroup' ],
 796                            \%exportnums,
 797                            $job,
 798                          );
 799     $param->{'svcpart'} = $new->getfield('svcpart');
 800   }
 801
 802   die "$error\n" if $error;
 803 }
 804
 805 =item process_bulk_cust_svc
 806
 807 Job-queue processor for web interface bulk customer service changes
 808
 809 =cut
 810
 811 use Storable qw(thaw);
 812 use Data::Dumper;
 813 use MIME::Base64;
 814 sub process_bulk_cust_svc {
 815   my $job = shift;
 816
 817   my $param = thaw(decode_base64(shift));
 818   warn Dumper($param) if $DEBUG;
 819
 820   local($FS::svc_Common::noexport_hack) = 1
 821     if $param->{'noexport'};
 822
 823   my $old_part_svc =
 824     qsearchs('part_svc', { 'svcpart' => $param->{'old_svcpart'} } );
 825
 826   die "Must select a new service definition\n" unless $param->{'new_svcpart'};
 827
 828   #the rest should be abstracted out to to its own subroutine?
 829
 830   local $SIG{HUP} = 'IGNORE';
 831   local $SIG{INT} = 'IGNORE';
 832   local $SIG{QUIT} = 'IGNORE';
 833   local $SIG{TERM} = 'IGNORE';
 834   local $SIG{TSTP} = 'IGNORE';
 835   local $SIG{PIPE} = 'IGNORE';
 836
 837   my $oldAutoCommit = $FS::UID::AutoCommit;
 838   local $FS::UID::AutoCommit = 0;
 839   my $dbh = dbh;
 840
 841   local( $FS::cust_svc::ignore_quantity ) = 1;
 842
 843   my $total = $old_part_svc->num_cust_svc( $param->{'pkgpart'} );
 844
 845   my $n = 0;
 846   foreach my $old_cust_svc ( $old_part_svc->cust_svc( $param->{'pkgpart'} ) ) {
 847
 848     my $new_cust_svc = new FS::cust_svc { $old_cust_svc->hash };
 849
 850     $new_cust_svc->svcpart( $param->{'new_svcpart'} );
 851     my $error = $new_cust_svc->replace($old_cust_svc);
 852     if ( $error ) {
 853       $dbh->rollback if $oldAutoCommit;
 854       die "$error\n" if $error;
 855     }
 856
 857     $error = $job->update_statustext( int( 100 * ++$n / $total ) );
 858     if ( $error ) {
 859       $dbh->rollback if $oldAutoCommit;
 860       die $error if $error;
 861     }
 862
 863   }
 864
 865   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 866
 867   '';
 868
 869 }
 870
 871 sub _upgrade_data {  #class method
 872   my ($class, %opts) = @_;
 873
 874   my @part_svc_column = qsearch('part_svc_column', { 'columnname' => 'usergroup' });
 875   foreach my $col ( @part_svc_column ) {
 876     next if $col->columnvalue =~ /^[\d,]+$/ || !$col->columnvalue;
 877     my @groupnames = split(',',$col->columnvalue);
 878     my @groupnums;
 879     my $error = '';
 880     foreach my $groupname ( @groupnames ) {
 881         my $g = qsearchs('radius_group', { 'groupname' => $groupname } );
 882         unless ( $g ) {
 883             $g = new FS::radius_group {
 884                             'groupname' => $groupname,
 885                             'description' => $groupname,
 886                             };
 887             $error = $g->insert;
 888             die $error if $error;
 889         }
 890         push @groupnums, $g->groupnum;
 891     }
 892     $col->columnvalue(join(',',@groupnums));
 893     $error = $col->replace;
 894     die $error if $error;
 895   }
 896
 897   my @badlabels = qsearch({
 898     'table' => 'part_svc_column',
 899     'hashref' => {},
 900     'extra_sql' => 'WHERE columnlabel IN ('.
 901       "'Descriptive label for this particular device.',".
 902       "'IP address.  Leave blank for automatic assignment.',".
 903       "'Maximum upload speed for this service in Kbps.  0 denotes unlimited.',".
 904       "'Maximum download speed for this service in Kbps.  0 denotes unlimited.')"
 905   });
 906   foreach my $col ( @badlabels ) {
 907     $col->columnlabel('');
 908     my $error = $col->replace;
 909     die $error if $error;
 910   }
 911
 912 }
 913
 914 =head1 BUGS
 915
 916 Delete is unimplemented.
 917
 918 The list of svc_* tables is no longer hardcoded, but svc_acct_pop is skipped
 919 as a special case until it is renamed.
 920
 921 all_part_svc_column methods should be documented
 922
 923 =head1 SEE ALSO
 924
 925 L<FS::Record>, L<FS::part_svc_column>, L<FS::part_pkg>, L<FS::pkg_svc>,
 926 L<FS::cust_svc>, L<FS::svc_acct>, L<FS::svc_forward>, L<FS::svc_domain>,
 927 schema.html from the base documentation.
 928
 929 =cut
 930
 931 1;
 932