FS/FS/part_pkg/recur_Common.pm

   1 package FS::part_pkg::recur_Common;
   2 use base qw( FS::part_pkg::flat );
   3
   4 use strict;
   5 use vars qw( %info %recur_method );
   6 use Tie::IxHash;
   7 use Time::Local;
   8
   9 %info = ( 'disabled' => 1 ); #recur_Common not a usable price plan directly
  10
  11 tie %recur_method, 'Tie::IxHash',
  12   'anniversary'  => 'Charge the recurring fee at the frequency specified above',
  13   'prorate'      => 'Charge a prorated fee the first time (selectable billing date)',
  14   'subscription' => 'Charge the full fee for the first partial period (selectable billing date)',
  15 ;
  16
  17 sub base_recur {
  18   my $self = shift;
  19   $self->option('recur_fee', 1) || 0;
  20 }
  21
  22 sub calc_setup {
  23   # moved from all descendant packages which just had $self->option('setup_fee')
  24   my($self, $cust_pkg, $sdate, $details, $param) = @_;
  25
  26   return 0 if $self->prorate_setup($cust_pkg, $sdate);
  27
  28   my $charge = $self->option('setup_fee');
  29
  30   my $discount = 0;
  31   if ( $charge > 0 ) {
  32       $param->{'setup_charge'} = $charge;
  33       $discount = $self->calc_discount($cust_pkg, $sdate, $details, $param);
  34       delete $param->{'setup_charge'};
  35   }
  36
  37   sprintf('%.2f', $charge - $discount);
  38 }
  39
  40 sub cutoff_day {
  41   # prorate/subscription only; we don't support sync_bill_date here
  42   my( $self, $cust_pkg ) = @_;
  43   my $recur_method = $self->option('recur_method',1) || 'anniversary';
  44   return () unless $recur_method eq 'prorate'
  45                 || $recur_method eq 'subscription';
  46
  47   #false laziness w/prorate.pm::cutoff_day
  48   my $prorate_day = $cust_pkg->cust_main->prorate_day;
  49   $prorate_day ? ( $prorate_day )
  50                : split(/\s*,\s*/, $self->option('cutoff_day', 1) || '1');
  51 }
  52
  53 sub calc_recur_Common {
  54   my $self = shift;
  55   my($cust_pkg, $sdate, $details, $param ) = @_; #only need $sdate & $param
  56
  57   my $charges = 0;
  58
  59   if ( $param->{'increment_next_bill'} ) {
  60
  61     my $recur_method = $self->option('recur_method', 1) || 'anniversary';
  62     my @cutoff_day = $self->cutoff_day($cust_pkg);
  63
  64     $charges = $self->base_recur($cust_pkg, $sdate, $details, $param);
  65     $charges += $param->{'override_charges'} if $param->{'override_charges'};
  66
  67     if ( $recur_method eq 'prorate' ) {
  68
  69       $charges = $self->calc_prorate(@_, @cutoff_day);
  70       $charges += $param->{'override_charges'} if $param->{'override_charges'};
  71
  72     } elsif ( $recur_method eq 'subscription' ) {
  73
  74       my ($day, $mon, $year) = ( localtime($$sdate) )[ 3..5 ];
  75
  76       if ( $day < $cutoff_day[0] ) {
  77         if ( $mon == 0 ) { $mon=11; $year--; }
  78         else { $mon--; }
  79       }
  80
  81       $$sdate = timelocal(0, 0, 0, $cutoff_day[0], $mon, $year);
  82
  83     }#$recur_method
  84
  85     $charges -= $self->calc_discount( $cust_pkg, $sdate, $details, $param );
  86
  87   }#increment_next_bill
  88
  89   return $charges;
  90
  91 }
  92
  93 1;