FS/FS/part_pkg/flat.pm

   1 package FS::part_pkg::flat;
   2
   3 use strict;
   4 use base qw( FS::part_pkg
   5              FS::part_pkg::prorate_Mixin
   6              FS::part_pkg::discount_Mixin
   7            );
   8 use vars qw( %info %usage_recharge_fields @usage_recharge_fieldorder );
   9 use Tie::IxHash;
  10 use List::Util qw(min); # max);
  11 #use FS::Record qw(qsearch);
  12 use FS::UI::bytecount;
  13 use FS::Conf;
  14
  15 tie my %temporalities, 'Tie::IxHash',
  16   'upcoming'  => "Upcoming (future)",
  17   'preceding' => "Preceding (past)",
  18 ;
  19
  20 tie my %contract_years, 'Tie::IxHash', (
  21   '' => '(none)',
  22   map { $_*12 => $_ } (1..5),
  23 );
  24
  25 %info = (
  26   'name' => 'Flat rate (anniversary billing)',
  27   'shortname' => 'Anniversary',
  28   'inherit_fields' => [ 'usage_Mixin', 'global_Mixin' ],
  29   'fields' => {
  30     #false laziness w/voip_cdr.pm
  31     'recur_temporality' => { 'name' => 'Charge recurring fee for period',
  32                              'type' => 'select',
  33                              'select_options' => \%temporalities,
  34                            },
  35
  36     #used in cust_pkg.pm so could add to any price plan
  37     'expire_months' => { 'name' => 'Auto-add an expiration date this number of months out',
  38                        },
  39     'adjourn_months'=> { 'name' => 'Auto-add a suspension date this number of months out',
  40                        },
  41     'contract_end_months'=> {
  42                         'name' => 'Auto-add a contract end date this number of years out',
  43                         'type' => 'select',
  44                         'select_options' => \%contract_years,
  45                       },
  46     #used in cust_pkg.pm so could add to any price plan where it made sense
  47     'start_1st'     => { 'name' => 'Auto-add a start date to the 1st, ignoring the current month.',
  48                          'type' => 'checkbox',
  49                        },
  50     'sync_bill_date' => { 'name' => 'Prorate first month to synchronize '.
  51                                     'with the customer\'s other packages',
  52                           'type' => 'checkbox',
  53                         },
  54     'prorate_defer_bill' => {
  55                           'name' => 'When synchronizing, defer the bill until '.
  56                                     'the customer\'s next bill date',
  57                           'type' => 'checkbox',
  58                         },
  59     'suspend_bill' => { 'name' => 'Continue recurring billing while suspended',
  60                         'type' => 'checkbox',
  61                       },
  62     'unsuspend_adjust_bill' =>
  63                         { 'name' => 'Adjust next bill date forward when '.
  64                                     'unsuspending',
  65                           'type' => 'checkbox',
  66                         },
  67
  68     'externalid' => { 'name'   => 'Optional External ID',
  69                       'default' => '',
  70                     },
  71   },
  72   'fieldorder' => [ qw( recur_temporality
  73                         expire_months adjourn_months
  74                         contract_end_months
  75                         start_1st sync_bill_date prorate_defer_bill
  76                         suspend_bill unsuspend_adjust_bill
  77                         externalid ),
  78                   ],
  79   'weight' => 10,
  80 );
  81
  82 sub price_info {
  83     my $self = shift;
  84     my $conf = new FS::Conf;
  85     my $money_char = $conf->config('money_char') || '$';
  86     my $setup = $self->option('setup_fee') || 0;
  87     my $recur = $self->option('recur_fee', 1) || 0;
  88     my $str = '';
  89     $str = $money_char . $setup . ' one-time' if $setup;
  90     $str .= ', ' if ($setup && $recur);
  91     $str .= $money_char . $recur . ' recurring ' if $recur;
  92     $str;
  93 }
  94
  95 sub calc_setup {
  96   my($self, $cust_pkg, $sdate, $details ) = @_;
  97
  98   return 0 if $self->prorate_setup($cust_pkg, $sdate);
  99
 100   my $i = 0;
 101   my $count = $self->option( 'additional_count', 'quiet' ) || 0;
 102   while ($i < $count) {
 103     push @$details, $self->option( 'additional_info' . $i++ );
 104   }
 105
 106   my $quantity = $cust_pkg->quantity || 1;
 107
 108   my $charge = $quantity * $self->unit_setup($cust_pkg, $sdate, $details);
 109   sprintf('%.2f', $charge);
 110 }
 111
 112 sub unit_setup {
 113   my($self, $cust_pkg, $sdate, $details ) = @_;
 114
 115   $self->option('setup_fee') || 0;
 116 }
 117
 118 sub calc_recur {
 119   my $self = shift;
 120   my($cust_pkg, $sdate, $details, $param ) = @_;
 121
 122   #my $last_bill = $cust_pkg->last_bill;
 123   my $last_bill = $cust_pkg->get('last_bill'); #->last_bill falls back to setup
 124
 125   return 0
 126     if $self->recur_temporality eq 'preceding' && $last_bill == 0;
 127
 128   my $charge = $self->base_recur($cust_pkg, $sdate);
 129   if ( my $cutoff_day = $self->cutoff_day($cust_pkg) ) {
 130     $charge = $self->calc_prorate(@_, $cutoff_day);
 131   }
 132   elsif ( $param->{freq_override} ) {
 133     # XXX not sure if this should be mutually exclusive with sync_bill_date.
 134     # Given the very specific problem that freq_override is meant to 'solve',
 135     # it probably should.
 136     $charge *= $param->{freq_override} if $param->{freq_override};
 137   }
 138
 139   my $discount = $self->calc_discount($cust_pkg, $sdate, $details, $param);
 140   return sprintf('%.2f', $charge - $discount);
 141 }
 142
 143 sub cutoff_day {
 144   my $self = shift;
 145   my $cust_pkg = shift;
 146   if ( $self->option('sync_bill_date',1) ) {
 147     my $next_bill = $cust_pkg->cust_main->next_bill_date;
 148     if ( defined($next_bill) ) {
 149       return (localtime($next_bill))[3];
 150     }
 151   }
 152   return 0;
 153 }
 154
 155 sub base_recur {
 156   my($self, $cust_pkg, $sdate) = @_;
 157   $self->option('recur_fee', 1) || 0;
 158 }
 159
 160 sub base_recur_permonth {
 161   my($self, $cust_pkg) = @_;
 162
 163   return 0 unless $self->freq =~ /^\d+$/ && $self->freq > 0;
 164
 165   sprintf('%.2f', $self->base_recur($cust_pkg) / $self->freq );
 166 }
 167
 168 sub calc_remain {
 169   my ($self, $cust_pkg, %options) = @_;
 170
 171   my $time;
 172   if ($options{'time'}) {
 173     $time = $options{'time'};
 174   } else {
 175     $time = time;
 176   }
 177
 178   my $next_bill = $cust_pkg->getfield('bill') || 0;
 179
 180   return 0 if    ! $self->base_recur($cust_pkg, \$time)
 181               || ! $next_bill
 182               || $next_bill < $time;
 183
 184   my %sec = (
 185     'h' =>    3600, # 60 * 60
 186     'd' =>   86400, # 60 * 60 * 24
 187     'w' =>  604800, # 60 * 60 * 24 * 7
 188     'm' => 2629744, # 60 * 60 * 24 * 365.2422 / 12
 189   );
 190
 191   $self->freq =~ /^(\d+)([hdwm]?)$/
 192     or die 'unparsable frequency: '. $self->freq;
 193   my $freq_sec = $1 * $sec{$2||'m'};
 194   return 0 unless $freq_sec;
 195
 196   sprintf("%.2f", $self->base_recur($cust_pkg, \$time) * ( $next_bill - $time ) / $freq_sec );
 197
 198 }
 199
 200 sub is_free_options {
 201   qw( setup_fee recur_fee );
 202 }
 203
 204 sub is_prepaid { 0; } #no, we're postpaid
 205
 206 #XXX discounts only on recurring fees for now (no setup/one-time or usage)
 207 sub can_discount {
 208   my $self = shift;
 209   $self->freq =~ /^\d+$/ && $self->freq > 0;
 210 }
 211
 212 sub recur_temporality {
 213   my $self = shift;
 214   $self->option('recur_temporality', 1);
 215 }
 216
 217 sub usage_valuehash {
 218   my $self = shift;
 219   map { $_, $self->option($_) }
 220     grep { $self->option($_, 'hush') }
 221     qw(seconds upbytes downbytes totalbytes);
 222 }
 223
 224 sub reset_usage {
 225   my($self, $cust_pkg, %opt) = @_;
 226   warn "   resetting usage counters" if defined($opt{debug}) && $opt{debug} > 1;
 227   my %values = $self->usage_valuehash;
 228   if ($self->option('usage_rollover', 1)) {
 229     $cust_pkg->recharge(\%values);
 230   }else{
 231     $cust_pkg->set_usage(\%values, %opt);
 232   }
 233 }
 234
 235 1;