FS/FS/part_export/artera_turbo.pm

   1 package FS::part_export::artera_turbo;
   2
   3 use vars qw(@ISA %info);
   4 use Tie::IxHash;
   5 use FS::Record qw(qsearch);
   6 use FS::part_export;
   7 use FS::cust_svc;
   8 use FS::svc_external;
   9
  10 @ISA = qw(FS::part_export);
  11
  12 tie my %options, 'Tie::IxHash',
  13   'rid'        => { 'label' => 'Reseller ID (RID)' },
  14   'username'   => { 'label' => 'Reseller username', },
  15   'password'   => { 'label' => 'Reseller password', },
  16   'pid'        => { 'label' => 'Artera Product ID', },
  17   'priceid'    => { 'label' => 'Artera Price ID', },
  18   'agent_aid'  => { 'label' => 'Export agentnum values to Artera AID',
  19                     'type'  => 'checkbox',
  20                   },
  21   'production' => { 'label' => 'Production mode (leave unchecked for staging)',
  22                     'type'  => 'checkbox',
  23                   },
  24 ;
  25
  26 %info = (
  27   'svc'      => 'svc_external',
  28   #'svc'      => [qw( svc_acct svc_forward )],
  29   'desc'     =>
  30     'Real-time export to Artera Turbo Reseller API',
  31   'options'  => \%options,
  32   #'nodomain' => 'Y',
  33   'notes'    => <<'END'
  34 Real-time export to <a href="http://www.arteraturbo.com/">Artera Turbo</a>
  35 Reseller API.  Requires installation of
  36 <a href="http://search.cpan.org/dist/Net-Artera">Net::Artera</a>
  37 from CPAN.  You probably also want to:
  38 <UL>
  39   <LI>In the configuraiton UI section: set the <B>svc_external-skip_manual</B> and <B>svc_external-display_type</B> configuration values.
  40   <LI>In the message catalog: set <B>svc_external-id</B> to <I>Artera Serial Number</I> and set <B>svc_external-title</B> to <I>Artera Key Code</I>.
  41 </UL>
  42 END
  43 );
  44
  45 sub rebless { shift; }
  46
  47 sub _new_Artera {
  48   my $self = shift;
  49
  50   my $artera = new Net::Artera (
  51     map { $_ => $self->option($_) }
  52         qw( rid username password production )
  53   );
  54 }
  55
  56
  57 sub _export_insert {
  58   my($self, $svc_external) = (shift, shift);
  59
  60   # want the ASN (serial) and AKC (key code) right away
  61
  62   eval "use Net::Artera;";
  63   return $@ if $@;
  64
  65   my $artera = $self->_new_Artera;
  66
  67   my $cust_pkg = $svc_external->cust_svc->cust_pkg;
  68   my $part_pkg = $cust_pkg->part_pkg;
  69   my @svc_acct = grep { $_->table eq 'svc_acct' }
  70                  map { $_->svc_x }
  71                  sort { my $svcpart = $part_pkg->svcpart('svc_acct');
  72                         ($b->svcpart==$svcpart) cmp ($a->svcpart==$svcpart); }
  73                  qsearch('cust_svc', { 'pkgnum' => $cust_pkg->pkgnum } );
  74   my $email = scalar(@svc_acct) ? $svc_acct[0]->email : '';
  75
  76   my $cust_main = $cust_pkg->cust_main;
  77
  78   my $result = $artera->newOrder(
  79     'pid'     => $self->option('pid'),
  80     'priceid' => $self->option('priceid'),
  81     'email'   => $email,
  82     'cname'   => $cust_main->name,
  83     'ref'     => $svc_external->svcnum,
  84     'aid'     => ( $self->option('agent_aid') ? $cust_main->agentnum : '' ),
  85     'add1'    => $cust_main->address1,
  86     'add2'    => $cust_main->address2,
  87     'add3'    => $cust_main->city,
  88     'add4'    => $cust_main->state,
  89     'zip'     => $cust_main->zip,
  90     'cid'     => $cust_main->country,
  91     'phone'   => $cust_main->daytime || $cust_main->night,
  92     'fax'     => $cust_main->fax,
  93   );
  94
  95   if ( $result->{'id'} == 1 ) {
  96     my $new = new FS::svc_external { $svc_external->hash };
  97     $new->id($result->{'ASN'});
  98     $new->title($result->{'AKC'});
  99     $new->replace($svc_external);
 100   } else {
 101     $result->{'message'} || 'No response from Artera';
 102   }
 103 }
 104
 105 sub _export_replace {
 106   my( $self, $new, $old ) = (shift, shift, shift);
 107   return "can't change serial number with Artera"
 108     if $old->id != $new->id && $old->id;
 109   return "can't change key code with Artera"
 110     if $old->title ne $new->title && $old->title;
 111   '';
 112 }
 113
 114 sub _export_delete {
 115   my( $self, $svc_external ) = (shift, shift);
 116   $self->StatusChange(17, $svc_external);
 117 }
 118
 119 sub _export_suspend {
 120   my( $self, $svc_external ) = (shift, shift);
 121   $self->StatusChange(16, $svc_external);
 122 }
 123
 124 sub _export_unsuspend {
 125   my( $self, $svc_external ) = (shift, shift);
 126   $self->StatusChange(15, $svc_external);
 127 }
 128
 129 sub StatusChange {
 130   my( $self, $status, $svc_external ) = @_;
 131
 132   my $artera = $self->_new_Artera;
 133
 134   my $result = $artera->StatusChange(
 135     'asn'      => sprintf('%010d', $svc_external->id),
 136     'akc'      => $svc_external->title,
 137     'statusid' => $status,
 138   );
 139
 140   $result->{'id'} == 1
 141     ? ''
 142     : $result->{'message'};
 143 }
 144
 145 1;
 146