FS/FS/part_pkg/bulk_Common.pm

   1 package FS::part_pkg::bulk_Common;
   2 use base qw( FS::part_pkg::flat );
   3
   4 use strict;
   5 use vars qw($DEBUG $me %info);
   6 use Date::Format;
   7 use FS::Conf;
   8 use FS::Record qw(qsearchs);
   9
  10 $DEBUG = 0;
  11 $me = '[FS::part_pkg::bulk_Common]';
  12
  13 %info = (
  14   'disabled' => 1,
  15   'inherit_fields' => [ 'global_Mixin' ],
  16   'fields' => {
  17     'svc_setup_fee' => { 'name'    => 'Setup fee for each new service',
  18                          'default' => 0,
  19                        },
  20     'svc_recur_fee' => { 'name'    => 'Recurring fee for each service',
  21                          'default' => 0,
  22                        },
  23     'summarize_svcs'=> { 'name' => 'Show a count of services on the invoice, '.
  24                                    'instead of a detailed list',
  25                          'type' => 'checkbox',
  26                        },
  27     'only_svcs' => {
  28       'name' => 'Only charge fees for these services',
  29       'type' => 'select_multiple',
  30       'select_table'  => 'part_svc',
  31       'select_key'    => 'svcpart',
  32       'select_label'  => 'svc',
  33       'disable_empty' => 1,
  34       'parse'         => sub { @_ }, #should this be the default in /edit/process/part_pkg.cgi?
  35     },
  36   },
  37   'fieldorder' => [ 'svc_setup_fee', 'svc_recur_fee', 'only_svcs',
  38                     'summarize_svcs', 'no_prorate' ],
  39   'weight' => 51,
  40 );
  41
  42 sub price_info {
  43     my $self = shift;
  44     my $str = $self->SUPER::price_info(@_);
  45     my $svc_setup_fee = $self->option('svc_setup_fee');
  46     my $svc_recur_fee = $self->option('svc_recur_fee');
  47     my $conf = new FS::Conf;
  48     my $money_char = $conf->config('money_char') || '$';
  49     $str .= ", bulk " if $str;
  50     $str .= ": $money_char" . $svc_setup_fee . " one-time per service"
  51         if $svc_setup_fee;
  52     $str .= ", " if ($svc_setup_fee && $svc_recur_fee);
  53     $str .= $money_char . $svc_recur_fee . " recurring per service"
  54         if $svc_recur_fee;
  55     $str;
  56 }
  57
  58 #some false laziness-ish w/agent.pm...  not a lot
  59 sub calc_recur {
  60   my($self, $cust_pkg, $sdate, $details, $param ) = @_;
  61
  62   my $conf = new FS::Conf;
  63   my $money_char = $conf->config('money_char') || '$';
  64
  65   my $last_bill = $cust_pkg->last_bill;
  66
  67   my $total_svc_charge = 0;
  68   my %n_setup = ();
  69   my %n_recur = ();
  70   my %part_svc_label = ();
  71   my %pkg_svc = ();
  72
  73   my $summarize = $self->option('summarize_svcs',1);
  74
  75   foreach my $cust_svc ( $self->_bulk_cust_svc( $cust_pkg, $sdate ) ) {
  76
  77     my $pkg_svc = $pkg_svc{ $cust_pkg->pkgpart. '_'. $cust_svc->svcpart }
  78                     ||= qsearchs('pkg_svc', { 'pkgpart' => $cust_pkg->pkgpart,
  79                                               'svcpart' => $cust_svc->svcpart});
  80     next if $pkg_svc->bulk_skip;
  81
  82     my @label = $cust_svc->label_long( $$sdate, $last_bill );
  83     die "fatal: no label found for svcnum ". $cust_svc->svcnum
  84       unless scalar(@label); #?
  85     my $svc_details = $label[0]. ': '. $label[1]. ': ';
  86     $part_svc_label{$cust_svc->svcpart} ||= $label[0];
  87
  88     my $svc_charge = 0;
  89
  90     my $setup = $self->_bulk_setup($cust_pkg, $cust_svc);
  91     if ( $setup ) {
  92       $svc_charge += $setup;
  93       $svc_details .= $money_char. sprintf('%.2f setup, ', $setup);
  94       $n_setup{$cust_svc->svcpart}++;
  95     }
  96
  97     my( $recur, $r_details ) = $self->_bulk_recur($cust_pkg, $cust_svc, $sdate);
  98     if ( $recur ) {
  99       $svc_charge += $recur;
 100       $svc_details .= $money_char. sprintf('%.2f', $recur). $r_details;
 101       $n_recur{$cust_svc->svcpart}++;
 102       push @$details, $svc_details if !$summarize;
 103     }
 104
 105     $total_svc_charge += $svc_charge;
 106
 107   }
 108
 109   if ( $summarize ) {
 110     foreach my $svcpart (keys %part_svc_label) {
 111       push @$details, sprintf('Setup fee: %d @ '.$money_char.'%.2f',
 112         $n_setup{$svcpart}, $self->option('svc_setup_fee') )
 113         if $self->option('svc_setup_fee') and $n_setup{$svcpart};
 114       push @$details, sprintf('%d services @ '.$money_char.'%.2f',
 115         $n_recur{$svcpart}, $self->option('svc_recur_fee') )
 116         if $n_recur{$svcpart};
 117     }
 118   }
 119
 120   my $charge = $self->base_recur($cust_pkg, $sdate) + $total_svc_charge;
 121
 122   $param->{'override_charges'} = $total_svc_charge / $self->freq;
 123   my $discount = $self->calc_discount($cust_pkg, $sdate, $details, $param);
 124
 125   sprintf('%.2f', $charge - $discount );
 126 }
 127
 128 sub hide_svc_detail { 1; }
 129
 130 sub is_free_options {
 131   qw( setup_fee recur_fee svc_setup_fee svc_recur_fee );
 132 }
 133
 134 sub can_usageprice { 0; }
 135
 136 sub _only_svcs_filter {
 137   my ($self, @cust_svc) = @_;
 138   my @only_svcs = split(', ',$self->option('only_svcs',1));
 139   if (@only_svcs) {
 140     @cust_svc = grep {
 141       my $svcpart = $_->svcpart;
 142       grep(/^$svcpart$/,@only_svcs);
 143     } @cust_svc;
 144   }
 145   return @cust_svc;
 146 }
 147
 148 1;
 149