FS/FS/part_pkg.pm

   1 package FS::part_pkg;
   2
   3 use strict;
   4 use vars qw( @ISA %plans $DEBUG $setup_hack $skip_pkg_svc_hack );
   5 use Carp qw(carp cluck confess);
   6 use Scalar::Util qw( blessed );
   7 use Time::Local qw( timelocal_nocheck );
   8 use Tie::IxHash;
   9 use FS::Conf;
  10 use FS::Record qw( qsearch qsearchs dbh dbdef );
  11 use FS::pkg_svc;
  12 use FS::part_svc;
  13 use FS::cust_pkg;
  14 use FS::agent_type;
  15 use FS::type_pkgs;
  16 use FS::part_pkg_option;
  17 use FS::pkg_class;
  18 use FS::agent;
  19 use FS::part_pkg_taxrate;
  20 use FS::part_pkg_taxoverride;
  21 use FS::part_pkg_taxproduct;
  22 use FS::part_pkg_link;
  23 use FS::part_pkg_discount;
  24 use FS::part_pkg_vendor;
  25
  26 @ISA = qw( FS::m2m_Common FS::option_Common );
  27 $DEBUG = 0;
  28 $setup_hack = 0;
  29 $skip_pkg_svc_hack = 0;
  30
  31 =head1 NAME
  32
  33 FS::part_pkg - Object methods for part_pkg objects
  34
  35 =head1 SYNOPSIS
  36
  37   use FS::part_pkg;
  38
  39   $record = new FS::part_pkg \%hash
  40   $record = new FS::part_pkg { 'column' => 'value' };
  41
  42   $custom_record = $template_record->clone;
  43
  44   $error = $record->insert;
  45
  46   $error = $new_record->replace($old_record);
  47
  48   $error = $record->delete;
  49
  50   $error = $record->check;
  51
  52   @pkg_svc = $record->pkg_svc;
  53
  54   $svcnum = $record->svcpart;
  55   $svcnum = $record->svcpart( 'svc_acct' );
  56
  57 =head1 DESCRIPTION
  58
  59 An FS::part_pkg object represents a package definition.  FS::part_pkg
  60 inherits from FS::Record.  The following fields are currently supported:
  61
  62 =over 4
  63
  64 =item pkgpart - primary key (assigned automatically for new package definitions)
  65
  66 =item pkg - Text name of this package definition (customer-viewable)
  67
  68 =item comment - Text name of this package definition (non-customer-viewable)
  69
  70 =item classnum - Optional package class (see L<FS::pkg_class>)
  71
  72 =item promo_code - Promotional code
  73
  74 =item setup - Setup fee expression (deprecated)
  75
  76 =item freq - Frequency of recurring fee
  77
  78 =item recur - Recurring fee expression (deprecated)
  79
  80 =item setuptax - Setup fee tax exempt flag, empty or `Y'
  81
  82 =item recurtax - Recurring fee tax exempt flag, empty or `Y'
  83
  84 =item taxclass - Tax class
  85
  86 =item plan - Price plan
  87
  88 =item plandata - Price plan data (deprecated - see L<FS::part_pkg_option> instead)
  89
  90 =item disabled - Disabled flag, empty or `Y'
  91
  92 =item custom - Custom flag, empty or `Y'
  93
  94 =item setup_cost - for cost tracking
  95
  96 =item recur_cost - for cost tracking
  97
  98 =item pay_weight - Weight (relative to credit_weight and other package definitions) that controls payment application to specific line items.
  99
 100 =item credit_weight - Weight (relative to other package definitions) that controls credit application to specific line items.
 101
 102 =item agentnum - Optional agentnum (see L<FS::agent>)
 103
 104 =item fcc_ds0s - Optional DS0 equivalency number for FCC form 477
 105
 106 =back
 107
 108 =head1 METHODS
 109
 110 =over 4
 111
 112 =item new HASHREF
 113
 114 Creates a new package definition.  To add the package definition to
 115 the database, see L<"insert">.
 116
 117 =cut
 118
 119 sub table { 'part_pkg'; }
 120
 121 =item clone
 122
 123 An alternate constructor.  Creates a new package definition by duplicating
 124 an existing definition.  A new pkgpart is assigned and the custom flag is
 125 set to Y.  To add the package definition to the database, see L<"insert">.
 126
 127 =cut
 128
 129 sub clone {
 130   my $self = shift;
 131   my $class = ref($self);
 132   my %hash = $self->hash;
 133   $hash{'pkgpart'} = '';
 134   $hash{'custom'} = 'Y';
 135   #new FS::part_pkg ( \%hash ); # ?
 136   new $class ( \%hash ); # ?
 137 }
 138
 139 =item insert [ , OPTION => VALUE ... ]
 140
 141 Adds this package definition to the database.  If there is an error,
 142 returns the error, otherwise returns false.
 143
 144 Currently available options are: I<pkg_svc>, I<primary_svc>, I<cust_pkg>,
 145 I<custnum_ref> and I<options>.
 146
 147 If I<pkg_svc> is set to a hashref with svcparts as keys and quantities as
 148 values, appropriate FS::pkg_svc records will be inserted.  I<hidden_svc> can
 149 be set to a hashref of svcparts and flag values ('Y' or '') to set the
 150 'hidden' field in these records.
 151
 152 If I<primary_svc> is set to the svcpart of the primary service, the appropriate
 153 FS::pkg_svc record will be updated.
 154
 155 If I<cust_pkg> is set to a pkgnum of a FS::cust_pkg record (or the FS::cust_pkg
 156 record itself), the object will be updated to point to this package definition.
 157
 158 In conjunction with I<cust_pkg>, if I<custnum_ref> is set to a scalar reference,
 159 the scalar will be updated with the custnum value from the cust_pkg record.
 160
 161 If I<tax_overrides> is set to a hashref with usage classes as keys and comma
 162 separated tax class numbers as values, appropriate FS::part_pkg_taxoverride
 163 records will be inserted.
 164
 165 If I<options> is set to a hashref of options, appropriate FS::part_pkg_option
 166 records will be inserted.
 167
 168 =cut
 169
 170 sub insert {
 171   my $self = shift;
 172   my %options = @_;
 173   warn "FS::part_pkg::insert called on $self with options ".
 174        join(', ', map "$_=>$options{$_}", keys %options)
 175     if $DEBUG;
 176
 177   local $SIG{HUP} = 'IGNORE';
 178   local $SIG{INT} = 'IGNORE';
 179   local $SIG{QUIT} = 'IGNORE';
 180   local $SIG{TERM} = 'IGNORE';
 181   local $SIG{TSTP} = 'IGNORE';
 182   local $SIG{PIPE} = 'IGNORE';
 183
 184   my $oldAutoCommit = $FS::UID::AutoCommit;
 185   local $FS::UID::AutoCommit = 0;
 186   my $dbh = dbh;
 187
 188   warn "  inserting part_pkg record" if $DEBUG;
 189   my $error = $self->SUPER::insert( $options{options} );
 190   if ( $error ) {
 191     $dbh->rollback if $oldAutoCommit;
 192     return $error;
 193   }
 194
 195   my $conf = new FS::Conf;
 196   if ( $conf->exists('agent_defaultpkg') ) {
 197     warn "  agent_defaultpkg set; allowing all agents to purchase package"
 198       if $DEBUG;
 199     foreach my $agent_type ( qsearch('agent_type', {} ) ) {
 200       my $type_pkgs = new FS::type_pkgs({
 201         'typenum' => $agent_type->typenum,
 202         'pkgpart' => $self->pkgpart,
 203       });
 204       my $error = $type_pkgs->insert;
 205       if ( $error ) {
 206         $dbh->rollback if $oldAutoCommit;
 207         return $error;
 208       }
 209     }
 210   }
 211
 212   warn "  inserting part_pkg_taxoverride records" if $DEBUG;
 213   my %overrides = %{ $options{'tax_overrides'} || {} };
 214   foreach my $usage_class ( keys %overrides ) {
 215     my $override =
 216       ( exists($overrides{$usage_class}) && defined($overrides{$usage_class}) )
 217         ? $overrides{$usage_class}
 218         : '';
 219     my @overrides = (grep "$_", split(',', $override) );
 220     my $error = $self->process_m2m (
 221                   'link_table'   => 'part_pkg_taxoverride',
 222                   'target_table' => 'tax_class',
 223                   'hashref'      => { 'usage_class' => $usage_class },
 224                   'params'       => \@overrides,
 225                 );
 226     if ( $error ) {
 227       $dbh->rollback if $oldAutoCommit;
 228       return $error;
 229     }
 230   }
 231
 232   unless ( $skip_pkg_svc_hack ) {
 233
 234     warn "  inserting pkg_svc records" if $DEBUG;
 235     my $pkg_svc = $options{'pkg_svc'} || {};
 236     my $hidden_svc = $options{'hidden_svc'} || {};
 237     foreach my $part_svc ( qsearch('part_svc', {} ) ) {
 238       my $quantity = $pkg_svc->{$part_svc->svcpart} || 0;
 239       my $primary_svc =
 240         ( $options{'primary_svc'} && $options{'primary_svc'}==$part_svc->svcpart )
 241           ? 'Y'
 242           : '';
 243
 244       my $pkg_svc = new FS::pkg_svc( {
 245         'pkgpart'     => $self->pkgpart,
 246         'svcpart'     => $part_svc->svcpart,
 247         'quantity'    => $quantity,
 248         'primary_svc' => $primary_svc,
 249         'hidden'      => $hidden_svc->{$part_svc->svcpart},
 250       } );
 251       my $error = $pkg_svc->insert;
 252       if ( $error ) {
 253         $dbh->rollback if $oldAutoCommit;
 254         return $error;
 255       }
 256     }
 257
 258   }
 259
 260   if ( $options{'cust_pkg'} ) {
 261     warn "  updating cust_pkg record " if $DEBUG;
 262     my $old_cust_pkg =
 263       ref($options{'cust_pkg'})
 264         ? $options{'cust_pkg'}
 265         : qsearchs('cust_pkg', { pkgnum => $options{'cust_pkg'} } );
 266     ${ $options{'custnum_ref'} } = $old_cust_pkg->custnum
 267       if $options{'custnum_ref'};
 268     my %hash = $old_cust_pkg->hash;
 269     $hash{'pkgpart'} = $self->pkgpart,
 270     my $new_cust_pkg = new FS::cust_pkg \%hash;
 271     local($FS::cust_pkg::disable_agentcheck) = 1;
 272     my $error = $new_cust_pkg->replace($old_cust_pkg);
 273     if ( $error ) {
 274       $dbh->rollback if $oldAutoCommit;
 275       return "Error modifying cust_pkg record: $error";
 276     }
 277   }
 278
 279   if ( $options{'part_pkg_vendor'} ) {
 280       while ( my ($exportnum, $vendor_pkg_id) =
 281                 each %{ $options{part_pkg_vendor} }
 282             )
 283       {
 284             my $ppv = new FS::part_pkg_vendor( {
 285                     'pkgpart' => $self->pkgpart,
 286                     'exportnum' => $exportnum,
 287                     'vendor_pkg_id' => $vendor_pkg_id,
 288                 } );
 289             my $error = $ppv->insert;
 290             if ( $error ) {
 291               $dbh->rollback if $oldAutoCommit;
 292               return "Error inserting part_pkg_vendor record: $error";
 293             }
 294       }
 295   }
 296
 297   warn "  commiting transaction" if $DEBUG;
 298   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 299
 300   '';
 301 }
 302
 303 =item delete
 304
 305 Currently unimplemented.
 306
 307 =cut
 308
 309 sub delete {
 310   return "Can't (yet?) delete package definitions.";
 311 # check & make sure the pkgpart isn't in cust_pkg or type_pkgs?
 312 }
 313
 314 =item replace OLD_RECORD [ , OPTION => VALUE ... ]
 315
 316 Replaces OLD_RECORD with this one in the database.  If there is an error,
 317 returns the error, otherwise returns false.
 318
 319 Currently available options are: I<pkg_svc>, I<hidden_svc>, I<primary_svc>
 320 and I<options>
 321
 322 If I<pkg_svc> is set to a hashref with svcparts as keys and quantities as
 323 values, the appropriate FS::pkg_svc records will be replaced.  I<hidden_svc>
 324 can be set to a hashref of svcparts and flag values ('Y' or '') to set the
 325 'hidden' field in these records.
 326
 327 If I<primary_svc> is set to the svcpart of the primary service, the appropriate
 328 FS::pkg_svc record will be updated.
 329
 330 If I<options> is set to a hashref, the appropriate FS::part_pkg_option records
 331 will be replaced.
 332
 333 =cut
 334
 335 sub replace {
 336   my $new = shift;
 337
 338   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
 339               ? shift
 340               : $new->replace_old;
 341
 342   my $options =
 343     ( ref($_[0]) eq 'HASH' )
 344       ? shift
 345       : { @_ };
 346
 347   $options->{options} = {} unless defined($options->{options});
 348
 349   warn "FS::part_pkg::replace called on $new to replace $old with options".
 350        join(', ', map "$_ => ". $options->{$_}, keys %$options)
 351     if $DEBUG;
 352
 353   local $SIG{HUP} = 'IGNORE';
 354   local $SIG{INT} = 'IGNORE';
 355   local $SIG{QUIT} = 'IGNORE';
 356   local $SIG{TERM} = 'IGNORE';
 357   local $SIG{TSTP} = 'IGNORE';
 358   local $SIG{PIPE} = 'IGNORE';
 359
 360   my $oldAutoCommit = $FS::UID::AutoCommit;
 361   local $FS::UID::AutoCommit = 0;
 362   my $dbh = dbh;
 363
 364   #plandata shit stays in replace for upgrades until after 2.0 (or edit
 365   #_upgrade_data)
 366   warn "  saving legacy plandata" if $DEBUG;
 367   my $plandata = $new->get('plandata');
 368   $new->set('plandata', '');
 369
 370   warn "  deleting old part_pkg_option records" if $DEBUG;
 371   foreach my $part_pkg_option ( $old->part_pkg_option ) {
 372     my $error = $part_pkg_option->delete;
 373     if ( $error ) {
 374       $dbh->rollback if $oldAutoCommit;
 375       return $error;
 376     }
 377   }
 378
 379   warn "  replacing part_pkg record" if $DEBUG;
 380   my $error = $new->SUPER::replace($old, $options->{options} );
 381   if ( $error ) {
 382     $dbh->rollback if $oldAutoCommit;
 383     return $error;
 384   }
 385
 386   warn "  inserting part_pkg_option records for plandata: $plandata|" if $DEBUG;
 387   foreach my $part_pkg_option (
 388     map { /^(\w+)=(.*)$/ or do { $dbh->rollback if $oldAutoCommit;
 389                                  return "illegal plandata: $plandata";
 390                                };
 391           new FS::part_pkg_option {
 392             'pkgpart'     => $new->pkgpart,
 393             'optionname'  => $1,
 394             'optionvalue' => $2,
 395           };
 396         }
 397     split("\n", $plandata)
 398   ) {
 399     my $error = $part_pkg_option->insert;
 400     if ( $error ) {
 401       $dbh->rollback if $oldAutoCommit;
 402       return $error;
 403     }
 404   }
 405
 406   warn "  replacing pkg_svc records" if $DEBUG;
 407   my $pkg_svc = $options->{'pkg_svc'} || {};
 408   my $hidden_svc = $options->{'hidden_svc'} || {};
 409   foreach my $part_svc ( qsearch('part_svc', {} ) ) {
 410     my $quantity = $pkg_svc->{$part_svc->svcpart} || 0;
 411     my $hidden = $hidden_svc->{$part_svc->svcpart} || '';
 412     my $primary_svc =
 413       ( defined($options->{'primary_svc'}) && $options->{'primary_svc'}
 414         && $options->{'primary_svc'} == $part_svc->svcpart
 415       )
 416         ? 'Y'
 417         : '';
 418
 419     my $old_pkg_svc = qsearchs('pkg_svc', {
 420         'pkgpart' => $old->pkgpart,
 421         'svcpart' => $part_svc->svcpart,
 422       }
 423     );
 424     my $old_quantity = 0;
 425     my $old_primary_svc = '';
 426     my $old_hidden = '';
 427     if ( $old_pkg_svc ) {
 428       $old_quantity = $old_pkg_svc->quantity;
 429       $old_primary_svc = $old_pkg_svc->primary_svc
 430         if $old_pkg_svc->dbdef_table->column('primary_svc'); # is this needed?
 431       $old_hidden = $old_pkg_svc->hidden;
 432     }
 433
 434     next unless $old_quantity != $quantity ||
 435                 $old_primary_svc ne $primary_svc ||
 436                 $old_hidden ne $hidden;
 437
 438     my $new_pkg_svc = new FS::pkg_svc( {
 439       'pkgsvcnum'   => ( $old_pkg_svc ? $old_pkg_svc->pkgsvcnum : '' ),
 440       'pkgpart'     => $new->pkgpart,
 441       'svcpart'     => $part_svc->svcpart,
 442       'quantity'    => $quantity,
 443       'primary_svc' => $primary_svc,
 444       'hidden'      => $hidden,
 445     } );
 446     my $error = $old_pkg_svc
 447                   ? $new_pkg_svc->replace($old_pkg_svc)
 448                   : $new_pkg_svc->insert;
 449     if ( $error ) {
 450       $dbh->rollback if $oldAutoCommit;
 451       return $error;
 452     }
 453   }
 454
 455   my @part_pkg_vendor = $old->part_pkg_vendor;
 456   my @current_exportnum = ();
 457   if ( $options->{'part_pkg_vendor'} ) {
 458       my($exportnum,$vendor_pkg_id);
 459       while ( ($exportnum,$vendor_pkg_id)
 460                                 = each %{$options->{'part_pkg_vendor'}} ) {
 461           my $noinsert = 0;
 462           foreach my $part_pkg_vendor ( @part_pkg_vendor ) {
 463             if($exportnum == $part_pkg_vendor->exportnum
 464                 && $vendor_pkg_id ne $part_pkg_vendor->vendor_pkg_id) {
 465                 $part_pkg_vendor->vendor_pkg_id($vendor_pkg_id);
 466                 my $error = $part_pkg_vendor->replace;
 467                 if ( $error ) {
 468                   $dbh->rollback if $oldAutoCommit;
 469                   return "Error replacing part_pkg_vendor record: $error";
 470                 }
 471                 $noinsert = 1;
 472                 last;
 473             }
 474             elsif($exportnum == $part_pkg_vendor->exportnum
 475                 && $vendor_pkg_id eq $part_pkg_vendor->vendor_pkg_id) {
 476                 $noinsert = 1;
 477                 last;
 478             }
 479           }
 480           unless ( $noinsert ) {
 481             my $ppv = new FS::part_pkg_vendor( {
 482                     'pkgpart' => $new->pkgpart,
 483                     'exportnum' => $exportnum,
 484                     'vendor_pkg_id' => $vendor_pkg_id,
 485                 } );
 486             my $error = $ppv->insert;
 487             if ( $error ) {
 488               $dbh->rollback if $oldAutoCommit;
 489               return "Error inserting part_pkg_vendor record: $error";
 490             }
 491           }
 492           push @current_exportnum, $exportnum;
 493       }
 494   }
 495   foreach my $part_pkg_vendor ( @part_pkg_vendor ) {
 496       unless ( grep($_ eq $part_pkg_vendor->exportnum, @current_exportnum) ) {
 497         my $error = $part_pkg_vendor->delete;
 498         if ( $error ) {
 499           $dbh->rollback if $oldAutoCommit;
 500           return "Error deleting part_pkg_vendor record: $error";
 501         }
 502       }
 503   }
 504
 505   warn "  commiting transaction" if $DEBUG;
 506   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 507   '';
 508 }
 509
 510 =item check
 511
 512 Checks all fields to make sure this is a valid package definition.  If
 513 there is an error, returns the error, otherwise returns false.  Called by the
 514 insert and replace methods.
 515
 516 =cut
 517
 518 sub check {
 519   my $self = shift;
 520   warn "FS::part_pkg::check called on $self" if $DEBUG;
 521
 522   for (qw(setup recur plandata)) {
 523     #$self->set($_=>0) if $self->get($_) =~ /^\s*$/; }
 524     return "Use of $_ field is deprecated; set a plan and options: ".
 525            $self->get($_)
 526       if length($self->get($_));
 527     $self->set($_, '');
 528   }
 529
 530   if ( $self->dbdef_table->column('freq')->type =~ /(int)/i ) {
 531     my $error = $self->ut_number('freq');
 532     return $error if $error;
 533   } else {
 534     $self->freq =~ /^(\d+[hdw]?)$/
 535       or return "Illegal or empty freq: ". $self->freq;
 536     $self->freq($1);
 537   }
 538
 539   my @null_agentnum_right = ( 'Edit global package definitions' );
 540   push @null_agentnum_right, 'One-time charge'
 541     if $self->freq =~ /^0/;
 542   push @null_agentnum_right, 'Customize customer package'
 543     if $self->disabled eq 'Y'; #good enough
 544
 545   my $error = $self->ut_numbern('pkgpart')
 546     || $self->ut_text('pkg')
 547     || $self->ut_text('comment')
 548     || $self->ut_textn('promo_code')
 549     || $self->ut_alphan('plan')
 550     || $self->ut_enum('setuptax', [ '', 'Y' ] )
 551     || $self->ut_enum('recurtax', [ '', 'Y' ] )
 552     || $self->ut_textn('taxclass')
 553     || $self->ut_enum('disabled', [ '', 'Y' ] )
 554     || $self->ut_enum('custom', [ '', 'Y' ] )
 555     || $self->ut_enum('no_auto', [ '', 'Y' ])
 556     || $self->ut_enum('recur_show_zero', [ '', 'Y' ])
 557     || $self->ut_enum('setup_show_zero', [ '', 'Y' ])
 558     #|| $self->ut_moneyn('setup_cost')
 559     #|| $self->ut_moneyn('recur_cost')
 560     || $self->ut_floatn('setup_cost')
 561     || $self->ut_floatn('recur_cost')
 562     || $self->ut_floatn('pay_weight')
 563     || $self->ut_floatn('credit_weight')
 564     || $self->ut_numbern('taxproductnum')
 565     || $self->ut_foreign_keyn('classnum',       'pkg_class', 'classnum')
 566     || $self->ut_foreign_keyn('addon_classnum', 'pkg_class', 'classnum')
 567     || $self->ut_foreign_keyn('taxproductnum',
 568                               'part_pkg_taxproduct',
 569                               'taxproductnum'
 570                              )
 571     || ( $setup_hack
 572            ? $self->ut_foreign_keyn('agentnum', 'agent', 'agentnum' )
 573            : $self->ut_agentnum_acl('agentnum', \@null_agentnum_right)
 574        )
 575     || $self->ut_numbern('fcc_ds0s')
 576     || $self->SUPER::check
 577   ;
 578   return $error if $error;
 579
 580   return 'Unknown plan '. $self->plan
 581     unless exists($plans{$self->plan});
 582
 583   my $conf = new FS::Conf;
 584   return 'Taxclass is required'
 585     if ! $self->taxclass && $conf->exists('require_taxclasses');
 586
 587   '';
 588 }
 589
 590 =item pkg_comment [ OPTION => VALUE... ]
 591
 592 Returns an (internal) string representing this package.  Currently,
 593 "pkgpart: pkg - comment", is returned.  "pkg - comment" may be returned in the
 594 future, omitting pkgpart.  The comment will have '(CUSTOM) ' prepended if
 595 custom is Y.
 596
 597 If the option nopkgpart is true then the "pkgpart: ' is omitted.
 598
 599 =cut
 600
 601 sub pkg_comment {
 602   my $self = shift;
 603   my %opt = @_;
 604
 605   #$self->pkg. ' - '. $self->comment;
 606   #$self->pkg. ' ('. $self->comment. ')';
 607   my $pre = $opt{nopkgpart} ? '' : $self->pkgpart. ': ';
 608   $pre. $self->pkg. ' - '. $self->custom_comment;
 609 }
 610
 611 sub price_info { # safety, in case a part_pkg hasn't defined price_info
 612     '';
 613 }
 614
 615 sub custom_comment {
 616   my $self = shift;
 617   ( $self->custom ? '(CUSTOM) ' : '' ). $self->comment . ' ' . $self->price_info;
 618 }
 619
 620 =item pkg_class
 621
 622 Returns the package class, as an FS::pkg_class object, or the empty string
 623 if there is no package class.
 624
 625 =cut
 626
 627 sub pkg_class {
 628   my $self = shift;
 629   if ( $self->classnum ) {
 630     qsearchs('pkg_class', { 'classnum' => $self->classnum } );
 631   } else {
 632     return '';
 633   }
 634 }
 635
 636 =item addon_pkg_class
 637
 638 Returns the add-on package class, as an FS::pkg_class object, or the empty
 639 string if there is no add-on package class.
 640
 641 =cut
 642
 643 sub addon_pkg_class {
 644   my $self = shift;
 645   if ( $self->addon_classnum ) {
 646     qsearchs('pkg_class', { 'classnum' => $self->addon_classnum } );
 647   } else {
 648     return '';
 649   }
 650 }
 651
 652 =item categoryname
 653
 654 Returns the package category name, or the empty string if there is no package
 655 category.
 656
 657 =cut
 658
 659 sub categoryname {
 660   my $self = shift;
 661   my $pkg_class = $self->pkg_class;
 662   $pkg_class
 663     ? $pkg_class->categoryname
 664     : '';
 665 }
 666
 667 =item classname
 668
 669 Returns the package class name, or the empty string if there is no package
 670 class.
 671
 672 =cut
 673
 674 sub classname {
 675   my $self = shift;
 676   my $pkg_class = $self->pkg_class;
 677   $pkg_class
 678     ? $pkg_class->classname
 679     : '';
 680 }
 681
 682 =item addon_classname
 683
 684 Returns the add-on package class name, or the empty string if there is no
 685 add-on package class.
 686
 687 =cut
 688
 689 sub addon_classname {
 690   my $self = shift;
 691   my $pkg_class = $self->addon_pkg_class;
 692   $pkg_class
 693     ? $pkg_class->classname
 694     : '';
 695 }
 696
 697 =item agent
 698
 699 Returns the associated agent for this event, if any, as an FS::agent object.
 700
 701 =cut
 702
 703 sub agent {
 704   my $self = shift;
 705   qsearchs('agent', { 'agentnum' => $self->agentnum } );
 706 }
 707
 708 =item pkg_svc [ HASHREF | OPTION => VALUE ]
 709
 710 Returns all FS::pkg_svc objects (see L<FS::pkg_svc>) for this package
 711 definition (with non-zero quantity).
 712
 713 One option is available, I<disable_linked>.  If set true it will return the
 714 services for this package definition alone, omitting services from any add-on
 715 packages.
 716
 717 =cut
 718
 719 =item type_pkgs
 720
 721 Returns all FS::type_pkgs objects (see L<FS::type_pkgs>) for this package
 722 definition.
 723
 724 =cut
 725
 726 sub type_pkgs {
 727   my $self = shift;
 728   qsearch('type_pkgs', { 'pkgpart' => $self->pkgpart } );
 729 }
 730
 731 sub pkg_svc {
 732   my $self = shift;
 733
 734 #  #sort { $b->primary cmp $a->primary }
 735 #    grep { $_->quantity }
 736 #      qsearch( 'pkg_svc', { 'pkgpart' => $self->pkgpart } );
 737
 738   my $opt = ref($_[0]) ? $_[0] : { @_ };
 739   my %pkg_svc = map  { $_->svcpart => $_ }
 740                 grep { $_->quantity }
 741                 qsearch( 'pkg_svc', { 'pkgpart' => $self->pkgpart } );
 742
 743   unless ( $opt->{disable_linked} ) {
 744     foreach my $dst_pkg ( map $_->dst_pkg, $self->svc_part_pkg_link ) {
 745       my @pkg_svc = grep { $_->quantity }
 746                     qsearch( 'pkg_svc', { pkgpart=>$dst_pkg->pkgpart } );
 747       foreach my $pkg_svc ( @pkg_svc ) {
 748         if ( $pkg_svc{$pkg_svc->svcpart} ) {
 749           my $quantity = $pkg_svc{$pkg_svc->svcpart}->quantity;
 750           $pkg_svc{$pkg_svc->svcpart}->quantity($quantity + $pkg_svc->quantity);
 751         } else {
 752           $pkg_svc{$pkg_svc->svcpart} = $pkg_svc;
 753         }
 754       }
 755     }
 756   }
 757
 758   values(%pkg_svc);
 759
 760 }
 761
 762 =item svcpart [ SVCDB ]
 763
 764 Returns the svcpart of the primary service definition (see L<FS::part_svc>)
 765 associated with this package definition (see L<FS::pkg_svc>).  Returns
 766 false if there not a primary service definition or exactly one service
 767 definition with quantity 1, or if SVCDB is specified and does not match the
 768 svcdb of the service definition.  SVCDB can be specified as a scalar table
 769 name, such as 'svc_acct', or as an arrayref of possible table names.
 770
 771 =cut
 772
 773 sub svcpart {
 774   my $pkg_svc = shift->_primary_pkg_svc(@_);
 775   $pkg_svc ? $pkg_svc->svcpart : '';
 776 }
 777
 778 =item part_svc [ SVCDB ]
 779
 780 Like the B<svcpart> method, but returns the FS::part_svc object (see
 781 L<FS::part_svc>).
 782
 783 =cut
 784
 785 sub part_svc {
 786   my $pkg_svc = shift->_primary_pkg_svc(@_);
 787   $pkg_svc ? $pkg_svc->part_svc : '';
 788 }
 789
 790 sub _primary_pkg_svc {
 791   my $self = shift;
 792
 793   my $svcdb = scalar(@_) ? shift : [];
 794   $svcdb = ref($svcdb) ? $svcdb : [ $svcdb ];
 795   my %svcdb = map { $_=>1 } @$svcdb;
 796
 797   my @svcdb_pkg_svc =
 798     grep { !scalar(@$svcdb) || $svcdb{ $_->part_svc->svcdb } }
 799          $self->pkg_svc;
 800
 801   my @pkg_svc = grep { $_->primary_svc =~ /^Y/i } @svcdb_pkg_svc;
 802   @pkg_svc = grep {$_->quantity == 1 } @svcdb_pkg_svc
 803     unless @pkg_svc;
 804   return '' if scalar(@pkg_svc) != 1;
 805   $pkg_svc[0];
 806 }
 807
 808 =item svcpart_unique_svcdb SVCDB
 809
 810 Returns the svcpart of a service definition (see L<FS::part_svc>) matching
 811 SVCDB associated with this package definition (see L<FS::pkg_svc>).  Returns
 812 false if there not a primary service definition for SVCDB or there are multiple
 813 service definitions for SVCDB.
 814
 815 =cut
 816
 817 sub svcpart_unique_svcdb {
 818   my( $self, $svcdb ) = @_;
 819   my @svcdb_pkg_svc = grep { ( $svcdb eq $_->part_svc->svcdb ) } $self->pkg_svc;
 820   return '' if scalar(@svcdb_pkg_svc) != 1;
 821   $svcdb_pkg_svc[0]->svcpart;
 822 }
 823
 824 =item payby
 825
 826 Returns a list of the acceptable payment types for this package.  Eventually
 827 this should come out of a database table and be editable, but currently has the
 828 following logic instead:
 829
 830 If the package is free, the single item B<BILL> is
 831 returned, otherwise, the single item B<CARD> is returned.
 832
 833 (CHEK?  LEC?  Probably shouldn't accept those by default, prone to abuse)
 834
 835 =cut
 836
 837 sub payby {
 838   my $self = shift;
 839   if ( $self->is_free ) {
 840     ( 'BILL' );
 841   } else {
 842     ( 'CARD' );
 843   }
 844 }
 845
 846 =item is_free
 847
 848 Returns true if this package is free.
 849
 850 =cut
 851
 852 sub is_free {
 853   my $self = shift;
 854   if ( $self->can('is_free_options') ) {
 855     not grep { $_ !~ /^\s*0*(\.0*)?\s*$/ }
 856          map { $self->option($_) }
 857              $self->is_free_options;
 858   } else {
 859     warn "FS::part_pkg::is_free: FS::part_pkg::". $self->plan. " subclass ".
 860          "provides neither is_free_options nor is_free method; returning false";
 861     0;
 862   }
 863 }
 864
 865 sub can_discount { 0; }
 866
 867 sub can_start_date { 1; }
 868
 869 sub freqs_href {
 870   # moved to FS::Misc to make this accessible to other packages
 871   # at initialization
 872   FS::Misc::pkg_freqs();
 873 }
 874
 875 =item freq_pretty
 876
 877 Returns an english representation of the I<freq> field, such as "monthly",
 878 "weekly", "semi-annually", etc.
 879
 880 =cut
 881
 882 sub freq_pretty {
 883   my $self = shift;
 884   my $freq = $self->freq;
 885
 886   #my $freqs_href = $self->freqs_href;
 887   my $freqs_href = freqs_href();
 888
 889   if ( exists($freqs_href->{$freq}) ) {
 890     $freqs_href->{$freq};
 891   } else {
 892     my $interval = 'month';
 893     if ( $freq =~ /^(\d+)([hdw])$/ ) {
 894       my %interval = ( 'h' => 'hour', 'd'=>'day', 'w'=>'week' );
 895       $interval = $interval{$2};
 896     }
 897     if ( $1 == 1 ) {
 898       "every $interval";
 899     } else {
 900       "every $freq ${interval}s";
 901     }
 902   }
 903 }
 904
 905 =item add_freq TIMESTAMP [ FREQ ]
 906
 907 Adds a billing period of some frequency to the provided timestamp and
 908 returns the resulting timestamp, or -1 if the frequency could not be
 909 parsed (shouldn't happen).  By default, the frequency of this package
 910 will be used; to override this, pass a different frequency as a second
 911 argument.
 912
 913 =cut
 914
 915 sub add_freq {
 916   my( $self, $date, $freq ) = @_;
 917   $freq = $self->freq unless $freq;
 918
 919   #change this bit to use Date::Manip? CAREFUL with timezones (see
 920   # mailing list archive)
 921   my ($sec,$min,$hour,$mday,$mon,$year) = (localtime($date) )[0,1,2,3,4,5];
 922
 923   if ( $freq =~ /^\d+$/ ) {
 924     $mon += $freq;
 925     until ( $mon < 12 ) { $mon -= 12; $year++; }
 926   } elsif ( $freq =~ /^(\d+)w$/ ) {
 927     my $weeks = $1;
 928     $mday += $weeks * 7;
 929   } elsif ( $freq =~ /^(\d+)d$/ ) {
 930     my $days = $1;
 931     $mday += $days;
 932   } elsif ( $freq =~ /^(\d+)h$/ ) {
 933     my $hours = $1;
 934     $hour += $hours;
 935   } else {
 936     return -1;
 937   }
 938
 939   timelocal_nocheck($sec,$min,$hour,$mday,$mon,$year);
 940 }
 941
 942 =item plandata
 943
 944 For backwards compatibility, returns the plandata field as well as all options
 945 from FS::part_pkg_option.
 946
 947 =cut
 948
 949 sub plandata {
 950   my $self = shift;
 951   carp "plandata is deprecated";
 952   if ( @_ ) {
 953     $self->SUPER::plandata(@_);
 954   } else {
 955     my $plandata = $self->get('plandata');
 956     my %options = $self->options;
 957     $plandata .= join('', map { "$_=$options{$_}\n" } keys %options );
 958     $plandata;
 959   }
 960 }
 961
 962 =item part_pkg_vendor
 963
 964 Returns all vendor/external package ids as FS::part_pkg_vendor objects (see
 965 L<FS::part_pkg_vendor>).
 966
 967 =cut
 968
 969 sub part_pkg_vendor {
 970   my $self = shift;
 971   qsearch('part_pkg_vendor', { 'pkgpart' => $self->pkgpart } );
 972 }
 973
 974 =item vendor_pkg_ids
 975
 976 Returns a list of vendor/external package ids by exportnum
 977
 978 =cut
 979
 980 sub vendor_pkg_ids {
 981   my $self = shift;
 982   map { $_->exportnum => $_->vendor_pkg_id } $self->part_pkg_vendor;
 983 }
 984
 985 =item part_pkg_option
 986
 987 Returns all options as FS::part_pkg_option objects (see
 988 L<FS::part_pkg_option>).
 989
 990 =cut
 991
 992 sub part_pkg_option {
 993   my $self = shift;
 994   qsearch('part_pkg_option', { 'pkgpart' => $self->pkgpart } );
 995 }
 996
 997 =item options
 998
 999 Returns a list of option names and values suitable for assigning to a hash.
1000
1001 =cut
1002
1003 sub options {
1004   my $self = shift;
1005   map { $_->optionname => $_->optionvalue } $self->part_pkg_option;
1006 }
1007
1008 =item option OPTIONNAME [ QUIET ]
1009
1010 Returns the option value for the given name, or the empty string.  If a true
1011 value is passed as the second argument, warnings about missing the option
1012 will be suppressed.
1013
1014 =cut
1015
1016 sub option {
1017   my( $self, $opt, $ornull ) = @_;
1018   my $part_pkg_option =
1019     qsearchs('part_pkg_option', {
1020       pkgpart    => $self->pkgpart,
1021       optionname => $opt,
1022   } );
1023   return $part_pkg_option->optionvalue if $part_pkg_option;
1024   my %plandata = map { /^(\w+)=(.*)$/; ( $1 => $2 ); }
1025                      split("\n", $self->get('plandata') );
1026   return $plandata{$opt} if exists $plandata{$opt};
1027   cluck "WARNING: (pkgpart ". $self->pkgpart. ") Package def option $opt ".
1028         "not found in options or plandata!\n"
1029     unless $ornull;
1030   '';
1031 }
1032
1033 =item bill_part_pkg_link
1034
1035 Returns the associated part_pkg_link records (see L<FS::part_pkg_link>).
1036
1037 =cut
1038
1039 sub bill_part_pkg_link {
1040   shift->_part_pkg_link('bill', @_);
1041 }
1042
1043 =item svc_part_pkg_link
1044
1045 Returns the associated part_pkg_link records (see L<FS::part_pkg_link>).
1046
1047 =cut
1048
1049 sub svc_part_pkg_link {
1050   shift->_part_pkg_link('svc', @_);
1051 }
1052
1053 sub _part_pkg_link {
1054   my( $self, $type ) = @_;
1055   qsearch({ table    => 'part_pkg_link',
1056             hashref  => { 'src_pkgpart' => $self->pkgpart,
1057                           'link_type'   => $type,
1058                           #protection against infinite recursive links
1059                           'dst_pkgpart' => { op=>'!=', value=> $self->pkgpart },
1060                         },
1061             order_by => "ORDER BY hidden",
1062          });
1063 }
1064
1065 sub self_and_bill_linked {
1066   shift->_self_and_linked('bill', @_);
1067 }
1068
1069 sub self_and_svc_linked {
1070   shift->_self_and_linked('svc', @_);
1071 }
1072
1073 sub _self_and_linked {
1074   my( $self, $type, $hidden ) = @_;
1075   $hidden ||= '';
1076
1077   my @result = ();
1078   foreach ( ( $self, map { $_->dst_pkg->_self_and_linked($type, $_->hidden) }
1079                      $self->_part_pkg_link($type) ) )
1080   {
1081     $_->hidden($hidden) if $hidden;
1082     push @result, $_;
1083   }
1084
1085   (@result);
1086 }
1087
1088 =item part_pkg_taxoverride [ CLASS ]
1089
1090 Returns all associated FS::part_pkg_taxoverride objects (see
1091 L<FS::part_pkg_taxoverride>).  Limits the returned set to those
1092 of class CLASS if defined.  Class may be one of 'setup', 'recur',
1093 the empty string (default), or a usage class number (see L<FS::usage_class>).
1094 When a class is specified, the empty string class (default) is returned
1095 if no more specific values exist.
1096
1097 =cut
1098
1099 sub part_pkg_taxoverride {
1100   my $self = shift;
1101   my $class = shift;
1102
1103   my $hashref = { 'pkgpart' => $self->pkgpart };
1104   $hashref->{'usage_class'} = $class if defined($class);
1105   my @overrides = qsearch('part_pkg_taxoverride', $hashref );
1106
1107   unless ( scalar(@overrides) || !defined($class) || !$class ){
1108     $hashref->{'usage_class'} = '';
1109     @overrides = qsearch('part_pkg_taxoverride', $hashref );
1110   }
1111
1112   @overrides;
1113 }
1114
1115 =item has_taxproduct
1116
1117 Returns true if this package has any taxproduct associated with it.
1118
1119 =cut
1120
1121 sub has_taxproduct {
1122   my $self = shift;
1123
1124   $self->taxproductnum ||
1125   scalar( grep { $_ =~/^usage_taxproductnum_/ && $self->option($_) }
1126           keys %{ {$self->options} }
1127   )
1128
1129 }
1130
1131
1132 =item taxproduct [ CLASS ]
1133
1134 Returns the associated tax product for this package definition (see
1135 L<FS::part_pkg_taxproduct>).  CLASS may be one of 'setup', 'recur' or
1136 the usage classnum (see L<FS::usage_class>).  Returns the default
1137 tax product for this record if the more specific CLASS value does
1138 not exist.
1139
1140 =cut
1141
1142 sub taxproduct {
1143   my $self = shift;
1144   my $class = shift;
1145
1146   my $part_pkg_taxproduct;
1147
1148   my $taxproductnum = $self->taxproductnum;
1149   if ($class) {
1150     my $class_taxproductnum = $self->option("usage_taxproductnum_$class", 1);
1151     $taxproductnum = $class_taxproductnum
1152       if $class_taxproductnum
1153   }
1154
1155   $part_pkg_taxproduct =
1156     qsearchs( 'part_pkg_taxproduct', { 'taxproductnum' => $taxproductnum } );
1157
1158   unless ($part_pkg_taxproduct || $taxproductnum eq $self->taxproductnum ) {
1159     $taxproductnum = $self->taxproductnum;
1160     $part_pkg_taxproduct =
1161       qsearchs( 'part_pkg_taxproduct', { 'taxproductnum' => $taxproductnum } );
1162   }
1163
1164   $part_pkg_taxproduct;
1165 }
1166
1167 =item taxproduct_description [ CLASS ]
1168
1169 Returns the description of the associated tax product for this package
1170 definition (see L<FS::part_pkg_taxproduct>).
1171
1172 =cut
1173
1174 sub taxproduct_description {
1175   my $self = shift;
1176   my $part_pkg_taxproduct = $self->taxproduct(@_);
1177   $part_pkg_taxproduct ? $part_pkg_taxproduct->description : '';
1178 }
1179
1180 =item part_pkg_taxrate DATA_PROVIDER, GEOCODE, [ CLASS ]
1181
1182 Returns the package to taxrate m2m records for this package in the location
1183 specified by GEOCODE (see L<FS::part_pkg_taxrate>) and usage class CLASS.
1184 CLASS may be one of 'setup', 'recur', or one of the usage classes numbers
1185 (see L<FS::usage_class>).
1186
1187 =cut
1188
1189 sub _expand_cch_taxproductnum {
1190   my $self = shift;
1191   my $class = shift;
1192   my $part_pkg_taxproduct = $self->taxproduct($class);
1193
1194   my ($a,$b,$c,$d) = ( $part_pkg_taxproduct
1195                          ? ( split ':', $part_pkg_taxproduct->taxproduct )
1196                          : ()
1197                      );
1198   $a = '' unless $a; $b = '' unless $b; $c = '' unless $c; $d = '' unless $d;
1199   my $extra_sql = "AND ( taxproduct = '$a:$b:$c:$d'
1200                       OR taxproduct = '$a:$b:$c:'
1201                       OR taxproduct = '$a:$b:".":$d'
1202                       OR taxproduct = '$a:$b:".":' )";
1203   map { $_->taxproductnum } qsearch( { 'table'     => 'part_pkg_taxproduct',
1204                                        'hashref'   => { 'data_vendor'=>'cch' },
1205                                        'extra_sql' => $extra_sql,
1206                                    } );
1207
1208 }
1209
1210 sub part_pkg_taxrate {
1211   my $self = shift;
1212   my ($data_vendor, $geocode, $class) = @_;
1213
1214   my $dbh = dbh;
1215   my $extra_sql = 'WHERE part_pkg_taxproduct.data_vendor = '.
1216                   dbh->quote($data_vendor);
1217
1218   # CCH oddness in m2m
1219   $extra_sql .= ' AND ('.
1220     join(' OR ', map{ 'geocode = '. $dbh->quote(substr($geocode, 0, $_)) }
1221                  qw(10 5 2)
1222         ).
1223     ')';
1224   # much more CCH oddness in m2m -- this is kludgy
1225   my @tpnums = $self->_expand_cch_taxproductnum($class);
1226   if (scalar(@tpnums)) {
1227     $extra_sql .= ' AND ('.
1228                             join(' OR ', map{ "taxproductnum = $_" } @tpnums ).
1229                        ')';
1230   } else {
1231     $extra_sql .= ' AND ( 0 = 1 )';
1232   }
1233
1234   my $addl_from = 'LEFT JOIN part_pkg_taxproduct USING ( taxproductnum )';
1235   my $order_by = 'ORDER BY taxclassnum, length(geocode) desc, length(taxproduct) desc';
1236   my $select   = 'DISTINCT ON(taxclassnum) *, taxproduct';
1237
1238   # should qsearch preface columns with the table to facilitate joins?
1239   qsearch( { 'table'     => 'part_pkg_taxrate',
1240              'select'    => $select,
1241              'hashref'   => { # 'data_vendor'   => $data_vendor,
1242                               # 'taxproductnum' => $self->taxproductnum,
1243                             },
1244              'addl_from' => $addl_from,
1245              'extra_sql' => $extra_sql,
1246              'order_by'  => $order_by,
1247          } );
1248 }
1249
1250 =item part_pkg_discount
1251
1252 Returns the package to discount m2m records (see L<FS::part_pkg_discount>)
1253 for this package.
1254
1255 =cut
1256
1257 sub part_pkg_discount {
1258   my $self = shift;
1259   qsearch('part_pkg_discount', { 'pkgpart' => $self->pkgpart });
1260 }
1261
1262 =item _rebless
1263
1264 Reblesses the object into the FS::part_pkg::PLAN class (if available), where
1265 PLAN is the object's I<plan> field.  There should be better docs
1266 on how to create new price plans, but until then, see L</NEW PLAN CLASSES>.
1267
1268 =cut
1269
1270 sub _rebless {
1271   my $self = shift;
1272   my $plan = $self->plan;
1273   unless ( $plan ) {
1274     cluck "no price plan found for pkgpart ". $self->pkgpart. "\n"
1275       if $DEBUG;
1276     return $self;
1277   }
1278   return $self if ref($self) =~ /::$plan$/; #already blessed into plan subclass
1279   my $class = ref($self). "::$plan";
1280   warn "reblessing $self into $class" if $DEBUG;
1281   eval "use $class;";
1282   die $@ if $@;
1283   bless($self, $class) unless $@;
1284   $self;
1285 }
1286
1287 #fatal fallbacks
1288 sub calc_setup { die 'no calc_setup for '. shift->plan. "\n"; }
1289 sub calc_recur { die 'no calc_recur for '. shift->plan. "\n"; }
1290
1291 #fallback that return 0 for old legacy packages with no plan
1292 sub calc_remain { 0; }
1293 sub calc_cancel { 0; }
1294 sub calc_units  { 0; }
1295
1296 #fallback for everything except bulk.pm
1297 sub hide_svc_detail { 0; }
1298
1299 #fallback for packages that can't/won't summarize usage
1300 sub sum_usage { 0; }
1301
1302 =item recur_cost_permonth CUST_PKG
1303
1304 recur_cost divided by freq (only supported for monthly and longer frequencies)
1305
1306 =cut
1307
1308 sub recur_cost_permonth {
1309   my($self, $cust_pkg) = @_;
1310   return 0 unless $self->freq =~ /^\d+$/ && $self->freq > 0;
1311   sprintf('%.2f', $self->recur_cost / $self->freq );
1312 }
1313
1314 =item format OPTION DATA
1315
1316 Returns data formatted according to the function 'format' described
1317 in the plan info.  Returns DATA if no such function exists.
1318
1319 =cut
1320
1321 sub format {
1322   my ($self, $option, $data) = (shift, shift, shift);
1323   if (exists($plans{$self->plan}->{fields}->{$option}{format})) {
1324     &{$plans{$self->plan}->{fields}->{$option}{format}}($data);
1325   }else{
1326     $data;
1327   }
1328 }
1329
1330 =item parse OPTION DATA
1331
1332 Returns data parsed according to the function 'parse' described
1333 in the plan info.  Returns DATA if no such function exists.
1334
1335 =cut
1336
1337 sub parse {
1338   my ($self, $option, $data) = (shift, shift, shift);
1339   if (exists($plans{$self->plan}->{fields}->{$option}{parse})) {
1340     &{$plans{$self->plan}->{fields}->{$option}{parse}}($data);
1341   }else{
1342     $data;
1343   }
1344 }
1345
1346 =back
1347
1348 =cut
1349
1350 =head1 CLASS METHODS
1351
1352 =over 4
1353
1354 =cut
1355
1356 # _upgrade_data
1357 #
1358 # Used by FS::Upgrade to migrate to a new database.
1359
1360 sub _upgrade_data { # class method
1361   my($class, %opts) = @_;
1362
1363   warn "[FS::part_pkg] upgrading $class\n" if $DEBUG;
1364
1365   my @part_pkg = qsearch({
1366     'table'     => 'part_pkg',
1367     'extra_sql' => "WHERE ". join(' OR ',
1368                      'plan IS NULL', "plan = '' ",
1369                    ),
1370   });
1371
1372   foreach my $part_pkg (@part_pkg) {
1373
1374     unless ( $part_pkg->plan ) {
1375       $part_pkg->plan('flat');
1376     }
1377
1378     $part_pkg->replace;
1379
1380   }
1381
1382   # now upgrade to the explicit custom flag
1383
1384   @part_pkg = qsearch({
1385     'table'     => 'part_pkg',
1386     'hashref'   => { disabled => 'Y', custom => '' },
1387     'extra_sql' => "AND comment LIKE '(CUSTOM) %'",
1388   });
1389
1390   foreach my $part_pkg (@part_pkg) {
1391     my $new = new FS::part_pkg { $part_pkg->hash };
1392     $new->custom('Y');
1393     my $comment = $part_pkg->comment;
1394     $comment =~ s/^\(CUSTOM\) //;
1395     $comment = '(none)' unless $comment =~ /\S/;
1396     $new->comment($comment);
1397
1398     my $pkg_svc = { map { $_->svcpart => $_->quantity } $part_pkg->pkg_svc };
1399     my $primary = $part_pkg->svcpart;
1400     my $options = { $part_pkg->options };
1401
1402     my $error = $new->replace( $part_pkg,
1403                                'pkg_svc'     => $pkg_svc,
1404                                'primary_svc' => $primary,
1405                                'options'     => $options,
1406                              );
1407     die $error if $error;
1408   }
1409
1410   my @part_pkg_option = qsearch('part_pkg_option',
1411     { 'optionname'  => 'unused_credit',
1412       'optionvalue' => 1,
1413     });
1414   foreach my $old_opt (@part_pkg_option) {
1415     my $pkgpart = $old_opt->pkgpart;
1416     my $error = $old_opt->delete;
1417     die $error if $error;
1418
1419     foreach (qw(unused_credit_cancel unused_credit_change)) {
1420       my $new_opt = new FS::part_pkg_option {
1421         'pkgpart'     => $pkgpart,
1422         'optionname'  => $_,
1423         'optionvalue' => 1,
1424       };
1425       $error = $new_opt->insert;
1426       die $error if $error;
1427     }
1428   }
1429
1430   # migrate use_disposition_taqua and use_disposition to disposition_in
1431   @part_pkg_option = qsearch('part_pkg_option',
1432     { 'optionname'  => { op => 'LIKE',
1433                          value => 'use_disposition%',
1434                        },
1435       'optionvalue' => 1,
1436     });
1437   my %newopts = map { $_->pkgpart => $_ }
1438     qsearch('part_pkg_option',  { 'optionname'  => 'disposition_in', } );
1439   foreach my $old_opt (@part_pkg_option) {
1440         my $pkgpart = $old_opt->pkgpart;
1441         my $newval = $old_opt->optionname eq 'use_disposition_taqua' ? '100'
1442                                                                   : 'ANSWERED';
1443         my $error = $old_opt->delete;
1444         die $error if $error;
1445
1446         if ( exists($newopts{$pkgpart}) ) {
1447             my $opt = $newopts{$pkgpart};
1448             $opt->optionvalue($opt->optionvalue.",$newval");
1449             $error = $opt->replace;
1450             die $error if $error;
1451         } else {
1452             my $new_opt = new FS::part_pkg_option {
1453                 'pkgpart'     => $pkgpart,
1454                 'optionname'  => 'disposition_in',
1455                 'optionvalue' => $newval,
1456               };
1457               $error = $new_opt->insert;
1458               die $error if $error;
1459               $newopts{$pkgpart} = $new_opt;
1460         }
1461   }
1462
1463 }
1464
1465 =item curuser_pkgs_sql
1466
1467 Returns an SQL fragment for searching for packages the current user can
1468 use, either via part_pkg.agentnum directly, or via agent type (see
1469 L<FS::type_pkgs>).
1470
1471 =cut
1472
1473 sub curuser_pkgs_sql {
1474   my $class = shift;
1475
1476   $class->_pkgs_sql( $FS::CurrentUser::CurrentUser->agentnums );
1477
1478 }
1479
1480 =item agent_pkgs_sql AGENT | AGENTNUM, ...
1481
1482 Returns an SQL fragment for searching for packages the provided agent or agents
1483 can use, either via part_pkg.agentnum directly, or via agent type (see
1484 L<FS::type_pkgs>).
1485
1486 =cut
1487
1488 sub agent_pkgs_sql {
1489   my $class = shift;  #i'm a class method, not a sub (the question is... why??)
1490   my @agentnums = map { ref($_) ? $_->agentnum : $_ } @_;
1491
1492   $class->_pkgs_sql(@agentnums); #is this why
1493
1494 }
1495
1496 sub _pkgs_sql {
1497   my( $class, @agentnums ) = @_;
1498   my $agentnums = join(',', @agentnums);
1499
1500   "
1501     (
1502       ( agentnum IS NOT NULL AND agentnum IN ($agentnums) )
1503       OR ( agentnum IS NULL
1504            AND EXISTS ( SELECT 1
1505                           FROM type_pkgs
1506                             LEFT JOIN agent_type USING ( typenum )
1507                             LEFT JOIN agent AS typeagent USING ( typenum )
1508                           WHERE type_pkgs.pkgpart = part_pkg.pkgpart
1509                             AND typeagent.agentnum IN ($agentnums)
1510                       )
1511          )
1512     )
1513   ";
1514
1515 }
1516
1517 =back
1518
1519 =head1 SUBROUTINES
1520
1521 =over 4
1522
1523 =item plan_info
1524
1525 =cut
1526
1527 #false laziness w/part_export & cdr
1528 my %info;
1529 foreach my $INC ( @INC ) {
1530   warn "globbing $INC/FS/part_pkg/*.pm\n" if $DEBUG;
1531   foreach my $file ( glob("$INC/FS/part_pkg/*.pm") ) {
1532     warn "attempting to load plan info from $file\n" if $DEBUG;
1533     $file =~ /\/(\w+)\.pm$/ or do {
1534       warn "unrecognized file in $INC/FS/part_pkg/: $file\n";
1535       next;
1536     };
1537     my $mod = $1;
1538     my $info = eval "use FS::part_pkg::$mod; ".
1539                     "\\%FS::part_pkg::$mod\::info;";
1540     if ( $@ ) {
1541       die "error using FS::part_pkg::$mod (skipping): $@\n" if $@;
1542       next;
1543     }
1544     unless ( keys %$info ) {
1545       warn "no %info hash found in FS::part_pkg::$mod, skipping\n";
1546       next;
1547     }
1548     warn "got plan info from FS::part_pkg::$mod: $info\n" if $DEBUG;
1549     #if ( exists($info->{'disabled'}) && $info->{'disabled'} ) {
1550     #  warn "skipping disabled plan FS::part_pkg::$mod" if $DEBUG;
1551     #  next;
1552     #}
1553     $info{$mod} = $info;
1554     $info->{'weight'} ||= 0; # quiet warnings
1555   }
1556 }
1557
1558 # copy one level deep to allow replacement of fields and fieldorder
1559 tie %plans, 'Tie::IxHash',
1560   map  { my %infohash = %{ $info{$_} };
1561           $_ => \%infohash }
1562   sort { $info{$a}->{'weight'} <=> $info{$b}->{'weight'} }
1563   keys %info;
1564
1565 # inheritance of plan options
1566 foreach my $name (keys(%info)) {
1567   if (exists($info{$name}->{'disabled'}) and $info{$name}->{'disabled'}) {
1568     warn "skipping disabled plan FS::part_pkg::$name" if $DEBUG;
1569     delete $plans{$name};
1570     next;
1571   }
1572   my $parents = $info{$name}->{'inherit_fields'} || [];
1573   my (%fields, %field_exists, @fieldorder);
1574   foreach my $parent ($name, @$parents) {
1575     if ( !exists($info{$parent}) ) {
1576       warn "$name tried to inherit from nonexistent '$parent'\n";
1577       next;
1578     }
1579     %fields = ( # avoid replacing existing fields
1580       %{ $info{$parent}->{'fields'} || {} },
1581       %fields
1582     );
1583     foreach (@{ $info{$parent}->{'fieldorder'} || [] }) {
1584       # avoid duplicates
1585       next if $field_exists{$_};
1586       $field_exists{$_} = 1;
1587       # allow inheritors to remove inherited fields from the fieldorder
1588       push @fieldorder, $_ if !exists($fields{$_}) or
1589                               !exists($fields{$_}->{'disabled'});
1590     }
1591   }
1592   $plans{$name}->{'fields'} = \%fields;
1593   $plans{$name}->{'fieldorder'} = \@fieldorder;
1594 }
1595
1596 sub plan_info {
1597   \%plans;
1598 }
1599
1600
1601 =back
1602
1603 =head1 NEW PLAN CLASSES
1604
1605 A module should be added in FS/FS/part_pkg/  Eventually, an example may be
1606 found in eg/plan_template.pm.  Until then, it is suggested that you use the
1607 other modules in FS/FS/part_pkg/ as a guide.
1608
1609 =head1 BUGS
1610
1611 The delete method is unimplemented.
1612
1613 setup and recur semantics are not yet defined (and are implemented in
1614 FS::cust_bill.  hmm.).  now they're deprecated and need to go.
1615
1616 plandata should go
1617
1618 part_pkg_taxrate is Pg specific
1619
1620 replace should be smarter about managing the related tables (options, pkg_svc)
1621
1622 =head1 SEE ALSO
1623
1624 L<FS::Record>, L<FS::cust_pkg>, L<FS::type_pkgs>, L<FS::pkg_svc>, L<Safe>.
1625 schema.html from the base documentation.
1626
1627 =cut
1628
1629 1;
1630