FS/FS/part_pkg/flat.pm

   1 package FS::part_pkg::flat;
   2
   3 use strict;
   4 use vars qw( @ISA %info
   5              %usage_fields %usage_recharge_fields
   6              @usage_fieldorder @usage_recharge_fieldorder
   7            );
   8 use Tie::IxHash;
   9 use List::Util qw(min); # max);
  10 #use FS::Record qw(qsearch);
  11 use FS::UI::bytecount;
  12 use FS::Conf;
  13 use FS::part_pkg;
  14 use FS::cust_bill_pkg_discount;
  15
  16 @ISA = qw(FS::part_pkg);
  17
  18 tie my %temporalities, 'Tie::IxHash',
  19   'upcoming'  => "Upcoming (future)",
  20   'preceding' => "Preceding (past)",
  21 ;
  22
  23 %usage_fields = (
  24
  25     'seconds'       => { 'name' => 'Time limit for this package',
  26                          'default' => '',
  27                          'check' => sub { shift =~ /^\d*$/ },
  28                        },
  29     'upbytes'       => { 'name' => 'Upload limit for this package',
  30                          'default' => '',
  31                          'check' => sub { shift =~ /^\d*$/ },
  32                          'format' => \&FS::UI::bytecount::display_bytecount,
  33                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  34                        },
  35     'downbytes'     => { 'name' => 'Download limit for this package',
  36                          'default' => '',
  37                          'check' => sub { shift =~ /^\d*$/ },
  38                          'format' => \&FS::UI::bytecount::display_bytecount,
  39                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  40                        },
  41     'totalbytes'    => { 'name' => 'Transfer limit for this package',
  42                          'default' => '',
  43                          'check' => sub { shift =~ /^\d*$/ },
  44                          'format' => \&FS::UI::bytecount::display_bytecount,
  45                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  46                        },
  47 );
  48
  49 %usage_recharge_fields = (
  50
  51     'recharge_amount'       => { 'name' => 'Cost of recharge for this package',
  52                          'default' => '',
  53                          'check' => sub { shift =~ /^\d*(\.\d{2})?$/ },
  54                        },
  55     'recharge_seconds'      => { 'name' => 'Recharge time for this package',
  56                          'default' => '',
  57                          'check' => sub { shift =~ /^\d*$/ },
  58                        },
  59     'recharge_upbytes'      => { 'name' => 'Recharge upload for this package',
  60                          'default' => '',
  61                          'check' => sub { shift =~ /^\d*$/ },
  62                          'format' => \&FS::UI::bytecount::display_bytecount,
  63                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  64                        },
  65     'recharge_downbytes'    => { 'name' => 'Recharge download for this package',
  66                          'default' => '',
  67                          'check' => sub { shift =~ /^\d*$/ },
  68                          'format' => \&FS::UI::bytecount::display_bytecount,
  69                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  70                        },
  71     'recharge_totalbytes'   => { 'name' => 'Recharge transfer for this package',
  72                          'default' => '',
  73                          'check' => sub { shift =~ /^\d*$/ },
  74                          'format' => \&FS::UI::bytecount::display_bytecount,
  75                          'parse' => \&FS::UI::bytecount::parse_bytecount,
  76                        },
  77     'usage_rollover' => { 'name' => 'Allow usage from previous period to roll '.
  78                                     ' over into current period',
  79                           'type' => 'checkbox',
  80                         },
  81     'recharge_reset' => { 'name' => 'Reset usage to these values on manual '.
  82                                     'package recharge',
  83                           'type' => 'checkbox',
  84                         },
  85 );
  86
  87 @usage_fieldorder = qw( seconds upbytes downbytes totalbytes );
  88 @usage_recharge_fieldorder = qw(
  89   recharge_amount recharge_seconds recharge_upbytes
  90   recharge_downbytes recharge_totalbytes
  91   usage_rollover recharge_reset
  92 );
  93
  94 %info = (
  95   'name' => 'Flat rate (anniversary billing)',
  96   'shortname' => 'Anniversary',
  97   'fields' => {
  98     'setup_fee'     => { 'name' => 'Setup fee for this package',
  99                          'default' => 0,
 100                        },
 101     'recur_fee'     => { 'name' => 'Recurring fee for this package',
 102                          'default' => 0,
 103                        },
 104
 105     #false laziness w/voip_cdr.pm
 106     'recur_temporality' => { 'name' => 'Charge recurring fee for period',
 107                              'type' => 'select',
 108                              'select_options' => \%temporalities,
 109                            },
 110     'unused_credit' => { 'name' => 'Credit the customer for the unused portion'.
 111                                    ' of service at cancellation',
 112                          'type' => 'checkbox',
 113                        },
 114
 115     #used in cust_pkg.pm so could add to any price plan
 116     'expire_months' => { 'name' => 'Auto-add an expiration date this number of months out',
 117                        },
 118     #used in cust_pkg.pm so could add to any price plan where it made sense
 119     'start_1st'     => { 'name' => 'Auto-add a start date to the 1st, ignoring the current month.',
 120                          'type' => 'checkbox',
 121                        },
 122
 123     %usage_fields,
 124     %usage_recharge_fields,
 125
 126     'externalid' => { 'name'   => 'Optional External ID',
 127                       'default' => '',
 128                     },
 129   },
 130   'fieldorder' => [ qw( setup_fee recur_fee
 131                         recur_temporality unused_credit
 132                         expire_months start_1st
 133                       ),
 134                     @usage_fieldorder, @usage_recharge_fieldorder,
 135                     qw( externalid ),
 136                   ],
 137   'weight' => 10,
 138 );
 139
 140 sub calc_setup {
 141   my($self, $cust_pkg, $sdate, $details ) = @_;
 142
 143   my $i = 0;
 144   my $count = $self->option( 'additional_count', 'quiet' ) || 0;
 145   while ($i < $count) {
 146     push @$details, $self->option( 'additional_info' . $i++ );
 147   }
 148
 149   my $quantity = $cust_pkg->quantity || 1;
 150
 151   sprintf("%.2f", $quantity * $self->unit_setup($cust_pkg, $sdate, $details) );
 152 }
 153
 154 sub unit_setup {
 155   my($self, $cust_pkg, $sdate, $details ) = @_;
 156
 157   $self->option('setup_fee');
 158 }
 159
 160 sub calc_recur {
 161   my $self = shift;
 162   my($cust_pkg) = @_;
 163
 164   #my $last_bill = $cust_pkg->last_bill;
 165   my $last_bill = $cust_pkg->get('last_bill'); #->last_bill falls back to setup
 166
 167   return 0
 168     if $self->option('recur_temporality', 1) eq 'preceding' && $last_bill == 0;
 169
 170   my $br = $self->base_recur(@_);
 171
 172   my $discount = $self->calc_discount(@_);
 173
 174   sprintf('%.2f', $br - $discount);
 175 }
 176
 177 sub calc_discount {
 178   my $self = shift;
 179   my($cust_pkg, $sdate, $details, $param ) = @_;
 180
 181   my $br = $self->base_recur(@_);
 182
 183   my $tot_discount = 0;
 184   #UI enforces just 1 for now, will need ordering when they can be stacked
 185   foreach my $cust_pkg_discount ( $cust_pkg->cust_pkg_discount_active ) {
 186      my $discount = $cust_pkg_discount->discount;
 187      #UI enforces one or the other (for now?  probably for good)
 188      my $amount = 0;
 189      $amount += $discount->amount;
 190      $amount += sprintf('%.2f', $discount->percent * $br / 100 );
 191
 192      my $chg_months = $param->{'months'} || $cust_pkg->part_pkg->freq;
 193
 194      my $months = $discount->months
 195                     ? min( $chg_months,
 196                            $discount->months - $cust_pkg->months_used )
 197                     : $chg_months;
 198
 199      my $error = $cust_pkg_discount->increment_months_used($months);
 200      die "error discounting: $error" if $error;
 201
 202      $amount *= $months;
 203      $amount = sprintf('%.2f', $amount);
 204
 205      next unless $amount > 0;
 206
 207      #record details in cust_bill_pkg_discount
 208      my $cust_bill_pkg_discount = new FS::cust_bill_pkg_discount {
 209        'pkgdiscountnum' => $cust_pkg_discount->pkgdiscountnum,
 210        'amount'         => $amount,
 211        'months'         => $months,
 212      };
 213      push @{ $param->{'discounts'} }, $cust_bill_pkg_discount;
 214
 215      #add details on discount to invoice
 216      my $conf = new FS::Conf;
 217      my $money_char = $conf->config('money_char') || '$';
 218      $months = sprintf('%.2f', $months) if $months =~ /\./;
 219
 220      my $d = 'Includes ';
 221      $d .= $discount->name. ' ' if $discount->name;
 222      $d .= 'discount of '. $discount->description_short;
 223      $d .= " for $months month". ( $months!=1 ? 's' : '' );
 224      $d .= ": $money_char$amount" if $months != 1 || $discount->percent;
 225      push @$details, $d;
 226
 227      $tot_discount += $amount;
 228   }
 229
 230   sprintf('%.2f', $tot_discount);
 231 }
 232
 233 sub base_recur {
 234   my($self, $cust_pkg) = @_;
 235   $self->option('recur_fee', 1) || 0;
 236 }
 237
 238 sub base_recur_permonth {
 239   my($self, $cust_pkg) = @_;
 240
 241   return 0 unless $self->freq =~ /^\d+$/ && $self->freq > 0;
 242
 243   sprintf('%.2f', $self->base_recur($cust_pkg) / $self->freq );
 244 }
 245
 246 sub calc_remain {
 247   my ($self, $cust_pkg, %options) = @_;
 248
 249   my $time;
 250   if ($options{'time'}) {
 251     $time = $options{'time'};
 252   } else {
 253     $time = time;
 254   }
 255
 256   my $next_bill = $cust_pkg->getfield('bill') || 0;
 257
 258   #my $last_bill = $cust_pkg->last_bill || 0;
 259   my $last_bill = $cust_pkg->get('last_bill') || 0; #->last_bill falls back to setup
 260
 261   return 0 if    ! $self->base_recur($cust_pkg)
 262               || ! $self->option('unused_credit', 1)
 263               || ! $last_bill
 264               || ! $next_bill
 265               || $next_bill < $time;
 266
 267   my %sec = (
 268     'h' =>    3600, # 60 * 60
 269     'd' =>   86400, # 60 * 60 * 24
 270     'w' =>  604800, # 60 * 60 * 24 * 7
 271     'm' => 2629744, # 60 * 60 * 24 * 365.2422 / 12
 272   );
 273
 274   $self->freq =~ /^(\d+)([hdwm]?)$/
 275     or die 'unparsable frequency: '. $self->freq;
 276   my $freq_sec = $1 * $sec{$2||'m'};
 277   return 0 unless $freq_sec;
 278
 279   sprintf("%.2f", $self->base_recur($cust_pkg) * ( $next_bill - $time ) / $freq_sec );
 280
 281 }
 282
 283 sub is_free_options {
 284   qw( setup_fee recur_fee );
 285 }
 286
 287 sub is_prepaid { 0; } #no, we're postpaid
 288
 289 #XXX discounts only on recurring fees for now (no setup/one-time or usage)
 290 sub can_discount {
 291   my $self = shift;
 292   $self->freq =~ /^\d+$/ && $self->freq > 0;
 293 }
 294
 295 sub usage_valuehash {
 296   my $self = shift;
 297   map { $_, $self->option($_) }
 298     grep { $self->option($_, 'hush') }
 299     qw(seconds upbytes downbytes totalbytes);
 300 }
 301
 302 sub reset_usage {
 303   my($self, $cust_pkg, %opt) = @_;
 304   warn "   resetting usage counters" if defined($opt{debug}) && $opt{debug} > 1;
 305   my %values = $self->usage_valuehash;
 306   if ($self->option('usage_rollover', 1)) {
 307     $cust_pkg->recharge(\%values);
 308   }else{
 309     $cust_pkg->set_usage(\%values, %opt);
 310   }
 311 }
 312
 313 1;