FS/FS/part_pkg/flat.pm

   1 package FS::part_pkg::flat;
   2
   3 use strict;
   4 use vars qw( @ISA %info
   5              %usage_recharge_fields @usage_recharge_fieldorder
   6            );
   7 use Tie::IxHash;
   8 use List::Util qw(min); # max);
   9 #use FS::Record qw(qsearch);
  10 use FS::UI::bytecount;
  11 use FS::Conf;
  12 use FS::part_pkg;
  13
  14 @ISA = qw(FS::part_pkg
  15           FS::part_pkg::prorate_Mixin
  16           FS::part_pkg::discount_Mixin);
  17
  18 tie my %temporalities, 'Tie::IxHash',
  19   'upcoming'  => "Upcoming (future)",
  20   'preceding' => "Preceding (past)",
  21 ;
  22
  23 tie my %contract_years, 'Tie::IxHash', (
  24   '' => '(none)',
  25   map { $_*12 => $_ } (1..5),
  26 );
  27
  28 %info = (
  29   'name' => 'Flat rate (anniversary billing)',
  30   'shortname' => 'Anniversary',
  31   'inherit_fields' => [ 'usage_Mixin', 'global_Mixin' ],
  32   'fields' => {
  33     #false laziness w/voip_cdr.pm
  34     'recur_temporality' => { 'name' => 'Charge recurring fee for period',
  35                              'type' => 'select',
  36                              'select_options' => \%temporalities,
  37                            },
  38
  39     #used in cust_pkg.pm so could add to any price plan
  40     'expire_months' => { 'name' => 'Auto-add an expiration date this number of months out',
  41                        },
  42     'adjourn_months'=> { 'name' => 'Auto-add a suspension date this number of months out',
  43                        },
  44     'contract_end_months'=> {
  45                         'name' => 'Auto-add a contract end date this number of years out',
  46                         'type' => 'select',
  47                         'select_options' => \%contract_years,
  48                       },
  49     #used in cust_pkg.pm so could add to any price plan where it made sense
  50     'start_1st'     => { 'name' => 'Auto-add a start date to the 1st, ignoring the current month.',
  51                          'type' => 'checkbox',
  52                        },
  53     'sync_bill_date' => { 'name' => 'Prorate first month to synchronize '.
  54                                     'with the customer\'s other packages',
  55                           'type' => 'checkbox',
  56                         },
  57     'prorate_defer_bill' => {
  58                           'name' => 'When synchronizing, defer the bill until '.
  59                                     'the customer\'s next bill date',
  60                           'type' => 'checkbox',
  61                         },
  62     'suspend_bill' => { 'name' => 'Continue recurring billing while suspended',
  63                         'type' => 'checkbox',
  64                       },
  65     'unsuspend_adjust_bill' =>
  66                         { 'name' => 'Adjust next bill date forward when '.
  67                                     'unsuspending',
  68                           'type' => 'checkbox',
  69                         },
  70
  71     'externalid' => { 'name'   => 'Optional External ID',
  72                       'default' => '',
  73                     },
  74   },
  75   'fieldorder' => [ qw( recur_temporality
  76                         expire_months adjourn_months
  77                         contract_end_months
  78                         start_1st sync_bill_date prorate_defer_bill
  79                         suspend_bill unsuspend_adjust_bill
  80                         externalid ),
  81                   ],
  82   'weight' => 10,
  83 );
  84
  85 sub calc_setup {
  86   my($self, $cust_pkg, $sdate, $details ) = @_;
  87
  88   return 0 if $self->prorate_setup($cust_pkg, $sdate);
  89
  90   my $i = 0;
  91   my $count = $self->option( 'additional_count', 'quiet' ) || 0;
  92   while ($i < $count) {
  93     push @$details, $self->option( 'additional_info' . $i++ );
  94   }
  95
  96   my $quantity = $cust_pkg->quantity || 1;
  97
  98   my $charge = $quantity * $self->unit_setup($cust_pkg, $sdate, $details);
  99   sprintf('%.2f', $charge);
 100 }
 101
 102 sub unit_setup {
 103   my($self, $cust_pkg, $sdate, $details ) = @_;
 104
 105   $self->option('setup_fee') || 0;
 106 }
 107
 108 sub calc_recur {
 109   my $self = shift;
 110   my($cust_pkg, $sdate, $details, $param ) = @_;
 111
 112   #my $last_bill = $cust_pkg->last_bill;
 113   my $last_bill = $cust_pkg->get('last_bill'); #->last_bill falls back to setup
 114
 115   return 0
 116     if $self->option('recur_temporality', 1) eq 'preceding' && $last_bill == 0;
 117
 118   my $charge = $self->base_recur($cust_pkg, $sdate);
 119   if ( my $cutoff_day = $self->cutoff_day($cust_pkg) ) {
 120     $charge = $self->calc_prorate(@_);
 121   }
 122   elsif ( $param->{freq_override} ) {
 123     # XXX not sure if this should be mutually exclusive with sync_bill_date.
 124     # Given the very specific problem that freq_override is meant to 'solve',
 125     # it probably should.
 126     $charge *= $param->{freq_override} if $param->{freq_override};
 127   }
 128
 129   my $discount = $self->calc_discount($cust_pkg, $sdate, $details, $param);
 130   return sprintf('%.2f', $charge - $discount);
 131 }
 132
 133 sub cutoff_day {
 134   my $self = shift;
 135   my $cust_pkg = shift;
 136   if ( $self->option('sync_bill_date',1) ) {
 137     my $next_bill = $cust_pkg->cust_main->next_bill_date;
 138     if ( defined($next_bill) ) {
 139       return (localtime($next_bill))[3];
 140     }
 141   }
 142   return 0;
 143 }
 144
 145 sub base_recur {
 146   my($self, $cust_pkg, $sdate) = @_;
 147   $self->option('recur_fee', 1) || 0;
 148 }
 149
 150 sub base_recur_permonth {
 151   my($self, $cust_pkg) = @_;
 152
 153   return 0 unless $self->freq =~ /^\d+$/ && $self->freq > 0;
 154
 155   sprintf('%.2f', $self->base_recur($cust_pkg) / $self->freq );
 156 }
 157
 158 sub calc_remain {
 159   my ($self, $cust_pkg, %options) = @_;
 160
 161   my $time;
 162   if ($options{'time'}) {
 163     $time = $options{'time'};
 164   } else {
 165     $time = time;
 166   }
 167
 168   my $next_bill = $cust_pkg->getfield('bill') || 0;
 169
 170   return 0 if    ! $self->base_recur($cust_pkg, \$time)
 171               || ! $next_bill
 172               || $next_bill < $time;
 173
 174   my %sec = (
 175     'h' =>    3600, # 60 * 60
 176     'd' =>   86400, # 60 * 60 * 24
 177     'w' =>  604800, # 60 * 60 * 24 * 7
 178     'm' => 2629744, # 60 * 60 * 24 * 365.2422 / 12
 179   );
 180
 181   $self->freq =~ /^(\d+)([hdwm]?)$/
 182     or die 'unparsable frequency: '. $self->freq;
 183   my $freq_sec = $1 * $sec{$2||'m'};
 184   return 0 unless $freq_sec;
 185
 186   sprintf("%.2f", $self->base_recur($cust_pkg, \$time) * ( $next_bill - $time ) / $freq_sec );
 187
 188 }
 189
 190 sub is_free_options {
 191   qw( setup_fee recur_fee );
 192 }
 193
 194 sub is_prepaid { 0; } #no, we're postpaid
 195
 196 #XXX discounts only on recurring fees for now (no setup/one-time or usage)
 197 sub can_discount {
 198   my $self = shift;
 199   $self->freq =~ /^\d+$/ && $self->freq > 0;
 200 }
 201
 202 sub usage_valuehash {
 203   my $self = shift;
 204   map { $_, $self->option($_) }
 205     grep { $self->option($_, 'hush') }
 206     qw(seconds upbytes downbytes totalbytes);
 207 }
 208
 209 sub reset_usage {
 210   my($self, $cust_pkg, %opt) = @_;
 211   warn "   resetting usage counters" if defined($opt{debug}) && $opt{debug} > 1;
 212   my %values = $self->usage_valuehash;
 213   if ($self->option('usage_rollover', 1)) {
 214     $cust_pkg->recharge(\%values);
 215   }else{
 216     $cust_pkg->set_usage(\%values, %opt);
 217   }
 218 }
 219
 220 1;