FS/FS/part_pkg/voip_cdr.pm

   1 package FS::part_pkg::voip_cdr;
   2
   3 use strict;
   4 use vars qw(@ISA $DEBUG %info);
   5 use Date::Format;
   6 use Tie::IxHash;
   7 use FS::Conf;
   8 use FS::Record qw(qsearchs qsearch);
   9 use FS::part_pkg::flat;
  10 use FS::cdr;
  11 use FS::rate;
  12 use FS::rate_prefix;
  13 use FS::rate_detail;
  14
  15 @ISA = qw(FS::part_pkg::flat);
  16
  17 $DEBUG = 1;
  18
  19 tie my %rating_method, 'Tie::IxHash',
  20   'prefix' => 'Rate calls by using destination prefix to look up a region and rate according to the internal prefix and rate tables',
  21   'upstream' => 'Rate calls based on upstream data: If the call type is "1", map the upstream rate ID directly to an internal rate (rate_detail), otherwise, pass the upstream price through directly.',
  22   'upstream_simple' => 'Simply pass through and charge the "upstream_price" amount.',
  23 ;
  24
  25 #tie my %cdr_location, 'Tie::IxHash',
  26 #  'internal' => 'Internal: CDR records imported into the internal CDR table',
  27 #  'external' => 'External: CDR records queried directly from an external '.
  28 #                'Asterisk (or other?) CDR table',
  29 #;
  30
  31 tie my %temporalities, 'Tie::IxHash',
  32   'upcoming'  => "Upcoming (future)",
  33   'preceding' => "Preceding (past)",
  34 ;
  35
  36 %info = (
  37   'name' => 'VoIP rating by plan of CDR records in an internal (or external) SQL table',
  38   'shortname' => 'VoIP/telco CDR rating (standard)',
  39   'fields' => {
  40     'setup_fee'     => { 'name' => 'Setup fee for this package',
  41                          'default' => 0,
  42                        },
  43     'recur_fee'     => { 'name' => 'Base recurring fee for this package',
  44                          'default' => 0,
  45                        },
  46
  47     #false laziness w/flat.pm
  48     'recur_temporality' => { 'name' => 'Charge recurring fee for period',
  49                              'type' => 'select',
  50                              'select_options' => \%temporalities,
  51                            },
  52
  53     'unused_credit' => { 'name' => 'Credit the customer for the unused portion'.
  54                                    ' of service at cancellation',
  55                          'type' => 'checkbox',
  56                        },
  57
  58     'rating_method' => { 'name' => 'Region rating method',
  59                          'type' => 'radio',
  60                          'options' => \%rating_method,
  61                        },
  62
  63     'ratenum'   => { 'name' => 'Rate plan',
  64                      'type' => 'select',
  65                      'select_table' => 'rate',
  66                      'select_key'   => 'ratenum',
  67                      'select_label' => 'ratename',
  68                    },
  69
  70     'ignore_unrateable' => { 'name' => 'Ignore calls without a rate in the rate tables.  By default, the system will throw a fatal error upon encountering unrateable calls.',
  71                              'type' => 'checkbox',
  72                            },
  73
  74     'default_prefix' => { 'name'    => 'Default prefix optionally prepended to customer DID numbers when searching for CDR records',
  75                           'default' => '+1',
  76                         },
  77
  78     'disable_src' => { 'name' => 'Disable rating of CDR records based on the "src" field in addition to "charged_party"',
  79                        'type' => 'checkbox'
  80                      },
  81
  82     'domestic_prefix' => { 'name'    => 'Destination prefix for domestic CDR records',
  83                            'default' => '1',
  84                          },
  85
  86 #    'domestic_prefix_required' => { 'name' => 'Require explicit destination prefix for domestic CDR records',
  87 #                                    'type' => 'checkbox',
  88 #                                  },
  89
  90     'international_prefix' => { 'name'    => 'Destination prefix for international CDR records',
  91                                 'default' => '011',
  92                               },
  93
  94     'disable_tollfree' => { 'name' => 'Disable automatic toll-free processing',
  95                             'type' => 'checkbox',
  96                           },
  97
  98     'use_amaflags' => { 'name' => 'Do not charge for CDRs where the amaflags field is not set to "2" ("BILL"/"BILLING").',
  99                         'type' => 'checkbox',
 100                       },
 101
 102     'use_disposition' => { 'name' => 'Do not charge for CDRs where the disposition flag is not set to "ANSWERED".',
 103                            'type' => 'checkbox',
 104                          },
 105
 106     'use_disposition_taqua' => { 'name' => 'Do not charge for CDRs where the disposition is not set to "100" (Taqua).',
 107                                  'type' => 'checkbox',
 108                                },
 109
 110     'use_carrierid' => { 'name' => 'Do not charge for CDRs where the Carrier ID is not set to: ',
 111                          },
 112
 113     'use_cdrtypenum' => { 'name' => 'Do not charge for CDRs where the CDR Type is not set to: ',
 114                          },
 115
 116     'use_duration'   => { 'name' => 'Calculate usage based on the duration field instead of the billsec field',
 117                           'type' => 'checkbox',
 118                         },
 119
 120     '411_rewrite' => { 'name' => 'Rewrite these (comma-separated) destination numbers to 411 for rating purposes (also ignore any carrierid check): ',
 121                       },
 122
 123     'output_format' => { 'name' => 'CDR invoice display format',
 124                          'type' => 'select',
 125                          'select_options' => { FS::cdr::invoice_formats() },
 126                          'default'        => 'default', #XXX test
 127                        },
 128
 129     'usage_section' => { 'name' => 'Section in which to place separate usage charges',
 130                        },
 131
 132     'summarize_usage' => { 'name' => 'Include usage summary with recurring charges when usage is in separate section',
 133                           'type' => 'checkbox',
 134                         },
 135
 136     'bill_every_call' => { 'name' => 'Generate an invoice immediately for every call.  Useful for prepaid.',
 137                            'type' => 'checkbox',
 138                          },
 139
 140     #XXX also have option for an external db
 141 #    'cdr_location' => { 'name' => 'CDR database location'
 142 #                        'type' => 'select',
 143 #                        'select_options' => \%cdr_location,
 144 #                        'select_callback' => {
 145 #                          'external' => {
 146 #                            'enable' => [ 'datasrc', 'username', 'password' ],
 147 #                          },
 148 #                          'internal' => {
 149 #                            'disable' => [ 'datasrc', 'username', 'password' ],
 150 #                          }
 151 #                        },
 152 #                      },
 153 #    'datasrc' => { 'name' => 'DBI data source for external CDR table',
 154 #                   'disabled' => 'Y',
 155 #                 },
 156 #    'username' => { 'name' => 'External database username',
 157 #                    'disabled' => 'Y',
 158 #                  },
 159 #    'password' => { 'name' => 'External database password',
 160 #                    'disabled' => 'Y',
 161 #                  },
 162
 163   },
 164   'fieldorder' => [qw(
 165                        setup_fee recur_fee recur_temporality unused_credit
 166                        rating_method ratenum ignore_unrateable
 167                        default_prefix
 168                        disable_src
 169                        domestic_prefix international_prefix
 170                        disable_tollfree
 171                        use_amaflags use_disposition
 172                        use_disposition_taqua use_carrierid use_cdrtypenum
 173                        use_duration
 174                        411_rewrite
 175                        output_format summarize_usage usage_section
 176                        bill_every_call
 177                      )
 178                   ],
 179   'weight' => 40,
 180 );
 181
 182 sub calc_setup {
 183   my($self, $cust_pkg ) = @_;
 184   $self->option('setup_fee');
 185 }
 186
 187 #false laziness w/voip_sqlradacct calc_recur resolve it if that one ever gets used again
 188 sub calc_recur {
 189   my($self, $cust_pkg, $sdate, $details, $param ) = @_;
 190
 191   #my $last_bill = $cust_pkg->last_bill;
 192   my $last_bill = $cust_pkg->get('last_bill'); #->last_bill falls back to setup
 193
 194   return 0
 195     if $self->option('recur_temporality', 1) eq 'preceding' && $last_bill == 0;
 196
 197   my $ratenum = $cust_pkg->part_pkg->option('ratenum');
 198
 199   my $spool_cdr = $cust_pkg->cust_main->spool_cdr;
 200
 201   my %included_min = ();
 202
 203   my $charges = 0;
 204
 205   my $downstream_cdr = '';
 206
 207   my $rating_method     = $self->option('rating_method') || 'prefix';
 208   my $intl              = $self->option('international_prefix') || '011';
 209   my $domestic_prefix   = $self->option('domestic_prefix');
 210   my $disable_tollfree  = $self->option('disable_tollfree');
 211   my $ignore_unrateable = $self->option('ignore_unrateable', 'Hush!');
 212   my $use_duration      = $self->option('use_duration');
 213
 214   my $output_format     = $self->option('output_format', 'Hush!')
 215                           || ( $rating_method eq 'upstream_simple'
 216                                  ? 'simple'
 217                                  : 'default'
 218                              );
 219
 220   my @dirass = ();
 221   if ( $self->option('411_rewrite') ) {
 222     my $dirass = $self->option('411_rewrite');
 223     $dirass =~ s/\s//g;
 224     @dirass = split(',', $dirass);
 225   }
 226
 227   #for check_chargable, so we don't keep looking up options inside the loop
 228   my %opt_cache = ();
 229
 230   eval "use Text::CSV_XS;";
 231   die $@ if $@;
 232   my $csv = new Text::CSV_XS;
 233
 234   foreach my $cust_svc (
 235     grep { $_->part_svc->svcdb eq 'svc_phone' } $cust_pkg->cust_svc
 236   ) {
 237
 238     foreach my $cdr (
 239       $cust_svc->get_cdrs_for_update(
 240         'disable_src'    => $self->option('disable_src'),
 241         'default_prefix' => $self->option('default_prefix'),
 242       )  # $last_bill, $$sdate )
 243     ) {
 244       if ( $DEBUG > 1 ) {
 245         warn "rating CDR $cdr\n".
 246              join('', map { "  $_ => ". $cdr->{$_}. "\n" } keys %$cdr );
 247       }
 248
 249       my $rate_detail;
 250       my( $rate_region, $regionnum );
 251       my $pretty_destnum;
 252       my $charge = '';
 253       my $classnum = '';
 254       my @call_details = ();
 255       if ( $rating_method eq 'prefix' ) {
 256
 257         my $da_rewrote = 0;
 258         if ( length($cdr->dst) && grep { $cdr->dst eq $_ } @dirass ){
 259           $cdr->dst('411');
 260           $da_rewrote = 1;
 261         }
 262
 263         my $reason = $self->check_chargable( $cdr,
 264                                              'da_rewrote'   => $da_rewrote,
 265                                              'option_cache' => \%opt_cache,
 266                                            );
 267
 268         if ( $reason ) {
 269
 270           warn "not charging for CDR ($reason)\n" if $DEBUG;
 271           $charge = 0;
 272
 273         } else {
 274
 275           ###
 276           # look up rate details based on called station id
 277           # (or calling station id for toll free calls)
 278           ###
 279
 280           my( $to_or_from, $number );
 281           if ( $cdr->dst =~ /^(\+?1)?8([02-8])\1/
 282                && ! $disable_tollfree
 283               )
 284           { #tollfree call
 285             $to_or_from = 'from';
 286             $number = $cdr->src;
 287           } else { #regular call
 288             $to_or_from = 'to';
 289             $number = $cdr->dst;
 290           }
 291
 292           warn "parsing call $to_or_from $number\n" if $DEBUG;
 293
 294           #remove non-phone# stuff and whitespace
 295           $number =~ s/\s//g;
 296 #          my $proto = '';
 297 #          $dest =~ s/^(\w+):// and $proto = $1; #sip:
 298 #          my $siphost = '';
 299 #          $dest =~ s/\@(.*)$// and $siphost = $1; # @10.54.32.1, @sip.example.com
 300
 301           #determine the country code
 302           my $countrycode;
 303           if (    $number =~ /^$intl(((\d)(\d))(\d))(\d+)$/
 304                || $number =~ /^\+(((\d)(\d))(\d))(\d+)$/
 305              )
 306           {
 307
 308             my( $three, $two, $one, $u1, $u2, $rest ) = ( $1,$2,$3,$4,$5,$6 );
 309             #first look for 1 digit country code
 310             if ( qsearch('rate_prefix', { 'countrycode' => $one } ) ) {
 311               $countrycode = $one;
 312               $number = $u1.$u2.$rest;
 313             } elsif ( qsearch('rate_prefix', { 'countrycode' => $two } ) ) { #or 2
 314               $countrycode = $two;
 315               $number = $u2.$rest;
 316             } else { #3 digit country code
 317               $countrycode = $three;
 318               $number = $rest;
 319             }
 320
 321           } else {
 322             $countrycode = $domestic_prefix || '1';
 323             $number =~ s/^$countrycode//;# if length($number) > 10;
 324           }
 325
 326           warn "rating call $to_or_from +$countrycode $number\n" if $DEBUG;
 327           $pretty_destnum = "+$countrycode $number";
 328
 329           my $rate = qsearchs('rate', { 'ratenum' => $ratenum })
 330             or die "ratenum $ratenum not found!";
 331
 332           $rate_detail = $rate->dest_detail({ 'countrycode' => $countrycode,
 333                                               'phonenum'    => $number,
 334                                             });
 335
 336           if ( $rate_detail ) {
 337
 338             $rate_region = $rate_detail->dest_region;
 339             $regionnum = $rate_region->regionnum;
 340             warn "  found rate for regionnum $regionnum ".
 341                  "and rate detail $rate_detail\n"
 342               if $DEBUG;
 343
 344           } elsif ( $ignore_unrateable ) {
 345
 346             $rate_region = '';
 347             $regionnum = '';
 348             #code below will throw a warning & skip
 349
 350           } else {
 351
 352             die "FATAL: no rate_detail found in ".
 353                 $rate->ratenum. ":". $rate->ratename. " rate plan ".
 354                 "for +$countrycode $number (CDR acctid ". $cdr->acctid. "); ".
 355                 "add a rate or set ignore_unrateable flag on the package def\n";
 356           }
 357
 358         }
 359
 360       } elsif ( $rating_method eq 'upstream' ) { #XXX this was convergent, not currently used.  very much becoming the odd one out. remove?
 361
 362         if ( $cdr->cdrtypenum == 1 ) { #rate based on upstream rateid
 363
 364           $rate_detail = $cdr->cdr_upstream_rate->rate_detail;
 365
 366           $regionnum = $rate_detail->dest_regionnum;
 367           $rate_region = $rate_detail->dest_region;
 368
 369           $pretty_destnum = $cdr->dst;
 370
 371           warn "  found rate for regionnum $regionnum and ".
 372                "rate detail $rate_detail\n"
 373             if $DEBUG;
 374
 375         } else { #pass upstream price through
 376
 377           $charge = sprintf('%.2f', $cdr->upstream_price);
 378           $charges += $charge;
 379
 380           @call_details = (
 381             #time2str("%Y %b %d - %r", $cdr->calldate_unix ),
 382             time2str("%c", $cdr->calldate_unix),  #XXX this should probably be a config option dropdown so they can select US vs- rest of world dates or whatnot
 383             'N/A', #minutes...
 384             '$'.$charge,
 385             #$pretty_destnum,
 386             $cdr->description, #$rate_region->regionname,
 387           );
 388
 389         }
 390
 391       } elsif ( $rating_method eq 'upstream_simple' ) {
 392
 393         #XXX $charge = sprintf('%.2f', $cdr->upstream_price);
 394         $charge = sprintf('%.3f', $cdr->upstream_price);
 395         $charges += $charge;
 396
 397         @call_details = ($cdr->downstream_csv( 'format' => $output_format,
 398                                                'charge' => $charge,
 399                                              )
 400                         );
 401         $classnum = $cdr->calltypenum;
 402
 403       } else {
 404         die "don't know how to rate CDRs using method: $rating_method\n";
 405       }
 406
 407       ###
 408       # find the price and add detail to the invoice
 409       ###
 410
 411       # if $rate_detail is not found, skip this CDR... i.e.
 412       # don't add it to invoice, don't set its status to done,
 413       # don't call downstream_csv or something on it...
 414       # but DO emit a warning...
 415       #if ( ! $rate_detail && ! scalar(@call_details) ) {}
 416       if ( ! $rate_detail && $charge eq '' ) {
 417
 418         warn "no rate_detail found for CDR.acctid: ". $cdr->acctid.
 419              "; skipping\n"
 420
 421       } else { # there *is* a rate_detail (or call_details), proceed...
 422
 423         unless ( @call_details || ( $charge ne '' && $charge == 0 ) ) {
 424
 425           $included_min{$regionnum} = $rate_detail->min_included
 426             unless exists $included_min{$regionnum};
 427
 428           my $granularity = $rate_detail->sec_granularity;
 429
 430                       # length($cdr->billsec) ? $cdr->billsec : $cdr->duration;
 431           my $seconds = $use_duration ? $cdr->duration : $cdr->billsec;
 432
 433           $seconds += $granularity - ( $seconds % $granularity )
 434             if $seconds      # don't granular-ize 0 billsec calls (bills them)
 435             && $granularity; # 0 is per call
 436           my $minutes = sprintf("%.1f", $seconds / 60);
 437           $minutes =~ s/\.0$// if $granularity == 60;
 438
 439           # per call rather than per minute
 440           $minutes = 1 unless $granularity;
 441
 442           $included_min{$regionnum} -= $minutes;
 443
 444           if ( $included_min{$regionnum} < 0 ) {
 445             my $charge_min = 0 - $included_min{$regionnum};
 446             $included_min{$regionnum} = 0;
 447             $charge = sprintf('%.2f', $rate_detail->min_charge * $charge_min );
 448             $charges += $charge;
 449           }
 450
 451           # this is why we need regionnum/rate_region....
 452           warn "  (rate region $rate_region)\n" if $DEBUG;
 453
 454           @call_details = (
 455            $cdr->downstream_csv( 'format'         => $output_format,
 456                                  'granularity'    => $granularity,
 457                                  'minutes'        => $minutes,
 458                                  'charge'         => $charge,
 459                                  'pretty_dst'     => $pretty_destnum,
 460                                  'dst_regionname' => $rate_region->regionname,
 461                                )
 462           );
 463
 464           $classnum = $rate_detail->classnum;
 465
 466         }
 467
 468         if ( $charge > 0 ) {
 469           #just use FS::cust_bill_pkg_detail objects?
 470           my $call_details;
 471
 472           #if ( $self->option('rating_method') eq 'upstream_simple' ) {
 473           if ( scalar(@call_details) == 1 ) {
 474             $call_details = [ 'C', $call_details[0], $charge, $classnum ];
 475           } else { #only used for $rating_method eq 'upstream' now
 476             $csv->combine(@call_details);
 477             $call_details = [ 'C', $csv->string, $charge, $classnum ];
 478           }
 479           warn "  adding details on charge to invoice: [ ".
 480               join(', ', @{$call_details} ). " ]"
 481             if ( $DEBUG && ref($call_details) );
 482           push @$details, $call_details; #\@call_details,
 483         }
 484
 485         # if the customer flag is on, call "downstream_csv" or something
 486         # like it to export the call downstream!
 487         # XXX price plan option to pick format, or something...
 488         $downstream_cdr .= $cdr->downstream_csv( 'format' => 'convergent' )
 489           if $spool_cdr;
 490
 491         my $error = $cdr->set_status_and_rated_price('done', $charge);
 492         die $error if $error;
 493
 494       }
 495
 496     } # $cdr
 497
 498   } # $cust_svc
 499
 500   unshift @$details, [ 'C', FS::cdr::invoice_header($output_format) ]
 501     if @$details && $rating_method ne 'upstream';
 502
 503   if ( $spool_cdr && length($downstream_cdr) ) {
 504
 505     use FS::UID qw(datasrc);
 506     my $dir = '/usr/local/etc/freeside/export.'. datasrc. '/cdr';
 507     mkdir $dir, 0700 unless -d $dir;
 508     $dir .= '/'. $cust_pkg->custnum.
 509     mkdir $dir, 0700 unless -d $dir;
 510     my $filename = time2str("$dir/CDR%Y%m%d-spool.CSV", time); #XXX invoice date instead?  would require changing the order things are generated in cust_main::bill insert cust_bill first - with transactions it could be done though
 511
 512     push @{ $param->{'precommit_hooks'} },
 513          sub {
 514                #lock the downstream spool file and append the records
 515                use Fcntl qw(:flock);
 516                use IO::File;
 517                my $spool = new IO::File ">>$filename"
 518                  or die "can't open $filename: $!\n";
 519                flock( $spool, LOCK_EX)
 520                  or die "can't lock $filename: $!\n";
 521                seek($spool, 0, 2)
 522                  or die "can't seek to end of $filename: $!\n";
 523                print $spool $downstream_cdr;
 524                flock( $spool, LOCK_UN );
 525                close $spool;
 526              };
 527
 528   } #if ( $spool_cdr && length($downstream_cdr) )
 529
 530   $charges += $self->option('recur_fee')
 531     if $param->{'increment_next_bill'};
 532
 533   $charges;
 534 }
 535
 536 #returns a reason why not to rate this CDR, or false if the CDR is chargeable
 537 sub check_chargable {
 538   my( $self, $cdr, %flags ) = @_;
 539
 540   #should have some better way of checking these options from a hash
 541   #or something
 542
 543   my @opt = qw(
 544     use_amaflags
 545     use_disposition
 546     use_disposition_taqua
 547     use_carrierid
 548     use_cdrtypenum
 549   );
 550   foreach my $opt (grep !exists($flags{option_cache}->{$_}), @opt ) {
 551     $flags{option_cache}->{$opt} = $self->option($opt);
 552   }
 553   my %opt = %{ $flags{option_cache} };
 554
 555   return 'amaflags != 2'
 556     if $opt{'use_amaflags'} && $cdr->amaflags != 2;
 557
 558   return 'disposition != ANSWERED'
 559     if $opt{'use_disposition'} && $cdr->disposition ne 'ANSWERED';
 560
 561   return "disposition != 100"
 562     if $opt{'use_disposition_taqua'} && $cdr->disposition != 100;
 563
 564   return "carrierid != $opt{'use_carrierid'}"
 565     if $opt{'use_carrierid'}
 566     && $cdr->carrierid != $opt{'use_carrierid'}
 567     && ! $flags{'da_rewrote'};
 568
 569   return "cdrtypenum != $opt{'use_cdrtypenum'}"
 570     if $opt{'use_cdrtypenum'}
 571     && $cdr->cdrtypenum != $opt{'use_cdrtypenum'};
 572
 573   #all right then, rate it
 574   '';
 575 }
 576
 577 sub is_free {
 578   0;
 579 }
 580
 581 sub base_recur {
 582   my($self, $cust_pkg) = @_;
 583   $self->option('recur_fee');
 584 }
 585
 586 #  This equates svc_phone records; perhaps svc_phone should have a field
 587 #  to indicate it represents a line
 588 sub calc_units {
 589   my($self, $cust_pkg ) = @_;
 590   scalar(grep { $_->part_svc->svcdb eq 'svc_phone' } $cust_pkg->cust_svc);
 591 }
 592
 593 1;
 594