FS/FS/part_pkg/discount_Mixin.pm

   1 package FS::part_pkg::discount_Mixin;
   2
   3 use strict;
   4 use vars qw( %info );
   5 use Time::Local qw( timelocal );
   6 use List::Util  qw( min );
   7 use FS::cust_pkg;
   8 use FS::cust_bill_pkg_discount;
   9
  10 %info = ( 'disabled' => 1 );
  11
  12 =head1 NAME
  13
  14 FS::part_pkg::discount_Mixin - Mixin class for part_pkg:: classes that
  15 can be discounted.
  16
  17 =head1 SYNOPSIS
  18
  19 package FS::part_pkg::...;
  20 use base qw( FS::part_pkg::discount_Mixin );
  21
  22 sub calc_recur {
  23   ...
  24   my $discount = $self->calc_discount($cust_pkg, $$sdate, $details, $param);
  25   $charge -= $discount;
  26   ...
  27 }
  28
  29 =head METHODS
  30
  31 =item calc_discount
  32
  33 Takes all the arguments of calc_recur.  Calculates and returns  the amount
  34 by which to reduce the recurring fee; also increments months used on the
  35 discount and generates an invoice detail describing it.
  36
  37 =cut
  38
  39 sub calc_discount {
  40   my($self, $cust_pkg, $sdate, $details, $param ) = @_;
  41   my $conf = new FS::Conf;
  42
  43   my $br = $self->base_recur_permonth($cust_pkg, $sdate);
  44   $br += $param->{'override_charges'} if $param->{'override_charges'};
  45
  46   my $tot_discount = 0;
  47   #UI enforces just 1 for now, will need ordering when they can be stacked
  48
  49   if ( $param->{freq_override} ) {
  50     # When a customer pays for more than one month at a time to receive a
  51     # term discount, freq_override is set to the number of months.
  52     my $real_part_pkg = new FS::part_pkg { $self->hash };
  53     $real_part_pkg->pkgpart($param->{real_pkgpart} || $self->pkgpart);
  54     # Find a discount with that duration...
  55     my @discount = grep { $_->months == $param->{freq_override} }
  56                     map { $_->discount } $real_part_pkg->part_pkg_discount;
  57     my $discount = shift @discount;
  58     # and default to bill that many months at once.
  59     $param->{months} = $param->{freq_override} unless $param->{months};
  60     my $error;
  61     if ($discount) {
  62       # Then set the cust_pkg discount.
  63       if ($discount->months == $param->{months}) {
  64         $cust_pkg->discountnum($discount->discountnum);
  65         $error = $cust_pkg->insert_discount;
  66       } else {
  67         $cust_pkg->discountnum(-1);
  68         foreach ( qw( amount percent months ) ) {
  69           my $method = "discountnum_$_";
  70           $cust_pkg->$method($discount->$_);
  71         }
  72         $error = $cust_pkg->insert_discount;
  73       }
  74       die "error discounting using part_pkg_discount: $error" if $error;
  75     }
  76   }
  77
  78   my @cust_pkg_discount = $cust_pkg->cust_pkg_discount_active;
  79   foreach my $cust_pkg_discount ( @cust_pkg_discount ) {
  80     my $discount_left;
  81     my $discount = $cust_pkg_discount->discount;
  82     #UI enforces one or the other (for now?  probably for good)
  83     my $amount = 0;
  84     $amount += $discount->amount
  85         if defined $param->{'real_pkgpart'} && $cust_pkg->pkgpart == $param->{'real_pkgpart'};
  86     $amount += sprintf('%.2f', $discount->percent * $br / 100 );
  87     my $chg_months = $param->{'months'} || $cust_pkg->part_pkg->freq;
  88
  89     my $months = $discount->months
  90     ? min( $chg_months,
  91       $discount->months - $cust_pkg_discount->months_used )
  92     : $chg_months;
  93
  94     if (defined $param->{'setup_charge'}) {
  95         next unless $discount->setup;
  96
  97         if ( $discount->percent > 0 ) {
  98             $amount = sprintf('%.2f', $discount->percent * $param->{'setup_charge'} / 100 );
  99             $months = 1;
 100         } elsif ( $discount->amount > 0 && $discount->months == 1) {
 101             $discount_left = $param->{'setup_charge'} - $discount->amount;
 102             $amount = $param->{'setup_charge'} if $discount_left < 0;
 103             $amount = $discount->amount if $discount_left >= 0;
 104             $months = 1;
 105
 106             # transfer remainder of discount, if any, to recur
 107             $param->{'discount_left_recur'}{$discount->discountnum} =
 108                 0 - $discount_left if $discount_left < 0;
 109         } else {
 110             next;
 111         }
 112     } elsif ( defined $param->{'discount_left_recur'}{$discount->discountnum}
 113               && $param->{'discount_left_recur'}{$discount->discountnum} > 0
 114             ) {
 115         # use up transferred remainder of discount from setup
 116         $amount = $param->{'discount_left_recur'}{$discount->discountnum};
 117         $param->{'discount_left_recur'}{$discount->discountnum} = 0;
 118         $months = 1;
 119     } elsif (    $discount->setup
 120               && $discount->months == 1
 121               && $discount->amount > 0
 122             ) {
 123         next;
 124     }
 125
 126     if ( ! defined $param->{'setup_charge'} ) {
 127       my $error = $cust_pkg_discount->increment_months_used($months)
 128         if defined $param->{'real_pkgpart'}
 129         && $cust_pkg->pkgpart == $param->{'real_pkgpart'};
 130       die "error discounting: $error" if $error;
 131
 132       $amount = min($amount, $br);
 133       $amount *= $months;
 134     }
 135
 136     $amount = sprintf('%.2f', $amount);
 137
 138     next unless $amount > 0;
 139
 140     # transfer remainder of discount, if any, to setup
 141     if ( $discount->setup && $discount->amount > 0
 142         && (!$discount->months || $discount->months != 1)
 143         && !defined $param->{'setup_charge'}
 144        )
 145     {
 146       $discount_left = $br - $amount;
 147       if ( $discount_left < 0 ) {
 148         $amount = $br;
 149         $param->{'discount_left_setup'}{$discount->discountnum} =
 150           0 - $discount_left;
 151       }
 152     }
 153
 154     #record details in cust_bill_pkg_discount
 155     my $cust_bill_pkg_discount = new FS::cust_bill_pkg_discount {
 156       'pkgdiscountnum' => $cust_pkg_discount->pkgdiscountnum,
 157       'amount'         => $amount,
 158       'months'         => $months,
 159     };
 160     push @{ $param->{'discounts'} }, $cust_bill_pkg_discount;
 161
 162     #add details on discount to invoice
 163     my $money_char = $conf->config('money_char') || '$';
 164     $months = sprintf('%.2f', $months) if $months =~ /\./;
 165
 166     my $d = 'Includes ';
 167     $d .= 'setup ' if defined $param->{'setup_charge'};
 168     $d .= 'discount of '. $discount->description_short;
 169     $d .= " for $months month". ( $months!=1 ? 's' : '' ) unless defined $param->{'setup_charge'};
 170     $d .= ": $money_char$amount" if $months != 1 || $discount->percent;
 171     push @$details, $d;
 172
 173     $tot_discount += $amount;
 174   }
 175
 176   sprintf('%.2f', $tot_discount);
 177 }
 178
 179 1;