FS/FS/part_pkg/flat.pm

   1 package FS::part_pkg::flat;
   2 use base qw( FS::part_pkg::prorate_Mixin
   3              FS::part_pkg::discount_Mixin
   4              FS::part_pkg
   5            );
   6
   7 use strict;
   8 use vars qw( $conf $money_char %info
   9              %usage_recharge_fields @usage_recharge_fieldorder
  10            );
  11 use FS::UID;
  12 use FS::Record qw( qsearch );
  13 use FS::cust_credit_source_bill_pkg;
  14 use Tie::IxHash;
  15 use List::Util qw( min );
  16 use FS::UI::bytecount;
  17 use FS::Conf;
  18 use Time::Local 'timelocal';
  19
  20 #ask FS::UID to run this stuff for us later
  21 FS::UID->install_callback( sub {
  22   $conf = new FS::Conf;
  23   $money_char = $conf->config('money_char') || '$';
  24 });
  25
  26 tie my %temporalities, 'Tie::IxHash',
  27   'upcoming'  => "Upcoming (future)",
  28   'preceding' => "Preceding (past)",
  29 ;
  30
  31 tie my %contract_years, 'Tie::IxHash', (
  32   '' => '(none)',
  33   map { $_*12 => $_ } (1..5),
  34 );
  35
  36 %info = (
  37   'name' => 'Flat rate (anniversary billing)',
  38   'shortname' => 'Anniversary',
  39   'inherit_fields' => [ 'prorate_Mixin', 'usage_Mixin', 'global_Mixin' ],
  40   'fields' => {
  41     #false laziness w/voip_cdr.pm
  42     'recur_temporality' => { 'name' => 'Charge recurring fee for period',
  43                              'type' => 'select',
  44                              'select_options' => \%temporalities,
  45                            },
  46
  47     #used in cust_pkg.pm so could add to any price plan where it made sense
  48     'start_1st'     => { 'name' => 'Auto-add a start date to the 1st, ignoring the current month.',
  49                          'type' => 'checkbox',
  50                        },
  51     'sync_bill_date' => { 'name' => 'Prorate first month to synchronize '.
  52                                     'with the customer\'s other packages',
  53                           'type' => 'checkbox',
  54                         },
  55     'prorate_defer_bill' => {
  56                           'name' => 'When synchronizing, defer the bill until '.
  57                                     'the customer\'s next bill date',
  58                           'type' => 'checkbox',
  59                         },
  60     'prorate_round_day' => {
  61                           'name' => 'When synchronizing, round the prorated '.
  62                                     'period',
  63                           'type' => 'select',
  64                           'select_options' => \%FS::part_pkg::prorate_Mixin::prorate_round_day_opts,
  65                         },
  66     'add_full_period' => { 'disabled' => 1 }, # doesn't make sense with sync?
  67
  68     'suspend_bill' => { 'name' => 'Continue recurring billing while suspended',
  69                         'type' => 'checkbox',
  70                       },
  71     'unsuspend_adjust_bill' =>
  72                         { 'name' => 'Adjust next bill date forward when '.
  73                                     'unsuspending',
  74                           'type' => 'checkbox',
  75                         },
  76     'bill_recur_on_cancel' => {
  77                         'name' => 'Bill the last period on cancellation',
  78                         'type' => 'checkbox',
  79                         },
  80     'bill_suspend_as_cancel' => {
  81                         'name' => 'Bill immediately upon suspension', #desc?
  82                         'type' => 'checkbox',
  83                         },
  84     'externalid' => { 'name'   => 'Optional External ID',
  85                       'default' => '',
  86                     },
  87   },
  88   'fieldorder' => [ qw( recur_temporality
  89                         start_1st
  90                         sync_bill_date prorate_defer_bill prorate_round_day
  91                         suspend_bill unsuspend_adjust_bill
  92                         bill_recur_on_cancel
  93                         bill_suspend_as_cancel
  94                         externalid ),
  95                   ],
  96   'weight' => 10,
  97 );
  98
  99 sub price_info {
 100   my $self = shift;
 101   my %opt = @_;
 102
 103   my $setup = $opt{cust_pkg} ? $self->base_setup( $opt{cust_pkg} )
 104                              : ($self->option('setup_fee') || 0);
 105   my $recur = $opt{cust_pkg} ? $self->base_recur( $opt{cust_pkg} )
 106                              : ($self->option('recur_fee', 1) || 0);
 107   $recur += $self->usageprice_recur( $opt{cust_pkg} ) if $opt{cust_pkg};
 108
 109   my $str = '';
 110   $str = $money_char . $setup . ($recur ? ' setup' : ' one-time') if $setup;
 111   $str .= ', ' if ($setup && $recur);
 112   $str .= $money_char. $recur. '/'. $self->freq_pretty if $recur;
 113   $str;
 114 }
 115
 116 sub calc_setup {
 117   my($self, $cust_pkg, $sdate, $details, $param ) = @_;
 118
 119   return 0 if $self->prorate_setup($cust_pkg, $sdate);
 120
 121   my $i = 0;
 122   my $count = $self->option( 'additional_count', 'quiet' ) || 0;
 123   while ($i < $count) {
 124     push @$details, $self->option( 'additional_info' . $i++ );
 125   }
 126
 127   my $charge = $self->base_setup($cust_pkg, $sdate, $details);
 128
 129   my $discount = 0;
 130   if ( $charge > 0 ) {
 131     $param->{'setup_charge'} = $charge;
 132     $discount = $self->calc_discount($cust_pkg, $sdate, $details, $param);
 133     delete $param->{'setup_charge'};
 134   }
 135
 136   sprintf( '%.2f', ($cust_pkg->quantity || 1) * ($charge - $discount) );
 137
 138 }
 139
 140 sub base_setup {
 141   my($self, $cust_pkg, $sdate, $details ) = @_;
 142   $self->option('setup_fee', 1) || 0;
 143 }
 144
 145 sub calc_recur {
 146   my $self = shift;
 147   my($cust_pkg, $sdate, $details, $param ) = @_;
 148
 149   #my $last_bill = $cust_pkg->last_bill;
 150   my $last_bill = $cust_pkg->get('last_bill'); #->last_bill falls back to setup
 151
 152   return 0
 153     if $self->recur_temporality eq 'preceding' && !$last_bill;
 154
 155   my $charge = $self->base_recur($cust_pkg, $sdate);
 156   # always treat cutoff_day as a list
 157   if ( my @cutoff_day = $self->cutoff_day($cust_pkg) ) {
 158     $charge = $self->calc_prorate(@_, @cutoff_day);
 159   }
 160   elsif ( $param->{freq_override} ) {
 161     # XXX not sure if this should be mutually exclusive with sync_bill_date.
 162     # Given the very specific problem that freq_override is meant to 'solve',
 163     # it probably should.
 164     $charge *= $param->{freq_override} if $param->{freq_override};
 165   }
 166
 167   $charge += $self->usageprice_recur($cust_pkg, $sdate);
 168   $cust_pkg->apply_usageprice(); #$sdate for prorating?
 169
 170   my $discount = $self->calc_discount($cust_pkg, $sdate, $details, $param);
 171
 172   sprintf( '%.2f', ($cust_pkg->quantity || 1) * ($charge - $discount) );
 173 }
 174
 175 sub cutoff_day {
 176   my $self = shift;
 177   my $cust_pkg = shift;
 178   my $cust_main = $cust_pkg->cust_main;
 179   # force it to act like a prorate package, is what this means
 180   # because we made a distinction once between prorate and flat packages
 181   if ( $cust_main->force_prorate_day  and $cust_main->prorate_day ) {
 182      return ( $cust_main->prorate_day );
 183   }
 184   if ( $self->option('sync_bill_date',1) ) {
 185     my $next_bill = $cust_pkg->cust_main->next_bill_date;
 186     if ( $next_bill ) {
 187       return (localtime($next_bill))[3];
 188     } else {
 189       # This is the customer's only active package and hasn't been billed
 190       # yet, so set the cutoff day to either today or tomorrow, whichever
 191       # would result in a full period after rounding.
 192       my $setup = $cust_pkg->setup; # because it's "now"
 193       my $rounding_mode = $self->option('prorate_round_day',1);
 194       return () if !$setup or !$rounding_mode;
 195       my ($sec, $min, $hour, $mday, $mon, $year) = localtime($setup);
 196
 197       if (   ( $rounding_mode == 1 and $hour >= 12 )
 198           or ( $rounding_mode == 3 and ( $sec > 0 or $min > 0 or $hour > 0 ))
 199       ) {
 200         # then the prorate period will be rounded down to start from
 201         # midnight tomorrow, so the cutoff day should be the current day +
 202         # 1.
 203         $setup = timelocal(59,59,23,$mday,$mon,$year) + 1;
 204         $mday = (localtime($setup))[3];
 205       }
 206       # otherwise, it will be rounded up, so leave the cutoff day at today.
 207       return $mday;
 208     }
 209   }
 210   return ();
 211 }
 212
 213 sub base_recur {
 214   my($self, $cust_pkg, $sdate) = @_;
 215   $self->option('recur_fee', 1) || 0;
 216 }
 217
 218 sub base_recur_permonth {
 219   my($self, $cust_pkg) = @_;
 220
 221   return 0 unless $self->freq =~ /^\d+$/ && $self->freq > 0;
 222
 223   sprintf('%.2f', $self->base_recur($cust_pkg) / $self->freq );
 224 }
 225
 226 sub usageprice_recur {
 227   my($self, $cust_pkg, $sdate) = @_;
 228
 229   my $recur = 0;
 230   $recur += $_->price foreach $cust_pkg->cust_pkg_usageprice;
 231
 232   sprintf('%.2f', $recur);
 233 }
 234
 235 sub calc_cancel {
 236   my $self = shift;
 237   if ( $self->recur_temporality eq 'preceding'
 238        and $self->option('bill_recur_on_cancel', 1) ) {
 239     # run another recurring cycle
 240     return $self->calc_recur(@_);
 241   } elsif ( $conf->exists('bill_usage_on_cancel') # should be a package option?
 242           and $self->can('calc_usage') ) {
 243     # bill for outstanding usage
 244     return $self->calc_usage(@_);
 245   } else {
 246     return 'NOTHING'; # numerically zero, but has special meaning
 247   }
 248 }
 249
 250 # no longer used; see credit_remaining in FS::cust_pkg
 251
 252 sub calc_remain {
 253   my ($self, $cust_pkg, %options) = @_;
 254
 255   my $time;
 256   if ($options{'time'}) {
 257     $time = $options{'time'};
 258   } else {
 259     $time = time;
 260   }
 261
 262   my $next_bill = $cust_pkg->getfield('bill') || 0;
 263
 264   return 0 if    ! $self->base_recur($cust_pkg, \$time)
 265               || ! $next_bill
 266               || $next_bill < $time;
 267
 268   # Use actual charge for this period, not base_recur (for discounts).
 269   # Use sdate < $time and edate >= $time because when billing on
 270   # cancellation, edate = $time.
 271   my $credit = 0;
 272   foreach my $cust_bill_pkg (
 273     qsearch('cust_bill_pkg', {
 274       pkgnum => $cust_pkg->pkgnum,
 275       edate => {op => '>=', value => $time},
 276       recur => {op => '>' , value => 0},
 277     })
 278   ) {
 279
 280     # hack to deal with the weird behavior of edate on package cancellation
 281     my $edate = $cust_bill_pkg->edate;
 282     if ( $self->recur_temporality eq 'preceding' ) {
 283       $edate = $self->add_freq($cust_bill_pkg->sdate);
 284     }
 285
 286     # this will also get any package charges that are _entirely_ after the
 287     # cancellation date (can happen with advance billing). in that case,
 288     # use the entire recurring charge:
 289     my $amount = $cust_bill_pkg->recur - $cust_bill_pkg->usage;
 290
 291     # but if the cancellation happens during the interval, prorate it:
 292     # (XXX obey prorate_round_day here?)
 293     if ( $cust_bill_pkg->sdate < $time ) {
 294       $amount = $amount * ($edate - $time) / ($edate - $cust_bill_pkg->sdate);
 295     }
 296
 297     $credit += $amount;
 298
 299     push @{ $options{'cust_credit_source_bill_pkg'} },
 300       new FS::cust_credit_source_bill_pkg {
 301         'billpkgnum' => $cust_bill_pkg->billpkgnum,
 302         'amount'     => sprintf('%.2f', $amount),
 303         'currency'   => $cust_bill_pkg->cust_bill->currency,
 304       }
 305         if $options{'cust_credit_source_bill_pkg'};
 306
 307   }
 308
 309   sprintf('%.2f', $credit);
 310
 311 }
 312
 313 sub is_free_options {
 314   qw( setup_fee recur_fee );
 315 }
 316
 317 sub is_prepaid { 0; } #no, we're postpaid
 318
 319 sub can_start_date {
 320   my $self = shift;
 321   my %opt = @_;
 322   return 0 if $self->start_on_hold;
 323
 324   ! $self->option('start_1st', 1) && (   ! $self->option('sync_bill_date',1)
 325                                       || ! $self->option('prorate_defer_bill',1)
 326                                       || ! $opt{'num_ncancelled_pkgs'}
 327                                      );
 328 }
 329
 330 sub can_discount { 1; }
 331
 332 sub can_usageprice { 1; }
 333
 334 sub recur_temporality {
 335   my $self = shift;
 336   $self->option('recur_temporality', 1);
 337 }
 338
 339 sub usage_valuehash {
 340   my $self = shift;
 341   map { $_, $self->option($_) }
 342     grep { $self->option($_, 'hush') }
 343     qw(seconds upbytes downbytes totalbytes);
 344 }
 345
 346 sub reset_usage {
 347   my($self, $cust_pkg, %opt) = @_;
 348   warn "   resetting usage counters" if defined($opt{debug}) && $opt{debug} > 1;
 349   my %values = $self->usage_valuehash;
 350   if ($self->option('usage_rollover', 1)) {
 351     $cust_pkg->recharge(\%values);
 352   }else{
 353     $cust_pkg->set_usage(\%values, %opt);
 354   }
 355 }
 356
 357 1;