FS/FS/part_pkg/flat.pm

   1 package FS::part_pkg::flat;
   2
   3 use strict;
   4 use vars qw( @ISA %info
   5              %usage_fields %usage_recharge_fields
   6              @usage_fieldorder @usage_recharge_fieldorder
   7            );
   8 use Tie::IxHash;
   9 use List::Util qw(min); # max);
  10 #use FS::Record qw(qsearch);
  11 use FS::UI::bytecount;
  12 use FS::Conf;
  13 use FS::part_pkg;
  14 use FS::cust_bill_pkg_discount;
  15
  16 @ISA = qw(FS::part_pkg FS::part_pkg::prorate_Mixin);
  17
  18 tie my %temporalities, 'Tie::IxHash',
  19   'upcoming'  => "Upcoming (future)",
  20   'preceding' => "Preceding (past)",
  21 ;
  22
  23 %usage_fields = (
  24
  25     'seconds'       => { 'name' => 'Time limit for this package',
  26                          'default' => '',
  27                          'check' => sub { shift =~ /^\d*$/ },
  28                        },
  29     'upbytes'       => { 'name' => 'Upload limit for this package',
  30                          'default' => '',
  31                          'check' => sub { shift =~ /^\d*$/ },
  32                          'format' => \&FS::UI::bytecount::display_bytecount,
  33                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  34                        },
  35     'downbytes'     => { 'name' => 'Download limit for this package',
  36                          'default' => '',
  37                          'check' => sub { shift =~ /^\d*$/ },
  38                          'format' => \&FS::UI::bytecount::display_bytecount,
  39                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  40                        },
  41     'totalbytes'    => { 'name' => 'Transfer limit for this package',
  42                          'default' => '',
  43                          'check' => sub { shift =~ /^\d*$/ },
  44                          'format' => \&FS::UI::bytecount::display_bytecount,
  45                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  46                        },
  47 );
  48
  49 %usage_recharge_fields = (
  50
  51     'recharge_amount'       => { 'name' => 'Cost of recharge for this package',
  52                          'default' => '',
  53                          'check' => sub { shift =~ /^\d*(\.\d{2})?$/ },
  54                        },
  55     'recharge_seconds'      => { 'name' => 'Recharge time for this package',
  56                          'default' => '',
  57                          'check' => sub { shift =~ /^\d*$/ },
  58                        },
  59     'recharge_upbytes'      => { 'name' => 'Recharge upload for this package',
  60                          'default' => '',
  61                          'check' => sub { shift =~ /^\d*$/ },
  62                          'format' => \&FS::UI::bytecount::display_bytecount,
  63                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  64                        },
  65     'recharge_downbytes'    => { 'name' => 'Recharge download for this package',
  66                          'default' => '',
  67                          'check' => sub { shift =~ /^\d*$/ },
  68                          'format' => \&FS::UI::bytecount::display_bytecount,
  69                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  70                        },
  71     'recharge_totalbytes'   => { 'name' => 'Recharge transfer for this package',
  72                          'default' => '',
  73                          'check' => sub { shift =~ /^\d*$/ },
  74                          'format' => \&FS::UI::bytecount::display_bytecount,
  75                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  76                        },
  77     'usage_rollover' => { 'name' => 'Allow usage from previous period to roll '.
  78                                     ' over into current period',
  79                           'type' => 'checkbox',
  80                         },
  81     'recharge_reset' => { 'name' => 'Reset usage to these values on manual '.
  82                                     'package recharge',
  83                           'type' => 'checkbox',
  84                         },
  85 );
  86
  87 @usage_fieldorder = qw( seconds upbytes downbytes totalbytes );
  88 @usage_recharge_fieldorder = qw(
  89   recharge_amount recharge_seconds recharge_upbytes
  90   recharge_downbytes recharge_totalbytes
  91   usage_rollover recharge_reset
  92 );
  93
  94 %info = (
  95   'name' => 'Flat rate (anniversary billing)',
  96   'shortname' => 'Anniversary',
  97   'fields' => {
  98     'setup_fee'     => { 'name' => 'Setup fee for this package',
  99                          'default' => 0,
 100                        },
 101     'recur_fee'     => { 'name' => 'Recurring fee for this package',
 102                          'default' => 0,
 103                        },
 104
 105     #false laziness w/voip_cdr.pm
 106     'recur_temporality' => { 'name' => 'Charge recurring fee for period',
 107                              'type' => 'select',
 108                              'select_options' => \%temporalities,
 109                            },
 110     'unused_credit' => { 'name' => 'Credit the customer for the unused portion'.
 111                                    ' of service at cancellation',
 112                          'type' => 'checkbox',
 113                        },
 114
 115     #used in cust_pkg.pm so could add to any price plan
 116     'expire_months' => { 'name' => 'Auto-add an expiration date this number of months out',
 117                        },
 118     #used in cust_pkg.pm so could add to any price plan where it made sense
 119     'start_1st'     => { 'name' => 'Auto-add a start date to the 1st, ignoring the current month.',
 120                          'type' => 'checkbox',
 121                        },
 122     'sync_bill_date' => { 'name' => 'Prorate first month to synchronize '.
 123                                     'with the customer\'s other packages',
 124                           'type' => 'checkbox',
 125                         },
 126
 127     %usage_fields,
 128     %usage_recharge_fields,
 129
 130     'externalid' => { 'name'   => 'Optional External ID',
 131                       'default' => '',
 132                     },
 133   },
 134   'fieldorder' => [ qw( setup_fee recur_fee
 135                         recur_temporality unused_credit
 136                         expire_months start_1st sync_bill_date
 137                       ),
 138                     @usage_fieldorder, @usage_recharge_fieldorder,
 139                     qw( externalid ),
 140                   ],
 141   'weight' => 10,
 142 );
 143
 144 sub calc_setup {
 145   my($self, $cust_pkg, $sdate, $details ) = @_;
 146
 147   my $i = 0;
 148   my $count = $self->option( 'additional_count', 'quiet' ) || 0;
 149   while ($i < $count) {
 150     push @$details, $self->option( 'additional_info' . $i++ );
 151   }
 152
 153   my $quantity = $cust_pkg->quantity || 1;
 154
 155   sprintf("%.2f", $quantity * $self->unit_setup($cust_pkg, $sdate, $details) );
 156 }
 157
 158 sub unit_setup {
 159   my($self, $cust_pkg, $sdate, $details ) = @_;
 160
 161   $self->option('setup_fee') || 0;
 162 }
 163
 164 sub calc_recur {
 165   my $self = shift;
 166   my($cust_pkg, $sdate, $details, $param ) = @_;
 167
 168   #my $last_bill = $cust_pkg->last_bill;
 169   my $last_bill = $cust_pkg->get('last_bill'); #->last_bill falls back to setup
 170
 171   return 0
 172     if $self->option('recur_temporality', 1) eq 'preceding' && $last_bill == 0;
 173
 174   if( $self->option('sync_bill_date') ) {
 175     return $self->calc_prorate(@_);
 176   }
 177   else {
 178     my $charge = $self->base_recur($cust_pkg);
 179     my $discount = $self->calc_discount($cust_pkg, $sdate, $details, $param);
 180
 181     return sprintf('%.2f', $charge - $discount);
 182   }
 183 }
 184
 185 sub calc_discount {
 186   my($self, $cust_pkg, $sdate, $details, $param ) = @_;
 187
 188   my $br = $self->base_recur($cust_pkg);
 189
 190   my $tot_discount = 0;
 191   #UI enforces just 1 for now, will need ordering when they can be stacked
 192   my @cust_pkg_discount = $cust_pkg->cust_pkg_discount_active;
 193   foreach my $cust_pkg_discount ( @cust_pkg_discount ) {
 194      my $discount = $cust_pkg_discount->discount;
 195      #UI enforces one or the other (for now?  probably for good)
 196      my $amount = 0;
 197      $amount += $discount->amount
 198        if $cust_pkg->pkgpart == $param->{real_pkgpart};
 199      $amount += sprintf('%.2f', $discount->percent * $br / 100 );
 200
 201      my $chg_months = $param->{'months'} || $cust_pkg->part_pkg->freq;
 202
 203      my $months = $discount->months
 204                     ? min( $chg_months,
 205                            $discount->months - $cust_pkg_discount->months_used )
 206                     : $chg_months;
 207
 208      my $error = $cust_pkg_discount->increment_months_used($months);
 209      die "error discounting: $error" if $error;
 210
 211      $amount *= $months;
 212      $amount = sprintf('%.2f', $amount);
 213
 214      next unless $amount > 0;
 215
 216      #record details in cust_bill_pkg_discount
 217      my $cust_bill_pkg_discount = new FS::cust_bill_pkg_discount {
 218        'pkgdiscountnum' => $cust_pkg_discount->pkgdiscountnum,
 219        'amount'         => $amount,
 220        'months'         => $months,
 221      };
 222      push @{ $param->{'discounts'} }, $cust_bill_pkg_discount;
 223
 224      #add details on discount to invoice
 225      my $conf = new FS::Conf;
 226      my $money_char = $conf->config('money_char') || '$';
 227      $months = sprintf('%.2f', $months) if $months =~ /\./;
 228
 229      my $d = 'Includes ';
 230      $d .= $discount->name. ' ' if $discount->name;
 231      $d .= 'discount of '. $discount->description_short;
 232      $d .= " for $months month". ( $months!=1 ? 's' : '' );
 233      $d .= ": $money_char$amount" if $months != 1 || $discount->percent;
 234      push @$details, $d;
 235
 236      $tot_discount += $amount;
 237   }
 238
 239   sprintf('%.2f', $tot_discount);
 240 }
 241
 242 sub base_recur {
 243   my($self, $cust_pkg) = @_;
 244   $self->option('recur_fee', 1) || 0;
 245 }
 246
 247 sub base_recur_permonth {
 248   my($self, $cust_pkg) = @_;
 249
 250   return 0 unless $self->freq =~ /^\d+$/ && $self->freq > 0;
 251
 252   sprintf('%.2f', $self->base_recur($cust_pkg) / $self->freq );
 253 }
 254
 255 sub calc_remain {
 256   my ($self, $cust_pkg, %options) = @_;
 257
 258   my $time;
 259   if ($options{'time'}) {
 260     $time = $options{'time'};
 261   } else {
 262     $time = time;
 263   }
 264
 265   my $next_bill = $cust_pkg->getfield('bill') || 0;
 266
 267   #my $last_bill = $cust_pkg->last_bill || 0;
 268   my $last_bill = $cust_pkg->get('last_bill') || 0; #->last_bill falls back to setup
 269
 270   return 0 if    ! $self->base_recur($cust_pkg)
 271               || ! $self->option('unused_credit', 1)
 272               || ! $last_bill
 273               || ! $next_bill
 274               || $next_bill < $time;
 275
 276   my %sec = (
 277     'h' =>    3600, # 60 * 60
 278     'd' =>   86400, # 60 * 60 * 24
 279     'w' =>  604800, # 60 * 60 * 24 * 7
 280     'm' => 2629744, # 60 * 60 * 24 * 365.2422 / 12
 281   );
 282
 283   $self->freq =~ /^(\d+)([hdwm]?)$/
 284     or die 'unparsable frequency: '. $self->freq;
 285   my $freq_sec = $1 * $sec{$2||'m'};
 286   return 0 unless $freq_sec;
 287
 288   sprintf("%.2f", $self->base_recur($cust_pkg) * ( $next_bill - $time ) / $freq_sec );
 289
 290 }
 291
 292 sub is_free_options {
 293   qw( setup_fee recur_fee );
 294 }
 295
 296 sub is_prepaid { 0; } #no, we're postpaid
 297
 298 #XXX discounts only on recurring fees for now (no setup/one-time or usage)
 299 sub can_discount {
 300   my $self = shift;
 301   $self->freq =~ /^\d+$/ && $self->freq > 0;
 302 }
 303
 304 sub usage_valuehash {
 305   my $self = shift;
 306   map { $_, $self->option($_) }
 307     grep { $self->option($_, 'hush') }
 308     qw(seconds upbytes downbytes totalbytes);
 309 }
 310
 311 sub reset_usage {
 312   my($self, $cust_pkg, %opt) = @_;
 313   warn "   resetting usage counters" if defined($opt{debug}) && $opt{debug} > 1;
 314   my %values = $self->usage_valuehash;
 315   if ($self->option('usage_rollover', 1)) {
 316     $cust_pkg->recharge(\%values);
 317   }else{
 318     $cust_pkg->set_usage(\%values, %opt);
 319   }
 320 }
 321
 322 1;