FS/FS/part_export/sqlradius.pm

   1 package FS::part_export::sqlradius;
   2
   3 use vars qw(@ISA);
   4 use FS::Record qw( dbh );
   5 use FS::part_export;
   6
   7 @ISA = qw(FS::part_export);
   8
   9 sub rebless { shift; }
  10
  11 sub _export_insert {
  12   my($self, $svc_acct) = (shift, shift);
  13
  14   foreach my $table (qw(reply check)) {
  15     my $method = "radius_$table";
  16     my %attrib = $svc_acct->$method();
  17     next unless keys %attrib;
  18     my $err_or_queue = $self->sqlradius_queue( $svc_acct->svcnum, 'insert',
  19       $table, $svc_acct->username, %attrib );
  20     return $err_or_queue unless ref($err_or_queue);
  21   }
  22   my @groups = $svc_acct->radius_groups;
  23   if ( @groups ) {
  24     my $err_or_queue = $self->sqlradius_queue(
  25       $svc_acct->svcnum, 'usergroup_insert',
  26       $svc_acct->username, @groups );
  27     return $err_or_queue unless ref($err_or_queue);
  28   }
  29   '';
  30 }
  31
  32 sub _export_replace {
  33   my( $self, $new, $old ) = (shift, shift, shift);
  34
  35   local $SIG{HUP} = 'IGNORE';
  36   local $SIG{INT} = 'IGNORE';
  37   local $SIG{QUIT} = 'IGNORE';
  38   local $SIG{TERM} = 'IGNORE';
  39   local $SIG{TSTP} = 'IGNORE';
  40   local $SIG{PIPE} = 'IGNORE';
  41
  42   my $oldAutoCommit = $FS::UID::AutoCommit;
  43   local $FS::UID::AutoCommit = 0;
  44   my $dbh = dbh;
  45
  46   my $jobnum = '';
  47   if ( $old->username ne $new->username ) {
  48     my $err_or_queue = $self->sqlradius_queue( $new->svcnum, 'rename',
  49       $new->username, $old->username );
  50     unless ( ref($err_or_queue) ) {
  51       $dbh->rollback if $oldAutoCommit;
  52       return $err_or_queue;
  53     }
  54     $jobnum = $err_or_queue->jobnum;
  55   }
  56
  57   foreach my $table (qw(reply check)) {
  58     my $method = "radius_$table";
  59     my %new = $new->$method();
  60     my %old = $old->$method();
  61     if ( grep { !exists $old{$_} #new attributes
  62                 || $new{$_} ne $old{$_} #changed
  63               } keys %new
  64     ) {
  65       my $err_or_queue = $self->sqlradius_queue( $new->svcnum, 'insert',
  66         $table, $new->username, %new );
  67       unless ( ref($err_or_queue) ) {
  68         $dbh->rollback if $oldAutoCommit;
  69         return $err_or_queue;
  70       }
  71       if ( $jobnum ) {
  72         my $error = $err_or_queue->depend_insert( $jobnum );
  73         if ( $error ) {
  74           $dbh->rollback if $oldAutoCommit;
  75           return $error;
  76         }
  77       }
  78     }
  79
  80     my @del = grep { !exists $new{$_} } keys %old;
  81     if ( @del ) {
  82       my $err_or_queue = $self->sqlradius_queue( $new->svcnum, 'attrib_delete',
  83         $table, $new->username, @del );
  84       unless ( ref($err_or_queue) ) {
  85         $dbh->rollback if $oldAutoCommit;
  86         return $err_or_queue;
  87       }
  88       if ( $jobnum ) {
  89         my $error = $err_or_queue->depend_insert( $jobnum );
  90         if ( $error ) {
  91           $dbh->rollback if $oldAutoCommit;
  92           return $error;
  93         }
  94       }
  95     }
  96   }
  97
  98   # (sorta) false laziness with FS::svc_acct::replace
  99   my @oldgroups = @{$old->usergroup}; #uuuh
 100   my @newgroups = $new->radius_groups;
 101   my @delgroups = ();
 102   foreach my $oldgroup ( @oldgroups ) {
 103     if ( grep { $oldgroup eq $_ } @newgroups ) {
 104       @newgroups = grep { $oldgroup ne $_ } @newgroups;
 105       next;
 106     }
 107     push @delgroups, $oldgroup;
 108   }
 109
 110   if ( @delgroups ) {
 111     my $err_or_queue = $self->sqlradius_queue( $new->svcnum, 'usergroup_delete',
 112       $new->username, @delgroups );
 113     unless ( ref($err_or_queue) ) {
 114       $dbh->rollback if $oldAutoCommit;
 115       return $err_or_queue;
 116     }
 117     if ( $jobnum ) {
 118       my $error = $err_or_queue->depend_insert( $jobnum );
 119       if ( $error ) {
 120         $dbh->rollback if $oldAutoCommit;
 121         return $error;
 122       }
 123     }
 124   }
 125
 126   if ( @newgroups ) {
 127     my $err_or_queue = $self->sqlradius_queue( $new->svcnum, 'usergroup_insert',
 128       $new->username, @newgroups );
 129     unless ( ref($err_or_queue) ) {
 130       $dbh->rollback if $oldAutoCommit;
 131       return $err_or_queue;
 132     }
 133     if ( $jobnum ) {
 134       my $error = $err_or_queue->depend_insert( $jobnum );
 135       if ( $error ) {
 136         $dbh->rollback if $oldAutoCommit;
 137         return $error;
 138       }
 139     }
 140   }
 141
 142   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 143
 144   '';
 145 }
 146
 147 sub _export_delete {
 148   my( $self, $svc_acct ) = (shift, shift);
 149   my $err_or_queue = $self->sqlradius_queue( $svc_acct->svcnum, 'delete',
 150     $svc_acct->username );
 151   ref($err_or_queue) ? '' : $err_or_queue;
 152 }
 153
 154 sub sqlradius_queue {
 155   my( $self, $svcnum, $method ) = (shift, shift, shift);
 156   my $queue = new FS::queue {
 157     'svcnum' => $svcnum,
 158     'job'    => "FS::part_export::sqlradius::sqlradius_$method",
 159   };
 160   $queue->insert(
 161     $self->option('datasrc'),
 162     $self->option('username'),
 163     $self->option('password'),
 164     @_,
 165   ) or $queue;
 166 }
 167
 168 sub sqlradius_insert { #subroutine, not method
 169   my $dbh = sqlradius_connect(shift, shift, shift);
 170   my( $table, $username, %attributes ) = @_;
 171
 172   foreach my $attribute ( keys %attributes ) {
 173
 174     my $s_sth = $dbh->prepare(
 175       "SELECT COUNT(*) FROM rad$table WHERE UserName = ? AND Attribute = ?"
 176     ) or die $dbh->errstr;
 177     $s_sth->execute( $username, $attribute ) or die $s_sth->errstr;
 178
 179     if ( $s_sth->fetchrow_arrayref->[0] ) {
 180
 181       my $u_sth = $dbh->prepare(
 182         "UPDATE rad$table SET Value = ? WHERE UserName = ? AND Attribute = ?"
 183       ) or die $dbh->errstr;
 184       $u_sth->execute($attributes{$attribute}, $username, $attribute)
 185         or die $u_sth->errstr;
 186
 187     } else {
 188
 189       my $i_sth = $dbh->prepare(
 190         "INSERT INTO rad$table ( id, UserName, Attribute, Value ) ".
 191           "VALUES ( ?, ?, ?, ? )"
 192       ) or die $dbh->errstr;
 193       $i_sth->execute( '', $username, $attribute, $attributes{$attribute} )
 194         or die $i_sth->errstr;
 195
 196     }
 197
 198   }
 199   $dbh->disconnect;
 200 }
 201
 202 sub sqlradius_usergroup_insert { #subroutine, not method
 203   my $dbh = sqlradius_connect(shift, shift, shift);
 204   my( $username, @groups ) = @_;
 205
 206   my $sth = $dbh->prepare(
 207     "INSERT INTO usergroup ( id, UserName, GroupName ) VALUES ( ?, ?, ? )"
 208   ) or die $dbh->errstr;
 209   foreach my $group ( @groups ) {
 210     $sth->execute( '', $username, $group )
 211       or die "can't insert into groupname table: ". $sth->errstr;
 212   }
 213   $dbh->disconnect;
 214 }
 215
 216 sub sqlradius_usergroup_delete { #subroutine, not method
 217   my $dbh = sqlradius_connect(shift, shift, shift);
 218   my( $username, @groups ) = @_;
 219
 220   my $sth = $dbh->prepare(
 221     "DELETE FROM usergroup WHERE UserName = ? AND GroupName = ?"
 222   ) or die $dbh->errstr;
 223   foreach my $group ( @groups ) {
 224     $sth->execute( $username, $group )
 225       or die "can't delete from groupname table: ". $sth->errstr;
 226   }
 227   $dbh->disconnect;
 228 }
 229
 230 sub sqlradius_rename { #subroutine, not method
 231   my $dbh = sqlradius_connect(shift, shift, shift);
 232   my($new_username, $old_username) = @_;
 233   foreach my $table (qw(radreply radcheck usergroup )) {
 234     my $sth = $dbh->prepare("UPDATE $table SET Username = ? WHERE UserName = ?")
 235       or die $dbh->errstr;
 236     $sth->execute($new_username, $old_username)
 237       or die "can't update $table: ". $sth->errstr;
 238   }
 239   $dbh->disconnect;
 240 }
 241
 242 sub sqlradius_attrib_delete { #subroutine, not method
 243   my $dbh = sqlradius_connect(shift, shift, shift);
 244   my( $table, $username, @attrib ) = @_;
 245
 246   foreach my $attribute ( @attrib ) {
 247     my $sth = $dbh->prepare(
 248         "DELETE FROM rad$table WHERE UserName = ? AND Attribute = ?" )
 249       or die $dbh->errstr;
 250     $sth->execute($username,$attribute)
 251       or die "can't delete from rad$table table: ". $sth->errstr;
 252   }
 253   $dbh->disconnect;
 254 }
 255
 256 sub sqlradius_delete { #subroutine, not method
 257   my $dbh = sqlradius_connect(shift, shift, shift);
 258   my $username = shift;
 259
 260   foreach my $table (qw( radcheck radreply usergroup )) {
 261     my $sth = $dbh->prepare( "DELETE FROM $table WHERE UserName = ?" );
 262     $sth->execute($username)
 263       or die "can't delete from $table table: ". $sth->errstr;
 264   }
 265   $dbh->disconnect;
 266 }
 267
 268 sub sqlradius_connect {
 269   #my($datasrc, $username, $password) = @_;
 270   #DBI->connect($datasrc, $username, $password) or die $DBI::errstr;
 271   DBI->connect(@_) or die $DBI::errstr;
 272 }
 273